New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in trunk/NEMOGCM/NEMO/OPA_SRC – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 3604

Last change on this file since 3604 was 3604, checked in by rblod, 10 years ago

Adding routines and modules for TAM - Ticket #1005

  • Property svn:keywords set to Id
File size: 36.2 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35   !!   nemo_init      : initialization of the NEMO system
36   !!   nemo_ctl       : initialisation of the contol print
37   !!   nemo_closefile : close remaining open files
38   !!   nemo_alloc     : dynamical allocation
39   !!   nemo_partition : calculate MPP domain decomposition
40   !!   factorise      : calculate the factors of the no. of MPI processes
41   !!----------------------------------------------------------------------
42   USE step_oce        ! module used in the ocean time stepping module
43   USE sbc_oce         ! surface boundary condition: ocean
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48   USE obcini          ! open boundary cond. initialization (obc_ini routine)
49   USE bdyini          ! open boundary cond. initialization (bdy_init routine)
50   USE bdydta          ! open boundary cond. initialization (bdy_dta_init routine)
51   USE bdytides        ! open boundary cond. initialization (tide_init routine)
52   USE istate          ! initial state setting          (istate_init routine)
53   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
54   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
55   USE zdfini          ! vertical physics setting          (zdf_init routine)
56   USE phycst          ! physical constant                  (par_cst routine)
57   USE trdmod          ! momentum/tracers trends       (trd_mod_init routine)
58   USE asmbkg          ! writing out state trajectory
59   USE diaptr          ! poleward transports           (dia_ptr_init routine)
60   USE diadct          ! sections transports           (dia_dct_init routine)
61   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
62   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
63   USE step            ! NEMO time-stepping                 (stp     routine)
64#if defined key_oasis3
65   USE cpl_oasis3      ! OASIS3 coupling
66#elif defined key_oasis4
67   USE cpl_oasis4      ! OASIS4 coupling (not working)
68#endif
69   USE c1d             ! 1D configuration
70   USE step_c1d        ! Time stepping loop for the 1D configuration
71#if defined key_top
72   USE trcini          ! passive tracer initialisation
73#endif
74   USE lib_mpp         ! distributed memory computing
75#if defined key_iomput
76   USE mod_ioclient
77#endif
78   USE tamtrj          ! Output trajectory, needed for TAM
79
80   IMPLICIT NONE
81   PRIVATE
82
83   PUBLIC   nemo_gcm    ! called by model.F90
84   PUBLIC   nemo_init   ! needed by AGRIF
85   PUBLIC   nemo_alloc  ! needed by TAM
86
87   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
88
89   !!----------------------------------------------------------------------
90   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
91   !! $Id$
92   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
93   !!----------------------------------------------------------------------
94CONTAINS
95
96   SUBROUTINE nemo_gcm
97      !!----------------------------------------------------------------------
98      !!                     ***  ROUTINE nemo_gcm  ***
99      !!
100      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
101      !!              curvilinear mesh on the sphere.
102      !!
103      !! ** Method  : - model general initialization
104      !!              - launch the time-stepping (stp routine)
105      !!              - finalize the run by closing files and communications
106      !!
107      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
108      !!              Madec, 2008, internal report, IPSL.
109      !!----------------------------------------------------------------------
110      INTEGER ::   istp       ! time step index
111      !!----------------------------------------------------------------------
112      !
113#if defined key_agrif
114      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
115#endif
116
117      !                            !-----------------------!
118      CALL nemo_init               !==  Initialisations  ==!
119      !                            !-----------------------!
120#if defined key_agrif
121      CALL Agrif_Declare_Var       ! AGRIF: set the meshes
122# if defined key_top
123      CALL Agrif_Declare_Var_Top   ! AGRIF: set the meshes
124# endif
125#endif
126      ! check that all process are still there... If some process have an error,
127      ! they will never enter in step and other processes will wait until the end of the cpu time!
128      IF( lk_mpp )   CALL mpp_max( nstop )
129
130      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
131
132      !                            !-----------------------!
133      !                            !==   time stepping   ==!
134      !                            !-----------------------!
135      istp = nit000
136#if defined key_c1d
137         DO WHILE ( istp <= nitend .AND. nstop == 0 )
138            CALL stp_c1d( istp )
139            istp = istp + 1
140         END DO
141#else
142          IF( lk_asminc ) THEN
143             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
144             IF( ln_asmdin ) THEN                        ! Direct initialization
145                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
146                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
147                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
148             ENDIF
149          ENDIF
150
151         DO WHILE ( istp <= nitend .AND. nstop == 0 )
152#if defined key_agrif
153            CALL Agrif_Step( stp )           ! AGRIF: time stepping
154#else
155            CALL stp( istp )                 ! standard time stepping
156#endif
157            istp = istp + 1
158            IF( lk_mpp )   CALL mpp_max( nstop )
159         END DO
160#endif
161
162      IF( lk_diaobs ) CALL dia_obs_wri
163
164      !                            !------------------------!
165      !                            !==  finalize the run  ==!
166      !                            !------------------------!
167      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
168      !
169      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
170         WRITE(numout,cform_err)
171         WRITE(numout,*) nstop, ' error have been found'
172      ENDIF
173      !
174#if defined key_agrif
175      CALL Agrif_ParentGrid_To_ChildGrid()
176      IF( lk_diaobs ) CALL dia_obs_wri
177      IF( nn_timing == 1 )   CALL timing_finalize
178      CALL Agrif_ChildGrid_To_ParentGrid()
179#endif
180      IF( nn_timing == 1 )   CALL timing_finalize
181      !
182      CALL nemo_closefile
183#if defined key_oasis3 || defined key_oasis4
184      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
185#else
186      IF( lk_mpp )   CALL mppstop       ! end mpp communications
187#endif
188      !
189   END SUBROUTINE nemo_gcm
190
191
192   SUBROUTINE nemo_init
193      !!----------------------------------------------------------------------
194      !!                     ***  ROUTINE nemo_init  ***
195      !!
196      !! ** Purpose :   initialization of the NEMO GCM
197      !!----------------------------------------------------------------------
198      INTEGER ::   ji            ! dummy loop indices
199      INTEGER ::   ilocal_comm   ! local integer
200      CHARACTER(len=80), DIMENSION(16) ::   cltxt
201      !!
202      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
203         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
204         &             nn_bench, nn_timing
205      !!----------------------------------------------------------------------
206      !
207      cltxt = ''
208      !
209      !                             ! open Namelist file
210      CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
211      !
212      READ( numnam, namctl )        ! Namelist namctl : Control prints & Benchmark
213      !
214      !                             !--------------------------------------------!
215      !                             !  set communicator & select the local node  !
216      !                             !--------------------------------------------!
217#if defined key_iomput
218      IF( Agrif_Root() ) THEN
219# if defined key_oasis3 || defined key_oasis4
220         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
221# endif
222         CALL  init_ioclient( ilocal_comm )                 ! exchange io_server nemo local communicator with the io_server
223      ENDIF
224      narea = mynode( cltxt, numnam, nstop, ilocal_comm )   ! Nodes selection
225#else
226# if defined key_oasis3 || defined key_oasis4
227      IF( Agrif_Root() ) THEN
228         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
229      ENDIF
230      narea = mynode( cltxt, numnam, nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
231# else
232      ilocal_comm = 0
233      narea = mynode( cltxt, numnam, nstop )                 ! Nodes selection (control print return in cltxt)
234# endif
235#endif
236      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
237
238      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
239
240      ! If dimensions of processor grid weren't specified in the namelist file
241      ! then we calculate them here now that we have our communicator size
242      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
243#if   defined key_mpp_mpi
244         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
245#else
246         jpni  = 1
247         jpnj  = 1
248         jpnij = jpni*jpnj
249#endif
250      END IF
251
252      ! Calculate domain dimensions given calculated jpni and jpnj
253      ! This used to be done in par_oce.F90 when they were parameters rather
254      ! than variables
255      IF( Agrif_Root() ) THEN
256         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
257#if defined key_nemocice_decomp
258         jpj = ( jpjglo+1-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
259#else
260         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
261#endif
262         jpk = jpkdta                                             ! third dim
263         jpim1 = jpi-1                                            ! inner domain indices
264         jpjm1 = jpj-1                                            !   "           "
265         jpkm1 = jpk-1                                            !   "           "
266         jpij  = jpi*jpj                                          !  jpi x j
267      ENDIF
268
269      IF(lwp) THEN                            ! open listing units
270         !
271         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
272         !
273         WRITE(numout,*)
274         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
275         WRITE(numout,*) '                       NEMO team'
276         WRITE(numout,*) '            Ocean General Circulation Model'
277         WRITE(numout,*) '                  version 3.4  (2011) '
278         WRITE(numout,*)
279         WRITE(numout,*)
280         DO ji = 1, SIZE(cltxt)
281            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
282         END DO
283         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
284         !
285      ENDIF
286
287      ! Now we know the dimensions of the grid and numout has been set we can
288      ! allocate arrays
289      CALL nemo_alloc()
290
291      !                             !-------------------------------!
292      !                             !  NEMO general initialization  !
293      !                             !-------------------------------!
294
295      CALL nemo_ctl                          ! Control prints & Benchmark
296
297      !                                      ! Domain decomposition
298      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
299      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
300      ENDIF
301      !
302      IF( nn_timing == 1 )  CALL timing_init
303      !
304      !                                      ! General initialization
305                            CALL     phy_cst    ! Physical constants
306                            CALL     eos_init   ! Equation of state
307                            CALL     dom_cfg    ! Domain configuration
308                            CALL     dom_init   ! Domain
309
310      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
311
312      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
313
314      IF( lk_obc        )   CALL     obc_init   ! Open boundaries
315      IF( lk_bdy        )   CALL     bdy_init       ! Open boundaries initialisation
316      IF( lk_bdy        )   CALL     bdy_dta_init   ! Open boundaries initialisation of external data arrays
317      IF( lk_bdy        )   CALL     tide_init      ! Open boundaries initialisation of tidal harmonic forcing
318
319                            CALL flush(numout)
320                            CALL dyn_nept_init  ! simplified form of Neptune effect
321                            CALL flush(numout)
322
323                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
324
325      !                                     ! Ocean physics
326                            CALL     sbc_init   ! Forcings : surface module
327      !                                         ! Vertical physics
328                            CALL     zdf_init      ! namelist read
329                            CALL zdf_bfr_init      ! bottom friction
330      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
331      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
332      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
333      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
334      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
335      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
336         &                  CALL zdf_ddm_init      ! double diffusive mixing
337      !                                         ! Lateral physics
338                            CALL ldf_tra_init      ! Lateral ocean tracer physics
339                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
340      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
341
342      !                                     ! Active tracers
343                            CALL tra_qsr_init   ! penetrative solar radiation qsr
344                            CALL tra_bbc_init   ! bottom heat flux
345      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
346      IF( ln_tradmp     )   CALL tra_dmp_init   ! internal damping trends
347                            CALL tra_adv_init   ! horizontal & vertical advection
348                            CALL tra_ldf_init   ! lateral mixing
349                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
350
351      !                                     ! Dynamics
352                            CALL dyn_adv_init   ! advection (vector or flux form)
353                            CALL dyn_vor_init   ! vorticity term including Coriolis
354                            CALL dyn_ldf_init   ! lateral mixing
355                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
356                            CALL dyn_zdf_init   ! vertical diffusion
357                            CALL dyn_spg_init   ! surface pressure gradient
358
359      !                                     ! Misc. options
360      IF( nn_cla == 1   )   CALL cla_init       ! Cross Land Advection
361
362#if defined key_top
363      !                                     ! Passive tracers
364                            CALL     trc_init
365#endif
366      !                                     ! Diagnostics
367      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
368                            CALL     iom_init   ! iom_put initialization
369      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
370                            CALL dia_ptr_init   ! Poleward TRansports initialization
371      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
372                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
373                            CALL trd_mod_init   ! Mixed-layer/Vorticity/Integral constraints trends
374      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
375                            CALL dia_obs_init            ! Initialize observational data
376                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
377      ENDIF
378      !                                     ! Assimilation increments
379      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
380      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
381                            CALL tam_trj_init ! Trajectory handling
382      !
383   END SUBROUTINE nemo_init
384
385
386   SUBROUTINE nemo_ctl
387      !!----------------------------------------------------------------------
388      !!                     ***  ROUTINE nemo_ctl  ***
389      !!
390      !! ** Purpose :   control print setting
391      !!
392      !! ** Method  : - print namctl information and check some consistencies
393      !!----------------------------------------------------------------------
394      !
395      IF(lwp) THEN                  ! control print
396         WRITE(numout,*)
397         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
398         WRITE(numout,*) '~~~~~~~ '
399         WRITE(numout,*) '   Namelist namctl'
400         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
401         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
402         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
403         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
404         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
405         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
406         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
407         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
408         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
409         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
410      ENDIF
411      !
412      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
413      nictls    = nn_ictls
414      nictle    = nn_ictle
415      njctls    = nn_jctls
416      njctle    = nn_jctle
417      isplt     = nn_isplt
418      jsplt     = nn_jsplt
419      nbench    = nn_bench
420      !                             ! Parameter control
421      !
422      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
423         IF( lk_mpp .AND. jpnij > 1 ) THEN
424            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
425         ELSE
426            IF( isplt == 1 .AND. jsplt == 1  ) THEN
427               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
428                  &           ' - the print control will be done over the whole domain' )
429            ENDIF
430            ijsplt = isplt * jsplt            ! total number of processors ijsplt
431         ENDIF
432         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
433         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
434         !
435         !                              ! indices used for the SUM control
436         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
437            lsp_area = .FALSE.
438         ELSE                                             ! print control done over a specific  area
439            lsp_area = .TRUE.
440            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
441               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
442               nictls = 1
443            ENDIF
444            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
445               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
446               nictle = jpiglo
447            ENDIF
448            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
449               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
450               njctls = 1
451            ENDIF
452            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
453               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
454               njctle = jpjglo
455            ENDIF
456         ENDIF
457      ENDIF
458      !
459      IF( nbench == 1 ) THEN              ! Benchmark
460         SELECT CASE ( cp_cfg )
461         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
462         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
463            &                                 ' key_gyre must be used or set nbench = 0' )
464         END SELECT
465      ENDIF
466      !
467      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
468         &                                               'with the IOM Input/Output manager. '         ,   &
469         &                                               'Compile with key_iomput enabled' )
470      !
471      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
472         &                                               'f2003 standard. '                              ,  &
473         &                                               'Compile with key_nosignedzero enabled' )
474      !
475   END SUBROUTINE nemo_ctl
476
477
478   SUBROUTINE nemo_closefile
479      !!----------------------------------------------------------------------
480      !!                     ***  ROUTINE nemo_closefile  ***
481      !!
482      !! ** Purpose :   Close the files
483      !!----------------------------------------------------------------------
484      !
485      IF( lk_mpp )   CALL mppsync
486      !
487      CALL iom_close                                 ! close all input/output files managed by iom_*
488      !
489      IF( numstp      /= -1 )   CLOSE( numstp      )   ! time-step file
490      IF( numsol      /= -1 )   CLOSE( numsol      )   ! solver file
491      IF( numnam      /= -1 )   CLOSE( numnam      )   ! oce namelist
492      IF( numnam_ice  /= -1 )   CLOSE( numnam_ice  )   ! ice namelist
493      IF( numevo_ice  /= -1 )   CLOSE( numevo_ice  )   ! ice variables (temp. evolution)
494      IF( numout      /=  6 )   CLOSE( numout      )   ! standard model output file
495      IF( numdct_vol  /= -1 )   CLOSE( numdct_vol  )   ! volume transports
496      IF( numdct_heat /= -1 )   CLOSE( numdct_heat )   ! heat transports
497      IF( numdct_salt /= -1 )   CLOSE( numdct_salt )   ! salt transports
498
499      !
500      numout = 6                                     ! redefine numout in case it is used after this point...
501      !
502   END SUBROUTINE nemo_closefile
503
504
505   SUBROUTINE nemo_alloc
506      !!----------------------------------------------------------------------
507      !!                     ***  ROUTINE nemo_alloc  ***
508      !!
509      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
510      !!
511      !! ** Method  :
512      !!----------------------------------------------------------------------
513      USE diawri    , ONLY: dia_wri_alloc
514      USE dom_oce   , ONLY: dom_oce_alloc
515      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
516      USE ldftra_oce, ONLY: ldftra_oce_alloc
517      USE trc_oce   , ONLY: trc_oce_alloc
518      !
519      INTEGER :: ierr
520      !!----------------------------------------------------------------------
521      !
522      ierr =        oce_alloc       ()          ! ocean
523      ierr = ierr + dia_wri_alloc   ()
524      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
525      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
526      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
527      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
528      !
529      ierr = ierr + lib_mpp_alloc   (numout)    ! mpp exchanges
530      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
531      !
532      IF( lk_mpp    )   CALL mpp_sum( ierr )
533      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
534      !
535   END SUBROUTINE nemo_alloc
536
537
538   SUBROUTINE nemo_partition( num_pes )
539      !!----------------------------------------------------------------------
540      !!                 ***  ROUTINE nemo_partition  ***
541      !!
542      !! ** Purpose :
543      !!
544      !! ** Method  :
545      !!----------------------------------------------------------------------
546      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
547      !
548      INTEGER, PARAMETER :: nfactmax = 20
549      INTEGER :: nfact ! The no. of factors returned
550      INTEGER :: ierr  ! Error flag
551      INTEGER :: ji
552      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
553      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
554      !!----------------------------------------------------------------------
555
556      ierr = 0
557
558      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
559
560      IF( nfact <= 1 ) THEN
561         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
562         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
563         jpnj = 1
564         jpni = num_pes
565      ELSE
566         ! Search through factors for the pair that are closest in value
567         mindiff = 1000000
568         imin    = 1
569         DO ji = 1, nfact-1, 2
570            idiff = ABS( ifact(ji) - ifact(ji+1) )
571            IF( idiff < mindiff ) THEN
572               mindiff = idiff
573               imin = ji
574            ENDIF
575         END DO
576         jpnj = ifact(imin)
577         jpni = ifact(imin + 1)
578      ENDIF
579      !
580      jpnij = jpni*jpnj
581      !
582   END SUBROUTINE nemo_partition
583
584
585   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
586      !!----------------------------------------------------------------------
587      !!                     ***  ROUTINE factorise  ***
588      !!
589      !! ** Purpose :   return the prime factors of n.
590      !!                knfax factors are returned in array kfax which is of
591      !!                maximum dimension kmaxfax.
592      !! ** Method  :
593      !!----------------------------------------------------------------------
594      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
595      INTEGER                    , INTENT(  out) ::   kerr, knfax
596      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
597      !
598      INTEGER :: ifac, jl, inu
599      INTEGER, PARAMETER :: ntest = 14
600      INTEGER :: ilfax(ntest)
601
602      ! lfax contains the set of allowed factors.
603      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
604         &                            128,   64,   32,   16,    8,   4,   2  /
605      !!----------------------------------------------------------------------
606
607      ! Clear the error flag and initialise output vars
608      kerr = 0
609      kfax = 1
610      knfax = 0
611
612      ! Find the factors of n.
613      IF( kn == 1 )   GOTO 20
614
615      ! nu holds the unfactorised part of the number.
616      ! knfax holds the number of factors found.
617      ! l points to the allowed factor list.
618      ! ifac holds the current factor.
619
620      inu   = kn
621      knfax = 0
622
623      DO jl = ntest, 1, -1
624         !
625         ifac = ilfax(jl)
626         IF( ifac > inu )   CYCLE
627
628         ! Test whether the factor will divide.
629
630         IF( MOD(inu,ifac) == 0 ) THEN
631            !
632            knfax = knfax + 1            ! Add the factor to the list
633            IF( knfax > kmaxfax ) THEN
634               kerr = 6
635               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
636               return
637            ENDIF
638            kfax(knfax) = ifac
639            ! Store the other factor that goes with this one
640            knfax = knfax + 1
641            kfax(knfax) = inu / ifac
642            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
643         ENDIF
644         !
645      END DO
646
647   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
648      !
649   END SUBROUTINE factorise
650
651#if defined key_mpp_mpi
652   SUBROUTINE nemo_northcomms
653      !!======================================================================
654      !!                     ***  ROUTINE  nemo_northcomms  ***
655      !! nemo_northcomms    :  Setup for north fold exchanges with explicit peer to peer messaging
656      !!=====================================================================
657      !!----------------------------------------------------------------------
658      !!
659      !! ** Purpose :   Initialization of the northern neighbours lists.
660      !!----------------------------------------------------------------------
661      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
662      !!----------------------------------------------------------------------
663
664      INTEGER ::   ji, jj, jk, ij, jtyp    ! dummy loop indices
665      INTEGER ::   ijpj                    ! number of rows involved in north-fold exchange
666      INTEGER ::   northcomms_alloc        ! allocate return status
667      REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) ::   znnbrs     ! workspace
668      LOGICAL,  ALLOCATABLE, DIMENSION ( : )   ::   lrankset   ! workspace
669
670      IF(lwp) WRITE(numout,*)
671      IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
672      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
673
674      !!----------------------------------------------------------------------
675      ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
676      ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
677      IF( northcomms_alloc /= 0 ) THEN
678         WRITE(numout,cform_war)
679         WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
680         CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
681      ENDIF
682      nsndto = 0
683      isendto = -1
684      ijpj   = 4
685      !
686      ! This routine has been called because ln_nnogather has been set true ( nammpp )
687      ! However, these first few exchanges have to use the mpi_allgather method to
688      ! establish the neighbour lists to use in subsequent peer to peer exchanges.
689      ! Consequently, set l_north_nogather to be false here and set it true only after
690      ! the lists have been established.
691      !
692      l_north_nogather = .FALSE.
693      !
694      ! Exchange and store ranks on northern rows
695
696      DO jtyp = 1,4
697
698         lrankset = .FALSE.
699         znnbrs = narea
700         SELECT CASE (jtyp)
701            CASE(1)
702               CALL lbc_lnk( znnbrs, 'T', 1. )      ! Type 1: T,W-points
703            CASE(2)
704               CALL lbc_lnk( znnbrs, 'U', 1. )      ! Type 2: U-point
705            CASE(3)
706               CALL lbc_lnk( znnbrs, 'V', 1. )      ! Type 3: V-point
707            CASE(4)
708               CALL lbc_lnk( znnbrs, 'F', 1. )      ! Type 4: F-point
709         END SELECT
710
711         IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
712            DO jj = nlcj-ijpj+1, nlcj
713               ij = jj - nlcj + ijpj
714               DO ji = 1,jpi
715                  IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
716               &     lrankset(INT(znnbrs(ji,jj))) = .true.
717               END DO
718            END DO
719
720            DO jj = 1,jpnij
721               IF ( lrankset(jj) ) THEN
722                  nsndto(jtyp) = nsndto(jtyp) + 1
723                  IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
724                     CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
725                  &                 ' jpmaxngh will need to be increased ')
726                  ENDIF
727                  isendto(nsndto(jtyp),jtyp) = jj-1   ! narea converted to MPI rank
728               ENDIF
729            END DO
730         ENDIF
731
732      END DO
733
734      !
735      ! Type 5: I-point
736      !
737      ! ICE point exchanges may involve some averaging. The neighbours list is
738      ! built up using two exchanges to ensure that the whole stencil is covered.
739      ! lrankset should not be reset between these 'J' and 'K' point exchanges
740
741      jtyp = 5
742      lrankset = .FALSE.
743      znnbrs = narea
744      CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
745
746      IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
747         DO jj = nlcj-ijpj+1, nlcj
748            ij = jj - nlcj + ijpj
749            DO ji = 1,jpi
750               IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
751            &     lrankset(INT(znnbrs(ji,jj))) = .true.
752         END DO
753        END DO
754      ENDIF
755
756      znnbrs = narea
757      CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
758
759      IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
760         DO jj = nlcj-ijpj+1, nlcj
761            ij = jj - nlcj + ijpj
762            DO ji = 1,jpi
763               IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND.  INT(znnbrs(ji,jj)) .NE. narea ) &
764            &       lrankset( INT(znnbrs(ji,jj))) = .true.
765            END DO
766         END DO
767
768         DO jj = 1,jpnij
769            IF ( lrankset(jj) ) THEN
770               nsndto(jtyp) = nsndto(jtyp) + 1
771               IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
772                  CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
773               &                 ' jpmaxngh will need to be increased ')
774               ENDIF
775               isendto(nsndto(jtyp),jtyp) = jj-1   ! narea converted to MPI rank
776            ENDIF
777         END DO
778         !
779         ! For northern row areas, set l_north_nogather so that all subsequent exchanges
780         ! can use peer to peer communications at the north fold
781         !
782         l_north_nogather = .TRUE.
783         !
784      ENDIF
785      DEALLOCATE( znnbrs )
786      DEALLOCATE( lrankset )
787
788   END SUBROUTINE nemo_northcomms
789#else
790   SUBROUTINE nemo_northcomms      ! Dummy routine
791      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
792   END SUBROUTINE nemo_northcomms
793#endif
794   !!======================================================================
795END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.