New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/IOM/iom.F90 @ 3940

Last change on this file since 3940 was 3940, checked in by smasson, 9 years ago

trunk: upgrade XIOS inteface, see #1122

  • Property svn:keywords set to Id
File size: 74.1 KB
Line 
1MODULE iom
2   !!=====================================================================
3   !!                    ***  MODULE  iom ***
4   !! Input/Output manager :  Library to read input files
5   !!====================================================================
6   !! History :  2.0  ! 2005-12  (J. Belier) Original code
7   !!            2.0  ! 2006-02  (S. Masson) Adaptation to NEMO
8   !!            3.0  ! 2007-07  (D. Storkey) Changes to iom_gettime
9   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  add C1D case 
10   !!--------------------------------------------------------------------
11
12   !!--------------------------------------------------------------------
13   !!   iom_open       : open a file read only
14   !!   iom_close      : close a file or all files opened by iom
15   !!   iom_get        : read a field (interfaced to several routines)
16   !!   iom_gettime    : read the time axis cdvar in the file
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!--------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE c1d             ! 1D vertical configuration
22   USE flo_oce         ! floats module declarations
23   USE lbclnk          ! lateal boundary condition / mpp exchanges
24   USE iom_def         ! iom variables definitions
25   USE iom_ioipsl      ! NetCDF format with IOIPSL library
26   USE iom_nf90        ! NetCDF format with native NetCDF library
27   USE iom_rstdimg     ! restarts access direct format "dimg" style...
28   USE in_out_manager  ! I/O manager
29   USE lib_mpp           ! MPP library
30#if defined key_iomput
31   USE sbc_oce, ONLY :   nn_fsbc         ! ocean space and time domain
32   USE trc_oce, ONLY :   nn_dttrc        !  !: frequency of step on passive tracers
33   USE domngb          ! ocean space and time domain
34   USE phycst          ! physical constants
35   USE dianam          ! build name of file
36   USE xios
37# endif
38   USE ioipsl, ONLY :  ju2ymds    ! for calendar
39
40   IMPLICIT NONE
41   PUBLIC   !   must be public to be able to access iom_def through iom
42   
43#if defined key_iomput
44   LOGICAL, PUBLIC, PARAMETER ::   lk_iomput = .TRUE.        !: iom_put flag
45#else
46   LOGICAL, PUBLIC, PARAMETER ::   lk_iomput = .FALSE.       !: iom_put flag
47#endif
48   PUBLIC iom_init, iom_swap, iom_open, iom_close, iom_setkt, iom_varid, iom_get, iom_gettime, iom_rstput, iom_put
49   PUBLIC iom_getatt
50
51   PRIVATE iom_rp0d, iom_rp1d, iom_rp2d, iom_rp3d
52   PRIVATE iom_g0d, iom_g1d, iom_g2d, iom_g3d, iom_get_123d
53   PRIVATE iom_p1d, iom_p2d, iom_p3d
54#if defined key_iomput
55   PRIVATE iom_set_domain_attr, iom_set_axis_attr, iom_set_field_attr, iom_set_file_attr, iom_get_file_attr, iom_set_grid_attr
56   PRIVATE set_grid, set_scalar, set_xmlatt, set_mooring, iom_update_file_name, iom_sdate
57# endif
58
59   INTERFACE iom_get
60      MODULE PROCEDURE iom_g0d, iom_g1d, iom_g2d, iom_g3d
61   END INTERFACE
62   INTERFACE iom_getatt
63      MODULE PROCEDURE iom_g0d_intatt
64   END INTERFACE
65   INTERFACE iom_rstput
66      MODULE PROCEDURE iom_rp0d, iom_rp1d, iom_rp2d, iom_rp3d
67   END INTERFACE
68  INTERFACE iom_put
69     MODULE PROCEDURE iom_p0d, iom_p1d, iom_p2d, iom_p3d
70  END INTERFACE
71#if defined key_iomput
72   INTERFACE iom_setkt
73      MODULE PROCEDURE xios_update_calendar
74   END INTERFACE
75# endif
76
77   !!----------------------------------------------------------------------
78   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
79   !! $Id$
80   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
81   !!----------------------------------------------------------------------
82
83CONTAINS
84
85   SUBROUTINE iom_init
86      !!----------------------------------------------------------------------
87      !!                     ***  ROUTINE   ***
88      !!
89      !! ** Purpose :   
90      !!
91      !!----------------------------------------------------------------------
92#if defined key_iomput
93      TYPE(xios_time)   :: dtime    = xios_time(0, 0, 0, 0, 0, 0)
94      CHARACTER(len=19) :: cldate 
95      CHARACTER(len=10) :: clname
96      INTEGER           ::   ji
97      !!----------------------------------------------------------------------
98
99      clname = "nemo"
100      IF( TRIM(Agrif_CFixed()) /= '0' )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(clname)
101      CALL xios_context_initialize(TRIM(clname), mpi_comm_opa)
102      CALL iom_swap
103
104      ! calendar parameters
105      SELECT CASE ( nleapy )        ! Choose calendar for IOIPSL
106      CASE ( 1)   ;   CALL xios_set_context_attr(TRIM(clname), calendar_type= "Gregorian")
107      CASE ( 0)   ;   CALL xios_set_context_attr(TRIM(clname), calendar_type= "NoLeap")
108      CASE (30)   ;   CALL xios_set_context_attr(TRIM(clname), calendar_type= "D360")
109      END SELECT
110      WRITE(cldate,"(i4.4,'-',i2.2,'-',i2.2,' 00:00:00')") nyear,nmonth,nday 
111      CALL xios_set_context_attr(TRIM(clname), start_date=cldate )
112
113      ! horizontal grid definition
114      CALL set_scalar
115      CALL set_grid( "T", glamt, gphit ) 
116      CALL set_grid( "U", glamu, gphiu )
117      CALL set_grid( "V", glamv, gphiv )
118      CALL set_grid( "W", glamt, gphit )
119
120      ! vertical grid definition
121      CALL iom_set_axis_attr( "deptht", gdept_0 )
122      CALL iom_set_axis_attr( "depthu", gdept_0 )
123      CALL iom_set_axis_attr( "depthv", gdept_0 )
124      CALL iom_set_axis_attr( "depthw", gdepw_0 )
125# if defined key_floats
126      CALL iom_set_axis_attr( "nfloat", (ji, ji=1,nfloat) )
127# endif
128     
129      ! automatic definitions of some of the xml attributs
130      CALL set_xmlatt
131
132      ! end file definition
133      dtime%second = rdt
134      CALL xios_set_timestep(dtime)
135      CALL xios_close_context_definition()
136     
137      CALL xios_update_calendar(0)
138#endif
139     
140   END SUBROUTINE iom_init
141
142
143   SUBROUTINE iom_swap
144      !!---------------------------------------------------------------------
145      !!                   ***  SUBROUTINE  iom_swap  ***
146      !!
147      !! ** Purpose :  swap context between different agrif grid for xmlio_server
148      !!---------------------------------------------------------------------
149#if defined key_iomput
150      TYPE(xios_context) :: nemo_hdl
151
152     IF( TRIM(Agrif_CFixed()) == '0' ) THEN
153        CALL xios_get_handle("nemo",nemo_hdl)
154     ELSE
155        CALL xios_get_handle(TRIM(Agrif_CFixed())//"_nemo",nemo_hdl)
156     ENDIF
157     CALL xios_set_current_context(nemo_hdl)
158
159#endif
160   END SUBROUTINE iom_swap
161
162
163   SUBROUTINE iom_open( cdname, kiomid, ldwrt, kdom, kiolib, ldstop, ldiof )
164      !!---------------------------------------------------------------------
165      !!                   ***  SUBROUTINE  iom_open  ***
166      !!
167      !! ** Purpose :  open an input file (return 0 if not found)
168      !!---------------------------------------------------------------------
169      CHARACTER(len=*), INTENT(in   )           ::   cdname   ! File name
170      INTEGER         , INTENT(  out)           ::   kiomid   ! iom identifier of the opened file
171      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldwrt    ! open in write modeb          (default = .FALSE.)
172      INTEGER         , INTENT(in   ), OPTIONAL ::   kdom     ! Type of domain to be written (default = jpdom_local_noovlap)
173      INTEGER         , INTENT(in   ), OPTIONAL ::   kiolib   ! library used to open the file (default = jpnf90)
174      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldstop   ! stop if open to read a non-existing file (default = .TRUE.)
175      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldiof    ! Interp On the Fly, needed for AGRIF (default = .FALSE.)
176
177      CHARACTER(LEN=256)    ::   clname    ! the name of the file based on cdname [[+clcpu]+clcpu]
178      CHARACTER(LEN=256)    ::   cltmpn    ! tempory name to store clname (in writting mode)
179      CHARACTER(LEN=10)     ::   clsuffix  ! ".nc" or ".dimg"
180      CHARACTER(LEN=15)     ::   clcpu     ! the cpu number (max jpmax_digits digits)
181      CHARACTER(LEN=256)    ::   clinfo    ! info character
182      LOGICAL               ::   llok      ! check the existence
183      LOGICAL               ::   llwrt     ! local definition of ldwrt
184      LOGICAL               ::   llnoov    ! local definition to read overlap
185      LOGICAL               ::   llstop    ! local definition of ldstop
186      LOGICAL               ::   lliof     ! local definition of ldiof
187      INTEGER               ::   iolib     ! library do we use to open the file
188      INTEGER               ::   icnt      ! counter for digits in clcpu (max = jpmax_digits)
189      INTEGER               ::   iln, ils  ! lengths of character
190      INTEGER               ::   idom      ! type of domain
191      INTEGER               ::   istop     !
192      INTEGER, DIMENSION(2,5) ::   idompar ! domain parameters:
193      ! local number of points for x,y dimensions
194      ! position of first local point for x,y dimensions
195      ! position of last local point for x,y dimensions
196      ! start halo size for x,y dimensions
197      ! end halo size for x,y dimensions
198      !---------------------------------------------------------------------
199      ! Initializations and control
200      ! =============
201      kiomid = -1
202      clinfo = '                    iom_open ~~~  '
203      istop = nstop
204      ! if iom_open is called for the first time: initialize iom_file(:)%nfid to 0
205      ! (could be done when defining iom_file in f95 but not in f90)
206      IF( Agrif_Root() ) THEN
207         IF( iom_open_init == 0 ) THEN
208            iom_file(:)%nfid = 0
209            iom_open_init = 1
210         ENDIF
211      ENDIF
212      ! do we read or write the file?
213      IF( PRESENT(ldwrt) ) THEN   ;   llwrt = ldwrt
214      ELSE                        ;   llwrt = .FALSE.
215      ENDIF
216      ! do we call ctl_stop if we try to open a non-existing file in read mode?
217      IF( PRESENT(ldstop) ) THEN   ;   llstop = ldstop
218      ELSE                         ;   llstop = .TRUE.
219      ENDIF
220      ! what library do we use to open the file?
221      IF( PRESENT(kiolib) ) THEN   ;   iolib = kiolib
222      ELSE                         ;   iolib = jpnf90
223      ENDIF
224      ! are we using interpolation on the fly?
225      IF( PRESENT(ldiof) ) THEN   ;   lliof = ldiof
226      ELSE                        ;   lliof = .FALSE.
227      ENDIF
228      ! do we read the overlap
229      ! ugly patch SM+JMM+RB to overwrite global definition in some cases
230      llnoov = (jpni * jpnj ) == jpnij .AND. .NOT. lk_agrif 
231      ! create the file name by added, if needed, TRIM(Agrif_CFixed()) and TRIM(clsuffix)
232      ! =============
233      clname   = trim(cdname)
234      IF ( .NOT. Agrif_Root() .AND. .NOT. lliof ) THEN
235         iln    = INDEX(clname,'/') 
236         cltmpn = clname(1:iln)
237         clname = clname(iln+1:LEN_TRIM(clname))
238         clname=TRIM(cltmpn)//TRIM(Agrif_CFixed())//'_'//TRIM(clname)
239      ENDIF
240      ! which suffix should we use?
241      SELECT CASE (iolib)
242      CASE (jpioipsl ) ;   clsuffix = '.nc'
243      CASE (jpnf90   ) ;   clsuffix = '.nc'
244      CASE (jprstdimg) ;   clsuffix = '.dimg'
245      CASE DEFAULT     ;   clsuffix = ''
246         CALL ctl_stop( TRIM(clinfo), 'accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
247      END SELECT
248      ! Add the suffix if needed
249      iln = LEN_TRIM(clname)
250      ils = LEN_TRIM(clsuffix)
251      IF( iln <= ils .OR. INDEX( TRIM(clname), TRIM(clsuffix), back = .TRUE. ) /= iln - ils + 1 )   &
252         &   clname = TRIM(clname)//TRIM(clsuffix)
253      cltmpn = clname   ! store this name
254      ! try to find if the file to be opened already exist
255      ! =============
256      INQUIRE( FILE = clname, EXIST = llok )
257      IF( .NOT.llok ) THEN
258         ! we try to add the cpu number to the name
259         IF( iolib == jprstdimg ) THEN   ;   WRITE(clcpu,*) narea
260         ELSE                            ;   WRITE(clcpu,*) narea-1
261         ENDIF
262         clcpu  = TRIM(ADJUSTL(clcpu))
263         iln = INDEX(clname,TRIM(clsuffix), back = .TRUE.)
264         clname = clname(1:iln-1)//'_'//TRIM(clcpu)//TRIM(clsuffix)
265         icnt = 0
266         INQUIRE( FILE = clname, EXIST = llok ) 
267         ! we try different formats for the cpu number by adding 0
268         DO WHILE( .NOT.llok .AND. icnt < jpmax_digits )
269            clcpu  = "0"//trim(clcpu)
270            clname = clname(1:iln-1)//'_'//TRIM(clcpu)//TRIM(clsuffix)
271            INQUIRE( FILE = clname, EXIST = llok )
272            icnt = icnt + 1
273         END DO
274      ENDIF
275      IF( llwrt ) THEN
276         ! check the domain definition
277! JMM + SM: ugly patch before getting the new version of lib_mpp)
278!         idom = jpdom_local_noovlap   ! default definition
279         IF( llnoov ) THEN   ;   idom = jpdom_local_noovlap   ! default definition
280         ELSE                ;   idom = jpdom_local_full      ! default definition
281         ENDIF
282         IF( PRESENT(kdom) )   idom = kdom
283         ! create the domain informations
284         ! =============
285         SELECT CASE (idom)
286         CASE (jpdom_local_full)
287            idompar(:,1) = (/ jpi             , jpj              /)
288            idompar(:,2) = (/ nimpp           , njmpp            /)
289            idompar(:,3) = (/ nimpp + jpi - 1 , njmpp + jpj - 1  /)
290            idompar(:,4) = (/ nldi - 1        , nldj - 1         /)
291            idompar(:,5) = (/ jpi - nlei      , jpj - nlej       /)
292         CASE (jpdom_local_noextra)
293            idompar(:,1) = (/ nlci            , nlcj             /)
294            idompar(:,2) = (/ nimpp           , njmpp            /)
295            idompar(:,3) = (/ nimpp + nlci - 1, njmpp + nlcj - 1 /)
296            idompar(:,4) = (/ nldi - 1        , nldj - 1         /)
297            idompar(:,5) = (/ nlci - nlei     , nlcj - nlej      /)
298         CASE (jpdom_local_noovlap)
299            idompar(:,1) = (/ nlei  - nldi + 1, nlej  - nldj + 1 /)
300            idompar(:,2) = (/ nimpp + nldi - 1, njmpp + nldj - 1 /)
301            idompar(:,3) = (/ nimpp + nlei - 1, njmpp + nlej - 1 /)
302            idompar(:,4) = (/ 0               , 0                /)
303            idompar(:,5) = (/ 0               , 0                /)
304         CASE DEFAULT
305            CALL ctl_stop( TRIM(clinfo), 'wrong value of kdom, only jpdom_local* cases are accepted' )
306         END SELECT
307      ENDIF
308      ! Open the NetCDF or RSTDIMG file
309      ! =============
310      ! do we have some free file identifier?
311      IF( MINVAL(iom_file(:)%nfid) /= 0 )   &
312         &   CALL ctl_stop( TRIM(clinfo), 'No more free file identifier', 'increase jpmax_files in iom_def' )
313      ! if no file was found...
314      IF( .NOT. llok ) THEN
315         IF( .NOT. llwrt ) THEN   ! we are in read mode
316            IF( llstop ) THEN   ;   CALL ctl_stop( TRIM(clinfo), 'File '//TRIM(cltmpn)//'* not found' )
317            ELSE                ;   istop = nstop + 1   ! make sure that istop /= nstop so we don't open the file
318            ENDIF
319         ELSE                     ! we are in write mode so we
320            clname = cltmpn       ! get back the file name without the cpu number
321         ENDIF
322      ELSE
323         IF( llwrt .AND. .NOT. ln_clobber ) THEN   ! we stop as we want to write in a new file
324            CALL ctl_stop( TRIM(clinfo), 'We want to write in a new file but '//TRIM(clname)//' already exists...' )
325            istop = nstop + 1                      ! make sure that istop /= nstop so we don't open the file
326         ENDIF
327      ENDIF
328      IF( istop == nstop ) THEN   ! no error within this routine
329         SELECT CASE (iolib)
330         CASE (jpioipsl )   ;   CALL iom_ioipsl_open(  clname, kiomid, llwrt, llok, idompar )
331         CASE (jpnf90   )   ;   CALL iom_nf90_open(    clname, kiomid, llwrt, llok, idompar )
332         CASE (jprstdimg)   ;   CALL iom_rstdimg_open( clname, kiomid, llwrt, llok, idompar )
333         CASE DEFAULT
334            CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
335         END SELECT
336      ENDIF
337      !
338   END SUBROUTINE iom_open
339
340
341   SUBROUTINE iom_close( kiomid )
342      !!--------------------------------------------------------------------
343      !!                   ***  SUBROUTINE  iom_close  ***
344      !!
345      !! ** Purpose : close an input file, or all files opened by iom
346      !!--------------------------------------------------------------------
347      INTEGER, INTENT(inout), OPTIONAL ::   kiomid   ! iom identifier of the file to be closed
348      !                                              ! return 0 when file is properly closed
349      !                                              ! No argument: all files opened by iom are closed
350
351      INTEGER ::   jf         ! dummy loop indices
352      INTEGER ::   i_s, i_e   ! temporary integer
353      CHARACTER(LEN=100)    ::   clinfo    ! info character
354      !---------------------------------------------------------------------
355      !
356      clinfo = '                    iom_close ~~~  '
357      IF( PRESENT(kiomid) ) THEN
358         i_s = kiomid
359         i_e = kiomid
360      ELSE
361         i_s = 1
362         i_e = jpmax_files
363      ENDIF
364
365      IF( i_s > 0 ) THEN
366         DO jf = i_s, i_e
367            IF( iom_file(jf)%nfid > 0 ) THEN
368               SELECT CASE (iom_file(jf)%iolib)
369               CASE (jpioipsl )   ;   CALL iom_ioipsl_close(  jf )
370               CASE (jpnf90   )   ;   CALL iom_nf90_close(    jf )
371               CASE (jprstdimg)   ;   CALL iom_rstdimg_close( jf )
372               CASE DEFAULT
373                  CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
374               END SELECT
375               iom_file(jf)%nfid       = 0          ! free the id
376               IF( PRESENT(kiomid) )   kiomid = 0   ! return 0 as id to specify that the file was closed
377               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' close file: '//TRIM(iom_file(jf)%name)//' ok'
378            ELSEIF( PRESENT(kiomid) ) THEN
379               WRITE(ctmp1,*) '--->',  kiomid
380               CALL ctl_stop( TRIM(clinfo)//' Invalid file identifier', ctmp1 )
381            ENDIF
382         END DO
383      ENDIF
384      !   
385   END SUBROUTINE iom_close
386
387
388   FUNCTION iom_varid ( kiomid, cdvar, kdimsz, ldstop ) 
389      !!-----------------------------------------------------------------------
390      !!                  ***  FUNCTION  iom_varid  ***
391      !!
392      !! ** Purpose : get the id of a variable in a file (return 0 if not found)
393      !!-----------------------------------------------------------------------
394      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
395      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
396      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
397      LOGICAL              , INTENT(in   ), OPTIONAL ::   ldstop   ! stop if looking for non-existing variable (default = .TRUE.)
398      !
399      INTEGER                        ::   iom_varid, iiv, i_nvd
400      LOGICAL                        ::   ll_fnd
401      CHARACTER(LEN=100)             ::   clinfo                   ! info character
402      LOGICAL                        ::   llstop                   ! local definition of ldstop
403      !!-----------------------------------------------------------------------
404      iom_varid = 0                         ! default definition
405      ! do we call ctl_stop if we look for non-existing variable?
406      IF( PRESENT(ldstop) ) THEN   ;   llstop = ldstop
407      ELSE                         ;   llstop = .TRUE.
408      ENDIF
409      !
410      IF( kiomid > 0 ) THEN
411         clinfo = 'iom_varid, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(cdvar)
412         IF( iom_file(kiomid)%nfid == 0 ) THEN
413            CALL ctl_stop( trim(clinfo), 'the file is not open' )
414         ELSE
415            ll_fnd  = .FALSE.
416            iiv = 0
417            !
418            DO WHILE ( .NOT.ll_fnd .AND. iiv < iom_file(kiomid)%nvars )
419               iiv = iiv + 1
420               ll_fnd  = ( TRIM(cdvar) == TRIM(iom_file(kiomid)%cn_var(iiv)) )
421            END DO
422            !
423            IF( .NOT.ll_fnd ) THEN
424               iiv = iiv + 1
425               IF( iiv <= jpmax_vars ) THEN
426                  SELECT CASE (iom_file(kiomid)%iolib)
427                  CASE (jpioipsl )   ;   iom_varid = iom_ioipsl_varid( kiomid, cdvar, iiv, kdimsz )
428                  CASE (jpnf90   )   ;   iom_varid = iom_nf90_varid  ( kiomid, cdvar, iiv, kdimsz )
429                  CASE (jprstdimg)   ;   iom_varid = -1   ! all variables are listed in iom_file
430                  CASE DEFAULT   
431                     CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
432                  END SELECT
433               ELSE
434                  CALL ctl_stop( trim(clinfo), 'Too many variables in the file '//iom_file(kiomid)%name,   &
435                        &                         'increase the parameter jpmax_vars')
436               ENDIF
437               IF( llstop .AND. iom_varid == -1 )   CALL ctl_stop( TRIM(clinfo)//' not found' ) 
438            ELSE
439               iom_varid = iiv
440               IF( PRESENT(kdimsz) ) THEN
441                  i_nvd = iom_file(kiomid)%ndims(iiv)
442                  IF( i_nvd == size(kdimsz) ) THEN
443                     kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,iiv)
444                  ELSE
445                     WRITE(ctmp1,*) i_nvd, size(kdimsz)
446                     CALL ctl_stop( trim(clinfo), 'error in kdimsz size'//trim(ctmp1) )
447                  ENDIF
448               ENDIF
449            ENDIF
450         ENDIF
451      ENDIF
452      !
453   END FUNCTION iom_varid
454
455
456   !!----------------------------------------------------------------------
457   !!                   INTERFACE iom_get
458   !!----------------------------------------------------------------------
459   SUBROUTINE iom_g0d( kiomid, cdvar, pvar )
460      INTEGER         , INTENT(in   )                 ::   kiomid    ! Identifier of the file
461      CHARACTER(len=*), INTENT(in   )                 ::   cdvar     ! Name of the variable
462      REAL(wp)        , INTENT(  out)                 ::   pvar      ! read field
463      !
464      INTEGER               :: idvar   ! variable id
465      !
466      IF( kiomid > 0 ) THEN
467         idvar = iom_varid( kiomid, cdvar )
468         IF( iom_file(kiomid)%nfid > 0 .AND. idvar > 0 ) THEN
469            SELECT CASE (iom_file(kiomid)%iolib)
470            CASE (jpioipsl )   ;   CALL iom_ioipsl_get(  kiomid, idvar, pvar )
471            CASE (jpnf90   )   ;   CALL iom_nf90_get(    kiomid, idvar, pvar )
472            CASE (jprstdimg)   ;   CALL iom_rstdimg_get( kiomid, idvar, pvar )
473            CASE DEFAULT   
474               CALL ctl_stop( 'iom_g0d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
475            END SELECT
476         ENDIF
477      ENDIF
478   END SUBROUTINE iom_g0d
479
480   SUBROUTINE iom_g1d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount )
481      INTEGER         , INTENT(in   )                         ::   kiomid    ! Identifier of the file
482      INTEGER         , INTENT(in   )                         ::   kdom      ! Type of domain to be read
483      CHARACTER(len=*), INTENT(in   )                         ::   cdvar     ! Name of the variable
484      REAL(wp)        , INTENT(  out), DIMENSION(:)           ::   pvar      ! read field
485      INTEGER         , INTENT(in   )              , OPTIONAL ::   ktime     ! record number
486      INTEGER         , INTENT(in   ), DIMENSION(1), OPTIONAL ::   kstart    ! start axis position of the reading
487      INTEGER         , INTENT(in   ), DIMENSION(1), OPTIONAL ::   kcount    ! number of points in each axis
488      !
489      IF( kiomid > 0 ) THEN
490         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r1d=pvar,   &
491              &                                                     ktime=ktime, kstart=kstart, kcount=kcount )
492      ENDIF
493   END SUBROUTINE iom_g1d
494
495   SUBROUTINE iom_g2d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount )
496      INTEGER         , INTENT(in   )                           ::   kiomid    ! Identifier of the file
497      INTEGER         , INTENT(in   )                           ::   kdom      ! Type of domain to be read
498      CHARACTER(len=*), INTENT(in   )                           ::   cdvar     ! Name of the variable
499      REAL(wp)        , INTENT(  out), DIMENSION(:,:)           ::   pvar      ! read field
500      INTEGER         , INTENT(in   )                , OPTIONAL ::   ktime     ! record number
501      INTEGER         , INTENT(in   ), DIMENSION(2)  , OPTIONAL ::   kstart    ! start axis position of the reading
502      INTEGER         , INTENT(in   ), DIMENSION(2)  , OPTIONAL ::   kcount    ! number of points in each axis
503      !
504      IF( kiomid > 0 ) THEN
505         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r2d=pvar,   &
506              &                                                     ktime=ktime, kstart=kstart, kcount=kcount )
507      ENDIF
508   END SUBROUTINE iom_g2d
509
510   SUBROUTINE iom_g3d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount )
511      INTEGER         , INTENT(in   )                             ::   kiomid    ! Identifier of the file
512      INTEGER         , INTENT(in   )                             ::   kdom      ! Type of domain to be read
513      CHARACTER(len=*), INTENT(in   )                             ::   cdvar     ! Name of the variable
514      REAL(wp)        , INTENT(  out), DIMENSION(:,:,:)           ::   pvar      ! read field
515      INTEGER         , INTENT(in   )                  , OPTIONAL ::   ktime     ! record number
516      INTEGER         , INTENT(in   ), DIMENSION(3)    , OPTIONAL ::   kstart    ! start axis position of the reading
517      INTEGER         , INTENT(in   ), DIMENSION(3)    , OPTIONAL ::   kcount    ! number of points in each axis
518      !
519      IF( kiomid > 0 ) THEN
520         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r3d=pvar,   &
521              &                                                     ktime=ktime, kstart=kstart, kcount=kcount )
522      ENDIF
523   END SUBROUTINE iom_g3d
524   !!----------------------------------------------------------------------
525
526   SUBROUTINE iom_get_123d( kiomid, kdom  , cdvar ,   &
527         &                  pv_r1d, pv_r2d, pv_r3d,   &
528         &                  ktime , kstart, kcount  )
529      !!-----------------------------------------------------------------------
530      !!                  ***  ROUTINE  iom_get_123d  ***
531      !!
532      !! ** Purpose : read a 1D/2D/3D variable
533      !!
534      !! ** Method : read ONE record at each CALL
535      !!-----------------------------------------------------------------------
536      INTEGER                    , INTENT(in   )           ::   kiomid     ! Identifier of the file
537      INTEGER                    , INTENT(in   )           ::   kdom       ! Type of domain to be read
538      CHARACTER(len=*)           , INTENT(in   )           ::   cdvar      ! Name of the variable
539      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d     ! read field (1D case)
540      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d     ! read field (2D case)
541      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d     ! read field (3D case)
542      INTEGER                    , INTENT(in   ), OPTIONAL ::   ktime      ! record number
543      INTEGER , DIMENSION(:)     , INTENT(in   ), OPTIONAL ::   kstart     ! start position of the reading in each axis
544      INTEGER , DIMENSION(:)     , INTENT(in   ), OPTIONAL ::   kcount     ! number of points to be read in each axis
545      !
546      LOGICAL                        ::   llnoov      ! local definition to read overlap
547      INTEGER                        ::   jl          ! loop on number of dimension
548      INTEGER                        ::   idom        ! type of domain
549      INTEGER                        ::   idvar       ! id of the variable
550      INTEGER                        ::   inbdim      ! number of dimensions of the variable
551      INTEGER                        ::   idmspc      ! number of spatial dimensions
552      INTEGER                        ::   itime       ! record number
553      INTEGER                        ::   istop       ! temporary value of nstop
554      INTEGER                        ::   ix1, ix2, iy1, iy2   ! subdomain indexes
555      INTEGER                        ::   ji, jj      ! loop counters
556      INTEGER                        ::   irankpv       !
557      INTEGER                        ::   ind1, ind2  ! substring index
558      INTEGER, DIMENSION(jpmax_dims) ::   istart      ! starting point to read for each axis
559      INTEGER, DIMENSION(jpmax_dims) ::   icnt        ! number of value to read along each axis
560      INTEGER, DIMENSION(jpmax_dims) ::   idimsz      ! size of the dimensions of the variable
561      INTEGER, DIMENSION(jpmax_dims) ::   ishape      ! size of the dimensions of the variable
562      REAL(wp)                       ::   zscf, zofs  ! sacle_factor and add_offset
563      INTEGER                        ::   itmp        ! temporary integer
564      CHARACTER(LEN=256)             ::   clinfo      ! info character
565      CHARACTER(LEN=256)             ::   clname      ! file name
566      CHARACTER(LEN=1)               ::   clrankpv, cldmspc      !
567      !---------------------------------------------------------------------
568      !
569      clname = iom_file(kiomid)%name   !   esier to read
570      clinfo = '          iom_get_123d, file: '//trim(clname)//', var: '//trim(cdvar)
571      ! local definition of the domain ?
572      idom = kdom
573      ! do we read the overlap
574      ! ugly patch SM+JMM+RB to overwrite global definition in some cases
575      llnoov = (jpni * jpnj ) == jpnij .AND. .NOT. lk_agrif 
576      ! check kcount and kstart optionals parameters...
577      IF( PRESENT(kcount) .AND. (.NOT. PRESENT(kstart)) ) CALL ctl_stop(trim(clinfo), 'kcount present needs kstart present')
578      IF( PRESENT(kstart) .AND. (.NOT. PRESENT(kcount)) ) CALL ctl_stop(trim(clinfo), 'kstart present needs kcount present')
579      IF( PRESENT(kstart) .AND. idom /= jpdom_unknown   ) CALL ctl_stop(trim(clinfo), 'kstart present needs kdom = jpdom_unknown')
580
581      ! Search for the variable in the data base (eventually actualize data)
582      istop = nstop
583      idvar = iom_varid( kiomid, cdvar )
584      !
585      IF( idvar > 0 ) THEN
586         ! to write iom_file(kiomid)%dimsz in a shorter way !
587         idimsz(:) = iom_file(kiomid)%dimsz(:, idvar) 
588         inbdim = iom_file(kiomid)%ndims(idvar)            ! number of dimensions in the file
589         idmspc = inbdim                                   ! number of spatial dimensions in the file
590         IF( iom_file(kiomid)%luld(idvar) )   idmspc = inbdim - 1
591         IF( idmspc > 3 )   CALL ctl_stop(trim(clinfo), 'the file has more than 3 spatial dimensions this case is not coded...') 
592         !
593         ! update idom definition...
594         ! Identify the domain in case of jpdom_auto(glo/dta) definition
595         IF( idom == jpdom_autoglo .OR. idom == jpdom_autodta ) THEN           
596            IF( idom == jpdom_autoglo ) THEN   ;   idom = jpdom_global 
597            ELSE                               ;   idom = jpdom_data
598            ENDIF
599            ind1 = INDEX( clname, '_', back = .TRUE. ) + 1
600            ind2 = INDEX( clname, '.', back = .TRUE. ) - 1
601            IF( ind2 > ind1 ) THEN   ;   IF( VERIFY( clname(ind1:ind2), '0123456789' ) == 0 )   idom = jpdom_local   ;   ENDIF
602         ENDIF
603         ! Identify the domain in case of jpdom_local definition
604         IF( idom == jpdom_local ) THEN
605            IF(     idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN   ;   idom = jpdom_local_full
606            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN   ;   idom = jpdom_local_noextra
607            ELSEIF( idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN   ;   idom = jpdom_local_noovlap
608            ELSE   ;   CALL ctl_stop( trim(clinfo), 'impossible to identify the local domain' )
609            ENDIF
610         ENDIF
611         !
612         ! check the consistency between input array and data rank in the file
613         !
614         ! initializations
615         itime = 1
616         IF( PRESENT(ktime) ) itime = ktime
617
618         irankpv = 1 * COUNT( (/PRESENT(pv_r1d)/) ) + 2 * COUNT( (/PRESENT(pv_r2d)/) ) + 3 * COUNT( (/PRESENT(pv_r3d)/) )
619         WRITE(clrankpv, fmt='(i1)') irankpv
620         WRITE(cldmspc , fmt='(i1)') idmspc
621         !
622         IF(     idmspc <  irankpv ) THEN
623            CALL ctl_stop( TRIM(clinfo), 'The file has only '//cldmspc//' spatial dimension',   &
624               &                         'it is impossible to read a '//clrankpv//'D array from this file...' )
625         ELSEIF( idmspc == irankpv ) THEN
626            IF( PRESENT(pv_r1d) .AND. idom /= jpdom_unknown )   &
627               &   CALL ctl_stop( TRIM(clinfo), 'case not coded...You must use jpdom_unknown' )
628         ELSEIF( idmspc >  irankpv ) THEN
629               IF( PRESENT(pv_r2d) .AND. itime == 1 .AND. idimsz(3) == 1 .AND. idmspc == 3 ) THEN
630                  CALL ctl_warn( trim(clinfo), '2D array but 3 spatial dimensions for the data...'              ,   &
631                        &         'As the size of the z dimension is 1 and as we try to read the first record, ',   &
632                        &         'we accept this case, even if there is a possible mix-up between z and time dimension' )   
633                  idmspc = idmspc - 1
634               ELSE
635                  CALL ctl_stop( TRIM(clinfo), 'To keep iom lisibility, when reading a '//clrankpv//'D array,'         ,   &
636                     &                         'we do not accept data with more than '//cldmspc//' spatial dimension',   &
637                     &                         'Use ncwa -a to suppress the unnecessary dimensions' )
638               ENDIF
639         ENDIF
640
641         !
642         ! definition of istart and icnt
643         !
644         icnt  (:) = 1
645         istart(:) = 1
646         istart(idmspc+1) = itime
647
648         IF(              PRESENT(kstart)       ) THEN ; istart(1:idmspc) = kstart(1:idmspc) ; icnt(1:idmspc) = kcount(1:idmspc)
649         ELSE
650            IF(           idom == jpdom_unknown ) THEN                                       ; icnt(1:idmspc) = idimsz(1:idmspc)
651            ELSE
652               IF( .NOT. PRESENT(pv_r1d) ) THEN   !   not a 1D array
653                  IF(     idom == jpdom_data    ) THEN ; istart(1:2) = (/ mig(1), mjg(1) /)  ! icnt(1:2) done bellow
654                  ELSEIF( idom == jpdom_global  ) THEN ; istart(1:2) = (/ nimpp , njmpp  /)  ! icnt(1:2) done bellow
655                  ENDIF
656                  ! we do not read the overlap                     -> we start to read at nldi, nldj
657! JMM + SM: ugly patch before getting the new version of lib_mpp)
658!                  IF( idom /= jpdom_local_noovlap )   istart(1:2) = istart(1:2) + (/ nldi - 1, nldj - 1 /)
659                  IF( llnoov .AND. idom /= jpdom_local_noovlap ) istart(1:2) = istart(1:2) + (/ nldi - 1, nldj - 1 /)
660                  ! we do not read the overlap and the extra-halos -> from nldi to nlei and from nldj to nlej
661! JMM + SM: ugly patch before getting the new version of lib_mpp)
662!                  icnt(1:2) = (/ nlei - nldi + 1, nlej - nldj + 1 /)
663                  IF( llnoov ) THEN   ;   icnt(1:2) = (/ nlei - nldi + 1, nlej - nldj + 1 /)
664                  ELSE                ;   icnt(1:2) = (/ nlci           , nlcj            /)
665                  ENDIF
666                  IF( PRESENT(pv_r3d) ) THEN
667                     IF( idom == jpdom_data ) THEN   ; icnt(3) = jpkdta
668                     ELSE                            ; icnt(3) = jpk
669                     ENDIF
670                  ENDIF
671               ENDIF
672            ENDIF
673         ENDIF
674
675         ! check that istart and icnt can be used with this file
676         !-
677         DO jl = 1, jpmax_dims
678            itmp = istart(jl)+icnt(jl)-1
679            IF( itmp > idimsz(jl) .AND. idimsz(jl) /= 0 ) THEN
680               WRITE( ctmp1, FMT="('(istart(', i1, ') + icnt(', i1, ') - 1) = ', i5)" ) jl, jl, itmp
681               WRITE( ctmp2, FMT="(' is larger than idimsz(', i1,') = ', i5)"         ) jl, idimsz(jl)
682               CALL ctl_stop( trim(clinfo), 'start and count too big regarding to the size of the data, ', ctmp1, ctmp2 )     
683            ENDIF
684         END DO
685
686         ! check that icnt matches the input array
687         !-     
688         IF( idom == jpdom_unknown ) THEN
689            IF( irankpv == 1 )        ishape(1:1) = SHAPE(pv_r1d)
690            IF( irankpv == 2 )        ishape(1:2) = SHAPE(pv_r2d)
691            IF( irankpv == 3 )        ishape(1:3) = SHAPE(pv_r3d)
692            ctmp1 = 'd'
693         ELSE
694            IF( irankpv == 2 ) THEN
695! JMM + SM: ugly patch before getting the new version of lib_mpp)
696!               ishape(1:2) = SHAPE(pv_r2d(nldi:nlei,nldj:nlej  ))   ;   ctmp1 = 'd(nldi:nlei,nldj:nlej)'
697               IF( llnoov ) THEN ; ishape(1:2)=SHAPE(pv_r2d(nldi:nlei,nldj:nlej  )) ; ctmp1='d(nldi:nlei,nldj:nlej)'
698               ELSE              ; ishape(1:2)=SHAPE(pv_r2d(1   :nlci,1   :nlcj  )) ; ctmp1='d(1:nlci,1:nlcj)'
699               ENDIF
700            ENDIF
701            IF( irankpv == 3 ) THEN 
702! JMM + SM: ugly patch before getting the new version of lib_mpp)
703!               ishape(1:3) = SHAPE(pv_r3d(nldi:nlei,nldj:nlej,:))   ;   ctmp1 = 'd(nldi:nlei,nldj:nlej,:)'
704               IF( llnoov ) THEN ; ishape(1:3)=SHAPE(pv_r3d(nldi:nlei,nldj:nlej,:)) ; ctmp1='d(nldi:nlei,nldj:nlej,:)'
705               ELSE              ; ishape(1:3)=SHAPE(pv_r3d(1   :nlci,1   :nlcj,:)) ; ctmp1='d(1:nlci,1:nlcj,:)'
706               ENDIF
707            ENDIF
708         ENDIF
709         
710         DO jl = 1, irankpv
711            WRITE( ctmp2, FMT="(', ', i1,'): ', i5,' /= icnt(', i1,'):', i5)" ) jl, ishape(jl), jl, icnt(jl)
712            IF( ishape(jl) /= icnt(jl) )   CALL ctl_stop( TRIM(clinfo), 'size(pv_r'//clrankpv//TRIM(ctmp1)//TRIM(ctmp2) )
713         END DO
714
715      ENDIF
716
717      ! read the data
718      !-     
719      IF( idvar > 0 .AND. istop == nstop ) THEN   ! no additional errors until this point...
720         !
721         ! find the right index of the array to be read
722! JMM + SM: ugly patch before getting the new version of lib_mpp)
723!         IF( idom /= jpdom_unknown ) THEN   ;   ix1 = nldi   ;   ix2 = nlei      ;   iy1 = nldj   ;   iy2 = nlej
724!         ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
725!         ENDIF
726         IF( llnoov ) THEN
727            IF( idom /= jpdom_unknown ) THEN   ;   ix1 = nldi   ;   ix2 = nlei      ;   iy1 = nldj   ;   iy2 = nlej
728            ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
729            ENDIF
730         ELSE
731            IF( idom /= jpdom_unknown ) THEN   ;   ix1 = 1      ;   ix2 = nlci      ;   iy1 = 1      ;   iy2 = nlcj
732            ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
733            ENDIF
734         ENDIF
735     
736         SELECT CASE (iom_file(kiomid)%iolib)
737         CASE (jpioipsl )   ;   CALL iom_ioipsl_get(  kiomid, idvar, inbdim, istart, icnt, ix1, ix2, iy1, iy2,   &
738            &                                         pv_r1d, pv_r2d, pv_r3d )
739         CASE (jpnf90   )   ;   CALL iom_nf90_get(    kiomid, idvar, inbdim, istart, icnt, ix1, ix2, iy1, iy2,   &
740            &                                         pv_r1d, pv_r2d, pv_r3d )
741         CASE (jprstdimg)   ;   CALL iom_rstdimg_get( kiomid, idom, idvar, ix1, ix2, iy1, iy2,   &
742            &                                         pv_r1d, pv_r2d, pv_r3d )
743         CASE DEFAULT   
744            CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
745         END SELECT
746
747         IF( istop == nstop ) THEN   ! no additional errors until this point...
748            IF(lwp) WRITE(numout,"(10x,' read ',a,' (rec: ',i4,') in ',a,' ok')") TRIM(cdvar), itime, TRIM(iom_file(kiomid)%name)
749         
750            !--- overlap areas and extra hallows (mpp)
751            IF(     PRESENT(pv_r2d) .AND. idom /= jpdom_unknown ) THEN
752               CALL lbc_lnk( pv_r2d,'Z',-999.,'no0' )
753            ELSEIF( PRESENT(pv_r3d) .AND. idom /= jpdom_unknown ) THEN
754               ! this if could be simplified with the new lbc_lnk that works with any size of the 3rd dimension
755               IF( icnt(3) == jpk ) THEN
756                  CALL lbc_lnk( pv_r3d,'Z',-999.,'no0' )
757               ELSE   ! put some arbitrary value (a call to lbc_lnk will be done later...)
758                  DO jj = nlcj+1, jpj   ;   pv_r3d(1:nlci, jj, :) = pv_r3d(1:nlci, nlej, :)   ;   END DO
759                  DO ji = nlci+1, jpi   ;   pv_r3d(ji    , : , :) = pv_r3d(nlei  , :   , :)   ;   END DO
760               ENDIF
761            ENDIF
762           
763            ! C1D case : always call lbc_lnk to replicate the central value over the whole 3X3 domain
764            IF( lk_c1d .AND. PRESENT(pv_r2d) )   CALL lbc_lnk( pv_r2d,'Z',1. )
765            IF( lk_c1d .AND. PRESENT(pv_r3d) )   CALL lbc_lnk( pv_r3d,'Z',1. )
766   
767            !--- Apply scale_factor and offset
768            zscf = iom_file(kiomid)%scf(idvar)      ! scale factor
769            zofs = iom_file(kiomid)%ofs(idvar)      ! offset
770            IF(     PRESENT(pv_r1d) ) THEN
771               IF( zscf /= 1. )   pv_r1d(:) = pv_r1d(:) * zscf 
772               IF( zofs /= 0. )   pv_r1d(:) = pv_r1d(:) + zofs
773            ELSEIF( PRESENT(pv_r2d) ) THEN
774!CDIR COLLAPSE
775               IF( zscf /= 1.)   pv_r2d(:,:) = pv_r2d(:,:) * zscf
776!CDIR COLLAPSE
777               IF( zofs /= 0.)   pv_r2d(:,:) = pv_r2d(:,:) + zofs
778            ELSEIF( PRESENT(pv_r3d) ) THEN
779!CDIR COLLAPSE
780               IF( zscf /= 1.)   pv_r3d(:,:,:) = pv_r3d(:,:,:) * zscf
781!CDIR COLLAPSE
782               IF( zofs /= 0.)   pv_r3d(:,:,:) = pv_r3d(:,:,:) + zofs
783            ENDIF
784            !
785         ENDIF
786         !
787      ENDIF
788      !
789   END SUBROUTINE iom_get_123d
790
791
792   SUBROUTINE iom_gettime( kiomid, ptime, cdvar, kntime, cdunits, cdcalendar )
793      !!--------------------------------------------------------------------
794      !!                   ***  SUBROUTINE iom_gettime  ***
795      !!
796      !! ** Purpose : read the time axis cdvar in the file
797      !!--------------------------------------------------------------------
798      INTEGER                    , INTENT(in   ) ::   kiomid     ! file Identifier
799      REAL(wp), DIMENSION(:)     , INTENT(  out) ::   ptime      ! the time axis
800      CHARACTER(len=*), OPTIONAL , INTENT(in   ) ::   cdvar      ! time axis name
801      INTEGER         , OPTIONAL , INTENT(  out) ::   kntime     ! number of times in file
802      CHARACTER(len=*), OPTIONAL , INTENT(  out) ::   cdunits    ! units attribute of time coordinate
803      CHARACTER(len=*), OPTIONAL , INTENT(  out) ::   cdcalendar ! calendar attribute of
804      !
805      INTEGER, DIMENSION(1) :: kdimsz
806      INTEGER            ::   idvar    ! id of the variable
807      CHARACTER(LEN=32)  ::   tname    ! local name of time coordinate
808      CHARACTER(LEN=100) ::   clinfo   ! info character
809      !---------------------------------------------------------------------
810      !
811      IF ( PRESENT(cdvar) ) THEN
812         tname = cdvar
813      ELSE
814         tname = iom_file(kiomid)%uldname
815      ENDIF
816      IF( kiomid > 0 ) THEN
817         clinfo = 'iom_gettime, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(tname)
818         IF ( PRESENT(kntime) ) THEN
819            idvar  = iom_varid( kiomid, tname, kdimsz = kdimsz )
820            kntime = kdimsz(1)
821         ELSE
822            idvar = iom_varid( kiomid, tname )
823         ENDIF
824         !
825         ptime(:) = 0. ! default definition
826         IF( idvar > 0 ) THEN
827            IF( iom_file(kiomid)%ndims(idvar) == 1 ) THEN
828               IF( iom_file(kiomid)%luld(idvar) ) THEN
829                  IF( iom_file(kiomid)%dimsz(1,idvar) <= size(ptime) ) THEN
830                     SELECT CASE (iom_file(kiomid)%iolib)
831                     CASE (jpioipsl )   ;   CALL iom_ioipsl_gettime( kiomid, idvar, ptime, cdunits, cdcalendar )
832                     CASE (jpnf90   )   ;   CALL iom_nf90_gettime(   kiomid, idvar, ptime, cdunits, cdcalendar )
833                     CASE (jprstdimg)   ;   CALL ctl_stop( TRIM(clinfo)//' case IO library == jprstdimg not coded...' )
834                     CASE DEFAULT   
835                        CALL ctl_stop( TRIM(clinfo)//' accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
836                     END SELECT
837                  ELSE
838                     WRITE(ctmp1,*) 'error with the size of ptime ',size(ptime),iom_file(kiomid)%dimsz(1,idvar)
839                     CALL ctl_stop( trim(clinfo), trim(ctmp1) )
840                  ENDIF
841               ELSE
842                  CALL ctl_stop( trim(clinfo), 'variable dimension is not unlimited... use iom_get' )
843               ENDIF
844            ELSE
845               CALL ctl_stop( trim(clinfo), 'the variable has more than 1 dimension' )
846            ENDIF
847         ELSE
848            CALL ctl_stop( trim(clinfo), 'variable not found in '//iom_file(kiomid)%name )
849         ENDIF
850      ENDIF
851      !
852   END SUBROUTINE iom_gettime
853
854
855   !!----------------------------------------------------------------------
856   !!                   INTERFACE iom_getatt
857   !!----------------------------------------------------------------------
858   SUBROUTINE iom_g0d_intatt( kiomid, cdatt, pvar )
859      INTEGER         , INTENT(in   )                 ::   kiomid    ! Identifier of the file
860      CHARACTER(len=*), INTENT(in   )                 ::   cdatt     ! Name of the attribute
861      INTEGER         , INTENT(  out)                 ::   pvar      ! read field
862      !
863      IF( kiomid > 0 ) THEN
864         IF( iom_file(kiomid)%nfid > 0 ) THEN
865            SELECT CASE (iom_file(kiomid)%iolib)
866            CASE (jpioipsl )   ;   CALL ctl_stop('iom_getatt: only nf90 available')
867            CASE (jpnf90   )   ;   CALL iom_nf90_getatt( kiomid, cdatt, pvar )
868            CASE (jprstdimg)   ;   CALL ctl_stop('iom_getatt: only nf90 available')
869            CASE DEFAULT   
870               CALL ctl_stop( 'iom_g0d_att: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
871            END SELECT
872         ENDIF
873      ENDIF
874   END SUBROUTINE iom_g0d_intatt
875
876
877   !!----------------------------------------------------------------------
878   !!                   INTERFACE iom_rstput
879   !!----------------------------------------------------------------------
880   SUBROUTINE iom_rp0d( kt, kwrite, kiomid, cdvar, pvar, ktype )
881      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
882      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
883      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
884      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
885      REAL(wp)        , INTENT(in)                         ::   pvar     ! written field
886      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
887      INTEGER :: ivid   ! variable id
888      IF( kiomid > 0 ) THEN
889         IF( iom_file(kiomid)%nfid > 0 ) THEN
890            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
891            SELECT CASE (iom_file(kiomid)%iolib)
892            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r0d = pvar )
893            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r0d = pvar )
894            CASE (jprstdimg)   ;   IF( kt == kwrite )    CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pvar )
895            CASE DEFAULT     
896               CALL ctl_stop( 'iom_rp0d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
897            END SELECT
898         ENDIF
899      ENDIF
900   END SUBROUTINE iom_rp0d
901
902   SUBROUTINE iom_rp1d( kt, kwrite, kiomid, cdvar, pvar, ktype )
903      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
904      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
905      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
906      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
907      REAL(wp)        , INTENT(in), DIMENSION(          :) ::   pvar     ! written field
908      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
909      INTEGER :: ivid   ! variable id
910      IF( kiomid > 0 ) THEN
911         IF( iom_file(kiomid)%nfid > 0 ) THEN
912            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
913            SELECT CASE (iom_file(kiomid)%iolib)
914            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r1d = pvar )
915            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r1d = pvar )
916            CASE (jprstdimg)   ;   IF( kt == kwrite )    CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pv_r1d = pvar )
917            CASE DEFAULT     
918               CALL ctl_stop( 'iom_rp1d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
919            END SELECT
920         ENDIF
921      ENDIF
922   END SUBROUTINE iom_rp1d
923
924   SUBROUTINE iom_rp2d( kt, kwrite, kiomid, cdvar, pvar, ktype )
925      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
926      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
927      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
928      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
929      REAL(wp)        , INTENT(in), DIMENSION(:,    :    ) ::   pvar     ! written field
930      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
931      INTEGER :: ivid   ! variable id
932      IF( kiomid > 0 ) THEN
933         IF( iom_file(kiomid)%nfid > 0 ) THEN
934            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
935            SELECT CASE (iom_file(kiomid)%iolib)
936            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r2d = pvar )
937            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r2d = pvar )
938            CASE (jprstdimg)   ;   IF( kt == kwrite )   CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pv_r2d = pvar ) 
939            CASE DEFAULT     
940               CALL ctl_stop( 'iom_rp2d: accepted IO library are only jpioipsl, jpnf90 and jprstdimg' )
941            END SELECT
942         ENDIF
943      ENDIF
944   END SUBROUTINE iom_rp2d
945
946   SUBROUTINE iom_rp3d( kt, kwrite, kiomid, cdvar, pvar, ktype )
947      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
948      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
949      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
950      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
951      REAL(wp)        , INTENT(in),       DIMENSION(:,:,:) ::   pvar     ! written field
952      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
953      INTEGER :: ivid   ! variable id
954      IF( kiomid > 0 ) THEN
955         IF( iom_file(kiomid)%nfid > 0 ) THEN
956            ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
957            SELECT CASE (iom_file(kiomid)%iolib)
958            CASE (jpioipsl )   ;   CALL iom_ioipsl_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r3d = pvar )
959            CASE (jpnf90   )   ;   CALL iom_nf90_rstput(   kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r3d = pvar )
960            CASE (jprstdimg)   ;   IF( kt == kwrite )   CALL iom_rstdimg_rstput( kiomid, cdvar, ivid, pv_r3d = pvar )
961            CASE DEFAULT     
962               CALL ctl_stop( 'iom_rp3d: accepted IO library are only jpioipsl and jprstdimg' )
963            END SELECT
964         ENDIF
965      ENDIF
966   END SUBROUTINE iom_rp3d
967
968
969   !!----------------------------------------------------------------------
970   !!                   INTERFACE iom_put
971   !!----------------------------------------------------------------------
972   SUBROUTINE iom_p0d( cdname, pfield0d )
973      CHARACTER(LEN=*), INTENT(in) ::   cdname
974      REAL(wp)        , INTENT(in) ::   pfield0d
975#if defined key_iomput
976      CALL xios_send_field(cdname, (/pfield0d/))
977#else
978      IF( .FALSE. )   WRITE(numout,*) cdname, pfield0d   ! useless test to avoid compilation warnings
979#endif
980   END SUBROUTINE iom_p0d
981
982   SUBROUTINE iom_p1d( cdname, pfield1d )
983      CHARACTER(LEN=*)          , INTENT(in) ::   cdname
984      REAL(wp),     DIMENSION(:), INTENT(in) ::   pfield1d
985#if defined key_iomput
986      CALL xios_send_field( cdname, RESHAPE( (/pfield1d/), (/1,1,SIZE(pfield1d)/) ) )
987#else
988      IF( .FALSE. )   WRITE(numout,*) cdname, pfield1d   ! useless test to avoid compilation warnings
989#endif
990   END SUBROUTINE iom_p1d
991
992   SUBROUTINE iom_p2d( cdname, pfield2d )
993      CHARACTER(LEN=*)            , INTENT(in) ::   cdname
994      REAL(wp),     DIMENSION(:,:), INTENT(in) ::   pfield2d
995#if defined key_iomput
996      CALL xios_send_field(cdname, pfield2d)
997#else
998      IF( .FALSE. )   WRITE(numout,*) cdname, pfield2d   ! useless test to avoid compilation warnings
999#endif
1000   END SUBROUTINE iom_p2d
1001
1002   SUBROUTINE iom_p3d( cdname, pfield3d )
1003      CHARACTER(LEN=*)                , INTENT(in) ::   cdname
1004      REAL(wp),       DIMENSION(:,:,:), INTENT(in) ::   pfield3d
1005#if defined key_iomput
1006      CALL xios_send_field(cdname, pfield3d)
1007#else
1008      IF( .FALSE. )   WRITE(numout,*) cdname, pfield3d   ! useless test to avoid compilation warnings
1009#endif
1010   END SUBROUTINE iom_p3d
1011   !!----------------------------------------------------------------------
1012
1013#if defined key_iomput
1014
1015   SUBROUTINE iom_set_domain_attr( cdid, ni_glo, nj_glo, ibegin, jbegin, ni, nj, zoom_ibegin, zoom_jbegin, zoom_ni, zoom_nj,   &
1016      &                                    data_dim, data_ibegin, data_ni, data_jbegin, data_nj, lonvalue, latvalue, mask )
1017      CHARACTER(LEN=*)                 , INTENT(in) ::   cdid
1018      INTEGER                , OPTIONAL, INTENT(in) ::   ni_glo, nj_glo, ibegin, jbegin, ni, nj
1019      INTEGER                , OPTIONAL, INTENT(in) ::   data_dim, data_ibegin, data_ni, data_jbegin, data_nj
1020      INTEGER                , OPTIONAL, INTENT(in) ::   zoom_ibegin, zoom_jbegin, zoom_ni, zoom_nj
1021      REAL(wp), DIMENSION(:) , OPTIONAL, INTENT(in) ::   lonvalue, latvalue
1022      LOGICAL, DIMENSION(:,:), OPTIONAL, INTENT(in) ::   mask
1023
1024      IF ( xios_is_valid_domain     (cdid) ) THEN
1025         CALL xios_set_domain_attr     ( cdid, ni_glo=ni_glo, nj_glo=nj_glo, ibegin=ibegin, jbegin=jbegin, ni=ni, nj=nj,   &
1026            &    data_dim=data_dim, data_ibegin=data_ibegin, data_ni=data_ni, data_jbegin=data_jbegin, data_nj=data_nj ,   &
1027            &    zoom_ibegin=zoom_ibegin, zoom_jbegin=zoom_jbegin, zoom_ni=zoom_ni, zoom_nj=zoom_nj,                       &
1028            &    lonvalue=lonvalue, latvalue=latvalue,mask=mask )
1029      ENDIF
1030
1031      IF ( xios_is_valid_domaingroup(cdid) ) THEN
1032         CALL xios_set_domaingroup_attr( cdid, ni_glo=ni_glo, nj_glo=nj_glo, ibegin=ibegin, jbegin=jbegin, ni=ni, nj=nj,   &
1033            &    data_dim=data_dim, data_ibegin=data_ibegin, data_ni=data_ni, data_jbegin=data_jbegin, data_nj=data_nj ,   &
1034            &    zoom_ibegin=zoom_ibegin, zoom_jbegin=zoom_jbegin, zoom_ni=zoom_ni, zoom_nj=zoom_nj,                       &
1035            &    lonvalue=lonvalue, latvalue=latvalue,mask=mask )
1036      ENDIF
1037      CALL xios_solve_inheritance()
1038
1039   END SUBROUTINE iom_set_domain_attr
1040
1041
1042   SUBROUTINE iom_set_axis_attr( cdid, paxis )
1043      CHARACTER(LEN=*)      , INTENT(in) ::   cdid
1044      REAL(wp), DIMENSION(:), INTENT(in) ::   paxis
1045      IF ( xios_is_valid_axis     (cdid) )   CALL xios_set_axis_attr     ( cdid, size=size(paxis),value=paxis )
1046      IF ( xios_is_valid_axisgroup(cdid) )   CALL xios_set_axisgroup_attr( cdid, size=size(paxis),value=paxis )
1047      CALL xios_solve_inheritance()
1048   END SUBROUTINE iom_set_axis_attr
1049
1050
1051   SUBROUTINE iom_set_field_attr( cdid, freq_op, freq_offset )
1052      CHARACTER(LEN=*)          , INTENT(in) ::   cdid
1053      CHARACTER(LEN=*),OPTIONAL , INTENT(in) ::   freq_op
1054      CHARACTER(LEN=*),OPTIONAL , INTENT(in) ::   freq_offset
1055      IF ( xios_is_valid_field     (cdid) )   CALL xios_set_field_attr     ( cdid, freq_op=freq_op, freq_offset=freq_offset )
1056      IF ( xios_is_valid_fieldgroup(cdid) )   CALL xios_set_fieldgroup_attr( cdid, freq_op=freq_op, freq_offset=freq_offset )
1057      CALL xios_solve_inheritance()
1058   END SUBROUTINE iom_set_field_attr
1059
1060
1061   SUBROUTINE iom_set_file_attr( cdid, name, name_suffix )
1062      CHARACTER(LEN=*)          , INTENT(in) ::   cdid
1063      CHARACTER(LEN=*),OPTIONAL , INTENT(in) ::   name, name_suffix
1064      IF ( xios_is_valid_file     (cdid) )   CALL xios_set_file_attr     ( cdid, name=name, name_suffix=name_suffix )
1065      IF ( xios_is_valid_filegroup(cdid) )   CALL xios_set_filegroup_attr( cdid, name=name, name_suffix=name_suffix )
1066      CALL xios_solve_inheritance()
1067   END SUBROUTINE iom_set_file_attr
1068
1069
1070   SUBROUTINE iom_get_file_attr( cdid, name, name_suffix, output_freq )
1071      CHARACTER(LEN=*)          , INTENT(in ) ::   cdid
1072      CHARACTER(LEN=*),OPTIONAL , INTENT(out) ::   name, name_suffix, output_freq
1073      LOGICAL                                 ::   llexist1,llexist2,llexist3
1074      !---------------------------------------------------------------------
1075      IF( PRESENT( name        ) )   name = ''          ! default values
1076      IF( PRESENT( name_suffix ) )   name_suffix = ''
1077      IF( PRESENT( output_freq ) )   output_freq = ''
1078      IF ( xios_is_valid_file     (cdid) ) THEN
1079         CALL xios_solve_inheritance()
1080         CALL xios_is_defined_file_attr     ( cdid, name = llexist1, name_suffix = llexist2, output_freq = llexist3)
1081         IF(llexist1)   CALL xios_get_file_attr     ( cdid, name = name )
1082         IF(llexist2)   CALL xios_get_file_attr     ( cdid, name_suffix = name_suffix )
1083         IF(llexist3)   CALL xios_get_file_attr     ( cdid, output_freq = output_freq )
1084      ENDIF
1085      IF ( xios_is_valid_filegroup(cdid) ) THEN
1086         CALL xios_solve_inheritance()
1087         CALL xios_is_defined_filegroup_attr( cdid, name = llexist1, name_suffix = llexist2, output_freq = llexist3)
1088         IF(llexist1)   CALL xios_get_filegroup_attr( cdid, name = name )
1089         IF(llexist2)   CALL xios_get_filegroup_attr( cdid, name_suffix = name_suffix )
1090         IF(llexist3)   CALL xios_get_filegroup_attr( cdid, output_freq = output_freq )
1091      ENDIF
1092   END SUBROUTINE iom_get_file_attr
1093
1094
1095   SUBROUTINE iom_set_grid_attr( cdid, mask )
1096      CHARACTER(LEN=*)                   , INTENT(in) ::   cdid
1097      LOGICAL, DIMENSION(:,:,:), OPTIONAL, INTENT(in) ::   mask
1098      IF ( xios_is_valid_grid     (cdid) )   CALL xios_set_grid_attr     ( cdid, mask=mask )
1099      IF ( xios_is_valid_gridgroup(cdid) )   CALL xios_set_gridgroup_attr( cdid, mask=mask )
1100      CALL xios_solve_inheritance()
1101   END SUBROUTINE iom_set_grid_attr
1102
1103
1104   SUBROUTINE set_grid( cdgrd, plon, plat )
1105      !!----------------------------------------------------------------------
1106      !!                     ***  ROUTINE set_grid  ***
1107      !!
1108      !! ** Purpose :   define horizontal grids
1109      !!
1110      !!----------------------------------------------------------------------
1111      CHARACTER(LEN=1)            , INTENT(in) ::   cdgrd
1112      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   plon
1113      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   plat
1114      !
1115      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zmask
1116      INTEGER  :: ni,nj
1117     
1118      ni=nlei-nldi+1 ; nj=nlej-nldj+1
1119
1120      CALL iom_set_domain_attr("grid_"//cdgrd, ni_glo=jpiglo, nj_glo=jpjglo, ibegin=nimpp+nldi-1, jbegin=njmpp+nldj-1, ni=ni, nj=nj)
1121      CALL iom_set_domain_attr("grid_"//cdgrd, data_dim=2, data_ibegin = 1-nldi, data_ni = jpi, data_jbegin = 1-nldj, data_nj = jpj)
1122      CALL iom_set_domain_attr("grid_"//cdgrd, lonvalue = RESHAPE(plon(nldi:nlei, nldj:nlej),(/ ni*nj /)),   &
1123         &                                     latvalue = RESHAPE(plat(nldi:nlei, nldj:nlej),(/ ni*nj /))) 
1124
1125      IF ( ln_mskland ) THEN
1126         ! mask land points, keep values on coast line -> specific mask for U, V and W points
1127         SELECT CASE ( cdgrd )
1128         CASE('T')   ;   zmask(:,:,:)       = tmask(:,:,:)
1129         CASE('U')   ;   zmask(2:jpim1,:,:) = tmask(2:jpim1,:,:) + tmask(3:jpi,:,:)   ;   CALL lbc_lnk( zmask, 'U', 1. )
1130         CASE('V')   ;   zmask(:,2:jpjm1,:) = tmask(:,2:jpjm1,:) + tmask(:,3:jpi,:)   ;   CALL lbc_lnk( zmask, 'V', 1. )
1131         CASE('W')   ;   zmask(:,:,2:jpk  ) = tmask(:,:,1:jpkm1) + tmask(:,:,2:jpk)   ;   zmask(:,:,1) = tmask(:,:,1)
1132         END SELECT
1133         !
1134         CALL iom_set_domain_attr( "grid_"//cdgrd       , mask = RESHAPE(zmask(nldi:nlei,nldj:nlej,1),(/ni,nj    /)) /= 0. )
1135         CALL iom_set_grid_attr  ( "grid_"//cdgrd//"_3D", mask = RESHAPE(zmask(nldi:nlei,nldj:nlej,:),(/ni,nj,jpk/)) /= 0. )
1136      ENDIF
1137     
1138   END SUBROUTINE set_grid
1139
1140
1141   SUBROUTINE set_scalar
1142      !!----------------------------------------------------------------------
1143      !!                     ***  ROUTINE set_scalar  ***
1144      !!
1145      !! ** Purpose :   define fake grids for scalar point
1146      !!
1147      !!----------------------------------------------------------------------
1148      REAL(wp), DIMENSION(1,1) ::   zz = 1.
1149      !!----------------------------------------------------------------------
1150      CALL iom_set_domain_attr('scalarpoint', ni_glo=jpnij, nj_glo=1, ibegin=narea, jbegin=1, ni=1, nj=1)
1151      CALL iom_set_domain_attr('scalarpoint', data_dim=1)
1152      CALL iom_set_domain_attr('scalarpoint', lonvalue=(/ zz /), latvalue=(/ zz /))
1153
1154   END SUBROUTINE set_scalar
1155
1156
1157   SUBROUTINE set_xmlatt
1158      !!----------------------------------------------------------------------
1159      !!                     ***  ROUTINE set_xmlatt  ***
1160      !!
1161      !! ** Purpose :   automatic definitions of some of the xml attributs...
1162      !!
1163      !!----------------------------------------------------------------------
1164      CHARACTER(len=1),DIMENSION( 3) ::   clgrd                    ! suffix name
1165      CHARACTER(len=256)             ::   clsuff                   ! suffix name
1166      CHARACTER(len=1)               ::   cl1                      ! 1 character
1167      CHARACTER(len=2)               ::   cl2                      ! 1 character
1168      INTEGER                        ::   ji, jg                   ! loop counters
1169      INTEGER                        ::   ix, iy                   ! i-,j- index
1170      REAL(wp)        ,DIMENSION(11) ::   zlontao                  ! longitudes of tao    moorings
1171      REAL(wp)        ,DIMENSION( 7) ::   zlattao                  ! latitudes  of tao    moorings
1172      REAL(wp)        ,DIMENSION( 4) ::   zlonrama                 ! longitudes of rama   moorings
1173      REAL(wp)        ,DIMENSION(11) ::   zlatrama                 ! latitudes  of rama   moorings
1174      REAL(wp)        ,DIMENSION( 3) ::   zlonpira                 ! longitudes of pirata moorings
1175      REAL(wp)        ,DIMENSION( 9) ::   zlatpira                 ! latitudes  of pirata moorings
1176      !!----------------------------------------------------------------------
1177      !
1178      ! frequency of the call of iom_put (attribut: freq_op)
1179      WRITE(cl1,'(i1)')        1   ;   CALL iom_set_field_attr('field_definition', freq_op = cl1//'ts', freq_offset='0ts')
1180      WRITE(cl1,'(i1)')  nn_fsbc   ;   CALL iom_set_field_attr('SBC'             , freq_op = cl1//'ts', freq_offset='0ts')
1181      WRITE(cl1,'(i1)') nn_dttrc   ;   CALL iom_set_field_attr('ptrc_T'          , freq_op = cl1//'ts', freq_offset='0ts')
1182      WRITE(cl1,'(i1)') nn_dttrc   ;   CALL iom_set_field_attr('diad_T'          , freq_op = cl1//'ts', freq_offset='0ts')
1183       
1184      ! output file names (attribut: name)
1185      DO ji = 1, 9
1186         WRITE(cl1,'(i1)') ji 
1187         CALL iom_update_file_name('file'//cl1)
1188      END DO
1189      DO ji = 1, 99
1190         WRITE(cl2,'(i2.2)') ji 
1191         CALL iom_update_file_name('file'//cl2)
1192      END DO
1193
1194      ! Zooms...
1195      clgrd = (/ 'T', 'U', 'W' /) 
1196      DO jg = 1, SIZE(clgrd)                                                                   ! grid type
1197         cl1 = clgrd(jg)
1198         ! Equatorial section (attributs: jbegin, ni, name_suffix)
1199         CALL dom_ngb( 0., 0., ix, iy, cl1 )
1200         CALL iom_set_domain_attr ('Eq'//cl1, zoom_jbegin=iy, zoom_ni=jpiglo)
1201         CALL iom_get_file_attr   ('Eq'//cl1, name_suffix = clsuff             )
1202         CALL iom_set_file_attr   ('Eq'//cl1, name_suffix = TRIM(clsuff)//'_Eq')
1203         CALL iom_update_file_name('Eq'//cl1)
1204      END DO
1205      ! TAO moorings (attributs: ibegin, jbegin, name_suffix)
1206      zlontao = (/ 137.0, 147.0, 156.0, 165.0, -180.0, -170.0, -155.0, -140.0, -125.0, -110.0, -95.0 /)
1207      zlattao = (/  -8.0,  -5.0,  -2.0,   0.0,    2.0,    5.0,    8.0 /)
1208      CALL set_mooring( zlontao, zlattao )
1209      ! RAMA moorings (attributs: ibegin, jbegin, name_suffix)
1210      zlonrama = (/  55.0,  67.0, 80.5, 90.0 /)
1211      zlatrama = (/ -16.0, -12.0, -8.0, -4.0, -1.5, 0.0, 1.5, 4.0, 8.0, 12.0, 15.0 /)
1212      CALL set_mooring( zlonrama, zlatrama )
1213      ! PIRATA moorings (attributs: ibegin, jbegin, name_suffix)
1214      zlonpira = (/ -38.0, -23.0, -10.0 /)
1215      zlatpira = (/ -19.0, -14.0,  -8.0, 0.0, 4.0, 8.0, 12.0, 15.0, 20.0 /)
1216      CALL set_mooring( zlonpira, zlatpira )
1217     
1218   END SUBROUTINE set_xmlatt
1219
1220
1221   SUBROUTINE set_mooring( plon, plat)
1222      !!----------------------------------------------------------------------
1223      !!                     ***  ROUTINE set_mooring  ***
1224      !!
1225      !! ** Purpose :   automatic definitions of moorings xml attributs...
1226      !!
1227      !!----------------------------------------------------------------------
1228      REAL(wp), DIMENSION(:), INTENT(in) ::  plon, plat           ! longitudes/latitudes oft the mooring
1229      !
1230!!$      CHARACTER(len=1),DIMENSION(4) ::   clgrd = (/ 'T', 'U', 'V', 'W' /)   ! suffix name
1231      CHARACTER(len=1),DIMENSION(1) ::   clgrd = (/ 'T' /)        ! suffix name
1232      CHARACTER(len=256)            ::   clname                   ! file name
1233      CHARACTER(len=256)            ::   clsuff                   ! suffix name
1234      CHARACTER(len=1)              ::   cl1                      ! 1 character
1235      CHARACTER(len=6)              ::   clon,clat                ! name of longitude, latitude
1236      INTEGER                       ::   ji, jj, jg               ! loop counters
1237      INTEGER                       ::   ix, iy                   ! i-,j- index
1238      REAL(wp)                      ::   zlon, zlat
1239      !!----------------------------------------------------------------------
1240      DO jg = 1, SIZE(clgrd)
1241         cl1 = clgrd(jg)
1242         DO ji = 1, SIZE(plon)
1243            DO jj = 1, SIZE(plat)
1244               zlon = plon(ji)
1245               zlat = plat(jj)
1246               ! modifications for RAMA moorings
1247               IF( zlon ==  67. .AND. zlat ==  15. )   zlon =  65.
1248               IF( zlon ==  90. .AND. zlat <=  -4. )   zlon =  95.
1249               IF( zlon ==  95. .AND. zlat ==  -4. )   zlat =  -5.
1250               ! modifications for PIRATA moorings
1251               IF( zlon == -38. .AND. zlat == -19. )   zlon = -34.
1252               IF( zlon == -38. .AND. zlat == -14. )   zlon = -32.
1253               IF( zlon == -38. .AND. zlat ==  -8. )   zlon = -30.
1254               IF( zlon == -38. .AND. zlat ==   0. )   zlon = -35.
1255               IF( zlon == -23. .AND. zlat ==  20. )   zlat =  21.
1256               IF( zlon == -10. .AND. zlat == -14. )   zlat = -10.
1257               IF( zlon == -10. .AND. zlat ==  -8. )   zlat =  -6.
1258               IF( zlon == -10. .AND. zlat ==   4. ) THEN   ;   zlon = 0.   ;   zlat = 0.   ;   ENDIF
1259               CALL dom_ngb( zlon, zlat, ix, iy, cl1 )
1260               IF( zlon >= 0. ) THEN 
1261                  IF( zlon == REAL(NINT(zlon), wp) ) THEN   ;   WRITE(clon, '(i3,  a)') NINT( zlon), 'e'
1262                  ELSE                                      ;   WRITE(clon, '(f5.1,a)')       zlon , 'e'
1263                  ENDIF
1264               ELSE             
1265                  IF( zlon == REAL(NINT(zlon), wp) ) THEN   ;   WRITE(clon, '(i3,  a)') NINT(-zlon), 'w'
1266                  ELSE                                      ;   WRITE(clon, '(f5.1,a)')      -zlon , 'w'
1267                  ENDIF
1268               ENDIF
1269               IF( zlat >= 0. ) THEN 
1270                  IF( zlat == REAL(NINT(zlat), wp) ) THEN   ;   WRITE(clat, '(i2,  a)') NINT( zlat), 'n'
1271                  ELSE                                      ;   WRITE(clat, '(f4.1,a)')       zlat , 'n'
1272                  ENDIF
1273               ELSE             
1274                  IF( zlat == REAL(NINT(zlat), wp) ) THEN   ;   WRITE(clat, '(i2,  a)') NINT(-zlat), 's'
1275                  ELSE                                      ;   WRITE(clat, '(f4.1,a)')      -zlat , 's'
1276                  ENDIF
1277               ENDIF
1278               clname = TRIM(ADJUSTL(clat))//TRIM(ADJUSTL(clon))
1279               CALL iom_set_domain_attr (TRIM(clname)//cl1, zoom_ibegin= ix, zoom_jbegin= iy)
1280               CALL iom_get_file_attr   (TRIM(clname)//cl1, name_suffix = clsuff                         )
1281               CALL iom_set_file_attr   (TRIM(clname)//cl1, name_suffix = TRIM(clsuff)//'_'//TRIM(clname))
1282               CALL iom_update_file_name(TRIM(clname)//cl1)
1283            END DO
1284         END DO
1285      END DO
1286     
1287   END SUBROUTINE set_mooring
1288
1289   
1290   SUBROUTINE iom_update_file_name( cdid )
1291      !!----------------------------------------------------------------------
1292      !!                     ***  ROUTINE iom_update_file_name  ***
1293      !!
1294      !! ** Purpose :   
1295      !!
1296      !!----------------------------------------------------------------------
1297      CHARACTER(LEN=*)          , INTENT(in) ::   cdid
1298      !
1299      CHARACTER(LEN=256) ::   clname
1300      CHARACTER(LEN=20)  ::   clfreq
1301      CHARACTER(LEN=20)  ::   cldate
1302      INTEGER            ::   idx
1303      INTEGER            ::   jn
1304      INTEGER            ::   itrlen
1305      INTEGER            ::   iyear, imonth, iday, isec
1306      REAL(wp)           ::   zsec
1307      LOGICAL            ::   llexist
1308      !!----------------------------------------------------------------------
1309
1310      DO jn = 1,2
1311
1312         IF( jn == 1 )   CALL iom_get_file_attr( cdid, name        = clname, output_freq = clfreq )
1313         IF( jn == 2 )   CALL iom_get_file_attr( cdid, name_suffix = clname )
1314
1315         IF ( TRIM(clname) /= '' ) THEN
1316
1317            idx = INDEX(clname,'@expname@') + INDEX(clname,'@EXPNAME@')
1318            DO WHILE ( idx /= 0 ) 
1319               clname = clname(1:idx-1)//TRIM(cexper)//clname(idx+9:LEN_TRIM(clname))
1320               idx = INDEX(clname,'@expname@') + INDEX(clname,'@EXPNAME@')
1321            END DO
1322
1323            idx = INDEX(clname,'@freq@') + INDEX(clname,'@FREQ@')
1324            DO WHILE ( idx /= 0 ) 
1325               IF ( TRIM(clfreq) /= '' ) THEN
1326                  itrlen = LEN_TRIM(clfreq)
1327                  IF ( clfreq(itrlen-1:itrlen) == 'mo' ) clfreq = clfreq(1:itrlen-1)
1328                  clname = clname(1:idx-1)//TRIM(clfreq)//clname(idx+6:LEN_TRIM(clname))
1329               ELSE
1330                  CALL ctl_stop('error in the name of file id '//TRIM(cdid),   &
1331                     & ' attribute output_freq is undefined -> cannot replace @freq@ in '//TRIM(clname) )
1332               ENDIF
1333               idx = INDEX(clname,'@freq@') + INDEX(clname,'@FREQ@')
1334            END DO
1335
1336            idx = INDEX(clname,'@startdate@') + INDEX(clname,'@STARTDATE@')
1337            DO WHILE ( idx /= 0 ) 
1338               cldate = iom_sdate( fjulday - rdttra(1) / rday )
1339               clname = clname(1:idx-1)//TRIM(cldate)//clname(idx+11:LEN_TRIM(clname))
1340               idx = INDEX(clname,'@startdate@') + INDEX(clname,'@STARTDATE@')
1341            END DO
1342
1343            idx = INDEX(clname,'@startdatefull@') + INDEX(clname,'@STARTDATEFULL@')
1344            DO WHILE ( idx /= 0 ) 
1345               cldate = iom_sdate( fjulday - rdttra(1) / rday, ldfull = .TRUE. )
1346               clname = clname(1:idx-1)//TRIM(cldate)//clname(idx+15:LEN_TRIM(clname))
1347               idx = INDEX(clname,'@startdatefull@') + INDEX(clname,'@STARTDATEFULL@')
1348            END DO
1349
1350            idx = INDEX(clname,'@enddate@') + INDEX(clname,'@ENDDATE@')
1351            DO WHILE ( idx /= 0 ) 
1352               cldate = iom_sdate( fjulday + rdttra(1) / rday * REAL( nitend - nit000, wp ), ld24 = .TRUE. )
1353               clname = clname(1:idx-1)//TRIM(cldate)//clname(idx+9:LEN_TRIM(clname))
1354               idx = INDEX(clname,'@enddate@') + INDEX(clname,'@ENDDATE@')
1355            END DO
1356
1357            idx = INDEX(clname,'@enddatefull@') + INDEX(clname,'@ENDDATEFULL@')
1358            DO WHILE ( idx /= 0 ) 
1359               cldate = iom_sdate( fjulday + rdttra(1) / rday * REAL( nitend - nit000, wp ), ld24 = .TRUE., ldfull = .TRUE. )
1360               clname = clname(1:idx-1)//TRIM(cldate)//clname(idx+13:LEN_TRIM(clname))
1361               idx = INDEX(clname,'@enddatefull@') + INDEX(clname,'@ENDDATEFULL@')
1362            END DO
1363
1364            IF( jn == 1 )   CALL iom_set_file_attr( cdid, name        = clname )
1365            IF( jn == 2 )   CALL iom_set_file_attr( cdid, name_suffix = clname )
1366
1367         ENDIF
1368
1369      END DO
1370
1371   END SUBROUTINE iom_update_file_name
1372
1373
1374   FUNCTION iom_sdate( pjday, ld24, ldfull )
1375      !!----------------------------------------------------------------------
1376      !!                     ***  ROUTINE iom_sdate  ***
1377      !!
1378      !! ** Purpose :   send back the date corresponding to the given julian day
1379      !!
1380      !!----------------------------------------------------------------------
1381      REAL(wp), INTENT(in   )           ::   pjday         ! julian day
1382      LOGICAL , INTENT(in   ), OPTIONAL ::   ld24          ! true to force 24:00 instead of 00:00
1383      LOGICAL , INTENT(in   ), OPTIONAL ::   ldfull        ! true to get the compleate date: yyyymmdd_hh:mm:ss
1384      !
1385      CHARACTER(LEN=20) ::   iom_sdate
1386      CHARACTER(LEN=50) ::   clfmt                         !  format used to write the date
1387      INTEGER           ::   iyear, imonth, iday, ihour, iminute, isec
1388      REAL(wp)          ::   zsec
1389      LOGICAL           ::   ll24, llfull
1390      !
1391      IF( PRESENT(ld24) ) THEN   ;   ll24 = ld24
1392      ELSE                       ;   ll24 = .FALSE.
1393      ENDIF
1394
1395      IF( PRESENT(ldfull) ) THEN   ;   llfull = ldfull
1396      ELSE                         ;   llfull = .FALSE.
1397      ENDIF
1398
1399      CALL ju2ymds( pjday, iyear, imonth, iday, zsec )
1400      isec = NINT(zsec)
1401
1402      IF ( ll24 .AND. isec == 0 ) THEN   ! 00:00 of the next day -> move to 24:00 of the current day
1403         CALL ju2ymds( pjday - 1., iyear, imonth, iday, zsec )
1404         isec = 86400
1405      ENDIF
1406
1407      IF( iyear < 10000 ) THEN   ;   clfmt = "i4.4,2i2.2"                ! format used to write the date
1408      ELSE                       ;   WRITE(clfmt, "('i',i1,',2i2.2')") INT(LOG10(REAL(iyear,wp))) + 1
1409      ENDIF
1410     
1411      IF( llfull ) THEN
1412         clfmt = TRIM(clfmt)//",'_',i2.2,':',i2.2,':',i2.2"
1413         ihour   = isec / 3600
1414         isec    = MOD(isec, 3600)
1415         iminute = isec / 60
1416         isec    = MOD(isec, 60)
1417         WRITE(iom_sdate, '('//TRIM(clfmt)//')') iyear, imonth, iday, ihour, iminute, isec    ! date of the end of run
1418      ELSE
1419         WRITE(iom_sdate, '('//TRIM(clfmt)//')') iyear, imonth, iday                          ! date of the end of run
1420      ENDIF
1421
1422   END FUNCTION iom_sdate
1423
1424#else
1425
1426   SUBROUTINE iom_setkt( kt )
1427      INTEGER, INTENT(in   )::   kt 
1428      IF( .FALSE. )   WRITE(numout,*) kt   ! useless test to avoid compilation warnings
1429   END SUBROUTINE iom_setkt
1430
1431#endif
1432   
1433   !!======================================================================
1434END MODULE iom
Note: See TracBrowser for help on using the repository browser.