New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 5215

Last change on this file since 5215 was 5215, checked in by nicolasmartin, 7 years ago

SVN keywords tag inconsistencies resolution

  • Property svn:keywords set to Id
File size: 21.5 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_sed        :  Compute loss of organic matter in the sediments
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE p4zrem          !  Remineralisation of organic matter
24   USE p4zsbc          !  External source of nutrients
25   USE p4zint          !  interpolation and computation of various fields
26   USE iom             !  I/O manager
27   USE prtctl_trc      !  print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sed   
33
34   !! * Module variables
35   REAL(wp) :: r1_rday                  !: inverse of rday
36
37   INTEGER ::  numnit 
38
39
40   !!* Substitution
41#  include "top_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE p4z_sed( kt, jnt )
50      !!---------------------------------------------------------------------
51      !!                     ***  ROUTINE p4z_sed  ***
52      !!
53      !! ** Purpose :   Compute loss of organic matter in the sediments. This
54      !!              is by no way a sediment model. The loss is simply
55      !!              computed to balance the inout from rivers and dust
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      !
60      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
61      INTEGER  ::   ji, jj, jk, ikt
62#if ! defined key_sed
63      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
64      REAL(wp) ::   zrivalk, zrivsil, zrivno3
65#endif
66      REAL(wp) ::  zwflux, zfminus, zfplus
67      REAL(wp) ::  zlim, zfact, zfactcal
68      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit
69      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep, zwstpoc
70      REAL(wp) ::  ztrfer, ztrpo4, zwdust, zlight
71      REAL(wp) ::  zrdenittot, zsdenittot, znitrpottot
72      !
73      CHARACTER (len=25) :: charout
74      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpdep, zsidep, zwork1, zwork2, zwork3, zwork4
75      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice, zbureff
76      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
77      REAL(wp), POINTER, DIMENSION(:,:,:) :: znitrpot, zirondep, zsoufer
78      !!---------------------------------------------------------------------
79      !
80      IF( nn_timing == 1 )  CALL timing_start('p4z_sed')
81      !
82      IF( kt == nittrc000 .AND. jnt == 1 )  THEN
83         r1_rday  = 1. / rday
84         IF( ln_check_mass .AND. lwp)  &
85           &  CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
86      ENDIF
87      !
88      ! Allocate temporary workspace
89      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
90      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
91      CALL wrk_alloc( jpi, jpj, jpk, znitrpot, zsoufer )
92
93      zdenit2d(:,:) = 0.e0
94      zbureff (:,:) = 0.e0
95      zwork1  (:,:) = 0.e0
96      zwork2  (:,:) = 0.e0
97      zwork3  (:,:) = 0.e0
98      zwork4  (:,:) = 0.e0
99
100      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
101      ! ----------------------------------------------------
102      IF( ln_ironice ) THEN 
103         !                                             
104         CALL wrk_alloc( jpi, jpj, zironice )
105         !                                             
106         DO jj = 1, jpj
107            DO ji = 1, jpi
108               zdep    = rfact2 / fse3t(ji,jj,1)
109               zwflux  = fmmflx(ji,jj) / 1000._wp
110               zfminus = MIN( 0._wp, -zwflux ) * trn(ji,jj,1,jpfer) * zdep
111               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
112               zironice(ji,jj) =  zfplus + zfminus
113            END DO
114         END DO
115         !
116         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + zironice(:,:) 
117         !
118         IF( lk_iomput .AND. jnt == nrdttrc .AND. iom_use( "Ironice" ) )   &
119            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
120         !
121         CALL wrk_dealloc( jpi, jpj, zironice )
122         !                                             
123      ENDIF
124
125      ! Add the external input of nutrients from dust deposition
126      ! ----------------------------------------------------------
127      IF( ln_dust ) THEN
128         !                                             
129         CALL wrk_alloc( jpi, jpj,      zpdep, zsidep )
130         CALL wrk_alloc( jpi, jpj, jpk, zirondep      )
131         !                                              ! Iron and Si deposition at the surface
132         IF( ln_solub ) THEN
133            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
134         ELSE
135            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
136         ENDIF
137         zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 28.1 
138         zpdep (:,:) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 31. / po4r 
139         !                                              ! Iron solubilization of particles in the water column
140         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
141         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
142         DO jk = 2, jpkm1
143            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -fsdept(:,:,jk) / 540. )
144         END DO
145         !                                              ! Iron solubilization of particles in the water column
146         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + zpdep   (:,:)
147         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + zsidep  (:,:)
148         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + zirondep(:,:,:) 
149         !
150         IF( lk_iomput ) THEN
151            IF( jnt == nrdttrc ) THEN
152                IF( iom_use( "Irondep" ) )   &
153                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
154                IF( iom_use( "pdust" ) )   &
155                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
156            ENDIF
157         ELSE                                   
158            IF( ln_diatrc )  &
159              &  trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1)
160         ENDIF
161         CALL wrk_dealloc( jpi, jpj,      zpdep, zsidep )
162         CALL wrk_dealloc( jpi, jpj, jpk, zirondep      )
163         !                                             
164      ENDIF
165     
166      ! Add the external input of nutrients from river
167      ! ----------------------------------------------------------
168      IF( ln_river ) THEN
169         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + rivdip(:,:) * rfact2
170         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + rivdin(:,:) * rfact2
171         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + rivdic(:,:) * 5.e-5 * rfact2
172         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + rivdsi(:,:) * rfact2
173         trn(:,:,1,jpdic) = trn(:,:,1,jpdic) + rivdic(:,:) * rfact2
174         trn(:,:,1,jptal) = trn(:,:,1,jptal) + ( rivalk(:,:) - rno3 * rivdin(:,:) ) * rfact2
175      ENDIF
176     
177      ! Add the external input of nutrients from nitrogen deposition
178      ! ----------------------------------------------------------
179      IF( ln_ndepo ) THEN
180         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + nitdep(:,:) * rfact2
181         trn(:,:,1,jptal) = trn(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
182      ENDIF
183
184      ! Add the external input of iron from sediment mobilization
185      ! ------------------------------------------------------
186      IF( ln_ironsed ) THEN
187         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
188         !
189         IF( lk_iomput .AND. jnt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
190            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
191      ENDIF
192
193      ! Add the external input of iron from hydrothermal vents
194      ! ------------------------------------------------------
195      IF( ln_hydrofe ) THEN
196         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
197         !
198         IF( lk_iomput .AND. jnt == nrdttrc .AND. iom_use( "HYDR" ) )   &
199            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
200      ENDIF
201
202      ! OA: Warning, the following part is necessary, especially with Kriest
203      ! to avoid CFL problems above the sediments
204      ! --------------------------------------------------------------------
205      DO jj = 1, jpj
206         DO ji = 1, jpi
207            ikt  = mbkt(ji,jj)
208            zdep = fse3t(ji,jj,ikt) / xstep
209            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
210            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
211            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
212         END DO
213      END DO
214
215#if ! defined key_sed
216      ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
217      ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
218      ! -------------------------------------------------------
219      DO jj = 1, jpj
220         DO ji = 1, jpi
221           IF( tmask(ji,jj,1) == 1 ) THEN
222              ikt = mbkt(ji,jj)
223# if defined key_kriest
224              zflx =    trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)    * 1E3 * 1E6 / 1E4
225# else
226              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
227                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
228#endif
229              zflx  = LOG10( MAX( 1E-3, zflx ) )
230              zo2   = LOG10( MAX( 10. , trn(ji,jj,ikt,jpoxy) * 1E6 ) )
231              zno3  = LOG10( MAX( 1.  , trn(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
232              zdep  = LOG10( fsdepw(ji,jj,ikt+1) )
233              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
234              &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
235              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
236              !
237              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
238                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
239              zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
240           ENDIF
241         END DO
242      END DO 
243
244      ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
245      ! First, the total loss is computed.
246      ! The factor for calcite comes from the alkalinity effect
247      ! -------------------------------------------------------------
248      DO jj = 1, jpj
249         DO ji = 1, jpi
250            IF( tmask(ji,jj,1) == 1 ) THEN
251               ikt = mbkt(ji,jj) 
252# if defined key_kriest
253               zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwscal (ji,jj)
254               zwork2(ji,jj) = trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)
255# else
256               zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
257               zwork2(ji,jj) = trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
258# endif
259               ! For calcite, burial efficiency is made a function of saturation
260               zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
261               zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
262               zwork3(ji,jj) = trn(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
263            ENDIF
264         END DO
265      END DO
266      zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
267      zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
268      zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
269#endif
270
271      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
272      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
273      ! ------------------------------------------------------
274#if ! defined key_sed
275      zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn )
276#endif
277
278      DO jj = 1, jpj
279         DO ji = 1, jpi
280            ikt  = mbkt(ji,jj)
281            zdep = xstep / fse3t(ji,jj,ikt)
282            zws4 = zwsbio4(ji,jj) * zdep
283            zwsc = zwscal (ji,jj) * zdep
284# if defined key_kriest
285            zsiloss = trn(ji,jj,ikt,jpgsi) * zws4
286# else
287            zsiloss = trn(ji,jj,ikt,jpgsi) * zwsc
288# endif
289            zcaloss = trn(ji,jj,ikt,jpcal) * zwsc
290            !
291            trn(ji,jj,ikt,jpgsi) = trn(ji,jj,ikt,jpgsi) - zsiloss
292            trn(ji,jj,ikt,jpcal) = trn(ji,jj,ikt,jpcal) - zcaloss
293#if ! defined key_sed
294            trn(ji,jj,ikt,jpsil) = trn(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
295            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
296            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
297            zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
298            trn(ji,jj,ikt,jptal) =  trn(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
299            trn(ji,jj,ikt,jpdic) =  trn(ji,jj,ikt,jpdic) + zcaloss * zrivalk
300#endif
301         END DO
302      END DO
303
304      DO jj = 1, jpj
305         DO ji = 1, jpi
306            ikt     = mbkt(ji,jj)
307            zdep    = xstep / fse3t(ji,jj,ikt)
308            zws4 = zwsbio4(ji,jj) * zdep
309            zws3 = zwsbio3(ji,jj) * zdep
310            zrivno3 = 1. - zbureff(ji,jj)
311# if ! defined key_kriest
312            trn(ji,jj,ikt,jpgoc) = trn(ji,jj,ikt,jpgoc) - trn(ji,jj,ikt,jpgoc) * zws4
313            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
314            trn(ji,jj,ikt,jpbfe) = trn(ji,jj,ikt,jpbfe) - trn(ji,jj,ikt,jpbfe) * zws4
315            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
316            zwstpoc              =  trn(ji,jj,ikt,jpgoc) * zws4 + trn(ji,jj,ikt,jppoc) * zws3 
317# else
318            trn(ji,jj,ikt,jpnum) = trn(ji,jj,ikt,jpnum) - trn(ji,jj,ikt,jpnum) * zws4
319            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
320            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
321            zwstpoc = trn(ji,jj,ikt,jppoc) * zws3 
322# endif
323
324#if ! defined key_sed
325            ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification
326            ! in the sediments and just above the sediments. Not very clever, but simpliest option.
327            zpdenit  = MIN( 0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
328            z1pdenit = zwstpoc * zrivno3 - zpdenit
329            zolimit = MIN( ( trn(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
330            zdenitt = MIN(  0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) )
331            trn(ji,jj,ikt,jpdoc) = trn(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt
332            trn(ji,jj,ikt,jppo4) = trn(ji,jj,ikt,jppo4) + zpdenit + zolimit + zdenitt
333            trn(ji,jj,ikt,jpnh4) = trn(ji,jj,ikt,jpnh4) + zpdenit + zolimit + zdenitt
334            trn(ji,jj,ikt,jpno3) = trn(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt)
335            trn(ji,jj,ikt,jpoxy) = trn(ji,jj,ikt,jpoxy) - zolimit * o2ut
336            trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * (zpdenit + zdenitt) )
337            trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt
338            zwork4(ji,jj) = rdenit * zpdenit * fse3t(ji,jj,ikt)
339#endif
340         END DO
341      END DO
342
343      ! Nitrogen fixation process
344      ! Small source iron from particulate inorganic iron
345      !-----------------------------------
346      DO jk = 1, jpkm1
347         DO jj = 1, jpj
348            DO ji = 1, jpi
349               !                      ! Potential nitrogen fixation dependant on temperature and iron
350               zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
351               IF( zlim <= 0.2 )   zlim = 0.01
352#if defined key_degrad
353               zfact = zlim * rfact2 * facvol(ji,jj,jk)
354#else
355               zfact = zlim * rfact2
356#endif
357               ztrfer = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
358               ztrpo4 = trn  (ji,jj,jk,jppo4) / ( concnnh4   + trn  (ji,jj,jk,jppo4) ) 
359               zlight =  ( 1.- EXP( -etot(ji,jj,jk) / diazolight ) ) 
360               znitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday )   &
361                 &         *  zfact * MIN( ztrfer, ztrpo4 ) * zlight
362               zsoufer(ji,jj,jk) = zlight * 2E-11 / (2E-11 + biron(ji,jj,jk))
363            END DO
364         END DO
365      END DO
366
367      ! Nitrogen change due to nitrogen fixation
368      ! ----------------------------------------
369      DO jk = 1, jpkm1
370         DO jj = 1, jpj
371            DO ji = 1, jpi
372               zfact = znitrpot(ji,jj,jk) * nitrfix
373               trn(ji,jj,jk,jpnh4) = trn(ji,jj,jk,jpnh4) +             zfact
374               trn(ji,jj,jk,jptal) = trn(ji,jj,jk,jptal) + rno3      * zfact
375               trn(ji,jj,jk,jpoxy) = trn(ji,jj,jk,jpoxy) + o2nit     * zfact 
376               trn(ji,jj,jk,jppo4) = trn(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trn(ji,jj,jk,jppo4) ) &
377               &                     * 0.002 * trn(ji,jj,jk,jpdoc) * rfact2 / rday
378               trn(ji,jj,jk,jpfer) = trn(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
379           END DO
380         END DO
381      END DO
382
383      ! Global budget of N SMS : denitrification in the water column and in the sediment
384      !                          nitrogen fixation by the diazotrophs
385      ! --------------------------------------------------------------------------------
386      zrdenittot   = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
387      zsdenittot   = glob_sum ( zwork4(:,:)   * e1e2t(:,:) )
388      znitrpottot  = glob_sum ( znitrpot(:,:,:) * nitrfix              * cvol(:,:,:) )
389      zfact = 1.e+3 * rfact2r * rno3 * 14. / 1.e12 * ryyss   ! conversion molC/l/kt ----> TgN/m3/year
390      !
391      IF( ln_check_mass .AND. ( kt == nitend .AND. jnt == nrdttrc ) .AND. ( lwp )  )  &
392         &  WRITE(numnit,9100) ndastp, znitrpottot * zfact  , &
393         &                             zrdenittot  * zfact  , &
394         &                             zsdenittot  * zfact
395      !
396      IF( lk_iomput ) THEN
397         IF( jnt == nrdttrc ) THEN
398            zfact = 1.e+3 * rfact2r * rno3  !  conversion from molC/l/kt  to molN/m3/s
399            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix"  , znitrpot(:,:,:) * nitrfix * zfact * tmask(:,:,:) )  ! nitrogen fixation
400            IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", zwork4(:,:) * zfact * tmask(:,:,1) )  ! Nitrate reduction in the sediments
401            IF( iom_use("tnfix"  ) ) CALL iom_put( "tnfix"  , znitrpottot * zfact  )               ! Global  nitrogen fixation
402            IF( iom_use("tdenit" ) ) CALL iom_put( "tdenit" , zrdenittot  * zfact  )               ! Total denitrification
403            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
404               zwork1(:,:) = 0.
405               DO jk = 1, jpkm1
406                 zwork1(:,:) = zwork1(:,:) + znitrpot(:,:,jk) * nitrfix * zfact * fse3t(:,:,jk) * tmask(:,:,jk)
407               ENDDO
408               CALL iom_put( "INTNFIX" , zwork1 ) 
409            ENDIF
410         ENDIF
411      ELSE
412         IF( ln_diatrc )  &
413            &  trc2d(:,:,jp_pcs0_2d + 12) = znitrpot(:,:,1) * nitrfix * rno3 * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1)
414      ENDIF
415      !
416      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
417         WRITE(charout, fmt="('sed ')")
418         CALL prt_ctl_trc_info(charout)
419         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
420      ENDIF
421      !
422      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
423      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
424      CALL wrk_dealloc( jpi, jpj, jpk, znitrpot, zsoufer )
425      !
426      IF( nn_timing == 1 )  CALL timing_stop('p4z_sed')
427      !
428 9100  FORMAT(i8,3f10.5)
429      !
430   END SUBROUTINE p4z_sed
431
432#else
433   !!======================================================================
434   !!  Dummy module :                                   No PISCES bio-model
435   !!======================================================================
436CONTAINS
437   SUBROUTINE p4z_sed                         ! Empty routine
438   END SUBROUTINE p4z_sed
439#endif 
440
441   !!======================================================================
442END MODULE  p4zsed
Note: See TracBrowser for help on using the repository browser.