New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzdf_imp.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DYN/dynzdf_imp.F90 @ 6752

Last change on this file since 6752 was 6752, checked in by jchanut, 9 years ago

Mask vtau in dynzdf_imp, ticket #1744
  • Property svn:keywords set to Id
File size: 16.2 KB
Line 
1MODULE dynzdf_imp
2   !!======================================================================
3   !!                    ***  MODULE  dynzdf_imp  ***
4   !! Ocean dynamics:  vertical component(s) of the momentum mixing trend, implicit scheme
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            8.0  !  1997-05  (G. Madec)  vertical component of isopycnal
8   !!   NEMO     0.5  !  2002-08  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!            3.4  !  2012-01  (H. Liu) Semi-implicit bottom friction
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   dyn_zdf_imp   : compute the vertical diffusion using a implicit scheme
15   !!                   together with the Leap-Frog time integration.
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers
18   USE phycst         ! physical constants
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! variable volume
21   USE sbc_oce        ! surface boundary condition: ocean
22   USE dynadv   , ONLY: ln_dynadv_vec ! Momentum advection form
23   USE zdf_oce        ! ocean vertical physics
24   USE zdfbfr         ! Bottom friction setup
25   !
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! MPP library
28   USE wrk_nemo       ! Memory Allocation
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   dyn_zdf_imp   ! called by step.F90
35
36   REAL(wp) ::  r_vvl     ! non-linear free surface indicator: =0 if ln_linssh=T, =1 otherwise
37
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE dyn_zdf_imp( kt, p2dt )
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE dyn_zdf_imp  ***
50      !!                   
51      !! ** Purpose :   Compute the trend due to the vert. momentum diffusion
52      !!              together with the Leap-Frog time stepping using an
53      !!              implicit scheme.
54      !!
55      !! ** Method  :  - Leap-Frog time stepping on all trends but the vertical mixing
56      !!         ua =         ub + 2*dt *       ua             vector form or linear free surf.
57      !!         ua = ( e3u_b*ub + 2*dt * e3u_n*ua ) / e3u_a   otherwise
58      !!               - update the after velocity with the implicit vertical mixing.
59      !!      This requires to solver the following system:
60      !!         ua = ua + 1/e3u_a dk+1[ avmu / e3uw_a dk[ua] ]
61      !!      with the following surface/top/bottom boundary condition:
62      !!      surface: wind stress input (averaged over kt-1/2 & kt+1/2)
63      !!      top & bottom : top stress (iceshelf-ocean) & bottom stress (cf zdfbfr.F)
64      !!
65      !! ** Action :   (ua,va) after velocity
66      !!---------------------------------------------------------------------
67      INTEGER , INTENT(in) ::  kt     ! ocean time-step index
68      REAL(wp), INTENT(in) ::  p2dt   ! vertical profile of tracer time-step
69      !
70      INTEGER  ::   ji, jj, jk    ! dummy loop indices
71      INTEGER  ::   ikbu, ikbv    ! local integers
72      REAL(wp) ::   zzwi, ze3ua   ! local scalars
73      REAL(wp) ::   zzws, ze3va   !   -      -
74      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zwi, zwd, zws
75      !!----------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )  CALL timing_start('dyn_zdf_imp')
78      !
79      CALL wrk_alloc( jpi,jpj,jpk, zwi, zwd, zws ) 
80      !
81      IF( kt == nit000 ) THEN
82         IF(lwp) WRITE(numout,*)
83         IF(lwp) WRITE(numout,*) 'dyn_zdf_imp : vertical momentum diffusion implicit operator'
84         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
85         !
86         If( ln_linssh ) THEN   ;    r_vvl = 0._wp    ! non-linear free surface indicator
87         ELSE                   ;    r_vvl = 1._wp
88         ENDIF
89      ENDIF
90      !
91      !              !==  Time step dynamics  ==!
92      !
93      IF( ln_dynadv_vec .OR. ln_linssh ) THEN      ! applied on velocity
94         DO jk = 1, jpkm1
95            ua(:,:,jk) = ( ub(:,:,jk) + p2dt * ua(:,:,jk) ) * umask(:,:,jk)
96            va(:,:,jk) = ( vb(:,:,jk) + p2dt * va(:,:,jk) ) * vmask(:,:,jk)
97         END DO
98      ELSE                                         ! applied on thickness weighted velocity
99         DO jk = 1, jpkm1
100            ua(:,:,jk) = (         e3u_b(:,:,jk) * ub(:,:,jk)  &
101               &          + p2dt * e3u_n(:,:,jk) * ua(:,:,jk)  ) / e3u_a(:,:,jk) * umask(:,:,jk)
102            va(:,:,jk) = (         e3v_b(:,:,jk) * vb(:,:,jk)  &
103               &          + p2dt * e3v_n(:,:,jk) * va(:,:,jk)  ) / e3v_a(:,:,jk) * vmask(:,:,jk)
104         END DO
105      ENDIF
106      !
107      !              !==  Apply semi-implicit bottom friction  ==!
108      !
109      ! Only needed for semi-implicit bottom friction setup. The explicit
110      ! bottom friction has been included in "u(v)a" which act as the R.H.S
111      ! column vector of the tri-diagonal matrix equation
112      !
113      IF( ln_bfrimp ) THEN
114         DO jj = 2, jpjm1
115            DO ji = 2, jpim1
116               ikbu = mbku(ji,jj)       ! ocean bottom level at u- and v-points
117               ikbv = mbkv(ji,jj)       ! (deepest ocean u- and v-points)
118               avmu(ji,jj,ikbu+1) = -bfrua(ji,jj) * e3uw_n(ji,jj,ikbu+1)
119               avmv(ji,jj,ikbv+1) = -bfrva(ji,jj) * e3vw_n(ji,jj,ikbv+1)
120            END DO
121         END DO
122         IF ( ln_isfcav ) THEN
123            DO jj = 2, jpjm1
124               DO ji = 2, jpim1
125                  ikbu = miku(ji,jj)       ! ocean top level at u- and v-points
126                  ikbv = mikv(ji,jj)       ! (first wet ocean u- and v-points)
127                  IF( ikbu >= 2 )   avmu(ji,jj,ikbu) = -tfrua(ji,jj) * e3uw_n(ji,jj,ikbu)
128                  IF( ikbv >= 2 )   avmv(ji,jj,ikbv) = -tfrva(ji,jj) * e3vw_n(ji,jj,ikbv)
129               END DO
130            END DO
131         END IF
132      ENDIF
133      !
134      ! With split-explicit free surface, barotropic stress is treated explicitly
135      ! Update velocities at the bottom.
136      ! J. Chanut: The bottom stress is computed considering after barotropic velocities, which does
137      !            not lead to the effective stress seen over the whole barotropic loop.
138      ! G. Madec : in linear free surface, e3u_a = e3u_n = e3u_0, so systematic use of e3u_a
139      IF( ln_bfrimp .AND. ln_dynspg_ts ) THEN
140         DO jk = 1, jpkm1        ! remove barotropic velocities
141            ua(:,:,jk) = ( ua(:,:,jk) - ua_b(:,:) ) * umask(:,:,jk)
142            va(:,:,jk) = ( va(:,:,jk) - va_b(:,:) ) * vmask(:,:,jk)
143         END DO
144         DO jj = 2, jpjm1        ! Add bottom/top stress due to barotropic component only
145            DO ji = fs_2, fs_jpim1   ! vector opt.
146               ikbu = mbku(ji,jj)         ! ocean bottom level at u- and v-points
147               ikbv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
148               ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,ikbu) + r_vvl * e3u_a(ji,jj,ikbu)
149               ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,ikbv) + r_vvl * e3v_a(ji,jj,ikbv)
150               ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + p2dt * bfrua(ji,jj) * ua_b(ji,jj) / ze3ua
151               va(ji,jj,ikbv) = va(ji,jj,ikbv) + p2dt * bfrva(ji,jj) * va_b(ji,jj) / ze3va
152            END DO
153         END DO
154         IF( ln_isfcav ) THEN    ! Ocean cavities (ISF)
155            DO jj = 2, jpjm1       
156               DO ji = fs_2, fs_jpim1   ! vector opt.
157                  ikbu = miku(ji,jj)         ! top ocean level at u- and v-points
158                  ikbv = mikv(ji,jj)         ! (first wet ocean u- and v-points)
159                  ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,ikbu) + r_vvl * e3u_a(ji,jj,ikbu)
160                  ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,ikbv) + r_vvl * e3v_a(ji,jj,ikbv)
161                  ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + p2dt * tfrua(ji,jj) * ua_b(ji,jj) / ze3ua
162                  va(ji,jj,ikbv) = va(ji,jj,ikbv) + p2dt * tfrva(ji,jj) * va_b(ji,jj) / ze3va
163               END DO
164            END DO
165         END IF
166      ENDIF
167      !
168      !              !==  Vertical diffusion on u  ==!
169      !
170      ! Matrix and second member construction
171      ! bottom boundary condition: both zwi and zws must be masked as avmu can take
172      ! non zero value at the ocean bottom depending on the bottom friction used.
173      !
174      DO jk = 1, jpkm1        ! Matrix
175         DO jj = 2, jpjm1 
176            DO ji = fs_2, fs_jpim1   ! vector opt.
177               ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,jk) + r_vvl * e3u_a(ji,jj,jk)   ! after scale factor at T-point
178               zzwi = - p2dt * avmu(ji,jj,jk  ) / ( ze3ua * e3uw_n(ji,jj,jk  ) )
179               zzws = - p2dt * avmu(ji,jj,jk+1) / ( ze3ua * e3uw_n(ji,jj,jk+1) )
180               zwi(ji,jj,jk) = zzwi * wumask(ji,jj,jk  )
181               zws(ji,jj,jk) = zzws * wumask(ji,jj,jk+1)
182               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
183            END DO
184         END DO
185      END DO
186      DO jj = 2, jpjm1        ! Surface boundary conditions
187         DO ji = fs_2, fs_jpim1   ! vector opt.
188            zwi(ji,jj,1) = 0._wp
189            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
190         END DO
191      END DO
192
193      ! Matrix inversion starting from the first level
194      !-----------------------------------------------------------------------
195      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
196      !
197      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
198      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
199      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
200      !        (        ...               )( ...  ) ( ...  )
201      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
202      !
203      !   m is decomposed in the product of an upper and a lower triangular matrix
204      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
205      !   The solution (the after velocity) is in ua
206      !-----------------------------------------------------------------------
207      !
208      DO jk = 2, jpkm1        !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
209         DO jj = 2, jpjm1   
210            DO ji = fs_2, fs_jpim1   ! vector opt.
211               zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
212            END DO
213         END DO
214      END DO
215      !
216      DO jj = 2, jpjm1        !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
217         DO ji = fs_2, fs_jpim1   ! vector opt.
218            ze3ua =  ( 1._wp - r_vvl ) * e3u_n(ji,jj,1) + r_vvl * e3u_a(ji,jj,1) 
219            ua(ji,jj,1) = ua(ji,jj,1) + p2dt * 0.5_wp * ( utau_b(ji,jj) + utau(ji,jj) )   &
220               &                                      / ( ze3ua * rau0 ) * umask(ji,jj,1) 
221         END DO
222      END DO
223      DO jk = 2, jpkm1
224         DO jj = 2, jpjm1
225            DO ji = fs_2, fs_jpim1
226               ua(ji,jj,jk) = ua(ji,jj,jk) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * ua(ji,jj,jk-1)
227            END DO
228         END DO
229      END DO
230      !
231      DO jj = 2, jpjm1        !==  thrid recurrence : SOLk = ( Lk - Uk * Ek+1 ) / Dk  ==!
232         DO ji = fs_2, fs_jpim1   ! vector opt.
233            ua(ji,jj,jpkm1) = ua(ji,jj,jpkm1) / zwd(ji,jj,jpkm1)
234         END DO
235      END DO
236      DO jk = jpk-2, 1, -1
237         DO jj = 2, jpjm1
238            DO ji = fs_2, fs_jpim1
239               ua(ji,jj,jk) = ( ua(ji,jj,jk) - zws(ji,jj,jk) * ua(ji,jj,jk+1) ) / zwd(ji,jj,jk)
240            END DO
241         END DO
242      END DO
243      !
244      !              !==  Vertical diffusion on v  ==!
245      !
246      ! Matrix and second member construction
247      ! bottom boundary condition: both zwi and zws must be masked as avmv can take
248      ! non zero value at the ocean bottom depending on the bottom friction used
249      !
250      DO jk = 1, jpkm1        ! Matrix
251         DO jj = 2, jpjm1   
252            DO ji = fs_2, fs_jpim1   ! vector opt.
253               ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,jk) + r_vvl * e3v_a(ji,jj,jk)   ! after scale factor at T-point
254               zzwi = - p2dt * avmv (ji,jj,jk  ) / ( ze3va * e3vw_n(ji,jj,jk  ) )
255               zzws = - p2dt * avmv (ji,jj,jk+1) / ( ze3va * e3vw_n(ji,jj,jk+1) )
256               zwi(ji,jj,jk) = zzwi * wvmask(ji,jj,jk  )
257               zws(ji,jj,jk) = zzws * wvmask(ji,jj,jk+1)
258               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
259            END DO
260         END DO
261      END DO
262      DO jj = 2, jpjm1        ! Surface boundary conditions
263         DO ji = fs_2, fs_jpim1   ! vector opt.
264            zwi(ji,jj,1) = 0._wp
265            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
266         END DO
267      END DO
268
269      ! Matrix inversion
270      !-----------------------------------------------------------------------
271      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
272      !
273      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
274      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
275      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
276      !        (        ...               )( ...  ) ( ...  )
277      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
278      !
279      !   m is decomposed in the product of an upper and lower triangular matrix
280      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
281      !   The solution (after velocity) is in 2d array va
282      !-----------------------------------------------------------------------
283      !
284      DO jk = 2, jpkm1        !==  First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1   (increasing k)  ==
285         DO jj = 2, jpjm1   
286            DO ji = fs_2, fs_jpim1   ! vector opt.
287               zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
288            END DO
289         END DO
290      END DO
291      !
292      DO jj = 2, jpjm1        !==  second recurrence:    SOLk = RHSk - Lk / Dk-1  Lk-1  ==!
293         DO ji = fs_2, fs_jpim1   ! vector opt.         
294            ze3va =  ( 1._wp - r_vvl ) * e3v_n(ji,jj,1) + r_vvl * e3v_a(ji,jj,1) 
295            va(ji,jj,1) = va(ji,jj,1) + p2dt * 0.5_wp * ( vtau_b(ji,jj) + vtau(ji,jj) )   &
296               &                                      / ( ze3va * rau0 ) * vmask(ji,jj,1) 
297         END DO
298      END DO
299      DO jk = 2, jpkm1
300         DO jj = 2, jpjm1
301            DO ji = fs_2, fs_jpim1   ! vector opt.
302               va(ji,jj,jk) = va(ji,jj,jk) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * va(ji,jj,jk-1)
303            END DO
304         END DO
305      END DO
306      !
307      DO jj = 2, jpjm1        !==  third recurrence : SOLk = ( Lk - Uk * SOLk+1 ) / Dk  ==!
308         DO ji = fs_2, fs_jpim1   ! vector opt.
309            va(ji,jj,jpkm1) = va(ji,jj,jpkm1) / zwd(ji,jj,jpkm1)
310         END DO
311      END DO
312      DO jk = jpk-2, 1, -1
313         DO jj = 2, jpjm1
314            DO ji = fs_2, fs_jpim1
315               va(ji,jj,jk) = ( va(ji,jj,jk) - zws(ji,jj,jk) * va(ji,jj,jk+1) ) / zwd(ji,jj,jk)
316            END DO
317         END DO
318      END DO
319     
320      ! J. Chanut: Lines below are useless ?
321      !! restore bottom layer avmu(v)
322      !!gm  I almost sure it is !!!!
323      IF( ln_bfrimp ) THEN
324        DO jj = 2, jpjm1
325           DO ji = 2, jpim1
326              ikbu = mbku(ji,jj)         ! ocean bottom level at u- and v-points
327              ikbv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
328              avmu(ji,jj,ikbu+1) = 0._wp
329              avmv(ji,jj,ikbv+1) = 0._wp
330           END DO
331        END DO
332        IF (ln_isfcav) THEN
333           DO jj = 2, jpjm1
334              DO ji = 2, jpim1
335                 ikbu = miku(ji,jj)         ! ocean top level at u- and v-points
336                 ikbv = mikv(ji,jj)         ! (first wet ocean u- and v-points)
337                 IF( ikbu > 1 )   avmu(ji,jj,ikbu) = 0._wp
338                 IF( ikbv > 1 )   avmv(ji,jj,ikbv) = 0._wp
339              END DO
340           END DO
341        ENDIF
342      ENDIF
343      !
344      CALL wrk_dealloc( jpi,jpj,jpk,   zwi, zwd, zws) 
345      !
346      IF( nn_timing == 1 )   CALL timing_stop('dyn_zdf_imp')
347      !
348   END SUBROUTINE dyn_zdf_imp
349
350   !!==============================================================================
351END MODULE dynzdf_imp
Note: See TracBrowser for help on using the repository browser.