source: trunk/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfmxl.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 9 years ago

Merge of 3.4beta into the trunk

  • Property svn:keywords set to Id
File size: 6.1 KB
Line 
1MODULE zdfmxl
2   !!======================================================================
3   !!                       ***  MODULE  zdfmxl  ***
4   !! Ocean physics: mixed layer depth
5   !!======================================================================
6   !! History :  1.0  ! 2003-08  (G. Madec)  original code
7   !!            3.2  ! 2009-07  (S. Masson, G. Madec)  IOM + merge of DO-loop
8   !!----------------------------------------------------------------------
9   !!   zdf_mxl      : Compute the turbocline and mixed layer depths.
10   !!----------------------------------------------------------------------
11   USE oce             ! ocean dynamics and tracers variables
12   USE dom_oce         ! ocean space and time domain variables
13   USE zdf_oce         ! ocean vertical physics
14   USE in_out_manager  ! I/O manager
15   USE prtctl          ! Print control
16   USE iom             ! I/O library
17   USE lib_mpp         ! MPP library
18   USE wrk_nemo        ! work arrays
19   USE timing          ! Timing
20   USE trc_oce, ONLY : lk_offline ! offline flag
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   zdf_mxl       ! called by step.F90
26
27   INTEGER , PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   nmln    !: number of level in the mixed layer (used by TOP)
28   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmld    !: mixing layer depth (turbocline)      [m]
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlp    !: mixed layer depth  (rho=rho0+zdcrit) [m]
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlpt   !: mixed layer depth at t-points        [m]
31
32   !! * Substitutions
33#  include "domzgr_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
36   !! $Id$
37   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   INTEGER FUNCTION zdf_mxl_alloc()
42      !!----------------------------------------------------------------------
43      !!               ***  FUNCTION zdf_mxl_alloc  ***
44      !!----------------------------------------------------------------------
45      zdf_mxl_alloc = 0      ! set to zero if no array to be allocated
46      IF( .NOT. ALLOCATED( nmln ) ) THEN
47         ALLOCATE( nmln(jpi,jpj), hmld(jpi,jpj), hmlp(jpi,jpj), hmlpt(jpi,jpj), STAT= zdf_mxl_alloc )
48         !
49         IF( lk_mpp             )   CALL mpp_sum ( zdf_mxl_alloc )
50         IF( zdf_mxl_alloc /= 0 )   CALL ctl_warn('zdf_mxl_alloc: failed to allocate arrays.')
51         !
52      ENDIF
53   END FUNCTION zdf_mxl_alloc
54
55
56   SUBROUTINE zdf_mxl( kt )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE zdfmxl  ***
59      !!                   
60      !! ** Purpose :   Compute the turbocline depth and the mixed layer depth
61      !!              with density criteria.
62      !!
63      !! ** Method  :   The mixed layer depth is the shallowest W depth with
64      !!      the density of the corresponding T point (just bellow) bellow a
65      !!      given value defined locally as rho(10m) + zrho_c
66      !!               The turbocline depth is the depth at which the vertical
67      !!      eddy diffusivity coefficient (resulting from the vertical physics
68      !!      alone, not the isopycnal part, see trazdf.F) fall below a given
69      !!      value defined locally (avt_c here taken equal to 5 cm/s2)
70      !!
71      !! ** Action  :   nmln, hmld, hmlp, hmlpt
72      !!----------------------------------------------------------------------
73      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
74      !!
75      INTEGER  ::   ji, jj, jk          ! dummy loop indices
76      INTEGER  ::   iikn, iiki          ! temporary integer within a do loop
77      INTEGER, POINTER, DIMENSION(:,:) ::   imld                ! temporary workspace
78      REAL(wp) ::   zrho_c = 0.01_wp    ! density criterion for mixed layer depth
79      REAL(wp) ::   zavt_c = 5.e-4_wp   ! Kz criterion for the turbocline depth
80      !!----------------------------------------------------------------------
81      !
82      IF( nn_timing == 1 )  CALL timing_start('zdf_mxl')
83      !
84      CALL wrk_alloc( jpi,jpj, imld )
85
86      IF( kt == nit000 ) THEN
87         IF(lwp) WRITE(numout,*)
88         IF(lwp) WRITE(numout,*) 'zdf_mxl : mixed layer depth'
89         IF(lwp) WRITE(numout,*) '~~~~~~~ '
90         !                             ! allocate zdfmxl arrays
91         IF( zdf_mxl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl : unable to allocate arrays' )
92      ENDIF
93
94      ! w-level of the mixing and mixed layers
95      nmln(:,:) = mbkt(:,:) + 1        ! Initialization to the number of w ocean point
96      imld(:,:) = mbkt(:,:) + 1
97      DO jk = jpkm1, nlb10, -1         ! from the bottom to nlb10
98         DO jj = 1, jpj
99            DO ji = 1, jpi
100               IF( rhop(ji,jj,jk) > rhop(ji,jj,nla10) + zrho_c )   nmln(ji,jj) = jk      ! Mixed layer
101               IF( avt (ji,jj,jk) < zavt_c                     )   imld(ji,jj) = jk      ! Turbocline
102            END DO
103         END DO
104      END DO
105      ! depth of the mixing and mixed layers
106      DO jj = 1, jpj
107         DO ji = 1, jpi
108            iiki = imld(ji,jj)
109            iikn = nmln(ji,jj)
110            hmld (ji,jj) = fsdepw(ji,jj,iiki  ) * tmask(ji,jj,1)    ! Turbocline depth
111            hmlp (ji,jj) = fsdepw(ji,jj,iikn  ) * tmask(ji,jj,1)    ! Mixed layer depth
112            hmlpt(ji,jj) = fsdept(ji,jj,iikn-1)                     ! depth of the last T-point inside the mixed layer
113         END DO
114      END DO
115      IF( .NOT.lk_offline ) THEN            ! no need to output in offline mode
116         CALL iom_put( "mldr10_1", hmlp )   ! mixed layer depth
117         CALL iom_put( "mldkz5"  , hmld )   ! turbocline depth
118      ENDIF
119     
120      IF(ln_ctl)   CALL prt_ctl( tab2d_1=REAL(nmln,wp), clinfo1=' nmln : ', tab2d_2=hmlp, clinfo2=' hmlp : ', ovlap=1 )
121      !
122      CALL wrk_dealloc( jpi,jpj, imld )
123      !
124      IF( nn_timing == 1 )  CALL timing_stop('zdf_mxl')
125      !
126   END SUBROUTINE zdf_mxl
127
128   !!======================================================================
129END MODULE zdfmxl
Note: See TracBrowser for help on using the repository browser.