source: trunk/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfmxl.F90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 10 years ago

First attempt to put dynamic allocation on the trunk

  • Property svn:keywords set to Id
File size: 5.8 KB
Line 
1MODULE zdfmxl
2   !!======================================================================
3   !!                       ***  MODULE  zdfmxl  ***
4   !! Ocean physics: mixed layer depth
5   !!======================================================================
6   !! History :  1.0  ! 2003-08  (G. Madec)  original code
7   !!            3.2  ! 2009-07  (S. Masson, G. Madec)  IOM + merge of DO-loop
8   !!----------------------------------------------------------------------
9   !!   zdf_mxl      : Compute the turbocline and mixed layer depths.
10   !!----------------------------------------------------------------------
11   USE oce             ! ocean dynamics and tracers variables
12   USE dom_oce         ! ocean space and time domain variables
13   USE zdf_oce         ! ocean vertical physics
14   USE in_out_manager  ! I/O manager
15   USE prtctl          ! Print control
16   USE iom             ! I/O library
17   USE lib_mpp         ! MPP library
18
19   IMPLICIT NONE
20   PRIVATE
21
22   PUBLIC   zdf_mxl       ! called by step.F90
23
24   INTEGER , PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   nmln    !: number of level in the mixed layer (used by TOP)
25   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmld    !: mixing layer depth (turbocline)      [m]
26   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlp    !: mixed layer depth  (rho=rho0+zdcrit) [m]
27   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlpt   !: mixed layer depth at t-points        [m]
28
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
33   !! $Id$
34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   INTEGER FUNCTION zdf_mxl_alloc()
39      !!----------------------------------------------------------------------
40      !!               ***  FUNCTION zdf_mxl_alloc  ***
41      !!----------------------------------------------------------------------
42      ALLOCATE( nmln(jpi,jpj), hmld(jpi,jpj), hmlp(jpi,jpj), hmlpt(jpi,jpj), STAT= zdf_mxl_alloc )
43      !
44      IF( lk_mpp             )   CALL mpp_sum ( zdf_mxl_alloc )
45      IF( zdf_mxl_alloc /= 0 )   CALL ctl_warn('zdf_mxl_alloc: failed to allocate arrays.')
46   END FUNCTION zdf_mxl_alloc
47
48
49   SUBROUTINE zdf_mxl( kt )
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE zdfmxl  ***
52      !!                   
53      !! ** Purpose :   Compute the turbocline depth and the mixed layer depth
54      !!              with density criteria.
55      !!
56      !! ** Method  :   The mixed layer depth is the shallowest W depth with
57      !!      the density of the corresponding T point (just bellow) bellow a
58      !!      given value defined locally as rho(10m) + zrho_c
59      !!               The turbocline depth is the depth at which the vertical
60      !!      eddy diffusivity coefficient (resulting from the vertical physics
61      !!      alone, not the isopycnal part, see trazdf.F) fall below a given
62      !!      value defined locally (avt_c here taken equal to 5 cm/s2)
63      !!
64      !! ** Action  :   nmln, hmld, hmlp, hmlpt
65      !!----------------------------------------------------------------------
66      USE wrk_nemo, ONLY:   iwrk_in_use, iwrk_not_released
67      USE wrk_nemo, ONLY:   imld => iwrk_2d_1    ! 2D integer workspace
68      !!
69      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
70      !!
71      INTEGER  ::   ji, jj, jk          ! dummy loop indices
72      INTEGER  ::   iikn, iiki          ! temporary integer within a do loop
73      REAL(wp) ::   zrho_c = 0.01_wp    ! density criterion for mixed layer depth
74      REAL(wp) ::   zavt_c = 5.e-4_wp   ! Kz criterion for the turbocline depth
75      !!----------------------------------------------------------------------
76
77      IF( iwrk_in_use(2, 1) ) THEN
78         CALL ctl_stop('zdf_mxl : requested workspace array unavailable')   ;   RETURN
79      ENDIF
80
81      IF( kt == nit000 ) THEN
82         IF(lwp) WRITE(numout,*)
83         IF(lwp) WRITE(numout,*) 'zdf_mxl : mixed layer depth'
84         IF(lwp) WRITE(numout,*) '~~~~~~~ '
85         !                             ! allocate zdfmxl arrays
86         IF( zdf_mxl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl : unable to allocate arrays' )
87      ENDIF
88
89      ! w-level of the mixing and mixed layers
90      nmln(:,:) = mbkt(:,:) + 1        ! Initialization to the number of w ocean point
91      imld(:,:) = mbkt(:,:) + 1
92      DO jk = jpkm1, nlb10, -1         ! from the bottom to nlb10
93         DO jj = 1, jpj
94            DO ji = 1, jpi
95               IF( rhop(ji,jj,jk) > rhop(ji,jj,nla10) + zrho_c )   nmln(ji,jj) = jk      ! Mixed layer
96               IF( avt (ji,jj,jk) < zavt_c                     )   imld(ji,jj) = jk      ! Turbocline
97            END DO
98         END DO
99      END DO
100      ! depth of the mixing and mixed layers
101      DO jj = 1, jpj
102         DO ji = 1, jpi
103            iiki = imld(ji,jj)
104            iikn = nmln(ji,jj)
105            hmld (ji,jj) = fsdepw(ji,jj,iiki  ) * tmask(ji,jj,1)    ! Turbocline depth
106            hmlp (ji,jj) = fsdepw(ji,jj,iikn  ) * tmask(ji,jj,1)    ! Mixed layer depth
107            hmlpt(ji,jj) = fsdept(ji,jj,iikn-1)                     ! depth of the last T-point inside the mixed layer
108         END DO
109      END DO
110      CALL iom_put( "mldr10_1", hmlp )   ! mixed layer depth
111      CALL iom_put( "mldkz5"  , hmld )   ! turbocline depth
112     
113      IF(ln_ctl)   CALL prt_ctl( tab2d_1=REAL(nmln,wp), clinfo1=' nmln : ', tab2d_2=hmlp, clinfo2=' hmlp : ', ovlap=1 )
114      !
115      IF( iwrk_not_released(2, 1) )   CALL ctl_stop('zdf_mxl: failed to release workspace array')
116      !
117   END SUBROUTINE zdf_mxl
118
119   !!======================================================================
120END MODULE zdfmxl
Note: See TracBrowser for help on using the repository browser.