source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 10 years ago

Merge of 3.4beta into the trunk

  • Property svn:keywords set to Id
File size: 13.7 KB
Line 
1MODULE traadv_muscl
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   tra_adv_muscl : update the tracer trend with the horizontal
14   !!                   and vertical advection trends using MUSCL scheme
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE trdmod_oce      ! tracers trends
19   USE trdtra      ! tracers trends
20   USE in_out_manager  ! I/O manager
21   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
22   USE trabbl          ! tracers: bottom boundary layer
23   USE lib_mpp         ! distribued memory computing
24   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
25   USE diaptr          ! poleward transport diagnostics
26   USE trc_oce         ! share passive tracers/Ocean variables
27   USE wrk_nemo        ! Memory Allocation
28   USE timing          ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_muscl  ! routine called by step.F90
34
35   LOGICAL  :: l_trd       ! flag to compute trends
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_adv_muscl( kt, kit000, cdtype, p2dt, pun, pvn, pwn, &
48      &                                        ptb, pta, kjpt )
49      !!----------------------------------------------------------------------
50      !!                    ***  ROUTINE tra_adv_muscl  ***
51      !!
52      !! ** Purpose :   Compute the now trend due to total advection of T and
53      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
54      !!      Conservation Laws) and add it to the general tracer trend.
55      !!
56      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
57      !!
58      !! ** Action  : - update (ta,sa) with the now advective tracer trends
59      !!              - save trends
60      !!
61      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
62      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
63      !!----------------------------------------------------------------------
64      USE oce     , ONLY:   zwx   => ua    , zwy   => va          ! (ua,va) used as workspace
65      !
66      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
67      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
70      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
71      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
73      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
74      !
75      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
76      REAL(wp) ::   zu, z0u, zzwx, zw         ! local scalars
77      REAL(wp) ::   zv, z0v, zzwy, z0w        !   -      -
78      REAL(wp) ::   ztra, zbtr, zdt, zalpha   !   -      -
79      REAL(wp), POINTER, DIMENSION(:,:,:) :: zslpx, zslpy
80      !!----------------------------------------------------------------------
81      !
82      IF( nn_timing == 1 )  CALL timing_start('tra_adv_muscl')
83      !
84      CALL wrk_alloc( jpi, jpj, jpk, zslpx, zslpy )
85      !
86
87      IF( kt == kit000 )  THEN
88         IF(lwp) WRITE(numout,*)
89         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
90         IF(lwp) WRITE(numout,*) '~~~~~~~'
91         !
92         l_trd = .FALSE.
93         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
94      ENDIF
95
96      !                                                     ! ===========
97      DO jn = 1, kjpt                                       ! tracer loop
98         !                                                  ! ===========
99         ! I. Horizontal advective fluxes
100         ! ------------------------------
101         ! first guess of the slopes
102         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
103         ! interior values
104         DO jk = 1, jpkm1
105            DO jj = 1, jpjm1     
106               DO ji = 1, fs_jpim1   ! vector opt.
107                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
108                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
109               END DO
110           END DO
111         END DO
112         !
113         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
114         CALL lbc_lnk( zwy, 'V', -1. )
115         !                                             !-- Slopes of tracer
116         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
117         DO jk = 1, jpkm1                                     ! interior values
118            DO jj = 2, jpj
119               DO ji = fs_2, jpi   ! vector opt.
120                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
121                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
122                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
123                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
124               END DO
125            END DO
126         END DO
127         !
128         DO jk = 1, jpkm1                                     ! Slopes limitation
129            DO jj = 2, jpj
130               DO ji = fs_2, jpi   ! vector opt.
131                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
132                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
133                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
134                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
135                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
136                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
137               END DO
138           END DO
139         END DO             ! interior values
140
141         !                                             !-- MUSCL horizontal advective fluxes
142         DO jk = 1, jpkm1                                     ! interior values
143            zdt  = p2dt(jk)
144            DO jj = 2, jpjm1
145               DO ji = fs_2, fs_jpim1   ! vector opt.
146                  ! MUSCL fluxes
147                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
148                  zalpha = 0.5 - z0u
149                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
150                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
151                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
152                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
153                  !
154                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
155                  zalpha = 0.5 - z0v
156                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
157                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
158                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk) 
159                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
160               END DO
161            END DO
162         END DO
163         !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
164         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
165         !
166         ! Tracer flux divergence at t-point added to the general trend
167         DO jk = 1, jpkm1
168            DO jj = 2, jpjm1     
169               DO ji = fs_2, fs_jpim1   ! vector opt.
170                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
171                  ! horizontal advective trends
172                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
173                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
174                  ! add it to the general tracer trends
175                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
176               END DO
177           END DO
178         END DO       
179         !                                 ! trend diagnostics (contribution of upstream fluxes)
180         IF( l_trd )  THEN
181            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) )
182            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
183         END IF
184         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
185         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
186            IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
187            IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
188         ENDIF
189
190         ! II. Vertical advective fluxes
191         ! -----------------------------
192         !                                             !-- first guess of the slopes
193         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
194         DO jk = 2, jpkm1                                     ! interior values
195            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
196         END DO
197
198         !                                             !-- Slopes of tracer
199         zslpx(:,:,1) = 0.e0                                  ! surface values
200         DO jk = 2, jpkm1                                     ! interior value
201            DO jj = 1, jpj
202               DO ji = 1, jpi
203                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
204                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
205               END DO
206            END DO
207         END DO
208         !                                             !-- Slopes limitation
209         DO jk = 2, jpkm1                                     ! interior values
210            DO jj = 1, jpj
211               DO ji = 1, jpi
212                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
213                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
214                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
215               END DO
216            END DO
217         END DO
218         !                                             !-- vertical advective flux
219         !                                                    ! surface values  (bottom already set to zero)
220         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
221         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
222         ENDIF 
223         !
224         DO jk = 1, jpkm1                                     ! interior values
225            zdt  = p2dt(jk)
226            DO jj = 2, jpjm1     
227               DO ji = fs_2, fs_jpim1   ! vector opt.
228                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
229                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
230                  zalpha = 0.5 + z0w
231                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr 
232                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
233                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
234                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
235               END DO
236            END DO
237         END DO
238
239         ! Compute & add the vertical advective trend
240         DO jk = 1, jpkm1
241            DO jj = 2, jpjm1     
242               DO ji = fs_2, fs_jpim1   ! vector opt.
243                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
244                  ! vertical advective trends
245                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
246                  ! add it to the general tracer trends
247                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
248               END DO
249            END DO
250         END DO
251         !                                 ! Save the vertical advective trends for diagnostic
252         IF( l_trd ) CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
253         !
254      ENDDO
255      !
256      CALL wrk_dealloc( jpi, jpj, jpk, zslpx, zslpy )
257      !
258      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_muscl')
259      !
260   END SUBROUTINE tra_adv_muscl
261
262   !!======================================================================
263END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.