New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zrem.F90 @ 6140

Last change on this file since 6140 was 6140, checked in by timgraham, 9 years ago

Merge of branches/2015/dev_merge_2015 back into trunk. Merge excludes NEMOGCM/TOOLS/OBSTOOLS/ for now due to issues with the change of file type. Will sort these manually with further commits.

Branch merged as follows:
In the working copy of branch ran:
svn merge ​svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
Small conflicts due to bug fixes applied to trunk since the dev_merge_2015 was copied. Bug fixes were applied to the branch as well so these were easy to resolve.
Branch committed at this stage

In working copy run:
svn switch ​svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge --reintegrate ​svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2015/dev_merge_2015
to merge the branch into the trunk and then commit - no conflicts at this stage.
File size: 18.5 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_top'       and                                      TOP models
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
16   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
17   !!   p4z_rem_alloc :  Allocate remineralisation variables
18   !!----------------------------------------------------------------------
19   USE oce_trc         !  shared variables between ocean and passive tracers
20   USE trc             !  passive tracers common variables
21   USE sms_pisces      !  PISCES Source Minus Sink variables
22   USE p4zopt          !  optical model
23   USE p4zche          !  chemical model
24   USE p4zprod         !  Growth rate of the 2 phyto groups
25   USE p4zmeso         !  Sources and sinks of mesozooplankton
26   USE p4zint          !  interpolation and computation of various fields
27   USE p4zlim
28   USE prtctl_trc      !  print control for debugging
29   USE iom             !  I/O manager
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   p4z_rem         ! called in p4zbio.F90
36   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
37   PUBLIC   p4z_rem_alloc
38
39   !! * Shared module variables
40   REAL(wp), PUBLIC ::  xremik     !: remineralisation rate of POC
41   REAL(wp), PUBLIC ::  xremip     !: remineralisation rate of DOC
42   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
43   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of POC
44   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of POC
45   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
46   REAL(wp), PUBLIC ::  oxymin     !: halk saturation constant for anoxia
47
48
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr     !: denitrification array
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitnh4   !: -    -    -    -   -
51
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
54   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
55   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE p4z_rem( kt, knt )
60      !!---------------------------------------------------------------------
61      !!                     ***  ROUTINE p4z_rem  ***
62      !!
63      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
64      !!
65      !! ** Method  : - ???
66      !!---------------------------------------------------------------------
67      !
68      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
69      !
70      INTEGER  ::   ji, jj, jk
71      REAL(wp) ::   zremip, zremik, zsiremin 
72      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
73      REAL(wp) ::   zbactfer, zorem, zorem2, zofer, zolimit
74      REAL(wp) ::   zosil, ztem
75#if ! defined key_kriest
76      REAL(wp) ::   zofer2
77#endif
78      REAL(wp) ::   zonitr, zstep, zfact
79      CHARACTER (len=25) :: charout
80      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zolimi, zdepprod, zw3d
82      !!---------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('p4z_rem')
85      !
86      ! Allocate temporary workspace
87      CALL wrk_alloc( jpi, jpj,      ztempbac                  )
88      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zolimi )
89
90      ! Initialisation of temprary arrys
91      zdepprod(:,:,:) = 1._wp
92      ztempbac(:,:)   = 0._wp
93
94      ! Computation of the mean phytoplankton concentration as
95      ! a crude estimate of the bacterial biomass
96      ! this parameterization has been deduced from a model version
97      ! that was modeling explicitely bacteria
98      ! -------------------------------------------------------
99      DO jk = 1, jpkm1
100         DO jj = 1, jpj
101            DO ji = 1, jpi
102               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
103               IF( gdept_n(ji,jj,jk) < zdep ) THEN
104                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
105                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
106               ELSE
107                  zdepmin = MIN( 1., zdep / gdept_n(ji,jj,jk) )
108                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
109                  zdepprod(ji,jj,jk) = zdepmin**0.273
110               ENDIF
111            END DO
112         END DO
113      END DO
114
115      DO jk = 1, jpkm1
116         DO jj = 1, jpj
117            DO ji = 1, jpi
118               ! denitrification factor computed from O2 levels
119               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( 6.e-6  - trb(ji,jj,jk,jpoxy) )    &
120                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
121               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
122            END DO
123         END DO
124      END DO
125
126      DO jk = 1, jpkm1
127         DO jj = 1, jpj
128            DO ji = 1, jpi
129               zstep   = xstep
130# if defined key_degrad
131               zstep = zstep * facvol(ji,jj,jk)
132# endif
133               ! DOC ammonification. Depends on depth, phytoplankton biomass
134               ! and a limitation term which is supposed to be a parameterization
135               !     of the bacterial activity.
136               zremik = xremik * zstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
137               zremik = MAX( zremik, 2.74e-4 * xstep )
138               ! Ammonification in oxic waters with oxygen consumption
139               ! -----------------------------------------------------
140               zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
141               zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
142               ! Ammonification in suboxic waters with denitrification
143               ! -------------------------------------------------------
144               denitr(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit,   &
145                  &                     zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)  )
146               !
147               zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
148               denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
149               !
150            END DO
151         END DO
152      END DO
153
154
155      DO jk = 1, jpkm1
156         DO jj = 1, jpj
157            DO ji = 1, jpi
158               zstep   = xstep
159# if defined key_degrad
160               zstep = zstep * facvol(ji,jj,jk)
161# endif
162               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
163               ! below 2 umol/L. Inhibited at strong light
164               ! ----------------------------------------------------------
165               zonitr  =nitrif * zstep * trb(ji,jj,jk,jpnh4) / ( 1.+ emoy(ji,jj,jk) ) * ( 1.- nitrfac(ji,jj,jk) ) 
166               denitnh4(ji,jj,jk) = nitrif * zstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk) 
167               ! Update of the tracers trends
168               ! ----------------------------
169               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - denitnh4(ji,jj,jk)
170               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * denitnh4(ji,jj,jk)
171               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
172               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * denitnh4(ji,jj,jk)
173            END DO
174         END DO
175      END DO
176
177       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
178         WRITE(charout, FMT="('rem1')")
179         CALL prt_ctl_trc_info(charout)
180         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
181       ENDIF
182
183      DO jk = 1, jpkm1
184         DO jj = 1, jpj
185            DO ji = 1, jpi
186
187               ! Bacterial uptake of iron. No iron is available in DOC. So
188               ! Bacteries are obliged to take up iron from the water. Some
189               ! studies (especially at Papa) have shown this uptake to be significant
190               ! ----------------------------------------------------------
191               zbactfer = 10.e-6 *  rfact2 * prmax(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
192                  &              * trb(ji,jj,jk,jpfer) / ( 2.5E-10 + trb(ji,jj,jk,jpfer) )    &
193                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
194#if defined key_kriest
195               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.05
196               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.05
197#else
198               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
199               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
200               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
201#endif
202            END DO
203         END DO
204      END DO
205
206       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
207         WRITE(charout, FMT="('rem2')")
208         CALL prt_ctl_trc_info(charout)
209         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
210       ENDIF
211
212      DO jk = 1, jpkm1
213         DO jj = 1, jpj
214            DO ji = 1, jpi
215               zstep   = xstep
216# if defined key_degrad
217               zstep = zstep * facvol(ji,jj,jk)
218# endif
219               ! POC disaggregation by turbulence and bacterial activity.
220               ! --------------------------------------------------------
221               zremip = xremip * zstep * tgfunc(ji,jj,jk) * ( 1.- 0.55 * nitrfac(ji,jj,jk) ) 
222
223               ! POC disaggregation rate is reduced in anoxic zone as shown by
224               ! sediment traps data. In oxic area, the exponent of the martin s
225               ! law is around -0.87. In anoxic zone, it is around -0.35. This
226               ! means a disaggregation constant about 0.5 the value in oxic zones
227               ! -----------------------------------------------------------------
228               zorem  = zremip * trb(ji,jj,jk,jppoc)
229               zofer  = zremip * trb(ji,jj,jk,jpsfe)
230#if ! defined key_kriest
231               zorem2 = zremip * trb(ji,jj,jk,jpgoc)
232               zofer2 = zremip * trb(ji,jj,jk,jpbfe)
233#else
234               zorem2 = zremip * trb(ji,jj,jk,jpnum)
235#endif
236
237               ! Update the appropriate tracers trends
238               ! -------------------------------------
239
240               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zorem
241               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zofer
242#if defined key_kriest
243               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zorem
244               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zorem2
245               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zofer
246#else
247               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zorem2 - zorem
248               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) - zorem2
249               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zofer2 - zofer
250               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) - zofer2
251#endif
252
253            END DO
254         END DO
255      END DO
256
257       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
258         WRITE(charout, FMT="('rem3')")
259         CALL prt_ctl_trc_info(charout)
260         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
261       ENDIF
262
263      DO jk = 1, jpkm1
264         DO jj = 1, jpj
265            DO ji = 1, jpi
266               zstep   = xstep
267# if defined key_degrad
268               zstep = zstep * facvol(ji,jj,jk)
269# endif
270               ! Remineralization rate of BSi depedant on T and saturation
271               ! ---------------------------------------------------------
272               zsatur   = ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn )
273               zsatur   = MAX( rtrn, zsatur )
274               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
275               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
276               znusil2  = 0.225  * ( 1. + tsn(ji,jj,1,jp_tem) / 15.) + 0.775 * zsatur2
277
278               ! Two classes of BSi are considered : a labile fraction and
279               ! a more refractory one. The ratio between both fractions is
280               ! constant and specified in the namelist.
281               ! ----------------------------------------------------------
282               zdep     = MAX( hmld(ji,jj), heup(ji,jj) ) 
283               zdep     = MAX( 0., gdept_n(ji,jj,jk) - zdep )
284               ztem     = MAX( tsn(ji,jj,1,jp_tem), 0. )
285               zfactdep = xsilab * EXP(-( xsiremlab - xsirem ) * znusil2 * zdep / wsbio2 ) * ztem / ( ztem + 10. )
286               zsiremin = ( xsiremlab * zfactdep + xsirem * ( 1. - zfactdep ) ) * zstep * znusil
287               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
288               !
289               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
290               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
291               !
292            END DO
293         END DO
294      END DO
295
296      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
297         WRITE(charout, FMT="('rem4')")
298         CALL prt_ctl_trc_info(charout)
299         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
300       ENDIF
301
302      ! Update the arrays TRA which contain the biological sources and sinks
303      ! --------------------------------------------------------------------
304
305      DO jk = 1, jpkm1
306         tra(:,:,jk,jppo4) = tra(:,:,jk,jppo4) + zolimi (:,:,jk) + denitr(:,:,jk)
307         tra(:,:,jk,jpnh4) = tra(:,:,jk,jpnh4) + zolimi (:,:,jk) + denitr(:,:,jk)
308         tra(:,:,jk,jpno3) = tra(:,:,jk,jpno3) - denitr (:,:,jk) * rdenit
309         tra(:,:,jk,jpdoc) = tra(:,:,jk,jpdoc) - zolimi (:,:,jk) - denitr(:,:,jk)
310         tra(:,:,jk,jpoxy) = tra(:,:,jk,jpoxy) - zolimi (:,:,jk) * o2ut
311         tra(:,:,jk,jpdic) = tra(:,:,jk,jpdic) + zolimi (:,:,jk) + denitr(:,:,jk)
312         tra(:,:,jk,jptal) = tra(:,:,jk,jptal) + rno3 * ( zolimi(:,:,jk) + ( rdenit + 1.) * denitr(:,:,jk) )
313      END DO
314
315      IF( knt == nrdttrc ) THEN
316          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
317          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
318          !
319          IF( iom_use( "REMIN" ) )  THEN
320              zw3d(:,:,:) = zolimi(:,:,:) * tmask(:,:,:) * zfact !  Remineralisation rate
321              CALL iom_put( "REMIN"  , zw3d )
322          ENDIF
323          IF( iom_use( "DENIT" ) )  THEN
324              zw3d(:,:,:) = denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zfact ! Denitrification
325              CALL iom_put( "DENIT"  , zw3d )
326          ENDIF
327          !
328          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
329       ENDIF
330
331      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
332         WRITE(charout, FMT="('rem6')")
333         CALL prt_ctl_trc_info(charout)
334         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
335      ENDIF
336      !
337      CALL wrk_dealloc( jpi, jpj,      ztempbac                  )
338      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zolimi )
339      !
340      IF( nn_timing == 1 )  CALL timing_stop('p4z_rem')
341      !
342   END SUBROUTINE p4z_rem
343
344
345   SUBROUTINE p4z_rem_init
346      !!----------------------------------------------------------------------
347      !!                  ***  ROUTINE p4z_rem_init  ***
348      !!
349      !! ** Purpose :   Initialization of remineralization parameters
350      !!
351      !! ** Method  :   Read the nampisrem namelist and check the parameters
352      !!      called at the first timestep
353      !!
354      !! ** input   :   Namelist nampisrem
355      !!
356      !!----------------------------------------------------------------------
357      NAMELIST/nampisrem/ xremik, xremip, nitrif, xsirem, xsiremlab, xsilab,   &
358      &                   oxymin
359      INTEGER :: ios                 ! Local integer output status for namelist read
360
361      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
362      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
363901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
364
365      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
366      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
367902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
368      IF(lwm) WRITE ( numonp, nampisrem )
369
370      IF(lwp) THEN                         ! control print
371         WRITE(numout,*) ' '
372         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
373         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
374         WRITE(numout,*) '    remineralisation rate of POC              xremip    =', xremip
375         WRITE(numout,*) '    remineralization rate of DOC              xremik    =', xremik
376         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
377         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
378         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
379         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
380         WRITE(numout,*) '    halk saturation constant for anoxia       oxymin    =', oxymin
381      ENDIF
382      !
383      nitrfac (:,:,:) = 0._wp
384      denitr  (:,:,:) = 0._wp
385      denitnh4(:,:,:) = 0._wp
386      !
387   END SUBROUTINE p4z_rem_init
388
389
390   INTEGER FUNCTION p4z_rem_alloc()
391      !!----------------------------------------------------------------------
392      !!                     ***  ROUTINE p4z_rem_alloc  ***
393      !!----------------------------------------------------------------------
394      ALLOCATE( denitr(jpi,jpj,jpk), denitnh4(jpi,jpj,jpk), STAT=p4z_rem_alloc )
395      !
396      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
397      !
398   END FUNCTION p4z_rem_alloc
399
400#else
401   !!======================================================================
402   !!  Dummy module :                                   No PISCES bio-model
403   !!======================================================================
404CONTAINS
405   SUBROUTINE p4z_rem                    ! Empty routine
406   END SUBROUTINE p4z_rem
407#endif 
408
409   !!======================================================================
410END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.