source: trunk/NEMO/LIM_SRC/limthd_lac.F90 @ 12

Last change on this file since 12 was 12, checked in by opalod, 17 years ago

CT : UPDATE001 : First major NEMO update

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 11.9 KB
Line 
1MODULE limthd_lac
2#if defined key_ice_lim
3   !!======================================================================
4   !!                       ***  MODULE limthd_lac   ***
5   !!                lateral thermodynamic growth of the ice
6   !!======================================================================
7
8   !!----------------------------------------------------------------------
9   !!   lim_lat_acr    : lateral accretion of ice
10   !! * Modules used
11   USE par_oce          ! ocean parameters
12   USE phycst
13   USE ice_oce         ! ice variables
14   USE thd_ice
15   USE iceini
16   USE limistate 
17     
18   IMPLICIT NONE
19   PRIVATE
20
21   !! * Routine accessibility
22   PUBLIC lim_thd_lac     ! called by lim_thd
23
24  !! * Module variables
25     REAL(wp)  ::            &  ! constant values
26         epsi20 = 1e-20   ,  &
27         epsi13 = 1e-13   ,  &
28         zzero  = 0.0     ,  &
29         zone   = 1.0
30   !!----------------------------------------------------------------------
31   !!   LIM 2.0 , UCL-LODYC-IPSL  (2003)
32   !!----------------------------------------------------------------------
33CONTAINS
34   
35    SUBROUTINE lim_thd_lac( kideb, kiut )
36      !!-------------------------------------------------------------------
37      !!               ***   ROUTINE lim_thd_lac  ***
38      !! 
39      !! ** Purpose : Computation of the evolution of the ice thickness and
40      !!      concentration as a function of the heat balance in the leads.
41      !!      It is only used for lateral accretion
42      !!       
43      !! ** Method  : Ice is formed in the open water when ocean lose heat
44      !!      (heat budget of open water Bl is negative) .
45      !!      Computation of the increase of 1-A (ice concentration) fol-
46      !!      lowing the law :
47      !!      (dA/dt)acc = F[ (1-A)/(1-a) ] * [ Bl / (Li*h0) ]
48      !!       where - h0 is the thickness of ice created in the lead
49      !!             - a is a minimum fraction for leads
50      !!             - F is a monotonic non-increasing function defined as:
51      !!                  F(X)=( 1 - X**exld )**(1.0/exld)
52      !!             - exld is the exponent closure rate (=2 default val.)
53      !!
54      !! ** Action : - Adjustment of snow and ice thicknesses and heat
55      !!                content in brine pockets
56      !!             - Updating ice internal temperature
57      !!             - Computation of variation of ice volume and mass
58      !!             - Computation of frldb after lateral accretion and
59      !!               update h_snow_1d, h_ice_1d and tbif_1d(:,:)     
60      !!
61      !! ** References :
62      !!      M. Maqueda, 1995, PhD Thesis, Univesidad Complutense Madrid
63      !!      Fichefet T. and M. Maqueda 1997, J. Geo. Res., 102(C6),
64      !!                                                12609 -12646   
65      !!
66      !! History :
67      !!   1.0  !  01-04 (LIM)  original code
68      !!   2.0  !  02-08 (C. Ethe, G. Madec)  F90, mpp
69      !!-------------------------------------------------------------------
70      !! * Arguments
71      INTEGER , INTENT(IN)::  &
72         kideb          ,   &  ! start point on which the the computation is applied
73         kiut                  ! end point on which the the computation is applied
74
75      !! * Local variables
76      INTEGER ::            &
77         ji             ,   &  !  dummy loop indices
78         iicefr         ,   &  !  1 = existing ice ; 0 = no ice
79         iiceform       ,   &  !  1 = ice formed   ; 0 = no ice formed
80         ihemis                !  dummy indice
81      REAL(wp), DIMENSION(jpij) :: &
82         zqbgow           ,  &  !  heat budget of the open water (negative)
83         zfrl_old         ,  &  !  previous sea/ice fraction
84         zhice_old        ,  &  !  previous ice thickness
85         zhice0           ,  &  !  thickness of newly formed ice in leads
86         zfrlmin          ,  &  !  minimum fraction for leads
87         zdhicbot               !  part of thickness of newly formed ice in leads which
88                                !  has been already used in transport for example
89      REAL(wp)  ::  &
90         zhemis           ,  &  !  hemisphere (0 = North, 1 = South)
91         zhicenew         ,  &  !  new ice thickness
92         zholds2          ,  &  !  ratio of previous ice thickness and 2
93         zhnews2          ,  &  !  ratio of new ice thickness and 2
94         zfrlnew          ,  &  !  new sea/ice fraction
95         zfrld            ,  &  !  ratio of sea/ice fraction and minimum fraction for leads
96         zfrrate          ,  &  !  leads-closure rate
97         zdfrl                  !  sea-ice fraction increment
98      REAL(wp)  ::  &
99         zdh1 , zdh2 , zdh3 , zdh4, zdh5   , &   ! tempory scalars
100         ztint , zta1 , zta2 , zta3 , zta4 , &
101         zah, zalpha , zbeta
102      !!---------------------------------------------------------------------     
103                   
104      !--------------------------------------------------------------
105      !   Computation of the heat budget of the open water (negative)
106      !--------------------------------------------------------------
107     
108      DO ji = kideb , kiut     
109         zqbgow(ji) = qldif_1d(ji) - qcmif_1d(ji)
110      END DO
111     
112      !-----------------------------------------------------------------
113      !   Taking the appropriate values for the corresponding hemisphere
114      !-----------------------------------------------------------------
115      DO ji = kideb , kiut
116         zhemis       = MAX( zzero , SIGN( zone , frld_1d(ji) - 2.0 ) ) 
117         ihemis       = INT( 1 + zhemis )
118         zhice0  (ji) = hiccrit( ihemis ) 
119         zfrlmin (ji) = acrit  ( ihemis )   
120         frld_1d (ji) = frld_1d(ji) - 2.0 * zhemis
121         zfrl_old(ji) = frld_1d(ji)
122      END DO
123     
124      !-------------------------------------------------------------------
125      !     Lateral Accretion (modification of the fraction of open water)
126      !     The ice formed in the leads has always a thickness zhice0, but
127      !     only a fraction zfrrate of the ice formed contributes to the
128      !     increase of the ice fraction. The remaining part (1-zfrrate)
129      !     is rather assumed to lead to an increase in the thickness of the
130      !     pre-existing ice (transport for example).
131      !     Morales Maqueda, 1995 - Fichefet and Morales Maqueda, 1997
132      !---------------------------------------------------------------------
133     
134      !CDIR NOVERRCHK
135      DO ji = kideb , kiut
136         iicefr       = 1 - MAX( 0, INT( SIGN( 1.5 * zone , zfrl_old(ji) - 1.0 + epsi13 ) ) )
137         !---computation of the leads-closure rate
138         zfrld        = MIN( zone , ( 1.0 - frld_1d(ji) ) / ( 1.0 - zfrlmin(ji) ) )
139         zfrrate      = ( 1.0 - zfrld**exld )**( 1.0 / exld )
140         !--computation of the sea-ice fraction increment and the new fraction
141         zdfrl        = ( zfrrate / zhice0(ji) )  * ( zqbgow(ji) / xlic )
142         zfrlnew      = zfrl_old(ji) + zdfrl
143         !--update the sea-ice fraction
144         frld_1d   (ji) = MAX( zfrlnew , zfrlmin(ji) )
145         !--computation of the remaining part of ice thickness which has been already used
146         zdhicbot(ji) =  ( frld_1d(ji) - zfrlnew ) * zhice0(ji) / ( 1.0 - zfrlmin(ji) ) & 
147                      -  (  ( 1.0 - zfrrate ) / ( 1.0 - frld_1d(ji) ) )  * ( zqbgow(ji) / xlic ) 
148      END DO
149 
150      !----------------------------------------------------------------------------------------
151      !      Ajustement of snow and ice thicknesses and updating the total heat stored in brine pockets 
152      !      The thickness of newly formed ice is averaged with that of the pre-existing
153      !         (1-Anew) * hinew = (1-Aold) * hiold + ((1-Anew)-(1-Aold)) * h0
154      !      Snow is distributed over the new ice-covered area
155      !         (1-Anew) * hsnew = (1-Aold) * hsold           
156      !--------------------------------------------------------------------------------------------
157     
158      DO ji = kideb , kiut
159         iicefr       = 1 - MAX( 0, INT( SIGN( 1.5 * zone , zfrl_old(ji) - 1.0 + epsi13 ) ) )
160         zhice_old(ji) = h_ice_1d(ji)
161         zhicenew      = iicefr * zhice_old(ji) + ( 1 - iicefr ) * zhice0(ji)
162         zalpha        = ( 1. - zfrl_old(ji) ) / ( 1.- frld_1d(ji) )
163         h_snow_1d(ji) = zalpha * h_snow_1d(ji)
164         h_ice_1d (ji) = zalpha * zhicenew + ( 1.0 - zalpha ) * zhice0(ji)
165         qstbif_1d(ji) = zalpha * qstbif_1d(ji) 
166      END DO
167     
168      !-------------------------------------------------------
169      !   Ajustement of ice internal temperatures
170      !-------------------------------------------------------
171     
172      DO ji = kideb , kiut
173         iicefr      = 1 - MAX( 0, INT( SIGN( 1.5 * zone , zfrl_old(ji) - 1.0 + epsi13 ) ) )
174         iiceform    = 1 - MAX( 0 ,INT( SIGN( 1.5 * zone , zhice0(ji) - h_ice_1d(ji) ) ) )
175         zholds2     = zhice_old(ji)/ 2.
176         zhnews2     = h_ice_1d(ji) / 2.
177         zdh1        = MAX( zzero ,  zhice_old(ji)   - zhnews2 )
178         zdh2        = MAX( zzero , -zhice_old(ji)   + zhnews2 )
179         zdh3        = MAX( zzero ,  h_ice_1d(ji) - zholds2 )
180         zdh4        = MAX( zzero , -h_ice_1d(ji) + zholds2 )
181         zdh5        = MAX( zzero , zhice0(ji)      - zholds2 )
182         ztint       =       iiceform   * (  ( zholds2 - zdh3 ) * tbif_1d(ji,3) + zdh4 * tbif_1d(ji,2) )      &
183            &                           / MAX( epsi20 , h_ice_1d(ji) - zhice0(ji) )                           &
184            &                 + ( 1 - iiceform ) * tfu_1d(ji)
185         zta1        = iicefr * ( 1.  - zfrl_old(ji) ) * tbif_1d(ji,2) 
186         zta2        = iicefr * ( 1.  - zfrl_old(ji) ) * tbif_1d(ji,3)
187         zta3        = iicefr * ( 1.  - zfrl_old(ji) ) * ztint
188         zta4        = ( zfrl_old(ji) - frld_1d   (ji) ) * tfu_1d(ji)
189         zah         = ( 1. - frld_1d(ji) ) * zhnews2 
190
191         tbif_1d(ji,2) = (  MIN( zhnews2 , zholds2 )                                              * zta1   &
192            &          + ( 1 - iiceform ) * ( zholds2 - zdh1 )                                    * zta2   &
193            &          + ( iiceform * ( zhnews2 - zhice0(ji) + zdh5 ) + ( 1 - iiceform ) * zdh2 ) * zta3   & 
194            &          + MIN ( zhnews2 , zhice0(ji) )                                             * zta4   &
195            &          ) / zah
196         
197         tbif_1d(ji,3) =     (  iiceform * ( zhnews2 - zdh3 )                                          * zta1  &
198            &              + ( iiceform * zdh3 + ( 1 - iiceform ) * zdh1 )                             * zta2  &
199            &              + ( iiceform * ( zhnews2 - zdh5 ) + ( 1 - iiceform ) * ( zhnews2 - zdh1 ) ) * zta3  & 
200            &              + ( iiceform * zdh5 + ( 1 - iiceform ) * zhnews2 )                          * zta4  &
201            &            ) / zah
202         !---removing the remaining part of ice formed which has been already used
203         zbeta         = h_ice_1d(ji) / ( h_ice_1d(ji) + zdhicbot(ji) )
204         h_ice_1d(ji)  = h_ice_1d(ji) + zdhicbot(ji)
205         tbif_1d (ji,2)= zbeta * tbif_1d(ji,2) + ( 1.0 - zbeta ) * tbif_1d(ji,3)
206         tbif_1d (ji,3)= ( 2. * zbeta - 1.0 ) * tbif_1d(ji,3) + ( 2. * zdhicbot(ji) / h_ice_1d(ji) ) * tfu_1d(ji)
207         
208      END DO
209     
210      !-------------------------------------------------------------
211      !    Computation of variation of ice volume and ice mass
212      !           Vold = (1-Aold) * hiold ; Vnew = (1-Anew) * hinew
213      !           dV = Vnew - Vold
214      !-------------------------------------------------------------
215     
216      DO ji = kideb , kiut
217         dvlbq_1d  (ji) = ( 1. - frld_1d(ji) ) * h_ice_1d(ji) - ( 1. - zfrl_old(ji) ) * zhice_old(ji)
218         rdmicif_1d(ji) = rdmicif_1d(ji) + rhoic * dvlbq_1d(ji)
219      END DO
220     
221   END SUBROUTINE lim_thd_lac
222#else
223   !!======================================================================
224   !!                       ***  MODULE limthd_lac   ***
225   !!                           no sea ice model
226   !!======================================================================
227CONTAINS
228   SUBROUTINE lim_thd_lac           ! Empty routine
229   END SUBROUTINE lim_thd_lac
230#endif
231END MODULE limthd_lac
Note: See TracBrowser for help on using the repository browser.