source: trunk/NEMOGCM/NEMO/OFF_SRC/zdfmxl.F90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 10 years ago

First attempt to put dynamic allocation on the trunk

File size: 5.7 KB
Line 
1MODULE zdfmxl
2   !!======================================================================
3   !!                       ***  MODULE  zdfmxl  ***
4   !! Ocean physics: mixed layer depth
5   !!======================================================================
6   !! History :  1.0  ! 2003-08  (G. Madec)  original code
7   !!            3.2  ! 2009-07  (S. Masson, G. Madec)  IOM + merge of DO-loop
8   !!----------------------------------------------------------------------
9   !!   zdf_mxl      : Compute the turbocline and mixed layer depths.
10   !!----------------------------------------------------------------------
11   USE oce             ! ocean dynamics and tracers variables
12   USE dom_oce         ! ocean space and time domain variables
13   USE zdf_oce         ! ocean vertical physics
14   USE in_out_manager  ! I/O manager
15   USE prtctl          ! Print control
16   USE iom             ! I/O library
17   USE lib_mpp         ! MPP library
18
19   IMPLICIT NONE
20   PRIVATE
21
22   PUBLIC   zdf_mxl       ! called by step.F90
23   PUBLIC   zdf_mxl_alloc ! called by nemogcm.F90
24
25   INTEGER , PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   nmln    !: number of level in the mixed layer (used by TOP)
26   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmld    !: mixing layer depth (turbocline)      [m]
27   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlp    !: mixed layer depth  (rho=rho0+zdcrit) [m]
28   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlpt   !: mixed layer depth at t-points        [m]
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
34   !! $Id: zdfmxl.F90 2636 2011-03-01 19:04:06Z gm $
35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   INTEGER FUNCTION zdf_mxl_alloc()
40      !!----------------------------------------------------------------------
41      !!               ***  FUNCTION zdf_mxl_alloc  ***
42      !!----------------------------------------------------------------------
43      ALLOCATE( nmln(jpi,jpj), hmld(jpi,jpj), hmlp(jpi,jpj), hmlpt(jpi,jpj), STAT=zdf_mxl_alloc )
44      !
45      IF( lk_mpp             )   CALL mpp_sum ( zdf_mxl_alloc )
46      IF( zdf_mxl_alloc /= 0 )   CALL ctl_warn('zdf_mxl_alloc: failed to allocate arrays')
47   END FUNCTION zdf_mxl_alloc
48
49
50   SUBROUTINE zdf_mxl( kt )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE zdfmxl  ***
53      !!                   
54      !! ** Purpose :   Compute the turbocline depth and the mixed layer depth
55      !!              with density criteria.
56      !!
57      !! ** Method  :   The mixed layer depth is the shallowest W depth with
58      !!      the density of the corresponding T point (just bellow) bellow a
59      !!      given value defined locally as rho(10m) + zrho_c
60      !!               The turbocline depth is the depth at which the vertical
61      !!      eddy diffusivity coefficient (resulting from the vertical physics
62      !!      alone, not the isopycnal part, see trazdf.F) fall below a given
63      !!      value defined locally (avt_c here taken equal to 5 cm/s2)
64      !!
65      !! ** Action  :   nmln, hmld, hmlp, hmlpt
66      !!----------------------------------------------------------------------
67      USE wrk_nemo, ONLY:   iwrk_in_use, iwrk_not_released
68      USE wrk_nemo, ONLY:   imld => iwrk_2d_1    ! 2D integer workspace
69      !!
70      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
71      !!
72      INTEGER  ::   ji, jj, jk          ! dummy loop indices
73      INTEGER  ::   iikn, iiki          ! temporary integer within a do loop
74      REAL(wp) ::   zrho_c = 0.01_wp    ! density criterion for mixed layer depth
75      REAL(wp) ::   zavt_c = 5.e-4_wp   ! Kz criterion for the turbocline depth
76      !!----------------------------------------------------------------------
77
78      IF( iwrk_in_use(2, 1) ) THEN
79         CALL ctl_stop('zdf_mxl : requested workspace array unavailable')   ;   RETURN
80      ENDIF
81
82      IF( kt == nit000 ) THEN
83         IF(lwp) WRITE(numout,*)
84         IF(lwp) WRITE(numout,*) 'zdf_mxl : mixed layer depth'
85         IF(lwp) WRITE(numout,*) '~~~~~~~ '
86      ENDIF
87
88      ! w-level of the mixing and mixed layers
89      nmln(:,:) = mbkt(:,:) + 1        ! Initialization to the number of w ocean point
90      imld(:,:) = mbkt(:,:) + 1
91      DO jk = jpkm1, nlb10, -1         ! from the bottom to nlb10
92         DO jj = 1, jpj
93            DO ji = 1, jpi
94               IF( rhop(ji,jj,jk) > rhop(ji,jj,nla10) + zrho_c )   nmln(ji,jj) = jk      ! Mixed layer
95               IF( avt (ji,jj,jk) < zavt_c                     )   imld(ji,jj) = jk      ! Turbocline
96            END DO
97         END DO
98      END DO
99      ! depth of the mixing and mixed layers
100      DO jj = 1, jpj
101         DO ji = 1, jpi
102            iiki = imld(ji,jj)
103            iikn = nmln(ji,jj)
104            hmld (ji,jj) = fsdepw(ji,jj,iiki  ) * tmask(ji,jj,1)    ! Turbocline depth
105            hmlp (ji,jj) = fsdepw(ji,jj,iikn  ) * tmask(ji,jj,1)    ! Mixed layer depth
106            hmlpt(ji,jj) = fsdept(ji,jj,iikn-1)                     ! depth of the last T-point inside the mixed layer
107         END DO
108      END DO
109      CALL iom_put( "mldr10_1", hmlp )   ! mixed layer depth
110      CALL iom_put( "mldkz5"  , hmld )   ! turbocline depth
111     
112      IF(ln_ctl)   CALL prt_ctl( tab2d_1=REAL(nmln,wp), clinfo1=' nmln : ', tab2d_2=hmlp, clinfo2=' hmlp : ', ovlap=1 )
113      !
114      IF( iwrk_not_released(2, 1) )   CALL ctl_stop('zdf_mxl: failed to release workspace array')
115      !
116   END SUBROUTINE zdf_mxl
117
118   !!======================================================================
119END MODULE zdfmxl
Note: See TracBrowser for help on using the repository browser.