source: trunk/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfmxl.F90 @ 2787

Last change on this file since 2787 was 2787, checked in by cetlod, 10 years ago

Bug correction in NEMO/OFFLINE, see ticket #841

  • Property svn:keywords set to Id
File size: 6.1 KB
Line 
1MODULE zdfmxl
2   !!======================================================================
3   !!                       ***  MODULE  zdfmxl  ***
4   !! Ocean physics: mixed layer depth
5   !!======================================================================
6   !! History :  1.0  ! 2003-08  (G. Madec)  original code
7   !!            3.2  ! 2009-07  (S. Masson, G. Madec)  IOM + merge of DO-loop
8   !!----------------------------------------------------------------------
9   !!   zdf_mxl      : Compute the turbocline and mixed layer depths.
10   !!----------------------------------------------------------------------
11   USE oce             ! ocean dynamics and tracers variables
12   USE dom_oce         ! ocean space and time domain variables
13   USE zdf_oce         ! ocean vertical physics
14   USE in_out_manager  ! I/O manager
15   USE prtctl          ! Print control
16   USE iom             ! I/O library
17   USE lib_mpp         ! MPP library
18   USE trc_oce, ONLY : lk_offline ! offline flag
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   zdf_mxl       ! called by step.F90
24
25   INTEGER , PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   nmln    !: number of level in the mixed layer (used by TOP)
26   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmld    !: mixing layer depth (turbocline)      [m]
27   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlp    !: mixed layer depth  (rho=rho0+zdcrit) [m]
28   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlpt   !: mixed layer depth at t-points        [m]
29
30   !! * Substitutions
31#  include "domzgr_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
34   !! $Id$
35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   INTEGER FUNCTION zdf_mxl_alloc()
40      !!----------------------------------------------------------------------
41      !!               ***  FUNCTION zdf_mxl_alloc  ***
42      !!----------------------------------------------------------------------
43      zdf_mxl_alloc = 0      ! set to zero if no array to be allocated
44      IF( .NOT. ALLOCATED( nmln ) ) THEN
45         ALLOCATE( nmln(jpi,jpj), hmld(jpi,jpj), hmlp(jpi,jpj), hmlpt(jpi,jpj), STAT= zdf_mxl_alloc )
46         !
47         IF( lk_mpp             )   CALL mpp_sum ( zdf_mxl_alloc )
48         IF( zdf_mxl_alloc /= 0 )   CALL ctl_warn('zdf_mxl_alloc: failed to allocate arrays.')
49         !
50      ENDIF
51   END FUNCTION zdf_mxl_alloc
52
53
54   SUBROUTINE zdf_mxl( kt )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE zdfmxl  ***
57      !!                   
58      !! ** Purpose :   Compute the turbocline depth and the mixed layer depth
59      !!              with density criteria.
60      !!
61      !! ** Method  :   The mixed layer depth is the shallowest W depth with
62      !!      the density of the corresponding T point (just bellow) bellow a
63      !!      given value defined locally as rho(10m) + zrho_c
64      !!               The turbocline depth is the depth at which the vertical
65      !!      eddy diffusivity coefficient (resulting from the vertical physics
66      !!      alone, not the isopycnal part, see trazdf.F) fall below a given
67      !!      value defined locally (avt_c here taken equal to 5 cm/s2)
68      !!
69      !! ** Action  :   nmln, hmld, hmlp, hmlpt
70      !!----------------------------------------------------------------------
71      USE wrk_nemo, ONLY:   iwrk_in_use, iwrk_not_released
72      USE wrk_nemo, ONLY:   imld => iwrk_2d_1    ! 2D integer workspace
73      !!
74      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
75      !!
76      INTEGER  ::   ji, jj, jk          ! dummy loop indices
77      INTEGER  ::   iikn, iiki          ! temporary integer within a do loop
78      REAL(wp) ::   zrho_c = 0.01_wp    ! density criterion for mixed layer depth
79      REAL(wp) ::   zavt_c = 5.e-4_wp   ! Kz criterion for the turbocline depth
80      !!----------------------------------------------------------------------
81
82      IF( iwrk_in_use(2, 1) ) THEN
83         CALL ctl_stop('zdf_mxl : requested workspace array unavailable')   ;   RETURN
84      ENDIF
85
86      IF( kt == nit000 ) THEN
87         IF(lwp) WRITE(numout,*)
88         IF(lwp) WRITE(numout,*) 'zdf_mxl : mixed layer depth'
89         IF(lwp) WRITE(numout,*) '~~~~~~~ '
90         !                             ! allocate zdfmxl arrays
91         IF( zdf_mxl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl : unable to allocate arrays' )
92      ENDIF
93
94      ! w-level of the mixing and mixed layers
95      nmln(:,:) = mbkt(:,:) + 1        ! Initialization to the number of w ocean point
96      imld(:,:) = mbkt(:,:) + 1
97      DO jk = jpkm1, nlb10, -1         ! from the bottom to nlb10
98         DO jj = 1, jpj
99            DO ji = 1, jpi
100               IF( rhop(ji,jj,jk) > rhop(ji,jj,nla10) + zrho_c )   nmln(ji,jj) = jk      ! Mixed layer
101               IF( avt (ji,jj,jk) < zavt_c                     )   imld(ji,jj) = jk      ! Turbocline
102            END DO
103         END DO
104      END DO
105      ! depth of the mixing and mixed layers
106      DO jj = 1, jpj
107         DO ji = 1, jpi
108            iiki = imld(ji,jj)
109            iikn = nmln(ji,jj)
110            hmld (ji,jj) = fsdepw(ji,jj,iiki  ) * tmask(ji,jj,1)    ! Turbocline depth
111            hmlp (ji,jj) = fsdepw(ji,jj,iikn  ) * tmask(ji,jj,1)    ! Mixed layer depth
112            hmlpt(ji,jj) = fsdept(ji,jj,iikn-1)                     ! depth of the last T-point inside the mixed layer
113         END DO
114      END DO
115      IF( .NOT.lk_offline ) THEN            ! no need to output in offline mode
116         CALL iom_put( "mldr10_1", hmlp )   ! mixed layer depth
117         CALL iom_put( "mldkz5"  , hmld )   ! turbocline depth
118      ENDIF
119     
120      IF(ln_ctl)   CALL prt_ctl( tab2d_1=REAL(nmln,wp), clinfo1=' nmln : ', tab2d_2=hmlp, clinfo2=' hmlp : ', ovlap=1 )
121      !
122      IF( iwrk_not_released(2, 1) )   CALL ctl_stop('zdf_mxl: failed to release workspace array')
123      !
124   END SUBROUTINE zdf_mxl
125
126   !!======================================================================
127END MODULE zdfmxl
Note: See TracBrowser for help on using the repository browser.