New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 2674

Last change on this file since 2674 was 2674, checked in by rblod, 12 years ago

First set of changes in OPA_SRC to ensure AGRIF compatibility

  • Property svn:keywords set to Id
File size: 28.8 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            4.0  ! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!----------------------------------------------------------------------
31
32   !!----------------------------------------------------------------------
33   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
34   !!   nemo_init      : initialization of the NEMO system
35   !!   nemo_ctl       : initialisation of the contol print
36   !!   nemo_closefile : close remaining open files
37   !!   nemo_alloc     : dynamical allocation
38   !!   nemo_partition : calculate MPP domain decomposition
39   !!   factorise      : calculate the factors of the no. of MPI processes
40   !!----------------------------------------------------------------------
41   USE step_oce        ! module used in the ocean time stepping module
42   USE sbc_oce         ! surface boundary condition: ocean
43   USE cla             ! cross land advection               (tra_cla routine)
44   USE domcfg          ! domain configuration               (dom_cfg routine)
45   USE mppini          ! shared/distributed memory setting (mpp_init routine)
46   USE domain          ! domain initialization             (dom_init routine)
47   USE obcini          ! open boundary cond. initialization (obc_ini routine)
48   USE bdyini          ! unstructured open boundary cond. initialization (bdy_init routine)
49   USE istate          ! initial state setting          (istate_init routine)
50   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
51   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
52   USE zdfini          ! vertical physics setting          (zdf_init routine)
53   USE phycst          ! physical constant                  (par_cst routine)
54   USE trdmod          ! momentum/tracers trends       (trd_mod_init routine)
55   USE asminc          ! assimilation increments       (asm_inc_init routine)
56   USE asmtrj          ! writing out state trajectory
57   USE sshwzv          ! vertical velocity used in asm
58   USE diaptr          ! poleward transports           (dia_ptr_init routine)
59   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
60   USE step            ! NEMO time-stepping                 (stp     routine)
61#if defined key_oasis3
62   USE cpl_oasis3      ! OASIS3 coupling
63#elif defined key_oasis4
64   USE cpl_oasis4      ! OASIS4 coupling (not working)
65#endif
66   USE c1d             ! 1D configuration
67   USE step_c1d        ! Time stepping loop for the 1D configuration
68#if defined key_top
69   USE trcini          ! passive tracer initialisation
70#endif
71   USE lib_mpp         ! distributed memory computing
72#if defined key_iomput
73   USE mod_ioclient
74#endif
75
76   IMPLICIT NONE
77   PRIVATE
78
79   PUBLIC   nemo_gcm    ! called by model.F90
80   PUBLIC   nemo_init   ! needed by AGRIF
81
82   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
83
84   !!----------------------------------------------------------------------
85   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
86   !! $Id$
87   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
88   !!----------------------------------------------------------------------
89CONTAINS
90
91   SUBROUTINE nemo_gcm
92      !!----------------------------------------------------------------------
93      !!                     ***  ROUTINE nemo_gcm  ***
94      !!
95      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
96      !!              curvilinear mesh on the sphere.
97      !!
98      !! ** Method  : - model general initialization
99      !!              - launch the time-stepping (stp routine)
100      !!              - finalize the run by closing files and communications
101      !!
102      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
103      !!              Madec, 2008, internal report, IPSL.
104      !!----------------------------------------------------------------------
105      INTEGER ::   istp       ! time step index
106      !!----------------------------------------------------------------------
107      !
108#if defined key_agrif
109      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
110#endif
111
112      !                            !-----------------------!
113      CALL nemo_init               !==  Initialisations  ==!
114      !                            !-----------------------!
115#if defined key_agrif
116      CALL Agrif_Declare_Variables()      ! AGRIF: set the meshes
117#endif
118      ! check that all process are still there... If some process have an error,
119      ! they will never enter in step and other processes will wait until the end of the cpu time!
120      IF( lk_mpp )   CALL mpp_max( nstop )
121
122      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
123
124      !                            !-----------------------!
125      !                            !==   time stepping   ==!
126      !                            !-----------------------!
127      istp = nit000
128#if defined key_c1d
129         DO WHILE ( istp <= nitend .AND. nstop == 0 )
130            CALL stp_c1d( istp )
131            istp = istp + 1
132         END DO
133#else
134          IF( lk_asminc ) THEN
135             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
136             IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 )    ! Output trajectory fields
137             IF( ln_asmdin ) THEN                        ! Direct initialization
138                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
139                IF( ln_dyninc ) THEN
140                   CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
141                   IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 )      ! update vertical velocity
142                ENDIF
143                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
144             ENDIF
145          ENDIF
146       
147         DO WHILE ( istp <= nitend .AND. nstop == 0 )
148#if defined key_agrif
149            CALL Agrif_Step( stp )           ! AGRIF: time stepping
150#else
151            CALL stp( istp )                 ! standard time stepping
152#endif
153            istp = istp + 1
154            IF( lk_mpp )   CALL mpp_max( nstop )
155         END DO
156#endif
157
158      IF( lk_diaobs ) CALL dia_obs_wri
159       
160      !                            !------------------------!
161      !                            !==  finalize the run  ==!
162      !                            !------------------------!
163      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
164      !
165      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
166         WRITE(numout,cform_err)
167         WRITE(numout,*) nstop, ' error have been found' 
168      ENDIF
169      !
170      CALL nemo_closefile
171#if defined key_oasis3 || defined key_oasis4
172      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
173#else
174      IF( lk_mpp )   CALL mppstop       ! end mpp communications
175#endif
176      !
177   END SUBROUTINE nemo_gcm
178
179
180   SUBROUTINE nemo_init
181      !!----------------------------------------------------------------------
182      !!                     ***  ROUTINE nemo_init  ***
183      !!
184      !! ** Purpose :   initialization of the NEMO GCM
185      !!----------------------------------------------------------------------
186      INTEGER ::   ji            ! dummy loop indices
187      INTEGER ::   ilocal_comm   ! local integer
188      CHARACTER(len=80), DIMENSION(16) ::   cltxt
189      !!
190      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
191         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle, nn_bench
192      !!----------------------------------------------------------------------
193      !
194      cltxt = ''
195      !
196      !                             ! open Namelist file
197      CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
198      !
199      READ( numnam, namctl )        ! Namelist namctl : Control prints & Benchmark
200      !
201      !                             !--------------------------------------------!
202      !                             !  set communicator & select the local node  !
203      !                             !--------------------------------------------!
204#if defined key_iomput
205      IF( Agrif_Root() ) THEN
206# if defined key_oasis3 || defined key_oasis4
207         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
208# endif
209         CALL  init_ioclient( ilocal_comm )                 ! exchange io_server nemo local communicator with the io_server
210      ENDIF
211      narea = mynode( cltxt, numnam, nstop, ilocal_comm )   ! Nodes selection
212#else
213# if defined key_oasis3 || defined key_oasis4
214      IF( Agrif_Root() ) THEN
215         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
216      ENDIF
217      narea = mynode( cltxt, numnam, nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
218# else
219      ilocal_comm = 0
220      narea = mynode( cltxt, numnam, nstop )                 ! Nodes selection (control print return in cltxt)
221# endif
222#endif
223      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
224
225      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
226
227      ! If dimensions of processor grid weren't specified in the namelist file
228      ! then we calculate them here now that we have our communicator size
229      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
230#if   defined key_mpp_mpi
231         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
232#else
233         jpni = 1
234         jpnj = 1
235         jpnij = jpni*jpnj
236#endif
237      END IF
238
239      ! Calculate domain dimensions given calculated jpni and jpnj
240      ! This used to be done in par_oce.F90 when they were parameters rather
241      ! than variables
242      IF( Agrif_Root() ) THEN
243         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci !: first  dim.
244         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj !: second dim.
245         jpk = jpkdta                                           !: third dim
246         jpim1 = jpi-1                                          !: inner domain indices
247         jpjm1 = jpj-1                                          !:   "           "
248         jpkm1 = jpk-1                                          !:   "           "
249         jpij  = jpi*jpj                                        !:  jpi x j
250      ENDIF
251
252      IF(lwp) THEN                            ! open listing units
253         !
254         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
255         !
256         WRITE(numout,*)
257         WRITE(numout,*) '         CNRS - NERC - Met OFFICE - MERCATOR-ocean'
258         WRITE(numout,*) '                       NEMO team'
259         WRITE(numout,*) '            Ocean General Circulation Model'
260         WRITE(numout,*) '                  version 3.3  (2010) '
261         WRITE(numout,*)
262         WRITE(numout,*)
263         DO ji = 1, SIZE(cltxt) 
264            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
265         END DO
266         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
267         !
268      ENDIF
269
270      ! Now we know the dimensions of the grid and numout has been set we can
271      ! allocate arrays
272      CALL nemo_alloc()
273
274      !                             !-------------------------------!
275      !                             !  NEMO general initialization  !
276      !                             !-------------------------------!
277
278      CALL nemo_ctl                          ! Control prints & Benchmark
279
280      !                                      ! Domain decomposition
281      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
282      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
283      ENDIF
284      !
285      !                                      ! General initialization
286                            CALL     phy_cst    ! Physical constants
287                            CALL     eos_init   ! Equation of state
288                            CALL     dom_cfg    ! Domain configuration
289                            CALL     dom_init   ! Domain
290
291      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
292
293      IF( lk_obc        )   CALL     obc_init   ! Open boundaries
294      IF( lk_bdy        )   CALL     bdy_init   ! Unstructured open boundaries
295
296                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
297
298      !                                     ! Ocean physics
299                            CALL     sbc_init   ! Forcings : surface module
300      !                                         ! Vertical physics
301                            CALL     zdf_init      ! namelist read
302                            CALL zdf_bfr_init      ! bottom friction
303      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
304      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
305      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
306      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
307      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
308      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   & 
309         &                  CALL zdf_ddm_init      ! double diffusive mixing
310      !                                         ! Lateral physics
311                            CALL ldf_tra_init      ! Lateral ocean tracer physics
312                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
313      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
314
315      !                                     ! Active tracers
316                            CALL tra_qsr_init   ! penetrative solar radiation qsr
317                            CALL tra_bbc_init   ! bottom heat flux
318      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
319      IF( lk_tradmp     )   CALL tra_dmp_init   ! internal damping trends
320                            CALL tra_adv_init   ! horizontal & vertical advection
321                            CALL tra_ldf_init   ! lateral mixing
322                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
323
324      !                                     ! Dynamics
325                            CALL dyn_adv_init   ! advection (vector or flux form)
326                            CALL dyn_vor_init   ! vorticity term including Coriolis
327                            CALL dyn_ldf_init   ! lateral mixing
328                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
329                            CALL dyn_zdf_init   ! vertical diffusion
330                            CALL dyn_spg_init   ! surface pressure gradient
331                           
332      !                                     ! Misc. options
333      IF( nn_cla == 1   )   CALL cla_init       ! Cross Land Advection
334     
335#if defined key_top
336      !                                     ! Passive tracers
337                            CALL     trc_init
338#endif
339      !                                     ! Diagnostics
340                            CALL     iom_init   ! iom_put initialization
341      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
342      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
343                            CALL dia_ptr_init   ! Poleward TRansports initialization
344                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
345                            CALL trd_mod_init   ! Mixed-layer/Vorticity/Integral constraints trends
346      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
347                            CALL dia_obs_init            ! Initialize observational data
348                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
349      ENDIF     
350      !                                     ! Assimilation increments
351      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
352      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
353      !
354   END SUBROUTINE nemo_init
355
356
357   SUBROUTINE nemo_ctl
358      !!----------------------------------------------------------------------
359      !!                     ***  ROUTINE nemo_ctl  ***
360      !!
361      !! ** Purpose :   control print setting
362      !!
363      !! ** Method  : - print namctl information and check some consistencies
364      !!----------------------------------------------------------------------
365      !
366      IF(lwp) THEN                  ! control print
367         WRITE(numout,*)
368         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
369         WRITE(numout,*) '~~~~~~~ '
370         WRITE(numout,*) '   Namelist namctl'
371         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
372         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
373         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
374         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
375         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
376         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
377         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
378         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
379         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
380      ENDIF
381      !
382      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
383      nictls    = nn_ictls
384      nictle    = nn_ictle
385      njctls    = nn_jctls
386      njctle    = nn_jctle
387      isplt     = nn_isplt
388      jsplt     = nn_jsplt
389      nbench    = nn_bench
390      !                             ! Parameter control
391      !
392      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
393         IF( lk_mpp ) THEN
394            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
395         ELSE
396            IF( isplt == 1 .AND. jsplt == 1  ) THEN
397               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
398                  &           ' - the print control will be done over the whole domain' )
399            ENDIF
400            ijsplt = isplt * jsplt            ! total number of processors ijsplt
401         ENDIF
402         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
403         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
404         !
405         !                              ! indices used for the SUM control
406         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
407            lsp_area = .FALSE.                       
408         ELSE                                             ! print control done over a specific  area
409            lsp_area = .TRUE.
410            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
411               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
412               nictls = 1
413            ENDIF
414            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
415               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
416               nictle = jpiglo
417            ENDIF
418            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
419               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
420               njctls = 1
421            ENDIF
422            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
423               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
424               njctle = jpjglo
425            ENDIF
426         ENDIF
427      ENDIF
428      !
429      IF( nbench == 1 ) THEN              ! Benchmark
430         SELECT CASE ( cp_cfg )
431         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
432         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
433            &                                 ' key_gyre must be used or set nbench = 0' )
434         END SELECT
435      ENDIF
436      !
437      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
438         &                                               'with the IOM Input/Output manager. '         ,   &
439         &                                               'Compile with key_iomput enabled' )
440      !
441   END SUBROUTINE nemo_ctl
442
443
444   SUBROUTINE nemo_closefile
445      !!----------------------------------------------------------------------
446      !!                     ***  ROUTINE nemo_closefile  ***
447      !!
448      !! ** Purpose :   Close the files
449      !!----------------------------------------------------------------------
450      !
451      IF( lk_mpp )   CALL mppsync
452      !
453      CALL iom_close                                 ! close all input/output files managed by iom_*
454      !
455      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
456      IF( numsol     /= -1 )   CLOSE( numsol     )   ! solver file
457      IF( numnam     /= -1 )   CLOSE( numnam     )   ! oce namelist
458      IF( numnam_ice /= -1 )   CLOSE( numnam_ice )   ! ice namelist
459      IF( numevo_ice /= -1 )   CLOSE( numevo_ice )   ! ice variables (temp. evolution)
460      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
461      !
462      numout = 6                                     ! redefine numout in case it is used after this point...
463      !
464   END SUBROUTINE nemo_closefile
465
466
467   SUBROUTINE nemo_alloc
468     !!----------------------------------------------------------------------
469     !!                     ***  ROUTINE nemo_alloc  ***
470     !!
471     !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
472     !!
473     !! ** Method  :
474     !!----------------------------------------------------------------------
475     USE diawri,       ONLY: dia_wri_alloc
476     USE dom_oce,      ONLY: dom_oce_alloc
477     USE ldfdyn_oce,   ONLY: ldfdyn_oce_alloc
478     USE ldftra_oce,   ONLY: ldftra_oce_alloc
479     USE trc_oce,      ONLY: trc_oce_alloc
480
481      USE wrk_nemo,    ONLY: wrk_alloc
482
483      INTEGER :: ierr
484      INTEGER :: i
485      !!----------------------------------------------------------------------
486
487      ierr =        oce_alloc       ()          ! ocean
488      ierr = ierr + dia_wri_alloc   ()
489      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
490      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
491      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
492      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
493      !
494      ierr = ierr + lib_mpp_alloc   (numout)    ! mpp exchanges
495      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
496
497      ierr = ierr + wrk_alloc(numout, lwp)      ! workspace
498
499      IF( lk_mpp    )   CALL mpp_sum( ierr )
500      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
501      !
502   END SUBROUTINE nemo_alloc
503
504
505   SUBROUTINE nemo_partition( num_pes )
506      !!----------------------------------------------------------------------
507      !!                 ***  ROUTINE nemo_partition  ***
508      !!
509      !! ** Purpose :   
510      !!
511      !! ** Method  :
512      !!----------------------------------------------------------------------
513      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
514      !
515      INTEGER, PARAMETER :: nfactmax = 20
516      INTEGER :: nfact ! The no. of factors returned
517      INTEGER :: ierr  ! Error flag
518      INTEGER :: ji
519      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
520      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
521      !!----------------------------------------------------------------------
522
523      ierr = 0
524
525      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
526
527      IF( nfact <= 1 ) THEN
528         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
529         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
530         jpnj = 1
531         jpni = num_pes
532      ELSE
533         ! Search through factors for the pair that are closest in value
534         mindiff = 1000000
535         imin    = 1
536         DO ji = 1, nfact-1, 2
537            idiff = ABS( ifact(ji) - ifact(ji+1) )
538            IF( idiff < mindiff ) THEN
539               mindiff = idiff
540               imin = ji
541            ENDIF
542         END DO
543         jpnj = ifact(imin)
544         jpni = ifact(imin + 1)
545      ENDIF
546      !
547      jpnij = jpni*jpnj
548      !
549   END SUBROUTINE nemo_partition
550
551
552   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
553      !!----------------------------------------------------------------------
554      !!                     ***  ROUTINE factorise  ***
555      !!
556      !! ** Purpose :   return the prime factors of n.
557      !!                knfax factors are returned in array kfax which is of
558      !!                maximum dimension kmaxfax.
559      !! ** Method  :
560      !!----------------------------------------------------------------------
561      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
562      INTEGER                    , INTENT(  out) ::   kerr, knfax
563      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
564      !
565      INTEGER :: ifac, jl, inu
566      INTEGER, PARAMETER :: ntest = 14
567      INTEGER :: ilfax(ntest)
568
569      ! lfax contains the set of allowed factors.
570      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
571         &                            128,   64,   32,   16,    8,   4,   2  /
572      !!----------------------------------------------------------------------
573
574      ! Clear the error flag and initialise output vars
575      kerr = 0
576      kfax = 1
577      knfax = 0
578
579      ! Find the factors of n.
580      IF( kn == 1 )   GOTO 20
581
582      ! nu holds the unfactorised part of the number.
583      ! knfax holds the number of factors found.
584      ! l points to the allowed factor list.
585      ! ifac holds the current factor.
586
587      inu   = kn
588      knfax = 0
589
590      DO jl = ntest, 1, -1
591         !
592         ifac = ilfax(jl)
593         IF( ifac > inu )   CYCLE
594
595         ! Test whether the factor will divide.
596
597         IF( MOD(inu,ifac) == 0 ) THEN
598            !
599            knfax = knfax + 1            ! Add the factor to the list
600            IF( knfax > kmaxfax ) THEN
601               kerr = 6
602               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
603               return
604            ENDIF
605            kfax(knfax) = ifac
606            ! Store the other factor that goes with this one
607            knfax = knfax + 1
608            kfax(knfax) = inu / ifac
609            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
610         ENDIF
611         !
612      END DO
613
614   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
615      !
616   END SUBROUTINE factorise
617
618   !!======================================================================
619END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.