source: trunk/NEMOGCM/NEMO/OPA_SRC/DYN/dynadv_cen2.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 9 years ago

Merge of 3.4beta into the trunk

  • Property svn:keywords set to Id
File size: 8.4 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2       : flux form momentum advection (ln_dynadv_cen2=T)
13   !!                        trends using a 2nd order centred scheme 
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trdmod_oce     ! ocean variables trends
18   USE trdmod         ! ocean dynamics trends
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22   USE wrk_nemo        ! Memory Allocation
23   USE timing          ! Timing
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32#  include "vectopt_loop_substitute.h90"
33   !!----------------------------------------------------------------------
34   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
35   !! $Id$
36   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE dyn_adv_cen2( kt )
41      !!----------------------------------------------------------------------
42      !!                  ***  ROUTINE dyn_adv_cen2  ***
43      !!
44      !! ** Purpose :   Compute the now momentum advection trend in flux form
45      !!              and the general trend of the momentum equation.
46      !!
47      !! ** Method  :   Trend evaluated using now fields (centered in time)
48      !!
49      !! ** Action  :   (ua,va) updated with the now vorticity term trend
50      !!----------------------------------------------------------------------
51      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
52      !
53      INTEGER  ::   ji, jj, jk   ! dummy loop indices
54      REAL(wp) ::   zbu, zbv     ! local scalars
55      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfw
56      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu, zfv
57      !!----------------------------------------------------------------------
58      !
59      IF( nn_timing == 1 )  CALL timing_start('dyn_adv_cen2')
60      !
61      CALL wrk_alloc( jpi, jpj, jpk, zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
62      !
63      IF( kt == nit000 .AND. lwp ) THEN
64         WRITE(numout,*)
65         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
66         WRITE(numout,*) '~~~~~~~~~~~~'
67      ENDIF
68      !
69      IF( l_trddyn ) THEN           ! Save ua and va trends
70         zfu_uw(:,:,:) = ua(:,:,:)
71         zfv_vw(:,:,:) = va(:,:,:)
72      ENDIF
73
74      !                                      ! ====================== !
75      !                                      !  Horizontal advection  !
76      DO jk = 1, jpkm1                       ! ====================== !
77         !                                         ! horizontal volume fluxes
78         zfu(:,:,jk) = 0.25 * e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)
79         zfv(:,:,jk) = 0.25 * e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
80         !
81         DO jj = 1, jpjm1                          ! horizontal momentum fluxes at T- and F-point
82            DO ji = 1, fs_jpim1   ! vector opt.
83               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
84               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
85               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
86               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
87            END DO
88         END DO
89         DO jj = 2, jpjm1                          ! divergence of horizontal momentum fluxes
90            DO ji = fs_2, fs_jpim1   ! vector opt.
91               zbu = e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
92               zbv = e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
93               !
94               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj  ,jk) - zfu_t(ji  ,jj  ,jk)    &
95                  &                           + zfv_f(ji  ,jj  ,jk) - zfv_f(ji  ,jj-1,jk)  ) / zbu
96               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji  ,jj  ,jk) - zfu_f(ji-1,jj  ,jk)    &
97                  &                           + zfv_t(ji  ,jj+1,jk) - zfv_t(ji  ,jj  ,jk)  ) / zbv
98            END DO
99         END DO
100      END DO
101      !
102      IF( l_trddyn ) THEN                          ! save the horizontal advection trend for diagnostic
103         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
104         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
105         CALL trd_mod( zfu_uw, zfv_vw, jpdyn_trd_had, 'DYN', kt )
106         zfu_t(:,:,:) = ua(:,:,:)
107         zfv_t(:,:,:) = va(:,:,:)
108      ENDIF
109      !
110
111      !                                      ! ==================== !
112      !                                      !  Vertical advection  !
113      DO jk = 1, jpkm1                       ! ==================== !
114         !                                         ! Vertical volume fluxesÊ
115         zfw(:,:,jk) = 0.25 * e1t(:,:) * e2t(:,:) * wn(:,:,jk)
116         !
117         IF( jk == 1 ) THEN                        ! surface/bottom advective fluxes                   
118            zfu_uw(:,:,jpk) = 0.e0                      ! Bottom  value : flux set to zero
119            zfv_vw(:,:,jpk) = 0.e0
120            !                                           ! Surface value :
121            IF( lk_vvl ) THEN                                ! variable volume : flux set to zero
122               zfu_uw(:,:, 1 ) = 0.e0   
123               zfv_vw(:,:, 1 ) = 0.e0
124            ELSE                                             ! constant volume : advection through the surface
125               DO jj = 2, jpjm1
126                  DO ji = fs_2, fs_jpim1
127                     zfu_uw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji+1,jj  ,1) ) * un(ji,jj,1)
128                     zfv_vw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji  ,jj+1,1) ) * vn(ji,jj,1)
129                  END DO
130               END DO
131            ENDIF
132         ELSE                                      ! interior fluxes
133            DO jj = 2, jpjm1
134               DO ji = fs_2, fs_jpim1   ! vector opt.
135                  zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
136                  zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
137               END DO
138            END DO
139         ENDIF
140      END DO
141      DO jk = 1, jpkm1                             ! divergence of vertical momentum flux divergence
142         DO jj = 2, jpjm1 
143            DO ji = fs_2, fs_jpim1   ! vector opt.
144               ua(ji,jj,jk) =  ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) )    &
145                  &  / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
146               va(ji,jj,jk) =  va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) )    &
147                  &  / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
148            END DO
149         END DO
150      END DO
151      !
152      IF( l_trddyn ) THEN                          ! save the vertical advection trend for diagnostic
153         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
154         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
155         CALL trd_mod( zfu_t, zfv_t, jpdyn_trd_zad, 'DYN', kt )
156      ENDIF
157      !                                            ! Control print
158      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
159         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
160      !
161      CALL wrk_dealloc( jpi, jpj, jpk, zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
162      !
163      IF( nn_timing == 1 )  CALL timing_stop('dyn_adv_cen2')
164      !
165   END SUBROUTINE dyn_adv_cen2
166
167   !!==============================================================================
168END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.