source: trunk/NEMO/LIM_SRC_2/limrhg_2.F90 @ 1711

Last change on this file since 1711 was 1711, checked in by rblod, 12 years ago

Add tilt off sea-surface in LIM2 rheology, see ticket #587

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 33.4 KB
Line 
1MODULE limrhg_2
2   !!======================================================================
3   !!                     ***  MODULE  limrhg_2  ***
4   !!   Ice rheology :  performs sea ice rheology
5   !!======================================================================
6   !! History :  0.0  !  93-12  (M.A. Morales Maqueda.)  Original code
7   !!            1.0  !  94-12  (H. Goosse)
8   !!            2.0  !  03-12  (C. Ethe, G. Madec)  F90, mpp
9   !!            " "  !  06-08  (G. Madec)  surface module, ice-stress at I-point
10   !!            " "  !  09-09  (G. Madec)  Huge verctor optimisation
11   !!----------------------------------------------------------------------
12#if defined key_lim2
13   !!----------------------------------------------------------------------
14   !!   'key_lim2'                                    LIM 2.0 sea-ice model
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   lim_rhg_2   : computes ice velocities
18   !!----------------------------------------------------------------------
19   USE par_oce        ! ocean parameter
20   USE dom_oce        ! ocean space and time domain
21   USE sbc_oce        ! surface boundary condition: ocean variables
22   USE sbc_ice        ! surface boundary condition: ice variables
23   USE dom_ice_2      ! domaine: ice variables
24   USE phycst         ! physical constant
25   USE ice_2          ! ice variables
26   USE lbclnk         ! lateral boundary condition
27   USE lib_mpp        ! MPP library
28   USE in_out_manager ! I/O manager
29   USE prtctl         ! Print control
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   lim_rhg_2 ! routine called by lim_dyn
35
36   REAL(wp) ::   rzero   = 0.e0   ! constant value: zero
37   REAL(wp) ::   rone    = 1.e0   !            and  one
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !!   LIM 2.0,  UCL-LOCEAN-IPSL (2006)
43   !! $Id$
44   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46
47CONTAINS
48
49   SUBROUTINE lim_rhg_2( k_j1, k_jpj )
50      !!-------------------------------------------------------------------
51      !!                 ***  SUBROUTINR lim_rhg_2  ***
52      !!
53      !! ** purpose :   determines the velocity field of sea ice by using
54      !!  atmospheric (wind stress) and oceanic (water stress and surface
55      !!  tilt) forcings. Ice-ice interaction is described by a non-linear
56      !!  viscous-plastic law including shear strength and a bulk rheology.
57      !!
58      !! ** Action  : - compute u_ice, v_ice the sea-ice velocity defined
59      !!              at I-point
60      !!-------------------------------------------------------------------
61      INTEGER, INTENT(in) ::   k_j1    ! southern j-index for ice computation
62      INTEGER, INTENT(in) ::   k_jpj   ! northern j-index for ice computation
63      !!
64      INTEGER ::   ji, jj              ! dummy loop indices
65      INTEGER ::   iter, jter          ! temporary integers
66      CHARACTER (len=50) ::   charout
67      REAL(wp) ::   ze11  , ze12  , ze22  , ze21               ! temporary scalars
68      REAL(wp) ::   zt11  , zt12  , zt21  , zt22               !    "         "
69      REAL(wp) ::   zvis11, zvis21, zvis12, zvis22             !    "         "
70      REAL(wp) ::   zgphsx, ztagnx, zgsshx, zunw, zur, zusw    !    "         "
71      REAL(wp) ::   zgphsy, ztagny, zgsshy, zvnw, zvr          !    "         "
72      REAL(wp) ::   zresm,  za, zac, zmod
73      REAL(wp) ::   zmpzas, zstms, zindu, zusdtp, zmassdt, zcorlal
74      REAL(wp) ::   ztrace2, zdeter, zdelta, zmask, zdgp, zdgi, zdiag
75      REAL(wp) ::   za1, zb1, zc1, zd1
76      REAL(wp) ::   za2, zb2, zc2, zd2, zden
77      REAL(wp) ::   zs11_11, zs11_12, zs11_21, zs11_22
78      REAL(wp) ::   zs12_11, zs12_12, zs12_21, zs12_22
79      REAL(wp) ::   zs21_11, zs21_12, zs21_21, zs21_22
80      REAL(wp) ::   zs22_11, zs22_12, zs22_21, zs22_22
81      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zfrld, zmass, zcorl
82      REAL(wp), DIMENSION(jpi,  jpj  ) ::   za1ct, za2ct, zresr
83      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zc1u, zc1v, zc2u, zc2v
84      REAL(wp), DIMENSION(jpi,  jpj  ) ::   zsang
85      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu0, zv0
86      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu_n, zv_n
87      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zu_a, zv_a
88      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zviszeta, zviseta
89      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zzfrld, zztms
90      REAL(wp), DIMENSION(jpi,0:jpj+1) ::   zi1, zi2, zmasst, zpresh
91
92      !!-------------------------------------------------------------------
93
94!!bug
95!!    u_oce(:,:) = 0.e0
96!!    v_oce(:,:) = 0.e0
97!!    write(*,*) 'rhg min, max u & v', maxval(u_oce), minval(u_oce), maxval(v_oce), minval(v_oce)
98!!bug
99     
100      !  Store initial velocities
101      !  ----------------
102      zztms(:,0    ) = 0.e0       ;    zzfrld(:,0    ) = 0.e0
103      zztms(:,jpj+1) = 0.e0       ;    zzfrld(:,jpj+1) = 0.e0
104      zu0(:,0    ) = 0.e0         ;    zv0(:,0    ) = 0.e0
105      zu0(:,jpj+1) = 0.e0         ;    zv0(:,jpj+1) = 0.e0
106      zztms(:,1:jpj) = tms(:,:)   ;    zzfrld(:,1:jpj) = frld(:,:)
107      zu0(:,1:jpj) = u_ice(:,:)   ;    zv0(:,1:jpj) = v_ice(:,:)
108
109      zu_a(:,:)    = zu0(:,:)     ;   zv_a(:,:) = zv0(:,:)
110      zu_n(:,:)    = zu0(:,:)     ;   zv_n(:,:) = zv0(:,:)
111
112!i
113      zi1   (:,:) = 0.e0
114      zi2   (:,:) = 0.e0
115      zpresh(:,:) = 0.e0
116      zmasst(:,:) = 0.e0
117!i
118!!gm violant
119      zfrld(:,:) =0.e0
120      zcorl(:,:) =0.e0
121      zmass(:,:) =0.e0
122      za1ct(:,:) =0.e0
123      za2ct(:,:) =0.e0
124!!gm end
125
126      zviszeta(:,:) = 0.e0
127      zviseta (:,:) = 0.e0
128
129!i    zviszeta(:,0    ) = 0.e0    ;    zviseta(:,0    ) = 0.e0
130!i    zviszeta(:,jpj  ) = 0.e0    ;    zviseta(:,jpj  ) = 0.e0
131!i    zviszeta(:,jpj+1) = 0.e0    ;    zviseta(:,jpj+1) = 0.e0
132
133
134      ! Ice mass, ice strength, and wind stress at the center            |
135      ! of the grid squares.                                             |
136      !-------------------------------------------------------------------
137
138!CDIR NOVERRCHK
139      DO jj = k_j1 , k_jpj-1
140!CDIR NOVERRCHK
141         DO ji = 1 , jpi
142            ! only the sinus changes its sign with the hemisphere
143            zsang(ji,jj)  = SIGN( 1.e0, fcor(ji,jj) ) * sangvg   ! only the sinus changes its sign with the hemisphere
144            !
145            zmasst(ji,jj) = tms(ji,jj) * ( rhosn * hsnm(ji,jj) + rhoic * hicm(ji,jj) )
146            zpresh(ji,jj) = tms(ji,jj) *  pstarh * hicm(ji,jj) * EXP( -c_rhg * frld(ji,jj) )
147!!gm  :: stress given at I-point (F-point for the ocean) only compute the ponderation with the ice fraction (1-frld)
148            zi1(ji,jj)    = tms(ji,jj) * ( 1.0 - frld(ji,jj) )
149            zi2(ji,jj)    = tms(ji,jj) * ( 1.0 - frld(ji,jj) )
150         END DO
151      END DO
152
153
154      !---------------------------------------------------------------------------
155      !  Wind stress, coriolis and mass terms at the corners of the grid squares |
156      !  Gradient of ice strenght.                                               |
157      !---------------------------------------------------------------------------
158         
159      DO jj = k_j1+1, k_jpj-1
160         DO ji = fs_2, jpi
161            zstms = zztms(ji,jj  ) * wght(ji,jj,2,2) + zztms(ji-1,jj  ) * wght(ji,jj,1,2)   &
162               &  + zztms(ji,jj-1) * wght(ji,jj,2,1) + zztms(ji-1,jj-1) * wght(ji,jj,1,1)
163            zusw  = 1.0 / MAX( zstms, epsd )
164
165            zt11 = zztms(ji  ,jj  ) * zzfrld(ji  ,jj  ) 
166            zt12 = zztms(ji-1,jj  ) * zzfrld(ji-1,jj  ) 
167            zt21 = zztms(ji  ,jj-1) * zzfrld(ji  ,jj-1) 
168            zt22 = zztms(ji-1,jj-1) * zzfrld(ji-1,jj-1)
169
170            ! Leads area.
171            zfrld(ji,jj) =  (  zt11 * wght(ji,jj,2,2) + zt12 * wght(ji,jj,1,2)   &
172               &             + zt21 * wght(ji,jj,2,1) + zt22 * wght(ji,jj,1,1) ) * zusw
173
174            ! Mass and coriolis coeff. at I-point
175            zmass(ji,jj) = ( zmasst(ji,jj  ) * wght(ji,jj,2,2) + zmasst(ji-1,jj  ) * wght(ji,jj,1,2)   &
176               &           + zmasst(ji,jj-1) * wght(ji,jj,2,1) + zmasst(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw
177            zcorl(ji,jj) = zmass(ji,jj) &
178               &           *( fcor(ji,jj  ) * wght(ji,jj,2,2) + fcor(ji-1,jj  )*wght(ji,jj,1,2)   &
179               &            + fcor(ji,jj-1) * wght(ji,jj,2,1) + fcor(ji-1,jj-1)*wght(ji,jj,1,1) ) * zusw
180
181            ! Wind stress.
182            ! always provide stress at I-point
183            ztagnx = ( zi1(ji,jj  ) * wght(ji,jj,2,2) + zi1(ji-1,jj  ) * wght(ji,jj,1,2)   &
184               &     + zi1(ji,jj-1) * wght(ji,jj,2,1) + zi1(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * utau_ice(ji,jj)
185            ztagny = ( zi2(ji,jj  ) * wght(ji,jj,2,2) + zi2(ji-1,jj  ) * wght(ji,jj,1,2)   &
186               &     + zi2(ji,jj-1) * wght(ji,jj,2,1) + zi2(ji-1,jj-1) * wght(ji,jj,1,1) ) * zusw * vtau_ice(ji,jj)
187
188            ! Gradient of ice strength
189            zgphsx =   ( alambd(ji,jj,2,2,2,1) - alambd(ji,jj,2,1,2,1) ) * zpresh(ji  ,jj-1)   &
190               &     + ( alambd(ji,jj,2,2,2,2) - alambd(ji,jj,2,1,2,2) ) * zpresh(ji  ,jj  )   &
191               &     - ( alambd(ji,jj,2,2,1,1) + alambd(ji,jj,2,1,1,1) ) * zpresh(ji-1,jj-1)   &
192               &     - ( alambd(ji,jj,2,2,1,2) + alambd(ji,jj,2,1,1,2) ) * zpresh(ji-1,jj  )
193
194            zgphsy = - ( alambd(ji,jj,1,1,2,1) + alambd(ji,jj,1,2,2,1) ) * zpresh(ji  ,jj-1)   &
195               &     - ( alambd(ji,jj,1,1,1,1) + alambd(ji,jj,1,2,1,1) ) * zpresh(ji-1,jj-1)   &
196               &     + ( alambd(ji,jj,1,1,2,2) - alambd(ji,jj,1,2,2,2) ) * zpresh(ji  ,jj  )   &
197               &     + ( alambd(ji,jj,1,1,1,2) - alambd(ji,jj,1,2,1,2) ) * zpresh(ji-1,jj  )
198
199            ! Gradient of the sea surface height
200            zgsshx =  (   (ssh_m(ji  ,jj  ) - ssh_m(ji-1,jj  ))/e1u(ji-1,jj  )   &
201               &       +  (ssh_m(ji  ,jj-1) - ssh_m(ji-1,jj-1))/e1u(ji-1,jj-1)   ) * 0.5
202            zgsshy =  (   (ssh_m(ji  ,jj  ) - ssh_m(ji  ,jj-1))/e2v(ji  ,jj-1)   &
203               &       +  (ssh_m(ji-1,jj  ) - ssh_m(ji-1,jj-1))/e2v(ji-1,jj-1)   ) * 0.5
204
205            ! Computation of the velocity field taking into account the ice-ice interaction.                                 
206            ! Terms that are independent of the ice velocity field.
207            za1ct(ji,jj) = ztagnx - zmass(ji,jj) * grav * zgsshx - zgphsx
208            za2ct(ji,jj) = ztagny - zmass(ji,jj) * grav * zgsshy - zgphsy
209         END DO
210      END DO
211
212
213      ! SOLUTION OF THE MOMENTUM EQUATION.
214      !------------------------------------------
215      !                                                   ! ==================== !
216      DO iter = 1 , 2 * nbiter                            !    loop over iter    !
217         !                                                ! ==================== !       
218         zindu = MOD( iter , 2 )
219         zusdtp = ( zindu * 2.0 + ( 1.0 - zindu ) * 1.0 )  * REAL( nbiter ) / rdt_ice
220
221         ! Computation of free drift field for free slip boundary conditions.
222
223!CDIR NOVERRCHK
224         DO jj = k_j1, k_jpj-1
225!CDIR NOVERRCHK
226            DO ji = 1, fs_jpim1
227               !- Rate of strain tensor.
228               zt11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji,jj  ) - zu_a(ji  ,jj+1) )  &
229                  &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji,jj  ) + zv_a(ji  ,jj+1) )
230               zt12 = - akappa(ji,jj,2,2) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) - zu_a(ji,jj+1) - zu_a(ji+1,jj+1) )  &
231                  &   - akappa(ji,jj,2,1) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) + zv_a(ji,jj+1) + zv_a(ji+1,jj+1) )
232               zt22 = - akappa(ji,jj,2,2) * ( zv_a(ji  ,jj) + zv_a(ji+1,jj  ) - zv_a(ji,jj+1) - zv_a(ji+1,jj+1) )  &
233                  &   + akappa(ji,jj,2,1) * ( zu_a(ji  ,jj) + zu_a(ji+1,jj  ) + zu_a(ji,jj+1) + zu_a(ji+1,jj+1) )
234               zt21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji,jj  ) - zv_a(ji  ,jj+1) )  &
235                  &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji,jj  ) + zu_a(ji  ,jj+1) )
236
237               !- Rate of strain tensor.
238               zdgp = zt11 + zt22
239               zdgi = zt12 + zt21
240               ztrace2 = zdgp * zdgp 
241               zdeter  = zt11 * zt22 - 0.25 * zdgi * zdgi
242
243               !  Creep limit depends on the size of the grid.
244               zdelta = MAX( SQRT( ztrace2 + ( ztrace2 - 4.0 * zdeter ) * usecc2 ),  creepl)
245
246               !-  Computation of viscosities.
247               zviszeta(ji,jj) = MAX( zpresh(ji,jj) / zdelta, etamn )
248               zviseta (ji,jj) = zviszeta(ji,jj) * usecc2
249            END DO
250         END DO
251
252         !-  Determination of zc1u, zc2u, zc1v and zc2v.
253         DO jj = k_j1+1, k_jpj-1
254            DO ji = 2, fs_jpim1   ! NO vector opt.
255               !* zc1u , zc2v
256               zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
257               zvis12 =       zviseta (ji-1,jj-1) + dm
258               zvis21 =       zviseta (ji-1,jj-1)
259               zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
260               zdiag  = zvis22 * ( akappa(ji-1,jj-1,1,1) + akappa(ji-1,jj-1,2,1) )
261               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,1) + zdiag
262               zs12_11 =  zvis12 * akappa(ji-1,jj-1,2,2) - zvis21 * akappa(ji-1,jj-1,1,2)
263               zs21_11 = -zvis12 * akappa(ji-1,jj-1,1,2) + zvis21 * akappa(ji-1,jj-1,2,2)
264               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,1) + zdiag
265
266               zvis11 = 2.0 * zviseta (ji,jj-1) + dm
267               zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
268               zvis12 =       zviseta (ji,jj-1) + dm
269               zvis21 =       zviseta (ji,jj-1)
270               zdiag = zvis22 * ( -akappa(ji,jj-1,1,1) + akappa(ji,jj-1,2,1) )
271               zs11_21 = -zvis11 * akappa(ji,jj-1,1,1) + zdiag
272               zs12_21 =  zvis12 * akappa(ji,jj-1,2,2) - zvis21 * akappa(ji,jj-1,1,2)
273               zs22_21 =  zvis11 * akappa(ji,jj-1,2,1) + zdiag
274               zs21_21 = -zvis12 * akappa(ji,jj-1,1,2) + zvis21 * akappa(ji,jj-1,2,2)
275
276               zvis11 = 2.0 * zviseta (ji-1,jj) + dm
277               zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
278               zvis12 =       zviseta (ji-1,jj) + dm
279               zvis21 =       zviseta (ji-1,jj)
280               zdiag = zvis22 * ( akappa(ji-1,jj,1,1) + akappa(ji-1,jj,2,1) )
281               zs11_12 =  zvis11 * akappa(ji-1,jj,1,1) + zdiag
282               zs12_12 = -zvis12 * akappa(ji-1,jj,2,2) - zvis21 * akappa(ji-1,jj,1,2)
283               zs22_12 =  zvis11 * akappa(ji-1,jj,2,1) + zdiag
284               zs21_12 = -zvis12 * akappa(ji-1,jj,1,2) - zvis21 * akappa(ji-1,jj,2,2)
285
286               zvis11 = 2.0 * zviseta (ji,jj) + dm
287               zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
288               zvis12 =       zviseta (ji,jj) + dm
289               zvis21 =       zviseta (ji,jj)
290               zdiag = zvis22 * ( -akappa(ji,jj,1,1) + akappa(ji,jj,2,1) )
291               zs11_22 = -zvis11 * akappa(ji,jj,1,1) + zdiag
292               zs12_22 = -zvis12 * akappa(ji,jj,2,2) - zvis21 * akappa(ji,jj,1,2)
293               zs22_22 =  zvis11 * akappa(ji,jj,2,1) + zdiag
294               zs21_22 = -zvis12 * akappa(ji,jj,1,2) - zvis21 * akappa(ji,jj,2,2)
295
296               zc1u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
297                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
298                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
299                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
300                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
301                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
302                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
303                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
304
305               zc2u(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
306                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
307                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
308                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
309                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
310                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
311                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
312                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
313
314               !* zc1v , zc2v.
315               zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
316               zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
317               zvis12 =       zviseta (ji-1,jj-1) + dm
318               zvis21 =       zviseta (ji-1,jj-1)
319               zdiag = zvis22 * ( akappa(ji-1,jj-1,1,2) + akappa(ji-1,jj-1,2,2) )
320               zs11_11 =  zvis11 * akappa(ji-1,jj-1,1,2) + zdiag
321               zs12_11 = -zvis12 * akappa(ji-1,jj-1,2,1) + zvis21 * akappa(ji-1,jj-1,1,1)
322               zs22_11 =  zvis11 * akappa(ji-1,jj-1,2,2) + zdiag
323               zs21_11 =  zvis12 * akappa(ji-1,jj-1,1,1) - zvis21 * akappa(ji-1,jj-1,2,1)
324 
325               zvis11 = 2.0 * zviseta (ji,jj-1) + dm
326               zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
327               zvis12 =       zviseta (ji,jj-1) + dm
328               zvis21 =       zviseta (ji,jj-1)
329               zdiag = zvis22 * ( akappa(ji,jj-1,1,2) + akappa(ji,jj-1,2,2) )
330               zs11_21 =  zvis11 * akappa(ji,jj-1,1,2) + zdiag
331               zs12_21 = -zvis12 * akappa(ji,jj-1,2,1) - zvis21 * akappa(ji,jj-1,1,1)
332               zs22_21 =  zvis11 * akappa(ji,jj-1,2,2) + zdiag
333               zs21_21 = -zvis12 * akappa(ji,jj-1,1,1) - zvis21 * akappa(ji,jj-1,2,1)
334
335               zvis11 = 2.0 * zviseta (ji-1,jj) + dm
336               zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
337               zvis12 =       zviseta (ji-1,jj) + dm
338               zvis21 =       zviseta (ji-1,jj)
339               zdiag = zvis22 * ( akappa(ji-1,jj,1,2) - akappa(ji-1,jj,2,2) )
340               zs11_12 =  zvis11 * akappa(ji-1,jj,1,2) + zdiag
341               zs12_12 = -zvis12 * akappa(ji-1,jj,2,1) + zvis21 * akappa(ji-1,jj,1,1)
342               zs22_12 = -zvis11 * akappa(ji-1,jj,2,2) + zdiag
343               zs21_12 =  zvis12 * akappa(ji-1,jj,1,1) - zvis21 * akappa(ji-1,jj,2,1)
344
345               zvis11 = 2.0 * zviseta (ji,jj) + dm
346               zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
347               zvis12 =       zviseta (ji,jj) + dm
348               zvis21 =       zviseta (ji,jj)
349               zdiag = zvis22 * ( akappa(ji,jj,1,2) - akappa(ji,jj,2,2) )
350               zs11_22 =  zvis11 * akappa(ji,jj,1,2) + zdiag
351               zs12_22 = -zvis12 * akappa(ji,jj,2,1) - zvis21 * akappa(ji,jj,1,1)
352               zs22_22 = -zvis11 * akappa(ji,jj,2,2) + zdiag
353               zs21_22 = -zvis12 * akappa(ji,jj,1,1) - zvis21 * akappa(ji,jj,2,1)
354
355               zc1v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22   &
356                  &          - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12   &
357                  &          - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11   &
358                  &          + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12   &
359                  &          + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21   &
360                  &          + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22   &
361                  &          - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21   &
362                  &          - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
363
364               zc2v(ji,jj) = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22   &
365                  &          - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12   &
366                  &          - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11   &
367                  &          + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12   &
368                  &          - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21   &
369                  &          - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22   &
370                  &          + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21   &
371                  &          + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
372            END DO
373         END DO
374
375         ! GAUSS-SEIDEL method
376         !                                                      ! ================ !
377iflag:   DO jter = 1 , nbitdr                                   !    Relaxation    !
378            !                                                   ! ================ !
379!CDIR NOVERRCHK
380            DO jj = k_j1+1, k_jpj-1
381!CDIR NOVERRCHK
382               DO ji = 2, fs_jpim1   ! NO vector opt.
383                  !
384                  ze11 =   akappa(ji,jj-1,1,1) * zu_a(ji+1,jj) + akappa(ji,jj-1,1,2) * zv_a(ji+1,jj)
385                  ze12 = + akappa(ji,jj-1,2,2) * zu_a(ji+1,jj) - akappa(ji,jj-1,2,1) * zv_a(ji+1,jj)
386                  ze22 = + akappa(ji,jj-1,2,2) * zv_a(ji+1,jj) + akappa(ji,jj-1,2,1) * zu_a(ji+1,jj)
387                  ze21 =   akappa(ji,jj-1,1,1) * zv_a(ji+1,jj) - akappa(ji,jj-1,1,2) * zu_a(ji+1,jj)
388                  zvis11 = 2.0 * zviseta (ji,jj-1) + dm
389                  zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
390                  zvis12 =       zviseta (ji,jj-1) + dm
391                  zvis21 =       zviseta (ji,jj-1)
392                  zdiag = zvis22 * ( ze11 + ze22 )
393                  zs11_21 =  zvis11 * ze11 + zdiag
394                  zs12_21 =  zvis12 * ze12 + zvis21 * ze21
395                  zs22_21 =  zvis11 * ze22 + zdiag
396                  zs21_21 =  zvis12 * ze21 + zvis21 * ze12
397
398                  ze11 =   akappa(ji-1,jj,1,1) * ( zu_a(ji  ,jj+1) - zu_a(ji-1,jj+1) )   &
399                     &   + akappa(ji-1,jj,1,2) * ( zv_a(ji  ,jj+1) + zv_a(ji-1,jj+1) )
400                  ze12 = + akappa(ji-1,jj,2,2) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )   &
401                     &   - akappa(ji-1,jj,2,1) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )
402                  ze22 = + akappa(ji-1,jj,2,2) * ( zv_a(ji-1,jj+1) + zv_a(ji  ,jj+1) )   &
403                     &   + akappa(ji-1,jj,2,1) * ( zu_a(ji-1,jj+1) + zu_a(ji  ,jj+1) )
404                  ze21 =   akappa(ji-1,jj,1,1) * ( zv_a(ji  ,jj+1) - zv_a(ji-1,jj+1) )   &
405                     &   - akappa(ji-1,jj,1,2) * ( zu_a(ji  ,jj+1) + zu_a(ji-1,jj+1) )
406                  zvis11 = 2.0 * zviseta (ji-1,jj) + dm
407                  zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
408                  zvis12 =       zviseta (ji-1,jj) + dm
409                  zvis21 =       zviseta (ji-1,jj)
410                  zdiag = zvis22 * ( ze11 + ze22 )
411                  zs11_12 =  zvis11 * ze11 + zdiag
412                  zs12_12 =  zvis12 * ze12 + zvis21 * ze21
413                  zs22_12 =  zvis11 * ze22 + zdiag
414                  zs21_12 =  zvis12 * ze21 + zvis21 * ze12
415
416                  ze11 =   akappa(ji,jj,1,1) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) - zu_a(ji  ,jj+1) )   &
417                     &   + akappa(ji,jj,1,2) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) + zv_a(ji  ,jj+1) )
418                  ze12 = - akappa(ji,jj,2,2) * ( zu_a(ji+1,jj) - zu_a(ji  ,jj+1) - zu_a(ji+1,jj+1) )   &
419                     &   - akappa(ji,jj,2,1) * ( zv_a(ji+1,jj) + zv_a(ji  ,jj+1) + zv_a(ji+1,jj+1) )
420                  ze22 = - akappa(ji,jj,2,2) * ( zv_a(ji+1,jj) - zv_a(ji  ,jj+1) - zv_a(ji+1,jj+1) )   &
421                     &   + akappa(ji,jj,2,1) * ( zu_a(ji+1,jj) + zu_a(ji  ,jj+1) + zu_a(ji+1,jj+1) )
422                  ze21 =   akappa(ji,jj,1,1) * ( zv_a(ji+1,jj) + zv_a(ji+1,jj+1) - zv_a(ji  ,jj+1) )   &
423                     &   - akappa(ji,jj,1,2) * ( zu_a(ji+1,jj) + zu_a(ji+1,jj+1) + zu_a(ji  ,jj+1) )
424                  zvis11 = 2.0 * zviseta (ji,jj) + dm
425                  zvis22 =       zviszeta(ji,jj) - zviseta(ji,jj)
426                  zvis12 =       zviseta (ji,jj) + dm
427                  zvis21 =       zviseta (ji,jj)
428                  zdiag = zvis22 * ( ze11 + ze22 )
429                  zs11_22 =  zvis11 * ze11 + zdiag
430                  zs12_22 =  zvis12 * ze12 + zvis21 * ze21
431                  zs22_22 =  zvis11 * ze22 + zdiag
432                  zs21_22 =  zvis12 * ze21 + zvis21 * ze12
433
434            ! 2nd part
435                  ze11 =   akappa(ji-1,jj-1,1,1) * ( zu_a(ji  ,jj-1) - zu_a(ji-1,jj-1) - zu_a(ji-1,jj) )   &
436                     &   + akappa(ji-1,jj-1,1,2) * ( zv_a(ji  ,jj-1) + zv_a(ji-1,jj-1) + zv_a(ji-1,jj) )
437                  ze12 = - akappa(ji-1,jj-1,2,2) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) - zu_a(ji-1,jj) )   &
438                     &   - akappa(ji-1,jj-1,2,1) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) + zv_a(ji-1,jj) )
439                  ze22 = - akappa(ji-1,jj-1,2,2) * ( zv_a(ji-1,jj-1) + zv_a(ji  ,jj-1) - zv_a(ji-1,jj) )   &
440                     &   + akappa(ji-1,jj-1,2,1) * ( zu_a(ji-1,jj-1) + zu_a(ji  ,jj-1) + zu_a(ji-1,jj) )
441                  ze21 =   akappa(ji-1,jj-1,1,1) * ( zv_a(ji  ,jj-1) - zv_a(ji-1,jj-1) - zv_a(ji-1,jj) )   &
442                     &  -  akappa(ji-1,jj-1,1,2) * ( zu_a(ji  ,jj-1) + zu_a(ji-1,jj-1) + zu_a(ji-1,jj) )
443                  zvis11 = 2.0 * zviseta (ji-1,jj-1) + dm
444                  zvis22 =       zviszeta(ji-1,jj-1) - zviseta(ji-1,jj-1)
445                  zvis12 =       zviseta (ji-1,jj-1) + dm
446                  zvis21 =       zviseta (ji-1,jj-1)
447                  zdiag = zvis22 * ( ze11 + ze22 )
448                  zs11_11 =  zvis11 * ze11 + zdiag
449                  zs12_11 =  zvis12 * ze12 + zvis21 * ze21
450                  zs22_11 =  zvis11 * ze22 + zdiag
451                  zs21_11 =  zvis12 * ze21 + zvis21 * ze12
452
453                  ze11 =   akappa(ji,jj-1,1,1) * ( zu_a(ji+1,jj-1) - zu_a(ji  ,jj-1) )   &
454                     &   + akappa(ji,jj-1,1,2) * ( zv_a(ji+1,jj-1) + zv_a(ji  ,jj-1) )
455                  ze12 = - akappa(ji,jj-1,2,2) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )   &
456                     &   - akappa(ji,jj-1,2,1) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )
457                  ze22 = - akappa(ji,jj-1,2,2) * ( zv_a(ji  ,jj-1) + zv_a(ji+1,jj-1) )   &
458                     &   + akappa(ji,jj-1,2,1) * ( zu_a(ji  ,jj-1) + zu_a(ji+1,jj-1) )
459                  ze21 =   akappa(ji,jj-1,1,1) * ( zv_a(ji+1,jj-1) - zv_a(ji  ,jj-1) )   &
460                     &   - akappa(ji,jj-1,1,2) * ( zu_a(ji+1,jj-1) + zu_a(ji  ,jj-1) )
461                  zvis11 = 2.0 * zviseta (ji,jj-1) + dm
462                  zvis22 =       zviszeta(ji,jj-1) - zviseta(ji,jj-1)
463                  zvis12 =       zviseta (ji,jj-1) + dm
464                  zvis21 =       zviseta (ji,jj-1)
465                  zdiag = zvis22 * ( ze11 + ze22 )
466                  zs11_21 =  zs11_21 + zvis11 * ze11 + zdiag
467                  zs12_21 =  zs12_21 + zvis12 * ze12 + zvis21 * ze21
468                  zs22_21 =  zs22_21 + zvis11 * ze22 + zdiag
469                  zs21_21 =  zs21_21 + zvis12 * ze21 + zvis21 * ze12
470
471                  ze11 = - akappa(ji-1,jj,1,1) * zu_a(ji-1,jj) + akappa(ji-1,jj,1,2) * zv_a(ji-1,jj)
472                  ze12 = - akappa(ji-1,jj,2,2) * zu_a(ji-1,jj) - akappa(ji-1,jj,2,1) * zv_a(ji-1,jj)
473                  ze22 = - akappa(ji-1,jj,2,2) * zv_a(ji-1,jj) + akappa(ji-1,jj,2,1) * zu_a(ji-1,jj)
474                  ze21 = - akappa(ji-1,jj,1,1) * zv_a(ji-1,jj) - akappa(ji-1,jj,1,2) * zu_a(ji-1,jj)
475                  zvis11 = 2.0 * zviseta (ji-1,jj) + dm
476                  zvis22 =       zviszeta(ji-1,jj) - zviseta(ji-1,jj)
477                  zvis12 =       zviseta (ji-1,jj) + dm
478                  zvis21 =       zviseta (ji-1,jj)
479                  zdiag = zvis22 * ( ze11 + ze22 )
480                  zs11_12 =  zs11_12 + zvis11 * ze11 + zdiag
481                  zs12_12 =  zs12_12 + zvis12 * ze12 + zvis21 * ze21
482                  zs22_12 =  zs22_12 + zvis11 * ze22 + zdiag
483                  zs21_12 =  zs21_12 + zvis12 * ze21 + zvis21 * ze12
484
485                  zd1 = + alambd(ji,jj,2,2,2,1) * zs11_21 + alambd(ji,jj,2,2,2,2) * zs11_22  &
486                     &  - alambd(ji,jj,2,2,1,1) * zs11_11 - alambd(ji,jj,2,2,1,2) * zs11_12  &
487                     &  - alambd(ji,jj,1,1,2,1) * zs12_21 - alambd(ji,jj,1,1,1,1) * zs12_11  &
488                     &  + alambd(ji,jj,1,1,2,2) * zs12_22 + alambd(ji,jj,1,1,1,2) * zs12_12  &
489                     &  + alambd(ji,jj,1,2,1,1) * zs21_11 + alambd(ji,jj,1,2,2,1) * zs21_21  &
490                     &  + alambd(ji,jj,1,2,1,2) * zs21_12 + alambd(ji,jj,1,2,2,2) * zs21_22  &
491                     &  - alambd(ji,jj,2,1,1,1) * zs22_11 - alambd(ji,jj,2,1,2,1) * zs22_21  &
492                     &  - alambd(ji,jj,2,1,1,2) * zs22_12 - alambd(ji,jj,2,1,2,2) * zs22_22
493
494                  zd2 = + alambd(ji,jj,2,2,2,1) * zs21_21 + alambd(ji,jj,2,2,2,2) * zs21_22  &
495                     &  - alambd(ji,jj,2,2,1,1) * zs21_11 - alambd(ji,jj,2,2,1,2) * zs21_12  &
496                     &  - alambd(ji,jj,1,1,2,1) * zs22_21 - alambd(ji,jj,1,1,1,1) * zs22_11  &
497                     &  + alambd(ji,jj,1,1,2,2) * zs22_22 + alambd(ji,jj,1,1,1,2) * zs22_12  &
498                     &  - alambd(ji,jj,1,2,1,1) * zs11_11 - alambd(ji,jj,1,2,2,1) * zs11_21  &
499                     &  - alambd(ji,jj,1,2,1,2) * zs11_12 - alambd(ji,jj,1,2,2,2) * zs11_22  &
500                     &  + alambd(ji,jj,2,1,1,1) * zs12_11 + alambd(ji,jj,2,1,2,1) * zs12_21  &
501                     &  + alambd(ji,jj,2,1,1,2) * zs12_12 + alambd(ji,jj,2,1,2,2) * zs12_22
502
503                  zur     = zu_a(ji,jj) - u_oce(ji,jj)
504                  zvr     = zv_a(ji,jj) - v_oce(ji,jj)
505!!!!
506                  zmod    = SQRT( zur*zur + zvr*zvr ) * ( 1.0 - zfrld(ji,jj) )
507                  za      = rhoco * zmod
508!!!!
509!!gm chg resul    za      = rhoco * SQRT( zur*zur + zvr*zvr ) * ( 1.0 - zfrld(ji,jj) )
510                  zac     = za * cangvg
511                  zmpzas  = alpha * zcorl(ji,jj) + za * zsang(ji,jj)
512                  zmassdt = zusdtp * zmass(ji,jj)
513                  zcorlal = ( 1.0 - alpha ) * zcorl(ji,jj)
514
515                  za1 =  zmassdt * zu0(ji,jj) + zcorlal * zv0(ji,jj) + za1ct(ji,jj)   &
516                     &        + za * ( cangvg * u_oce(ji,jj) - zsang(ji,jj) * v_oce(ji,jj) )
517                  za2 =  zmassdt * zv0(ji,jj) - zcorlal * zu0(ji,jj) + za2ct(ji,jj)   &
518                     &        + za * ( cangvg * v_oce(ji,jj) + zsang(ji,jj) * u_oce(ji,jj) )
519                  zb1    = zmassdt + zac - zc1u(ji,jj)
520                  zb2    = zmpzas        - zc2u(ji,jj)
521                  zc1    = zmpzas        + zc1v(ji,jj)
522                  zc2    = zmassdt + zac - zc2v(ji,jj)
523                  zdeter = zc1 * zb2 + zc2 * zb1
524                  zden   = SIGN( rone, zdeter) / MAX( epsd , ABS( zdeter ) )
525                  zunw   = (  ( za1 + zd1 ) * zc2 + ( za2 + zd2 ) * zc1 ) * zden
526                  zvnw   = (  ( za2 + zd2 ) * zb1 - ( za1 + zd1 ) * zb2 ) * zden
527                  zmask  = ( 1.0 - MAX( rzero, SIGN( rone , 1.0 - zmass(ji,jj) ) ) ) * tmu(ji,jj)
528
529                  zu_n(ji,jj) = ( zu_a(ji,jj) + om * ( zunw - zu_a(ji,jj) ) * tmu(ji,jj) ) * zmask
530                  zv_n(ji,jj) = ( zv_a(ji,jj) + om * ( zvnw - zv_a(ji,jj) ) * tmu(ji,jj) ) * zmask
531               END DO
532            END DO
533
534            CALL lbc_lnk( zu_n(:,1:jpj), 'I', -1. )
535            CALL lbc_lnk( zv_n(:,1:jpj), 'I', -1. )
536
537            ! Test of Convergence
538            DO jj = k_j1+1 , k_jpj-1
539               zresr(:,jj) = MAX( ABS( zu_a(:,jj) - zu_n(:,jj) ) , ABS( zv_a(:,jj) - zv_n(:,jj) ) )
540            END DO
541            zresm = MAXVAL( zresr(1:jpi,k_j1+1:k_jpj-1) )
542!!!! this should be faster on scalar processor
543!           zresm = MAXVAL(  MAX( ABS( zu_a(1:jpi,k_j1+1:k_jpj-1) - zu_n(1:jpi,k_j1+1:k_jpj-1) ),   &
544!              &                  ABS( zv_a(1:jpi,k_j1+1:k_jpj-1) - zv_n(1:jpi,k_j1+1:k_jpj-1) ) )  )
545!!!!
546            IF( lk_mpp )   CALL mpp_max( zresm )   ! max over the global domain
547
548            DO jj = k_j1, k_jpj
549               zu_a(:,jj) = zu_n(:,jj)
550               zv_a(:,jj) = zv_n(:,jj)
551            END DO
552
553            IF( zresm <= resl )   EXIT   iflag
554
555            !                                                   ! ================ !
556         END DO    iflag                                        !  end Relaxation  !
557         !                                                      ! ================ !
558
559         IF( zindu == 0 ) THEN      ! even iteration
560            DO jj = k_j1 , k_jpj-1
561               zu0(:,jj) = zu_a(:,jj)
562               zv0(:,jj) = zv_a(:,jj)
563            END DO
564         ENDIF
565         !                                                ! ==================== !
566      END DO                                              !  end loop over iter  !
567      !                                                   ! ==================== !
568
569      u_ice(:,:) = zu_a(:,1:jpj)
570      v_ice(:,:) = zv_a(:,1:jpj)
571
572      IF(ln_ctl) THEN
573         WRITE(charout,FMT="('lim_rhg  : res =',D23.16, ' iter =',I4)") zresm, jter
574         CALL prt_ctl_info(charout)
575         CALL prt_ctl(tab2d_1=u_ice, clinfo1=' lim_rhg  : u_ice :', tab2d_2=v_ice, clinfo2=' v_ice :')
576      ENDIF
577
578   END SUBROUTINE lim_rhg_2
579
580#else
581   !!----------------------------------------------------------------------
582   !!   Default option          Dummy module       NO 2.0 LIM sea-ice model
583   !!----------------------------------------------------------------------
584CONTAINS
585   SUBROUTINE lim_rhg_2( k1 , k2 )       ! Dummy routine
586      WRITE(*,*) 'lim_rhg_2: You should not have seen this print! error?', k1, k2
587   END SUBROUTINE lim_rhg_2
588#endif
589
590   !!==============================================================================
591END MODULE limrhg_2
Note: See TracBrowser for help on using the repository browser.