New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DOM/daymod.F90 @ 3604

Last change on this file since 3604 was 3604, checked in by rblod, 10 years ago

Adding routines and modules for TAM - Ticket #1005

  • Property svn:keywords set to Id
File size: 17.5 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !!
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !!
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
33   USE prtctl          ! Print control
34   USE restart         !
35   USE trc_oce, ONLY : lk_offline ! offline flag
36   USE timing          ! Timing
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   day        ! called by step.F90
42   PUBLIC   day_init   ! called by istate.F90
43   PUBLIC   day_mth    ! Needed by TAM
44
45   INTEGER, PUBLIC ::   nsecd, nsecd05, ndt, ndt05 ! (PUBLIC for TAM)
46
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE day_init
55      !!----------------------------------------------------------------------
56      !!                   ***  ROUTINE day_init  ***
57      !!
58      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
59      !!                because day will be called at the beginning of step
60      !!
61      !! ** Action  : - nyear        : current year
62      !!              - nmonth       : current month of the year nyear
63      !!              - nday         : current day of the month nmonth
64      !!              - nday_year    : current day of the year nyear
65      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
66      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
67      !!              - nsec_day     : current time step counted in second since 00h of the current day
68      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
69      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
70      !!----------------------------------------------------------------------
71      INTEGER  ::   inbday, idweek
72      REAL(wp) ::   zjul
73      !!----------------------------------------------------------------------
74      !
75      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
76      IF( MOD( rday     , rdttra(1) ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
77      IF( MOD( rday     , 2.        ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
78      IF( MOD( rdttra(1), 2.        ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
79      nsecd   = NINT(rday           )
80      nsecd05 = NINT(0.5 * rday     )
81      ndt     = NINT(      rdttra(1))
82      ndt05   = NINT(0.5 * rdttra(1))
83
84      IF( .NOT. lk_offline ) CALL day_rst( nit000, 'READ' )
85
86      ! set the calandar from ndastp (read in restart file and namelist)
87
88      nyear   =   ndastp / 10000
89      nmonth  = ( ndastp - (nyear * 10000) ) / 100
90      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 )
91
92      CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday )  ! we assume that we start run at 00:00
93      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
94      fjulday = fjulday + 1.                             ! move back to the day at nit000 (and not at nit000 - 1)
95
96      nsec1jan000 = 0
97      CALL day_mth
98
99      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
100         nmonth = nmonth - 1
101         nday = nmonth_len(nmonth)
102      ENDIF
103      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
104         nmonth = 12
105         nyear = nyear - 1
106         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
107         IF( nleapy == 1 )   CALL day_mth
108      ENDIF
109
110      ! day since january 1st
111      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
112
113      !compute number of days between last monday and today
114      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
115      inbday = NINT(fjulday - zjul)            ! compute nb day between  01.01.1900 and current day
116      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day
117
118      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
119      nsec_year  = nday_year * nsecd - ndt05   ! 1 time step before the middle of the first time step
120      nsec_month = nday      * nsecd - ndt05   ! because day will be called at the beginning of step
121      nsec_week  = idweek    * nsecd - ndt05
122      nsec_day   =             nsecd - ndt05
123
124      ! control print
125      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i6)')' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
126           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week
127
128      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
129      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
130      CALL day( nit000 )
131      !
132   END SUBROUTINE day_init
133
134
135   SUBROUTINE day_mth
136      !!----------------------------------------------------------------------
137      !!                   ***  ROUTINE day_init  ***
138      !!
139      !! ** Purpose :   calendar values related to the months
140      !!
141      !! ** Action  : - nmonth_len    : length in days of the months of the current year
142      !!              - nyear_len     : length in days of the previous/current year
143      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
144      !!              - nmonth_end    : second since the beginning of the year and the end of the months
145      !!----------------------------------------------------------------------
146      INTEGER  ::   jm               ! dummy loop indice
147      !!----------------------------------------------------------------------
148
149      ! length of the month of the current year (from nleapy, read in namelist)
150      IF ( nleapy < 2 ) THEN
151         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
152         nyear_len(:) = 365
153         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
154            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
155               nyear_len(0) = 366
156            ENDIF
157            IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN
158               nmonth_len(2) = 29
159               nyear_len(1) = 366
160            ENDIF
161         ENDIF
162      ELSE
163         nmonth_len(:) = nleapy   ! all months with nleapy days per year
164         nyear_len(:) = 12 * nleapy
165      ENDIF
166
167      ! half month in second since the begining of the year:
168      ! time since Jan 1st   0     1     2    ...    11    12    13
169      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
170      !                 <---> <---> <--->  ...  <---> <---> <--->
171      ! month number      0     1     2    ...    11    12    13
172      !
173      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
174      nmonth_half(0) = - nsecd05 * nmonth_len(0)
175      DO jm = 1, 13
176         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
177      END DO
178
179      nmonth_end(0) = 0
180      DO jm = 1, 13
181         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
182      END DO
183      !
184   END SUBROUTINE
185
186
187   SUBROUTINE day( kt )
188      !!----------------------------------------------------------------------
189      !!                      ***  ROUTINE day  ***
190      !!
191      !! ** Purpose :   Compute the date with a day iteration IF necessary.
192      !!
193      !! ** Method  : - ???
194      !!
195      !! ** Action  : - nyear     : current year
196      !!              - nmonth    : current month of the year nyear
197      !!              - nday      : current day of the month nmonth
198      !!              - nday_year : current day of the year nyear
199      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
200      !!              - adatrj    : date in days since the beginning of the run
201      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
202      !!----------------------------------------------------------------------
203      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
204      !
205      CHARACTER (len=25) ::   charout
206      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
207      !!----------------------------------------------------------------------
208      !
209      IF( nn_timing == 1 )  CALL timing_start('day')
210      !
211      zprec = 0.1 / rday
212      !                                                 ! New time-step
213      nsec_year  = nsec_year  + ndt
214      nsec_month = nsec_month + ndt
215      nsec_week  = nsec_week  + ndt
216      nsec_day   = nsec_day   + ndt
217      adatrj  = adatrj  + rdttra(1) / rday
218      fjulday = fjulday + rdttra(1) / rday
219      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
220      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
221
222      IF( nsec_day > nsecd ) THEN                       ! New day
223         !
224         nday      = nday + 1
225         nday_year = nday_year + 1
226         nsec_day  = ndt05
227         !
228         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
229            nday   = 1
230            nmonth = nmonth + 1
231            nsec_month = ndt05
232            IF( nmonth == 13 ) THEN                     ! New year
233               nyear     = nyear + 1
234               nmonth    = 1
235               nday_year = 1
236               nsec_year = ndt05
237               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
238               IF( nleapy == 1 )   CALL day_mth
239            ENDIF
240         ENDIF
241         !
242         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
243         !
244         !compute first day of the year in julian days
245         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
246         !
247         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
248              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
249         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
250              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
251      ENDIF
252
253      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
254
255      IF(ln_ctl) THEN
256         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
257         CALL prt_ctl_info(charout)
258      ENDIF
259
260      IF( .NOT. lk_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
261      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
262      !
263      IF( nn_timing == 1 )  CALL timing_stop('day')
264      !
265   END SUBROUTINE day
266
267
268   SUBROUTINE day_rst( kt, cdrw )
269      !!---------------------------------------------------------------------
270      !!                   ***  ROUTINE ts_rst  ***
271      !!
272      !!  ** Purpose : Read or write calendar in restart file:
273      !!
274      !!  WRITE(READ) mode:
275      !!       kt        : number of time step since the begining of the experiment at the
276      !!                   end of the current(previous) run
277      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
278      !!                   end of the current(previous) run (REAL -> keep fractions of day)
279      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
280      !!
281      !!   According to namelist parameter nrstdt,
282      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
283      !!       nrstdt = 1  we verify that nit000 is equal to the last
284      !!                   time step of previous run + 1.
285      !!       In both those options, the  exact duration of the experiment
286      !!       since the beginning (cumulated duration of all previous restart runs)
287      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
288      !!       This is valid is the time step has remained constant.
289      !!
290      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
291      !!                    has been stored in the restart file.
292      !!----------------------------------------------------------------------
293      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
294      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
295      !
296      REAL(wp) ::   zkt, zndastp
297      !!----------------------------------------------------------------------
298
299      IF( TRIM(cdrw) == 'READ' ) THEN
300
301         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
302            ! Get Calendar informations
303            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
304            IF(lwp) THEN
305               WRITE(numout,*) ' *** Info read in restart : '
306               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
307               WRITE(numout,*) ' *** restart option'
308               SELECT CASE ( nrstdt )
309               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
310               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
311               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
312               END SELECT
313               WRITE(numout,*)
314            ENDIF
315            ! Control of date
316            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
317                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
318                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
319            ! define ndastp and adatrj
320            IF ( nrstdt == 2 ) THEN
321               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
322               CALL iom_get( numror, 'ndastp', zndastp )
323               ndastp = NINT( zndastp )
324               CALL iom_get( numror, 'adatrj', adatrj  )
325            ELSE
326               ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
327               ndastp = ndate0 - 1     ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
328               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
329               ! note this is wrong if time step has changed during run
330            ENDIF
331         ELSE
332            ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
333            ndastp = ndate0 - 1        ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
334            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
335         ENDIF
336         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
337         !
338         IF(lwp) THEN
339            WRITE(numout,*) ' *** Info used values : '
340            WRITE(numout,*) '   date ndastp                                      : ', ndastp
341            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
342            WRITE(numout,*)
343         ENDIF
344         !
345      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
346         !
347         IF( kt == nitrst ) THEN
348            IF(lwp) WRITE(numout,*)
349            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
350            IF(lwp) WRITE(numout,*) '~~~~~~~'
351         ENDIF
352         ! calendar control
353         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
354         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
355         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
356         !                                                                     ! the begining of the run [s]
357      ENDIF
358      !
359   END SUBROUTINE day_rst
360
361   !!======================================================================
362END MODULE daymod
Note: See TracBrowser for help on using the repository browser.