source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/trasbc.F90 @ 5431

Last change on this file since 5431 was 5431, checked in by smasson, 6 years ago

trunk bugfix see #1538

  • Property svn:keywords set to Id
File size: 16.5 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_sbc      : update the tracer trend at ocean surface
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and active tracers
18   USE sbc_oce         ! surface boundary condition: ocean
19   USE dom_oce         ! ocean space domain variables
20   USE phycst          ! physical constant
21   USE sbcmod          ! ln_rnf 
22   USE sbcrnf          ! River runoff 
23   USE sbcisf          ! Ice shelf   
24   USE traqsr          ! solar radiation penetration
25   USE trd_oce         ! trends: ocean variables
26   USE trdtra          ! trends manager: tracers
27   !
28   USE in_out_manager  ! I/O manager
29   USE prtctl          ! Print control
30   USE iom
31   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
32   USE wrk_nemo        ! Memory Allocation
33   USE timing          ! Timing
34   USE eosbn2
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_sbc    ! routine called by step.F90
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_sbc ( kt )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_sbc  ***
54      !!                   
55      !! ** Purpose :   Compute the tracer surface boundary condition trend of
56      !!      (flux through the interface, concentration/dilution effect)
57      !!      and add it to the general trend of tracer equations.
58      !!
59      !! ** Method :
60      !!      Following Roullet and Madec (2000), the air-sea flux can be divided
61      !!      into three effects: (1) Fext, external forcing;
62      !!      (2) Fwi, concentration/dilution effect due to water exchanged
63      !!         at the surface by evaporation, precipitations and runoff (E-P-R);
64      !!      (3) Fwe, tracer carried with the water that is exchanged.
65      !!            - salinity    : salt flux only due to freezing/melting
66      !!            sa = sa +  sfx / rau0 / e3t  for k=1
67      !!
68      !!      Fext, flux through the air-sea interface for temperature and salt:
69      !!            - temperature : heat flux q (w/m2). If penetrative solar
70      !!         radiation q is only the non solar part of the heat flux, the
71      !!         solar part is added in traqsr.F routine.
72      !!            ta = ta + q /(rau0 rcp e3t)  for k=1
73      !!            - salinity    : no salt flux
74      !!
75      !!      The formulation for Fwb and Fwi vary according to the free
76      !!      surface formulation (linear or variable volume).
77      !!      * Linear free surface
78      !!            The surface freshwater flux modifies the ocean volume
79      !!         and thus the concentration of a tracer and the temperature.
80      !!         First order of the effect of surface freshwater exchange
81      !!         for salinity, it can be neglected on temperature (especially
82      !!         as the temperature of precipitations and runoffs is usually
83      !!         unknown).
84      !!            - temperature : we assume that the temperature of both
85      !!         precipitations and runoffs is equal to the SST, thus there
86      !!         is no additional flux since in this case, the concentration
87      !!         dilution effect is balanced by the net heat flux associated
88      !!         to the freshwater exchange (Fwe+Fwi=0):
89      !!            (Tp P - Te E) + SST (P-E) = 0 when Tp=Te=SST
90      !!            - salinity    : evaporation, precipitation and runoff
91      !!         water has a zero salinity  but there is a salt flux due to
92      !!         freezing/melting, thus:
93      !!            sa = sa + emp * sn / rau0 / e3t   for k=1
94      !!                    + sfx    / rau0 / e3t
95      !!         where emp, the surface freshwater budget (evaporation minus
96      !!         precipitation minus runoff) given in kg/m2/s is divided
97      !!         by rau0 (density of sea water) to obtain m/s.   
98      !!         Note: even though Fwe does not appear explicitly for
99      !!         temperature in this routine, the heat carried by the water
100      !!         exchanged through the surface is part of the total heat flux
101      !!         forcing and must be taken into account in the global heat
102      !!         balance).
103      !!      * nonlinear free surface (variable volume, lk_vvl)
104      !!         contrary to the linear free surface case, Fwi is properly
105      !!         taken into account by using the true layer thicknesses to       
106      !!         calculate tracer content and advection. There is no need to
107      !!         deal with it in this routine.
108      !!           - temperature: Fwe=SST (P-E+R) is added to Fext.
109      !!           - salinity:  Fwe = 0, there is no surface flux of salt.
110      !!
111      !! ** Action  : - Update the 1st level of (ta,sa) with the trend associated
112      !!                with the tracer surface boundary condition
113      !!              - send trends to trdtra module (l_trdtra=T)
114      !!----------------------------------------------------------------------
115      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
116      !!
117      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
118      INTEGER  ::   ikt, ikb 
119      INTEGER  ::   nk_isf
120      REAL(wp) ::   zfact, z1_e3t, zdep
121      REAL(wp) ::   zalpha, zhk
122      REAL(wp) ::  zt_frz, zpress
123      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdt, ztrds
124      !!----------------------------------------------------------------------
125      !
126      IF( nn_timing == 1 )  CALL timing_start('tra_sbc')
127      !
128      IF( kt == nit000 ) THEN
129         IF(lwp) WRITE(numout,*)
130         IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
131         IF(lwp) WRITE(numout,*) '~~~~~~~ '
132      ENDIF
133
134      IF( l_trdtra ) THEN                    !* Save ta and sa trends
135         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds ) 
136         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
137         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
138      ENDIF
139
140!!gm      IF( .NOT.ln_traqsr )   qsr(:,:) = 0.e0   ! no solar radiation penetration
141      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
142         qns(:,:) = qns(:,:) + qsr(:,:)      ! total heat flux in qns
143         qsr(:,:) = 0.e0                     ! qsr set to zero
144      ENDIF
145
146      !----------------------------------------
147      !        EMP, SFX and QNS effects
148      !----------------------------------------
149      !                                          Set before sbc tracer content fields
150      !                                          ************************************
151      IF( kt == nit000 ) THEN                      ! Set the forcing field at nit000 - 1
152         !                                         ! -----------------------------------
153         IF( ln_rstart .AND.    &                     ! Restart: read in restart file
154              & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN
155            IF(lwp) WRITE(numout,*) '          nit000-1 surface tracer content forcing fields red in the restart file'
156            zfact = 0.5_wp
157            CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
158            CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
159         ELSE                                         ! No restart or restart not found: Euler forward time stepping
160            zfact = 1._wp
161            sbc_tsc_b(:,:,:) = 0._wp
162         ENDIF
163      ELSE                                         ! Swap of forcing fields
164         !                                         ! ----------------------
165         zfact = 0.5_wp
166         sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:)
167      ENDIF
168      !                                          Compute now sbc tracer content fields
169      !                                          *************************************
170
171                                                   ! Concentration dilution effect on (t,s) due to 
172                                                   ! evaporation, precipitation and qns, but not river runoff
173                                               
174      IF( lk_vvl ) THEN                            ! Variable Volume case  ==>> heat content of mass flux is in qns
175         DO jj = 1, jpj
176            DO ji = 1, jpi 
177               sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)                              ! non solar heat flux
178               sbc_tsc(ji,jj,jp_sal) = r1_rau0     * sfx(ji,jj)                              ! salt flux due to freezing/melting
179            END DO
180         END DO
181      ELSE                                         ! Constant Volume case ==>> Concentration dilution effect
182         DO jj = 2, jpj
183            DO ji = fs_2, fs_jpim1   ! vector opt.
184               ! temperature : heat flux
185               sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)                          &   ! non solar heat flux
186                  &                  + r1_rau0     * emp(ji,jj)  * tsn(ji,jj,1,jp_tem)       ! concent./dilut. effect
187               ! salinity    : salt flux + concent./dilut. effect (both in sfx)
188               sbc_tsc(ji,jj,jp_sal) = r1_rau0  * (  sfx(ji,jj)                          &   ! salt flux (freezing/melting)
189                  &                                + emp(ji,jj) * tsn(ji,jj,1,jp_sal) )      ! concent./dilut. effect
190            END DO
191         END DO
192         IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) )   ! c/d term on sst
193         IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) )   ! c/d term on sss
194      ENDIF
195      ! Concentration dilution effect on (t,s) due to evapouration, precipitation and qns, but not river runoff 
196      DO jn = 1, jpts
197         DO jj = 2, jpj
198            DO ji = fs_2, fs_jpim1   ! vector opt.
199               z1_e3t = zfact / fse3t(ji,jj,1)
200               tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) * z1_e3t
201            END DO
202         END DO
203      END DO
204      !                                          Write in the ocean restart file
205      !                                          *******************************
206      IF( lrst_oce ) THEN
207         IF(lwp) WRITE(numout,*)
208         IF(lwp) WRITE(numout,*) 'sbc : ocean surface tracer content forcing fields written in ocean restart file ',   &
209            &                    'at it= ', kt,' date= ', ndastp
210         IF(lwp) WRITE(numout,*) '~~~~'
211         CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
212         CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
213      ENDIF
214      !
215      !
216      !----------------------------------------
217      !       Ice Shelf effects (ISF)
218      !     tbl treated as in Losh (2008) JGR
219      !----------------------------------------
220      !
221      IF( nn_isf > 0 ) THEN
222         zfact = 0.5e0
223         DO jj = 2, jpj
224            DO ji = fs_2, fs_jpim1
225         
226               ikt = misfkt(ji,jj)
227               ikb = misfkb(ji,jj)
228   
229               ! level fully include in the ice shelf boundary layer
230               ! if isfdiv, we have to remove heat flux due to inflow at 0oC (as in rnf when you add rnf at sst)
231               ! sign - because fwf sign of evapo (rnf sign of precip)
232               DO jk = ikt, ikb - 1
233               ! compute tfreez for the temperature correction (we add water at freezing temperature)
234!                  zpress = grav*rau0*fsdept(ji,jj,jk)*1.e-04
235                  zt_frz = -1.9 !eos_fzp( tsn(ji,jj,jk,jp_sal), zpress )
236               ! compute trend
237                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                          &
238                     &           + zfact * (risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem)          &
239                     &               - rdivisf * (fwfisf(ji,jj) + fwfisf_b(ji,jj)) * zt_frz * r1_rau0) &
240                     &           * r1_hisf_tbl(ji,jj)
241                  tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)                                          &
242                     &           + zfact * (risf_tsc_b(ji,jj,jp_sal) + risf_tsc(ji,jj,jp_sal)) * r1_hisf_tbl(ji,jj)
243               END DO
244   
245               ! level partially include in ice shelf boundary layer
246               ! compute tfreez for the temperature correction (we add water at freezing temperature)
247!               zpress = grav*rau0*fsdept(ji,jj,ikb)*1.e-04
248               zt_frz = -1.9 !eos_fzp( tsn(ji,jj,ikb,jp_sal), zpress )
249               ! compute trend
250               tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem)                                           &
251                  &              + zfact * (risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem)          &
252                  &                  - rdivisf * (fwfisf(ji,jj) + fwfisf_b(ji,jj)) * zt_frz * r1_rau0) & 
253                  &              * r1_hisf_tbl(ji,jj) * ralpha(ji,jj)
254               tsa(ji,jj,ikb,jp_sal) = tsa(ji,jj,ikb,jp_sal)                                           &
255                  &              + zfact * (risf_tsc_b(ji,jj,jp_sal) + risf_tsc(ji,jj,jp_sal)) * r1_hisf_tbl(ji,jj) * ralpha(ji,jj) 
256            END DO
257         END DO
258         IF( lrst_oce ) THEN
259            IF(lwp) WRITE(numout,*)
260            IF(lwp) WRITE(numout,*) 'sbc : isf surface tracer content forcing fields written in ocean restart file ',   &
261               &                    'at it= ', kt,' date= ', ndastp
262            IF(lwp) WRITE(numout,*) '~~~~'
263            CALL iom_rstput( kt, nitrst, numrow, 'fwf_isf_b', fwfisf(:,:)          )
264            CALL iom_rstput( kt, nitrst, numrow, 'isf_hc_b' , risf_tsc(:,:,jp_tem) )
265            CALL iom_rstput( kt, nitrst, numrow, 'isf_sc_b' , risf_tsc(:,:,jp_sal) )
266         ENDIF
267      END IF
268      !
269      !----------------------------------------
270      !        River Runoff effects
271      !----------------------------------------
272      !
273      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
274         zfact = 0.5_wp
275         DO jj = 2, jpj 
276            DO ji = fs_2, fs_jpim1
277               IF( rnf(ji,jj) /= 0._wp ) THEN
278                  zdep = zfact / h_rnf(ji,jj)
279                  DO jk = 1, nk_rnf(ji,jj)
280                                        tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)   &
281                                          &               +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
282                     IF( ln_rnf_sal )   tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)   &
283                                          &               +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep 
284                  END DO
285               ENDIF
286            END DO 
287         END DO 
288      ENDIF
289 
290      IF( l_trdtra )   THEN                      ! send trends for further diagnostics
291         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
292         ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:)
293         CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt )
294         CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds )
295         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds ) 
296      ENDIF
297      !
298      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
299         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
300      !
301      IF( nn_timing == 1 )  CALL timing_stop('tra_sbc')
302      !
303   END SUBROUTINE tra_sbc
304
305   !!======================================================================
306END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.