New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in branches/devukmo2010/NEMO/OPA_SRC/SBC – NEMO

source: branches/devukmo2010/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 2128

Last change on this file since 2128 was 2128, checked in by rfurner, 14 years ago

merged branches OBS, ASM, Rivers, BDY & mixed_dynldf ready for vn3.3 merge

  • Property svn:keywords set to Id
File size: 10.5 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  8.2  !  01-02  (E. Durand)  Original code
7   !!            8.5  !  02-06  (G. Madec)  F90: Free form and module
8   !!            9.0  !  06-08  (G. Madec)  Surface module
9   !!            9.2  !  09-07  (C. Talandier) emp mean s spread over erp area
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_fwb      : freshwater budget for global ocean configurations
14   !!                  in free surface and forced mode
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface ocean boundary condition
19   USE phycst          ! physical constants
20   USE sbcrnf          ! ocean runoffs
21   USE sbcssr          ! SS damping terms
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE lbclnk          ! ocean lateral boundary conditions
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_fwb      ! routine called by step
30
31   REAL(wp) ::   a_fwb_b            ! annual domain averaged freshwater budget
32   REAL(wp) ::   a_fwb              ! for 2 year before (_b) and before year.
33   REAL(wp) ::   fwfold             ! fwfold to be suppressed
34   REAL(wp) ::   area               ! global mean ocean surface (interior domain)
35
36   REAL(wp), DIMENSION(jpi,jpj) ::   e1e2_i    ! area of the interior domain (e1t*e2t*tmask_i)
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !!  OPA 9.0 , LOCEAN-IPSL (2006)
43   !! $Id$
44   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
49      !!---------------------------------------------------------------------
50      !!                  ***  ROUTINE sbc_fwb  ***
51      !!
52      !! ** Purpose :   Control the mean sea surface drift
53      !!
54      !! ** Method  :   several ways  depending on kn_fwb
55      !!                =0 no control
56      !!                =1 global mean of emp set to zero at each nn_fsbc time step
57      !!                =2 annual global mean corrected from previous year
58      !!                =3 global mean of emp set to zero at each nn_fsbc time step
59      !!                   & spread out over erp area depending its sign
60      !!----------------------------------------------------------------------
61      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
62      INTEGER, INTENT( in ) ::   kn_fsbc  !
63      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
64      !!
65      INTEGER  ::   inum                  ! temporary logical unit
66      INTEGER  ::   ikty, iyear           !
67      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp       ! temporary scalars
68      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread
69      REAL(wp), DIMENSION(jpi,jpj) ::   ztmsk_neg, ztmsk_pos, ztmsk_tospread
70      REAL(wp), DIMENSION(jpi,jpj) ::   z_wgt, zerp_cor
71      !!----------------------------------------------------------------------
72      !
73      IF( kt == nit000 ) THEN
74         !
75         IF(lwp) THEN
76            WRITE(numout,*)
77            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
78            WRITE(numout,*) '~~~~~~~'
79            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
80            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
81            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
82            !
83            IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   &
84               &   CALL ctl_stop( 'The option nn_fwb = 3 must be associated to nn_sssr = 2 ' )
85           
86         ENDIF
87         !
88         e1e2_i(:,:) = e1t(:,:) * e2t(:,:) * tmask_i(:,:)
89         area = SUM( e1e2_i(:,:) )
90         IF( lk_mpp )   CALL  mpp_sum( area    )   ! sum over the global domain
91         !
92      ENDIF
93     
94
95      SELECT CASE ( kn_fwb )
96      !
97      CASE ( 0 )                               
98         WRITE(ctmp1,*)'sbc_fwb : nn_fwb = ', kn_fwb, ' is not yet associated to an option, choose either 1/2'
99         CALL ctl_stop( ctmp1 )
100         !
101         
102      !
103      CASE ( 1 )                               ! global mean fwf set to zero
104         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
105            z_fwf = SUM( e1e2_i(:,:) * ( emp(:,:)-rnf(:,:) ) ) / area 
106            IF( lk_mpp )   CALL  mpp_sum( z_fwf    )   ! sum over the global domain
107            emp (:,:) = emp (:,:) - z_fwf 
108            emps(:,:) = emps(:,:) - z_fwf 
109         ENDIF
110         !
111      CASE ( 2 )                               ! fwf budget adjusted from the previous year
112         ! initialisation
113         IF( kt == nit000 ) THEN
114            ! Read the corrective factor on precipitations (fwfold)
115            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
116            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
117            CLOSE( inum )
118            fwfold = a_fwb                  ! current year freshwater budget correction
119            !                               ! estimate from the previous year budget
120            IF(lwp)WRITE(numout,*)
121            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
122            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
123            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
124         ENDIF   
125         !
126         ! Update fwfold if new year start
127         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
128         IF( MOD( kt, ikty ) == 0 ) THEN
129            a_fwb_b = a_fwb
130            a_fwb   = SUM( e1e2_i(:,:) * sshn(:,:) )
131            IF( lk_mpp )   CALL  mpp_sum( a_fwb    )   ! sum over the global domain
132            a_fwb   = a_fwb * 1.e+3 / ( area * 86400. * 365. )     ! convert in Kg/m3/s = mm/s
133!!gm        !                                                      !!bug 365d year
134            fwfold =  a_fwb                 ! current year freshwater budget correction
135            !                               ! estimate from the previous year budget
136         ENDIF
137         !
138         ! correct the freshwater fluxes
139         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
140            emp (:,:) = emp (:,:) + fwfold
141            emps(:,:) = emps(:,:) + fwfold
142         ENDIF
143         !
144         ! save fwfold value in a file
145         IF( kt == nitend .AND. lwp ) THEN
146            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
147            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
148            CLOSE( inum )
149         ENDIF
150         !
151      CASE ( 3 )                               ! global fwf set to zero and spread out over erp area
152         !
153         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
154            ! Select <0 and >0 area of erp
155            ztmsk_pos(:,:) = tmask_i(:,:)
156            WHERE( erp < 0.e0 ) ztmsk_pos = 0.e0
157            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
158
159            ! Area filled by <0 and >0 erp
160            zsurf_neg = SUM( e1e2_i(:,:)*ztmsk_neg(:,:) )
161            zsurf_pos = SUM( e1e2_i(:,:)*ztmsk_pos(:,:) )
162       
163            ! fwf global mean
164            z_fwf = SUM( e1e2_i(:,:) * ( emp(:,:)-rnf(:,:) ) ) / area 
165            !
166            IF( lk_mpp )   CALL  mpp_sum( z_fwf )
167            IF( lk_mpp )   CALL  mpp_sum( zsurf_neg )
168            IF( lk_mpp )   CALL  mpp_sum( zsurf_pos )
169           
170            IF( z_fwf < 0.e0 ) THEN
171                ! to spread out over >0 erp area to increase evaporation damping process
172                zsurf_tospread = zsurf_pos
173                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
174            ELSE
175                ! to spread out over <0 erp area to increase precipitation damping process
176                zsurf_tospread = zsurf_neg
177                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
178            ENDIF
179
180            ! fwf global mean over <0 or >0 erp area
181            zsum_fwf = SUM( e1e2_i(:,:) * z_fwf )
182            IF( lk_mpp )   CALL  mpp_sum( zsum_fwf )
183            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
184            ! weight to respect erp field 2D structure
185            zsum_erp = SUM( ztmsk_tospread(:,:) * erp(:,:) * e1e2_i(:,:) )
186            IF( lk_mpp )   CALL  mpp_sum( zsum_erp )
187            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
188
189            ! final correction term to apply
190            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
191
192            CALL lbc_lnk( zerp_cor, 'T', 1. )
193
194            emp (:,:) = emp (:,:) + zerp_cor(:,:)
195            emps(:,:) = emps(:,:) + zerp_cor(:,:)
196            erp (:,:) = erp (:,:) + zerp_cor(:,:)
197           
198            IF( nprint == 1 .AND. lwp ) THEN
199               IF( z_fwf < 0.e0 ) THEN
200                  WRITE(numout,*)'       z_fwf < 0'
201                  WRITE(numout,*)'       SUM(erp+)        = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2_i(:,:) )*1.e-3,' m3.s-1'
202               ELSE
203                   WRITE(numout,*)'      z_fwf >= 0'
204                   WRITE(numout,*)'      SUM(erp-)        = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2_i(:,:) )*1.e-3,' m3.s-1'
205               ENDIF
206               WRITE(numout,*)'      SUM(empG)        = ', SUM( z_fwf*e1e2_i(:,:) )*1.e-3,' m3.s-1'
207               WRITE(numout,*)'      z_fwf            = ', z_fwf      ,' mm.s-1'
208               WRITE(numout,*)'      z_fwf_nsrf       = ', z_fwf_nsrf ,' mm.s-1'
209               WRITE(numout,*)'      MIN(zerp_cor)    = ', MINVAL(zerp_cor) 
210               WRITE(numout,*)'      MAX(zerp_cor)    = ', MAXVAL(zerp_cor) 
211            ENDIF
212            !
213         ENDIF
214         !
215      CASE DEFAULT    ! you should never be there
216         WRITE(ctmp1,*)'sbc_fwb : nn_fwb = ', kn_fwb, ' is not permitted for the FreshWater Budget correction, choose either 1/2'
217         CALL ctl_stop( ctmp1 )
218         !
219      END SELECT
220      !
221   END SUBROUTINE sbc_fwb
222
223   !!======================================================================
224END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.