New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 6152

Last change on this file since 6152 was 6152, checked in by acc, 9 years ago

Add wetting and drying option from dev_r5803_NOC_WAD branch. Logically isolated code changes in domvvl.F90, domzgr.F90, dynhpg.F90, dynspg_ts.F90, sshwzv.F90 and nemogcm.F90. New module wet_dry.F90 in DYN. Fully SETTE tested with code deactivated (ln_wad=.false.). No test case yet available to justify activating option (still under development)
  • Property svn:keywords set to Id
File size: 70.7 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE wet_dry         ! wetting and drying
36   USE phycst          ! physical constants
37   USE trd_oce         ! trends: ocean variables
38   USE trddyn          ! trend manager: dynamics
39!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
40   !
41   USE in_out_manager  ! I/O manager
42   USE prtctl          ! Print control
43   USE lbclnk          ! lateral boundary condition
44   USE lib_mpp         ! MPP library
45   USE eosbn2          ! compute density
46   USE wrk_nemo        ! Memory Allocation
47   USE timing          ! Timing
48   USE iom
49
50   IMPLICIT NONE
51   PRIVATE
52
53   PUBLIC   dyn_hpg        ! routine called by step module
54   PUBLIC   dyn_hpg_init   ! routine called by opa module
55
56   !                                 !!* Namelist namdyn_hpg : hydrostatic pressure gradient
57   LOGICAL , PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
58   LOGICAL , PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
59   LOGICAL , PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
60   LOGICAL , PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
61   LOGICAL , PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
62   LOGICAL , PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
63
64   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
65
66   !! * Substitutions
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
90      !
91      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
92         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93         ztrdu(:,:,:) = ua(:,:,:)
94         ztrdv(:,:,:) = va(:,:,:)
95      ENDIF
96      !
97      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
98      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
99      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
100      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
101      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
102      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
103      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
104      END SELECT
105      !
106      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111      ENDIF
112      !
113      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
114         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
115      !
116      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
117      !
118   END SUBROUTINE dyn_hpg
119
120
121   SUBROUTINE dyn_hpg_init
122      !!----------------------------------------------------------------------
123      !!                 ***  ROUTINE dyn_hpg_init  ***
124      !!
125      !! ** Purpose :   initializations for the hydrostatic pressure gradient
126      !!              computation and consistency control
127      !!
128      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
129      !!      with the type of vertical coordinate used (zco, zps, sco)
130      !!----------------------------------------------------------------------
131      INTEGER ::   ioptio = 0      ! temporary integer
132      INTEGER ::   ios             ! Local integer output status for namelist read
133      !!
134      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
135      REAL(wp) ::   znad
136      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop, zrhd ! hypothesys on isf density
137      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_isf  ! density at bottom of ISF
138      REAL(wp), POINTER, DIMENSION(:,:)     ::  ziceload     ! density at bottom of ISF
139      !!
140      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
141         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
142      !!----------------------------------------------------------------------
143      !
144      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
145      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
146901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
147      !
148      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
149      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
150902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
151      IF(lwm) WRITE ( numond, namdyn_hpg )
152      !
153      IF(lwp) THEN                   ! Control print
154         WRITE(numout,*)
155         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
156         WRITE(numout,*) '~~~~~~~~~~~~'
157         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
158         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
159         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
160         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
161         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
162         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
163         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
164      ENDIF
165      !
166      IF( ln_hpg_djc )   &
167         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
168                           & currently disabled (bugs under investigation). Please select &
169                           & either  ln_hpg_sco or  ln_hpg_prj instead')
170      !
171      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )        &
172         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ', &
173         &                 '   the standard jacobian formulation hpg_sco    or '    , &
174         &                 '   the pressure jacobian formulation hpg_prj'            )
175
176      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
177         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
178      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
179         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
180      !
181      !                               ! Set nhpg from ln_hpg_... flags
182      IF( ln_hpg_zco )   nhpg = 0
183      IF( ln_hpg_zps )   nhpg = 1
184      IF( ln_hpg_sco )   nhpg = 2
185      IF( ln_hpg_djc )   nhpg = 3
186      IF( ln_hpg_prj )   nhpg = 4
187      IF( ln_hpg_isf )   nhpg = 5
188      !
189      !                               ! Consistency check
190      ioptio = 0
191      IF( ln_hpg_zco )   ioptio = ioptio + 1
192      IF( ln_hpg_zps )   ioptio = ioptio + 1
193      IF( ln_hpg_sco )   ioptio = ioptio + 1
194      IF( ln_hpg_djc )   ioptio = ioptio + 1
195      IF( ln_hpg_prj )   ioptio = ioptio + 1
196      IF( ln_hpg_isf )   ioptio = ioptio + 1
197      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
198      !
199      ! initialisation of ice shelf load
200      IF ( .NOT. ln_isfcav ) riceload(:,:)=0.0
201      IF (       ln_isfcav ) THEN
202         CALL wrk_alloc( jpi,jpj, 2,  ztstop) 
203         CALL wrk_alloc( jpi,jpj,jpk, zrhd  )
204         CALL wrk_alloc( jpi,jpj,     zrhdtop_isf, ziceload) 
205         !
206         IF(lwp) WRITE(numout,*)
207         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
208         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' 
209
210         ! To use density and not density anomaly
211         znad=1._wp
212         
213         ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
214         ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
215
216         ! compute density of the water displaced by the ice shelf
217         DO jk = 1, jpk
218            CALL eos(ztstop(:,:,:),gdept_n(:,:,jk),zrhd(:,:,jk))
219         END DO
220     
221         ! compute rhd at the ice/oce interface (ice shelf side)
222         CALL eos(ztstop,risfdep,zrhdtop_isf)
223
224         ! Surface value + ice shelf gradient
225         ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
226         ! divided by 2 later
227         ziceload = 0._wp
228         DO jj = 1, jpj
229            DO ji = 1, jpi
230               ikt=mikt(ji,jj)
231               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * e3w_n(ji,jj,1) * (1._wp - tmask(ji,jj,1))
232               DO jk=2,ikt-1
233                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * e3w_n(ji,jj,jk) &
234                     &                              * (1._wp - tmask(ji,jj,jk))
235               END DO
236               IF (ikt  >=  2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
237                                  &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
238            END DO
239         END DO
240         riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
241
242         CALL wrk_dealloc( jpi,jpj, 2,  ztstop) 
243         CALL wrk_dealloc( jpi,jpj,jpk, zrhd  )
244         CALL wrk_dealloc( jpi,jpj,     zrhdtop_isf, ziceload) 
245      END IF
246      !
247   END SUBROUTINE dyn_hpg_init
248
249
250   SUBROUTINE hpg_zco( kt )
251      !!---------------------------------------------------------------------
252      !!                  ***  ROUTINE hpg_zco  ***
253      !!
254      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
255      !!      The now hydrostatic pressure gradient at a given level, jk,
256      !!      is computed by taking the vertical integral of the in-situ
257      !!      density gradient along the model level from the suface to that
258      !!      level:    zhpi = grav .....
259      !!                zhpj = grav .....
260      !!      add it to the general momentum trend (ua,va).
261      !!            ua = ua - 1/e1u * zhpi
262      !!            va = va - 1/e2v * zhpj
263      !!
264      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
265      !!----------------------------------------------------------------------
266      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
267      !
268      INTEGER  ::   ji, jj, jk       ! dummy loop indices
269      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
270      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
271      !!----------------------------------------------------------------------
272      !
273      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj )
274      !
275      IF( kt == nit000 ) THEN
276         IF(lwp) WRITE(numout,*)
277         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
278         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
279      ENDIF
280
281      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
282
283      ! Surface value
284      DO jj = 2, jpjm1
285         DO ji = fs_2, fs_jpim1   ! vector opt.
286            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
287            ! hydrostatic pressure gradient
288            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
289            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
290            ! add to the general momentum trend
291            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
292            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
293         END DO
294      END DO
295
296      !
297      ! interior value (2=<jk=<jpkm1)
298      DO jk = 2, jpkm1
299         DO jj = 2, jpjm1
300            DO ji = fs_2, fs_jpim1   ! vector opt.
301               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
302               ! hydrostatic pressure gradient
303               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
304                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
305                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
306
307               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
308                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
309                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
310               ! add to the general momentum trend
311               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
312               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
313            END DO
314         END DO
315      END DO
316      !
317      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zhpj )
318      !
319   END SUBROUTINE hpg_zco
320
321
322   SUBROUTINE hpg_zps( kt )
323      !!---------------------------------------------------------------------
324      !!                 ***  ROUTINE hpg_zps  ***
325      !!
326      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
327      !!
328      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
329      !!----------------------------------------------------------------------
330      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
331      !!
332      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
333      INTEGER  ::   iku, ikv                         ! temporary integers
334      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
335      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
336      !!----------------------------------------------------------------------
337      !
338      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj )
339      !
340      IF( kt == nit000 ) THEN
341         IF(lwp) WRITE(numout,*)
342         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
343         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
344      ENDIF
345
346      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
347!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
348
349      ! Local constant initialization
350      zcoef0 = - grav * 0.5_wp
351
352      !  Surface value (also valid in partial step case)
353      DO jj = 2, jpjm1
354         DO ji = fs_2, fs_jpim1   ! vector opt.
355            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
356            ! hydrostatic pressure gradient
357            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
358            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
359            ! add to the general momentum trend
360            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
361            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
362         END DO
363      END DO
364
365      ! interior value (2=<jk=<jpkm1)
366      DO jk = 2, jpkm1
367         DO jj = 2, jpjm1
368            DO ji = fs_2, fs_jpim1   ! vector opt.
369               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
370               ! hydrostatic pressure gradient
371               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
372                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
373                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
374
375               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
376                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
377                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
378               ! add to the general momentum trend
379               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
380               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
381            END DO
382         END DO
383      END DO
384
385      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
386      DO jj = 2, jpjm1
387         DO ji = 2, jpim1
388            iku = mbku(ji,jj)
389            ikv = mbkv(ji,jj)
390            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
391            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
392            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
393               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
394               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
395                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
396               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
397            ENDIF
398            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
399               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
400               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
401                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
402               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
403            ENDIF
404         END DO
405      END DO
406      !
407      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zhpj )
408      !
409   END SUBROUTINE hpg_zps
410
411
412   SUBROUTINE hpg_sco( kt )
413      !!---------------------------------------------------------------------
414      !!                  ***  ROUTINE hpg_sco  ***
415      !!
416      !! ** Method  :   s-coordinate case. Jacobian scheme.
417      !!      The now hydrostatic pressure gradient at a given level, jk,
418      !!      is computed by taking the vertical integral of the in-situ
419      !!      density gradient along the model level from the suface to that
420      !!      level. s-coordinates (ln_sco): a corrective term is added
421      !!      to the horizontal pressure gradient :
422      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
423      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
424      !!      add it to the general momentum trend (ua,va).
425      !!         ua = ua - 1/e1u * zhpi
426      !!         va = va - 1/e2v * zhpj
427      !!
428      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
429      !!----------------------------------------------------------------------
430      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
431      !!
432      INTEGER  ::   ji, jj, jk, jii, jjj                 ! dummy loop indices
433      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp       ! temporary scalars
434      LOGICAL  ::   ll_tmp1, ll_tmp2, ll_tmp3            ! local logical variables
435      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
436      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy !W/D pressure filter
437      !!----------------------------------------------------------------------
438      !
439      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
440      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
441      !
442      IF( kt == nit000 ) THEN
443         IF(lwp) WRITE(numout,*)
444         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
445         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
446      ENDIF
447      !
448      zcoef0 = - grav * 0.5_wp
449      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
450      ELSE                    ;   znad = 1._wp         ! Variable volume: density
451      ENDIF
452      !
453      IF(ln_wd) THEN
454        DO jj = 2, jpjm1
455           DO ji = 2, jpim1 
456             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) 
457             ll_tmp2 = MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) > rn_wdmin1 + rn_wdmin2
458             ll_tmp3 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) + &
459                                                       & rn_wdmin1 + rn_wdmin2
460
461             IF(ll_tmp1.AND.ll_tmp2) THEN
462               zcpx(ji,jj) = 1.0_wp
463               wduflt(ji,jj) = 1.0_wp
464             ELSE IF(ll_tmp3) THEN
465               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
466               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) / &
467                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
468               wduflt(ji,jj) = 1.0_wp
469             ELSE
470               zcpx(ji,jj) = 0._wp
471               wduflt(ji,jj) = 0.0_wp
472             END IF
473     
474             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) 
475             ll_tmp2 = MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) > rn_wdmin1 + rn_wdmin2
476             ll_tmp3 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) + &
477                                                       & rn_wdmin1 + rn_wdmin2
478
479             IF(ll_tmp1.AND.ll_tmp2) THEN
480               zcpy(ji,jj) = 1.0_wp
481               wdvflt(ji,jj) = 1.0_wp
482             ELSE IF(ll_tmp3) THEN
483               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
484               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) / &
485                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
486               wdvflt(ji,jj) = 1.0_wp
487             ELSE
488               zcpy(ji,jj) = 0._wp
489               wdvflt(ji,jj) = 0.0_wp
490             END IF
491           END DO
492        END DO
493        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
494      ENDIF
495
496
497      ! Surface value
498      DO jj = 2, jpjm1
499         DO ji = fs_2, fs_jpim1   ! vector opt.
500            ! hydrostatic pressure gradient along s-surfaces
501            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
502               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
503            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
504               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
505            ! s-coordinate pressure gradient correction
506            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
507               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
508            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
509               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
510
511
512            IF(ln_wd) THEN
513
514              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
515              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
516              zuap = zuap * zcpx(ji,jj)
517              zvap = zvap * zcpy(ji,jj)
518            ENDIF
519
520            ! add to the general momentum trend
521            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
522            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
523         END DO
524      END DO
525
526      ! interior value (2=<jk=<jpkm1)
527      DO jk = 2, jpkm1
528         DO jj = 2, jpjm1
529            DO ji = fs_2, fs_jpim1   ! vector opt.
530               ! hydrostatic pressure gradient along s-surfaces
531               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
532                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
533                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
534               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
535                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
536                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
537               ! s-coordinate pressure gradient correction
538               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
539                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
540               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
541                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
542
543               IF(ln_wd) THEN
544                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
545                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
546                 zuap = zuap * zcpx(ji,jj)
547                 zvap = zvap * zcpy(ji,jj)
548               ENDIF
549
550               ! add to the general momentum trend
551               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
552               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
553            END DO
554         END DO
555      END DO
556      !
557      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
558      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
559      !
560   END SUBROUTINE hpg_sco
561
562
563   SUBROUTINE hpg_isf( kt )
564      !!---------------------------------------------------------------------
565      !!                  ***  ROUTINE hpg_isf  ***
566      !!
567      !! ** Method  :   s-coordinate case. Jacobian scheme.
568      !!      The now hydrostatic pressure gradient at a given level, jk,
569      !!      is computed by taking the vertical integral of the in-situ
570      !!      density gradient along the model level from the suface to that
571      !!      level. s-coordinates (ln_sco): a corrective term is added
572      !!      to the horizontal pressure gradient :
573      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
574      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
575      !!      add it to the general momentum trend (ua,va).
576      !!         ua = ua - 1/e1u * zhpi
577      !!         va = va - 1/e2v * zhpj
578      !!      iceload is added and partial cell case are added to the top and bottom
579      !!     
580      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
581      !!----------------------------------------------------------------------
582      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
583      !!
584      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
585      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
586      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj
587      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
588      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_oce
589      !!----------------------------------------------------------------------
590      !
591      CALL wrk_alloc( jpi,jpj,  2, ztstop) 
592      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj)
593      CALL wrk_alloc( jpi,jpj,     zrhdtop_oce )
594      !
595      ! Local constant initialization
596      zcoef0 = - grav * 0.5_wp
597 
598      ! To use density and not density anomaly
599      znad=1._wp
600
601      ! iniitialised to 0. zhpi zhpi
602      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
603
604      ! compute rhd at the ice/oce interface (ocean side)
605      ! usefull to reduce residual current in the test case ISOMIP with no melting
606      DO ji=1,jpi
607        DO jj=1,jpj
608          ikt=mikt(ji,jj)
609          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
610          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
611        END DO
612      END DO
613      CALL eos( ztstop, risfdep, zrhdtop_oce )
614
615!==================================================================================     
616!===== Compute surface value =====================================================
617!==================================================================================
618      DO jj = 2, jpjm1
619         DO ji = fs_2, fs_jpim1   ! vector opt.
620            ikt    = mikt(ji,jj)
621            iktp1i = mikt(ji+1,jj)
622            iktp1j = mikt(ji,jj+1)
623            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
624            ! we assume ISF is in isostatic equilibrium
625            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
626               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
627               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
628               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
629               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                            ) 
630            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
631               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
632               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
633               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
634               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj))                            ) 
635            ! s-coordinate pressure gradient correction (=0 if z coordinate)
636            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
637               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
638            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
639               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
640            ! add to the general momentum trend
641            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
642            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
643         END DO
644      END DO
645!==================================================================================     
646!===== Compute interior value =====================================================
647!==================================================================================
648      ! interior value (2=<jk=<jpkm1)
649      DO jk = 2, jpkm1
650         DO jj = 2, jpjm1
651            DO ji = fs_2, fs_jpim1   ! vector opt.
652               ! hydrostatic pressure gradient along s-surfaces
653               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
654                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
655                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
656               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
657                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
658                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
659               ! s-coordinate pressure gradient correction
660               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
661                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
662               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
663                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
664               ! add to the general momentum trend
665               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
666               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
667            END DO
668         END DO
669      END DO
670     !
671      CALL wrk_dealloc( jpi,jpj,2  , ztstop)
672      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj)
673      CALL wrk_dealloc( jpi,jpj    , zrhdtop_oce )
674      !
675   END SUBROUTINE hpg_isf
676
677
678   SUBROUTINE hpg_djc( kt )
679      !!---------------------------------------------------------------------
680      !!                  ***  ROUTINE hpg_djc  ***
681      !!
682      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
683      !!
684      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
685      !!----------------------------------------------------------------------
686      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
687      !!
688      INTEGER  ::   ji, jj, jk          ! dummy loop indices
689      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
690      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
691      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
692      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
693      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
694      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
695      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
696      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
697      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy    !W/D pressure filter
698      !!----------------------------------------------------------------------
699      !
700      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
701      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
702      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
703      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
704      !
705      !
706      IF(ln_wd) THEN
707        DO jj = 2, jpjm1
708           DO ji = 2, jpim1 
709             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) &
710                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) &
711                     &  > rn_wdmin1 + rn_wdmin2
712             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
713                                                       & rn_wdmin1 + rn_wdmin2
714
715             IF(ll_tmp1) THEN
716               zcpx(ji,jj) = 1.0_wp
717             ELSE IF(ll_tmp2) THEN
718               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
719               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
720                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
721             ELSE
722               zcpx(ji,jj) = 0._wp
723             END IF
724     
725             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) &
726                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) &
727                     &  > rn_wdmin1 + rn_wdmin2
728             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
729                                                       & rn_wdmin1 + rn_wdmin2
730
731             IF(ll_tmp1) THEN
732               zcpy(ji,jj) = 1.0_wp
733             ELSE IF(ll_tmp2) THEN
734               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
735               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
736                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
737             ELSE
738               zcpy(ji,jj) = 0._wp
739             END IF
740           END DO
741        END DO
742        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
743      ENDIF
744
745
746      IF( kt == nit000 ) THEN
747         IF(lwp) WRITE(numout,*)
748         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
749         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
750      ENDIF
751
752      ! Local constant initialization
753      zcoef0 = - grav * 0.5_wp
754      z1_10  = 1._wp / 10._wp
755      z1_12  = 1._wp / 12._wp
756
757      !----------------------------------------------------------------------------------------
758      !  compute and store in provisional arrays elementary vertical and horizontal differences
759      !----------------------------------------------------------------------------------------
760
761!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
762
763      DO jk = 2, jpkm1
764         DO jj = 2, jpjm1
765            DO ji = fs_2, fs_jpim1   ! vector opt.
766               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
767               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
768               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
769               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
770               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
771               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
772            END DO
773         END DO
774      END DO
775
776      !-------------------------------------------------------------------------
777      ! compute harmonic averages using eq. 5.18
778      !-------------------------------------------------------------------------
779      zep = 1.e-15
780
781!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
782!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
783
784      DO jk = 2, jpkm1
785         DO jj = 2, jpjm1
786            DO ji = fs_2, fs_jpim1   ! vector opt.
787               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
788
789               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
790               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
791
792               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
793               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
794
795               IF( cffw > zep) THEN
796                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
797                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
798               ELSE
799                  drhow(ji,jj,jk) = 0._wp
800               ENDIF
801
802               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
803                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
804
805               IF( cffu > zep ) THEN
806                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
807                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
808               ELSE
809                  drhou(ji,jj,jk ) = 0._wp
810               ENDIF
811
812               IF( cffx > zep ) THEN
813                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
814                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
815               ELSE
816                  dzu(ji,jj,jk) = 0._wp
817               ENDIF
818
819               IF( cffv > zep ) THEN
820                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
821                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
822               ELSE
823                  drhov(ji,jj,jk) = 0._wp
824               ENDIF
825
826               IF( cffy > zep ) THEN
827                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
828                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
829               ELSE
830                  dzv(ji,jj,jk) = 0._wp
831               ENDIF
832
833            END DO
834         END DO
835      END DO
836
837      !----------------------------------------------------------------------------------
838      ! apply boundary conditions at top and bottom using 5.36-5.37
839      !----------------------------------------------------------------------------------
840      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
841      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
842      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
843
844      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
845      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
846      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
847
848
849      !--------------------------------------------------------------
850      ! Upper half of top-most grid box, compute and store
851      !-------------------------------------------------------------
852
853!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
854!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
855
856      DO jj = 2, jpjm1
857         DO ji = fs_2, fs_jpim1   ! vector opt.
858            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
859               &                   * (  rhd(ji,jj,1)                                     &
860               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
861               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
862               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
863         END DO
864      END DO
865
866!!bug gm    : here also, simplification is possible
867!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
868
869      DO jk = 2, jpkm1
870         DO jj = 2, jpjm1
871            DO ji = fs_2, fs_jpim1   ! vector opt.
872
873               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
874                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
875                  &            - grav * z1_10 * (                                                                   &
876                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
877                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
878                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
879                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
880                  &                             )
881
882               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
883                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
884                  &            - grav* z1_10 * (                                                                    &
885                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
886                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
887                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
888                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
889                  &                            )
890
891               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
892                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
893                  &            - grav* z1_10 * (                                                                    &
894                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
895                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
896                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
897                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
898                  &                            )
899
900            END DO
901         END DO
902      END DO
903      CALL lbc_lnk(rho_k,'W',1.)
904      CALL lbc_lnk(rho_i,'U',1.)
905      CALL lbc_lnk(rho_j,'V',1.)
906
907
908      ! ---------------
909      !  Surface value
910      ! ---------------
911      DO jj = 2, jpjm1
912         DO ji = fs_2, fs_jpim1   ! vector opt.
913            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
914            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
915            IF(ln_wd) THEN
916              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
917              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj) 
918            ENDIF
919            ! add to the general momentum trend
920            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
921            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
922         END DO
923      END DO
924
925      ! ----------------
926      !  interior value   (2=<jk=<jpkm1)
927      ! ----------------
928      DO jk = 2, jpkm1
929         DO jj = 2, jpjm1
930            DO ji = fs_2, fs_jpim1   ! vector opt.
931               ! hydrostatic pressure gradient along s-surfaces
932               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
933                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
934                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
935               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
936                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
937                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
938               IF(ln_wd) THEN
939                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
940                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj) 
941               ENDIF
942               ! add to the general momentum trend
943               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
944               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
945            END DO
946         END DO
947      END DO
948      !
949      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
950      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
951      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
952      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
953      !
954   END SUBROUTINE hpg_djc
955
956
957   SUBROUTINE hpg_prj( kt )
958      !!---------------------------------------------------------------------
959      !!                  ***  ROUTINE hpg_prj  ***
960      !!
961      !! ** Method  :   s-coordinate case.
962      !!      A Pressure-Jacobian horizontal pressure gradient method
963      !!      based on the constrained cubic-spline interpolation for
964      !!      all vertical coordinate systems
965      !!
966      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
967      !!----------------------------------------------------------------------
968      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
969      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
970      !!
971      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
972      REAL(wp) ::   zcoef0, znad                    ! local scalars
973      !
974      !! The local variables for the correction term
975      INTEGER  :: jk1, jis, jid, jjs, jjd
976      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
977      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
978      REAL(wp) :: zrhdt1
979      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
980      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
981      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
982      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
983      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy    !W/D pressure filter
984      !!----------------------------------------------------------------------
985      !
986      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
987      CALL wrk_alloc( jpi,jpj,jpk,   zdept, zrhh )
988      CALL wrk_alloc( jpi,jpj,       zsshu_n, zsshv_n )
989      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
990      !
991      IF( kt == nit000 ) THEN
992         IF(lwp) WRITE(numout,*)
993         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
994         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
995      ENDIF
996
997      ! Local constant initialization
998      zcoef0 = - grav
999      znad = 1._wp
1000      IF( ln_linssh )   znad = 0._wp
1001
1002      IF(ln_wd) THEN
1003        DO jj = 2, jpjm1
1004           DO ji = 2, jpim1 
1005             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) &
1006                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) &
1007                     &  > rn_wdmin1 + rn_wdmin2
1008             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
1009                                                       & rn_wdmin1 + rn_wdmin2
1010
1011             IF(ll_tmp1) THEN
1012               zcpx(ji,jj) = 1.0_wp
1013             ELSE IF(ll_tmp2) THEN
1014               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
1015               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
1016                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
1017             ELSE
1018               zcpx(ji,jj) = 0._wp
1019             END IF
1020     
1021             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) &
1022                     & .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) &
1023                     &  > rn_wdmin1 + rn_wdmin2
1024             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
1025                                                       & rn_wdmin1 + rn_wdmin2
1026
1027             IF(ll_tmp1.OR.ll_tmp2) THEN
1028               zcpy(ji,jj) = 1.0_wp
1029             ELSE IF(ll_tmp2) THEN
1030               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
1031               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
1032                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
1033             ELSE
1034               zcpy(ji,jj) = 0._wp
1035             END IF
1036           END DO
1037        END DO
1038        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
1039      ENDIF
1040
1041      ! Clean 3-D work arrays
1042      zhpi(:,:,:) = 0._wp
1043      zrhh(:,:,:) = rhd(:,:,:)
1044
1045      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1046      DO jj = 1, jpj
1047        DO ji = 1, jpi
1048          jk = mbathy(ji,jj)
1049          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
1050          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1051          ELSEIF( jk < jpkm1 ) THEN
1052             DO jkk = jk+1, jpk
1053                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
1054                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1055             END DO
1056          ENDIF
1057        END DO
1058      END DO
1059
1060      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1061      DO jj = 1, jpj
1062         DO ji = 1, jpi
1063            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1064         END DO
1065      END DO
1066
1067      DO jk = 2, jpk
1068         DO jj = 1, jpj
1069            DO ji = 1, jpi
1070               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1071            END DO
1072         END DO
1073      END DO
1074
1075      fsp(:,:,:) = zrhh (:,:,:)
1076      xsp(:,:,:) = zdept(:,:,:)
1077
1078      ! Construct the vertical density profile with the
1079      ! constrained cubic spline interpolation
1080      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1081      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1082
1083      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1084      DO jj = 2, jpj
1085        DO ji = 2, jpi
1086          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1087             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1088
1089          ! assuming linear profile across the top half surface layer
1090          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1091        END DO
1092      END DO
1093
1094      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1095      DO jk = 2, jpkm1
1096        DO jj = 2, jpj
1097          DO ji = 2, jpi
1098            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1099               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1100               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1101               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1102          END DO
1103        END DO
1104      END DO
1105
1106      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1107
1108      ! Prepare zsshu_n and zsshv_n
1109      DO jj = 2, jpjm1
1110        DO ji = 2, jpim1
1111!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1112!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1113!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1114!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1115!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1116!!gm not this:
1117          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1118                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1119          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1120                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1121        END DO
1122      END DO
1123
1124      CALL lbc_lnk (zsshu_n, 'U', 1.)
1125      CALL lbc_lnk (zsshv_n, 'V', 1.)
1126
1127      DO jj = 2, jpjm1
1128        DO ji = 2, jpim1
1129          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1130          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1131        END DO
1132      END DO
1133
1134      DO jk = 2, jpkm1
1135        DO jj = 2, jpjm1
1136          DO ji = 2, jpim1
1137            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1138            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1139          END DO
1140        END DO
1141      END DO
1142
1143      DO jk = 1, jpkm1
1144        DO jj = 2, jpjm1
1145          DO ji = 2, jpim1
1146            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1147            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1148          END DO
1149        END DO
1150      END DO
1151
1152      DO jk = 1, jpkm1
1153        DO jj = 2, jpjm1
1154          DO ji = 2, jpim1
1155            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1156            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1157            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1158            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1159          END DO
1160        END DO
1161      END DO
1162
1163
1164      DO jk = 1, jpkm1
1165        DO jj = 2, jpjm1
1166          DO ji = 2, jpim1
1167            zpwes = 0._wp; zpwed = 0._wp
1168            zpnss = 0._wp; zpnsd = 0._wp
1169            zuijk = zu(ji,jj,jk)
1170            zvijk = zv(ji,jj,jk)
1171
1172            !!!!!     for u equation
1173            IF( jk <= mbku(ji,jj) ) THEN
1174               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1175                 jis = ji + 1; jid = ji
1176               ELSE
1177                 jis = ji;     jid = ji +1
1178               ENDIF
1179
1180               ! integrate the pressure on the shallow side
1181               jk1 = jk
1182               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1183                 IF( jk1 == mbku(ji,jj) ) THEN
1184                   zuijk = -zdept(jis,jj,jk1)
1185                   EXIT
1186                 ENDIF
1187                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1188                 zpwes = zpwes +                                    &
1189                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1190                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1191                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1192                 jk1 = jk1 + 1
1193               END DO
1194
1195               ! integrate the pressure on the deep side
1196               jk1 = jk
1197               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1198                 IF( jk1 == 1 ) THEN
1199                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1200                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1201                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1202                                                     dsp(jid,jj,1)) * zdeps
1203                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1204                   EXIT
1205                 ENDIF
1206                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1207                 zpwed = zpwed +                                        &
1208                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1209                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1210                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1211                 jk1 = jk1 - 1
1212               END DO
1213
1214               ! update the momentum trends in u direction
1215
1216               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1217               IF( .NOT.ln_linssh ) THEN
1218                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1219                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1220                ELSE
1221                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1222               ENDIF
1223               IF(ln_wd) THEN
1224                  zdpdx1 = zdpdx1 * zcpx(ji,jj)
1225                  zdpdx2 = zdpdx2 * zcpx(ji,jj)
1226               ENDIF
1227               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1228            ENDIF
1229
1230            !!!!!     for v equation
1231            IF( jk <= mbkv(ji,jj) ) THEN
1232               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1233                 jjs = jj + 1; jjd = jj
1234               ELSE
1235                 jjs = jj    ; jjd = jj + 1
1236               ENDIF
1237
1238               ! integrate the pressure on the shallow side
1239               jk1 = jk
1240               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1241                 IF( jk1 == mbkv(ji,jj) ) THEN
1242                   zvijk = -zdept(ji,jjs,jk1)
1243                   EXIT
1244                 ENDIF
1245                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1246                 zpnss = zpnss +                                      &
1247                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1248                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1249                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1250                 jk1 = jk1 + 1
1251               END DO
1252
1253               ! integrate the pressure on the deep side
1254               jk1 = jk
1255               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1256                 IF( jk1 == 1 ) THEN
1257                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1258                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1259                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1260                                                     dsp(ji,jjd,1) ) * zdeps
1261                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1262                   EXIT
1263                 ENDIF
1264                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1265                 zpnsd = zpnsd +                                        &
1266                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1267                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1268                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1269                 jk1 = jk1 - 1
1270               END DO
1271
1272
1273               ! update the momentum trends in v direction
1274
1275               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1276               IF( .NOT.ln_linssh ) THEN
1277                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1278                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1279               ELSE
1280                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1281               ENDIF
1282               IF(ln_wd) THEN
1283                  zdpdy1 = zdpdy1 * zcpy(ji,jj)
1284                  zdpdy2 = zdpdy2 * zcpy(ji,jj)
1285               ENDIF
1286
1287               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1288            ENDIF
1289               !
1290            END DO
1291         END DO
1292      END DO
1293      !
1294      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1295      CALL wrk_dealloc( jpi,jpj,jpk,   zdept, zrhh )
1296      CALL wrk_dealloc( jpi,jpj,       zsshu_n, zsshv_n )
1297      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
1298      !
1299   END SUBROUTINE hpg_prj
1300
1301
1302   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1303      !!----------------------------------------------------------------------
1304      !!                 ***  ROUTINE cspline  ***
1305      !!
1306      !! ** Purpose :   constrained cubic spline interpolation
1307      !!
1308      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1309      !!
1310      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1311      !!----------------------------------------------------------------------
1312      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1313      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1314      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1315      !
1316      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1317      INTEGER  ::   jpi, jpj, jpkm1
1318      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1319      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1320      REAL(wp) ::   zdf(size(fsp,3))
1321      !!----------------------------------------------------------------------
1322      !
1323!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1324      jpi   = size(fsp,1)
1325      jpj   = size(fsp,2)
1326      jpkm1 = size(fsp,3) - 1
1327      !
1328      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1329         DO ji = 1, jpi
1330            DO jj = 1, jpj
1331           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1332           !    DO jk = 2, jpkm1-1
1333           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1334           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1335           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1336           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1337           !
1338           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1339           !
1340           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1341           !           zdf(jk) = 0._wp
1342           !       ELSE
1343           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1344           !       ENDIF
1345           !    END DO
1346
1347           !!Simply geometric average
1348               DO jk = 2, jpkm1-1
1349                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1350                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1351
1352                  IF(zdf1 * zdf2 <= 0._wp) THEN
1353                     zdf(jk) = 0._wp
1354                  ELSE
1355                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1356                  ENDIF
1357               END DO
1358
1359               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1360                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1361               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1362                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1363
1364               DO jk = 1, jpkm1 - 1
1365                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1366                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1367                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1368                 zddf1  = -2._wp * ztmp1 + ztmp2
1369                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1370                 zddf2  =  2._wp * ztmp1 - ztmp2
1371
1372                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1373                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1374                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1375                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1376                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1377                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1378                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1379                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1380                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1381               END DO
1382            END DO
1383         END DO
1384
1385      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1386         DO ji = 1, jpi
1387            DO jj = 1, jpj
1388               DO jk = 1, jpkm1-1
1389                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1390                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1391
1392                  dsp(ji,jj,jk) = 0._wp
1393                  csp(ji,jj,jk) = 0._wp
1394                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1395                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1396               END DO
1397            END DO
1398         END DO
1399
1400      ELSE
1401           CALL ctl_stop( 'invalid polynomial type in cspline' )
1402      ENDIF
1403
1404   END SUBROUTINE cspline
1405
1406
1407   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1408      !!----------------------------------------------------------------------
1409      !!                 ***  ROUTINE interp1  ***
1410      !!
1411      !! ** Purpose :   1-d linear interpolation
1412      !!
1413      !! ** Method  :   interpolation is straight forward
1414      !!                extrapolation is also permitted (no value limit)
1415      !!----------------------------------------------------------------------
1416      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1417      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1418      REAL(wp)             ::  zdeltx
1419      !!----------------------------------------------------------------------
1420      !
1421      zdeltx = xr - xl
1422      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1423         f = 0.5_wp * (fl + fr)
1424      ELSE
1425         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1426      ENDIF
1427      !
1428   END FUNCTION interp1
1429
1430
1431   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1432      !!----------------------------------------------------------------------
1433      !!                 ***  ROUTINE interp1  ***
1434      !!
1435      !! ** Purpose :   1-d constrained cubic spline interpolation
1436      !!
1437      !! ** Method  :  cubic spline interpolation
1438      !!
1439      !!----------------------------------------------------------------------
1440      REAL(wp), INTENT(in) ::  x, a, b, c, d
1441      REAL(wp)             ::  f ! value from the interpolation
1442      !!----------------------------------------------------------------------
1443      !
1444      f = a + x* ( b + x * ( c + d * x ) )
1445      !
1446   END FUNCTION interp2
1447
1448
1449   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1450      !!----------------------------------------------------------------------
1451      !!                 ***  ROUTINE interp1  ***
1452      !!
1453      !! ** Purpose :   Calculate the first order of deriavtive of
1454      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1455      !!
1456      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1457      !!
1458      !!----------------------------------------------------------------------
1459      REAL(wp), INTENT(in) ::  x, a, b, c, d
1460      REAL(wp)             ::  f ! value from the interpolation
1461      !!----------------------------------------------------------------------
1462      !
1463      f = b + x * ( 2._wp * c + 3._wp * d * x)
1464      !
1465   END FUNCTION interp3
1466
1467
1468   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1469      !!----------------------------------------------------------------------
1470      !!                 ***  ROUTINE interp1  ***
1471      !!
1472      !! ** Purpose :   1-d constrained cubic spline integration
1473      !!
1474      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1475      !!
1476      !!----------------------------------------------------------------------
1477      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1478      REAL(wp)             ::  za1, za2, za3
1479      REAL(wp)             ::  f                   ! integration result
1480      !!----------------------------------------------------------------------
1481      !
1482      za1 = 0.5_wp * b
1483      za2 = c / 3.0_wp
1484      za3 = 0.25_wp * d
1485      !
1486      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1487         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1488      !
1489   END FUNCTION integ_spline
1490
1491   !!======================================================================
1492END MODULE dynhpg
1493
Note: See TracBrowser for help on using the repository browser.