source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zsink.F90 @ 3685

Last change on this file since 3685 was 3685, checked in by cetlod, 9 years ago

trunk: minor bug correction in p4zsink

  • Property svn:keywords set to Id
File size: 33.1 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
13   !!   p4z_sink_init  :  Unitialisation of sinking speed parameters
14   !!   p4z_sink_alloc :  Allocate sinking speed variables
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_sink         ! called in p4zbio.F90
27   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
28   PUBLIC   p4z_sink_alloc
29
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio3   !: POC sinking speed
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio4   !: GOC sinking speed
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wscal    !: Calcite and BSi sinking speeds
33
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
35   !                                                          !  (different meanings depending on the parameterization)
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
38#if ! defined key_kriest
39   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
40#endif
41
42   INTEGER  :: iksed  = 10
43
44#if  defined key_kriest
45   REAL(wp) ::  xkr_sfact    = 250.     !: Sinking factor
46   REAL(wp) ::  xkr_stick    = 0.2      !: Stickiness
47   REAL(wp) ::  xkr_nnano    = 2.337    !: Nbr of cell in nano size class
48   REAL(wp) ::  xkr_ndiat    = 3.718    !: Nbr of cell in diatoms size class
49   REAL(wp) ::  xkr_nmeso    = 7.147    !: Nbr of cell in mesozoo  size class
50   REAL(wp) ::  xkr_naggr    = 9.877    !: Nbr of cell in aggregates  size class
51
52   REAL(wp) ::  xkr_frac 
53
54   REAL(wp), PUBLIC ::  xkr_dnano       !: Size of particles in nano pool
55   REAL(wp), PUBLIC ::  xkr_ddiat       !: Size of particles in diatoms pool
56   REAL(wp), PUBLIC ::  xkr_dmeso       !: Size of particles in mesozoo pool
57   REAL(wp), PUBLIC ::  xkr_daggr       !: Size of particles in aggregates pool
58   REAL(wp), PUBLIC ::  xkr_wsbio_min   !: min vertical particle speed
59   REAL(wp), PUBLIC ::  xkr_wsbio_max   !: max vertical particle speed
60
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) ::   xnumm   !:  maximum number of particles in aggregates
62#endif
63
64   !!* Substitution
65#  include "top_substitute.h90"
66   !!----------------------------------------------------------------------
67   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
68   !! $Id$
69   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71CONTAINS
72
73#if defined key_kriest
74   !!----------------------------------------------------------------------
75   !!   'key_kriest'                                                    ???
76   !!----------------------------------------------------------------------
77
78   SUBROUTINE p4z_sink ( kt, jnt )
79      !!---------------------------------------------------------------------
80      !!                ***  ROUTINE p4z_sink  ***
81      !!
82      !! ** Purpose :   Compute vertical flux of particulate matter due to
83      !!              gravitational sinking - Kriest parameterization
84      !!
85      !! ** Method  : - ???
86      !!---------------------------------------------------------------------
87      !
88      INTEGER, INTENT(in) :: kt, jnt
89      !
90      INTEGER  :: ji, jj, jk
91      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zaggsi, zaggsh
92      REAL(wp) :: zagg , zaggdoc, znumdoc
93      REAL(wp) :: znum , zeps, zfm, zgm, zsm
94      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
95      REAL(wp) :: zval1, zval2, zval3, zval4
96      REAL(wp) :: zrfact2
97      INTEGER  :: ik1
98      CHARACTER (len=25) :: charout
99      REAL(wp), POINTER, DIMENSION(:,:,:) :: znum3d 
100      !!---------------------------------------------------------------------
101      !
102      IF( nn_timing == 1 )  CALL timing_start('p4z_sink')
103      !
104      CALL wrk_alloc( jpi, jpj, jpk, znum3d )
105      !
106      !     Initialisation of variables used to compute Sinking Speed
107      !     ---------------------------------------------------------
108
109      znum3d(:,:,:) = 0.e0
110      zval1 = 1. + xkr_zeta
111      zval2 = 1. + xkr_zeta + xkr_eta
112      zval3 = 1. + xkr_eta
113
114      !     Computation of the vertical sinking speed : Kriest et Evans, 2000
115      !     -----------------------------------------------------------------
116
117      DO jk = 1, jpkm1
118         DO jj = 1, jpj
119            DO ji = 1, jpi
120               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
121                  znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
122                  ! -------------- To avoid sinking speed over 50 m/day -------
123                  znum  = MIN( xnumm(jk), znum )
124                  znum  = MAX( 1.1      , znum )
125                  znum3d(ji,jj,jk) = znum
126                  !------------------------------------------------------------
127                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
128                  zfm   = xkr_frac**( 1. - zeps )
129                  zgm   = xkr_frac**( zval1 - zeps )
130                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
131                  zdiv1 = zeps - zval3
132                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
133                     &             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
134                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
135                     &             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
136                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
137               ENDIF
138            END DO
139         END DO
140      END DO
141
142      wscal(:,:,:) = MAX( wsbio3(:,:,:), 50._wp )
143
144      !   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
145      !   -----------------------------------------
146
147      sinking (:,:,:) = 0.e0
148      sinking2(:,:,:) = 0.e0
149      sinkcal (:,:,:) = 0.e0
150      sinkfer (:,:,:) = 0.e0
151      sinksil (:,:,:) = 0.e0
152
153     !   Compute the sedimentation term using p4zsink2 for all the sinking particles
154     !   -----------------------------------------------------
155
156      CALL p4z_sink2( wsbio3, sinking , jppoc )
157      CALL p4z_sink2( wsbio4, sinking2, jpnum )
158      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
159      CALL p4z_sink2( wscal , sinksil , jpgsi )
160      CALL p4z_sink2( wscal , sinkcal , jpcal )
161
162     !  Exchange between organic matter compartments due to coagulation/disaggregation
163     !  ---------------------------------------------------
164
165      zval1 = 1. + xkr_zeta
166      zval2 = 1. + xkr_eta
167      zval3 = 3. + xkr_eta
168      zval4 = 4. + xkr_eta
169
170      DO jk = 1,jpkm1
171         DO jj = 1,jpj
172            DO ji = 1,jpi
173               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
174
175                  znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp
176                  !-------------- To avoid sinking speed over 50 m/day -------
177                  znum  = min(xnumm(jk),znum)
178                  znum  = MAX( 1.1,znum)
179                  !------------------------------------------------------------
180                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
181                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
182                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
183                  zdiv2 = zeps - 2.
184                  zdiv3 = zeps - 3.
185                  zdiv4 = zeps - zval2
186                  zdiv5 = 2.* zeps - zval4
187                  zfm   = xkr_frac**( 1.- zeps )
188                  zsm   = xkr_frac**xkr_eta
189
190                  !    Part I : Coagulation dependant on turbulence
191                  !    ----------------------------------------------
192
193                  zagg1 = ( 0.163 * trn(ji,jj,jk,jpnum)**2               &
194                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
195                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
196                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
197                     &            * (zeps-1.)**2/(zdiv2*zdiv3)) 
198                  zagg2 =  2*0.163*trn(ji,jj,jk,jpnum)**2*zfm*                       &
199                     &                   ((xkr_mass_max**3+3.*(xkr_mass_max**2          &
200                     &                    *xkr_mass_min*(zeps-1.)/zdiv2                 &
201                     &                    +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
202                     &                    +xkr_mass_min**3*(zeps-1)/zdiv1)                  &
203                     &                    -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/           &
204                     &                    (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))   
205
206                  zagg3 =  0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3 
207                 
208                 !    Aggregation of small into large particles
209                 !    Part II : Differential settling
210                 !    ----------------------------------------------
211
212                  zagg4 =  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2*                       &
213                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
214                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
215                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
216                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
217                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )   
218
219                  zagg5 =   2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2                         &
220                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
221                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
222                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
223                     &                 /zdiv) 
224                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
225
226                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
227
228                  !     Aggregation of DOC to small particles
229                  !     --------------------------------------
230
231                  zaggdoc = ( 0.4 * trn(ji,jj,jk,jpdoc)               &
232                     &        + 1018.  * trn(ji,jj,jk,jppoc)  ) * xstep    &
233                     &        * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
234
235# if defined key_degrad
236                   zagg1   = zagg1   * facvol(ji,jj,jk)                 
237                   zagg2   = zagg2   * facvol(ji,jj,jk)                 
238                   zagg3   = zagg3   * facvol(ji,jj,jk)                 
239                   zagg4   = zagg4   * facvol(ji,jj,jk)                 
240                   zagg5   = zagg5   * facvol(ji,jj,jk)                 
241                   zaggdoc = zaggdoc * facvol(ji,jj,jk)                 
242# endif
243                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
244                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
245                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
246                  !
247                  znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
248                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc
249                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zaggdoc * znumdoc - zagg
250                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc
251
252               ENDIF
253            END DO
254         END DO
255      END DO
256
257      IF( ln_diatrc ) THEN
258         !
259         ik1 = iksed + 1
260         zrfact2 = 1.e3 * rfact2r
261         IF( jnt == nrdttrc ) THEN
262           CALL iom_put( "POCFlx"  , sinking (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! POC export
263           CALL iom_put( "NumFlx"  , sinking2 (:,:,:)     * zrfact2 * tmask(:,:,:) )  ! Num export
264           CALL iom_put( "SiFlx"   , sinksil (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Silica export
265           CALL iom_put( "CaCO3Flx", sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Calcite export
266           CALL iom_put( "xnum"    , znum3d  (:,:,:)                * tmask(:,:,:) )  ! Number of particles in aggregats
267           CALL iom_put( "W1"      , wsbio3  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of POC
268           CALL iom_put( "W2"      , wsbio4  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of aggregats
269           CALL iom_put( "PMO"     , sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! POC export at 100m
270           CALL iom_put( "PMO2"    , sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! Num export at 100m
271           CALL iom_put( "ExpFe1"  , sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! Export of iron at 100m
272           CALL iom_put( "ExpSi"   , sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! export of silica at 100m
273           CALL iom_put( "ExpCaCO3", sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1) )  ! export of calcite at 100m
274         ENDIF
275# if ! defined key_iomput
276         trc2d(:,:  ,jp_pcs0_2d + 4)  = sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1)
277         trc2d(:,:  ,jp_pcs0_2d + 5)  = sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1)
278         trc2d(:,:  ,jp_pcs0_2d + 6)  = sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1)
279         trc2d(:,:  ,jp_pcs0_2d + 7)  = sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1)
280         trc2d(:,:  ,jp_pcs0_2d + 8)  = sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1)
281         trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)      * zrfact2 * tmask(:,:,:)
282         trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)      * zrfact2 * tmask(:,:,:)
283         trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)      * zrfact2 * tmask(:,:,:)
284         trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:)
285         trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)                * tmask(:,:,:)
286         trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)                * tmask(:,:,:)
287         trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)                * tmask(:,:,:)
288# endif
289        !
290      ENDIF
291      !
292      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
293         WRITE(charout, FMT="('sink')")
294         CALL prt_ctl_trc_info(charout)
295         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
296      ENDIF
297      !
298      CALL wrk_dealloc( jpi, jpj, jpk, znum3d )
299      !
300      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink')
301      !
302   END SUBROUTINE p4z_sink
303
304
305   SUBROUTINE p4z_sink_init
306      !!----------------------------------------------------------------------
307      !!                  ***  ROUTINE p4z_sink_init  ***
308      !!
309      !! ** Purpose :   Initialization of sinking parameters
310      !!                Kriest parameterization only
311      !!
312      !! ** Method  :   Read the nampiskrs namelist and check the parameters
313      !!      called at the first timestep
314      !!
315      !! ** input   :   Namelist nampiskrs
316      !!----------------------------------------------------------------------
317      INTEGER  ::   jk, jn, kiter
318      REAL(wp) ::   znum, zdiv
319      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
320      REAL(wp) ::   zmin, zmax, zl, zr, xacc
321      !
322      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
323         &                xkr_nnano, xkr_ndiat, xkr_nmeso, xkr_naggr
324      !!----------------------------------------------------------------------
325      !
326      IF( nn_timing == 1 )  CALL timing_start('p4z_sink_init')
327      !
328      REWIND( numnatp )                     ! read nampiskrs
329      READ  ( numnatp, nampiskrs )
330
331      IF(lwp) THEN
332         WRITE(numout,*)
333         WRITE(numout,*) ' Namelist : nampiskrs'
334         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
335         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
336         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
337         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
338         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
339         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
340      ENDIF
341
342
343      ! max and min vertical particle speed
344      xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
345      xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
346      WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
347
348      !
349      !    effect of the sizes of the different living pools on particle numbers
350      !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
351      !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
352      !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
353      !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
354      !    doc aggregates = 1um
355      ! ----------------------------------------------------------
356
357      xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
358      xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
359      xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
360      xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
361
362      !!---------------------------------------------------------------------
363      !!    'key_kriest'                                                  ???
364      !!---------------------------------------------------------------------
365      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
366      !  Search of the maximum number of particles in aggregates for each k-level.
367      !  Bissection Method
368      !--------------------------------------------------------------------
369      WRITE(numout,*)
370      WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
371
372      xacc     =  0.001_wp
373      kiter    = 50
374      zmin     =  1.10_wp
375      zmax     = xkr_mass_max / xkr_mass_min
376      xkr_frac = zmax
377
378      DO jk = 1,jpk
379         zl = zmin
380         zr = zmax
381         wmax = 0.5 * fse3t(1,1,jk) * rday / rfact2
382         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
383         znum = zl - 1.
384         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
385            & - ( xkr_wsbio_max * xkr_eta * znum * &
386            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
387            & - wmax
388
389         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
390         znum = zr - 1.
391         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
392            & - ( xkr_wsbio_max * xkr_eta * znum * &
393            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
394            & - wmax
395iflag:   DO jn = 1, kiter
396            IF    ( zwl == 0._wp ) THEN   ;   znummax = zl
397            ELSEIF( zwr == 0._wp ) THEN   ;   znummax = zr
398            ELSE
399               znummax = ( zr + zl ) / 2.
400               zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
401               znum = znummax - 1.
402               zws =  xkr_wsbio_min * xkr_zeta / zdiv &
403                  & - ( xkr_wsbio_max * xkr_eta * znum * &
404                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
405                  & - wmax
406               IF( zws * zwl < 0. ) THEN   ;   zr = znummax
407               ELSE                        ;   zl = znummax
408               ENDIF
409               zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
410               znum = zl - 1.
411               zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
412                  & - ( xkr_wsbio_max * xkr_eta * znum * &
413                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
414                  & - wmax
415
416               zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
417               znum = zr - 1.
418               zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
419                  & - ( xkr_wsbio_max * xkr_eta * znum * &
420                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
421                  & - wmax
422               !
423               IF ( ABS ( zws )  <= xacc ) EXIT iflag
424               !
425            ENDIF
426            !
427         END DO iflag
428
429         xnumm(jk) = znummax
430         WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
431         !
432      END DO
433      !
434      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink_init')
435      !
436  END SUBROUTINE p4z_sink_init
437
438#else
439
440   SUBROUTINE p4z_sink ( kt, jnt )
441      !!---------------------------------------------------------------------
442      !!                     ***  ROUTINE p4z_sink  ***
443      !!
444      !! ** Purpose :   Compute vertical flux of particulate matter due to
445      !!                gravitational sinking
446      !!
447      !! ** Method  : - ???
448      !!---------------------------------------------------------------------
449      INTEGER, INTENT(in) :: kt, jnt
450      INTEGER  ::   ji, jj, jk
451      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
452      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2, zaggdoc3
453      REAL(wp) ::   zfact, zwsmax, zmax, zstep
454      REAL(wp) ::   zrfact2
455      INTEGER  ::   ik1
456      CHARACTER (len=25) :: charout
457      !!---------------------------------------------------------------------
458      !
459      IF( nn_timing == 1 )  CALL timing_start('p4z_sink')
460      !
461      !    Sinking speeds of detritus is increased with depth as shown
462      !    by data and from the coagulation theory
463      !    -----------------------------------------------------------
464      DO jk = 1, jpkm1
465         DO jj = 1, jpj
466            DO ji = 1,jpi
467      !         zmax  = MAX( heup(ji,jj), hmld(ji,jj) )
468      !         zfact = MAX( 0., fsdepw(ji,jj,jk+1) - zmax ) / 5000._wp
469               zmax = hmld(ji,jj)
470               zfact = MAX( 0., fsdepw(ji,jj,jk+1) - zmax ) / 4000._wp
471               wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact
472            END DO
473         END DO
474      END DO
475
476      ! limit the values of the sinking speeds to avoid numerical instabilities 
477      wsbio3(:,:,:) = wsbio
478      !
479      ! OA Below, this is garbage. the ideal would be to find a time-splitting
480      ! OA algorithm that does not increase the computing cost by too much
481      ! OA In ROMS, I have included a time-splitting procedure. But it is
482      ! OA too expensive as the loop is computed globally. Thus, a small e3t
483      ! OA at one place determines the number of subtimesteps globally
484      ! OA AWFULLY EXPENSIVE !! Not able to find a better approach. Damned !!
485
486      DO jk = 1,jpkm1
487         DO jj = 1, jpj
488            DO ji = 1, jpi
489               zwsmax = 0.8 * fse3t(ji,jj,jk) / xstep
490               wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax )
491               wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax )
492            END DO
493         END DO
494      END DO
495
496      wscal(:,:,:) = wsbio4(:,:,:)
497
498      !  Initializa to zero all the sinking arrays
499      !   -----------------------------------------
500
501      sinking (:,:,:) = 0.e0
502      sinking2(:,:,:) = 0.e0
503      sinkcal (:,:,:) = 0.e0
504      sinkfer (:,:,:) = 0.e0
505      sinksil (:,:,:) = 0.e0
506      sinkfer2(:,:,:) = 0.e0
507
508      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
509      !   -----------------------------------------------------
510
511      CALL p4z_sink2( wsbio3, sinking , jppoc )
512      CALL p4z_sink2( wsbio3, sinkfer , jpsfe )
513      CALL p4z_sink2( wsbio4, sinking2, jpgoc )
514      CALL p4z_sink2( wsbio4, sinkfer2, jpbfe )
515      CALL p4z_sink2( wsbio4, sinksil , jpgsi )
516      CALL p4z_sink2( wscal , sinkcal , jpcal )
517
518      !  Exchange between organic matter compartments due to coagulation/disaggregation
519      !  ---------------------------------------------------
520
521      DO jk = 1, jpkm1
522         DO jj = 1, jpj
523            DO ji = 1, jpi
524               !
525               zstep = xstep 
526# if defined key_degrad
527               zstep = zstep * facvol(ji,jj,jk)
528# endif
529               zfact = zstep * xdiss(ji,jj,jk)
530               !  Part I : Coagulation dependent on turbulence
531               zagg1 = 354.  * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
532               zagg2 = 4452. * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
533
534               ! Part II : Differential settling
535
536               !  Aggregation of small into large particles
537               zagg3 =  4.7 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc)
538               zagg4 =  0.4 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc)
539
540               zagg   = zagg1 + zagg2 + zagg3 + zagg4
541               zaggfe = zagg * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn )
542
543               ! Aggregation of DOC to small particles
544               zaggdoc  = ( 0.83 * trn(ji,jj,jk,jpdoc) + 271. * trn(ji,jj,jk,jppoc) ) * zfact * trn(ji,jj,jk,jpdoc)
545               zaggdoc2 = 1.07e4 * zfact * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpdoc)
546               zaggdoc3 =   0.02 * ( 16706. * trn(ji,jj,jk,jppoc) + 231. * trn(ji,jj,jk,jpdoc) ) * zstep * trn(ji,jj,jk,jpdoc)
547
548               !  Update the trends
549               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc + zaggdoc3
550               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2
551               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
552               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
553               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2 - zaggdoc3
554               !
555            END DO
556         END DO
557      END DO
558
559      IF( ln_diatrc ) THEN
560         zrfact2 = 1.e3 * rfact2r
561         ik1  = iksed + 1
562         IF( lk_iomput ) THEN
563           IF( jnt == nrdttrc ) THEN
564              CALL iom_put( "EPC100"  , ( sinking(:,:,ik1) + sinking2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of carbon at 100m
565              CALL iom_put( "EPFE100" , ( sinkfer(:,:,ik1) + sinkfer2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of iron at 100m
566              CALL iom_put( "EPCAL100",   sinkcal(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of calcite  at 100m
567              CALL iom_put( "EPSI100" ,   sinksil(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of biogenic silica at 100m
568           ENDIF
569         ELSE
570           trc2d(:,:,jp_pcs0_2d + 4) = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1)
571           trc2d(:,:,jp_pcs0_2d + 5) = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1)
572           trc2d(:,:,jp_pcs0_2d + 6) = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1)
573           trc2d(:,:,jp_pcs0_2d + 7) = sinkfer2(:,:,ik1) * zrfact2 * tmask(:,:,1)
574           trc2d(:,:,jp_pcs0_2d + 8) = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1)
575           trc2d(:,:,jp_pcs0_2d + 9) = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1)
576         ENDIF
577      ENDIF
578      !
579      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
580         WRITE(charout, FMT="('sink')")
581         CALL prt_ctl_trc_info(charout)
582         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
583      ENDIF
584      !
585      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink')
586      !
587   END SUBROUTINE p4z_sink
588
589   SUBROUTINE p4z_sink_init
590      !!----------------------------------------------------------------------
591      !!                  ***  ROUTINE p4z_sink_init  ***
592      !!----------------------------------------------------------------------
593   END SUBROUTINE p4z_sink_init
594
595#endif
596
597
598
599   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra )
600      !!---------------------------------------------------------------------
601      !!                     ***  ROUTINE p4z_sink2  ***
602      !!
603      !! ** Purpose :   Compute the sedimentation terms for the various sinking
604      !!     particles. The scheme used to compute the trends is based
605      !!     on MUSCL.
606      !!
607      !! ** Method  : - this ROUTINE compute not exactly the advection but the
608      !!      transport term, i.e.  div(u*tra).
609      !!---------------------------------------------------------------------
610      !
611      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
612      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
613      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
614      !!
615      INTEGER  ::   ji, jj, jk, jn
616      REAL(wp) ::   zigma,zew,zign, zflx, zstep
617      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztraz, zakz, zwsink2, ztrb 
618      !!---------------------------------------------------------------------
619      !
620      IF( nn_timing == 1 )  CALL timing_start('p4z_sink2')
621      !
622      ! Allocate temporary workspace
623      CALL wrk_alloc( jpi, jpj, jpk, ztraz, zakz, zwsink2, ztrb )
624
625      zstep = rfact2 / 2.
626
627      ztraz(:,:,:) = 0.e0
628      zakz (:,:,:) = 0.e0
629      ztrb (:,:,:) = trn(:,:,:,jp_tra)
630
631      DO jk = 1, jpkm1
632         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
633      END DO
634      zwsink2(:,:,1) = 0.e0
635      IF( lk_degrad ) THEN
636         zwsink2(:,:,:) = zwsink2(:,:,:) * facvol(:,:,:)
637      ENDIF
638
639
640      ! Vertical advective flux
641      DO jn = 1, 2
642         !  first guess of the slopes interior values
643         DO jk = 2, jpkm1
644            ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk)
645         END DO
646         ztraz(:,:,1  ) = 0.0
647         ztraz(:,:,jpk) = 0.0
648
649         ! slopes
650         DO jk = 2, jpkm1
651            DO jj = 1,jpj
652               DO ji = 1, jpi
653                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
654                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
655               END DO
656            END DO
657         END DO
658         
659         ! Slopes limitation
660         DO jk = 2, jpkm1
661            DO jj = 1, jpj
662               DO ji = 1, jpi
663                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
664                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
665               END DO
666            END DO
667         END DO
668         
669         ! vertical advective flux
670         DO jk = 1, jpkm1
671            DO jj = 1, jpj     
672               DO ji = 1, jpi   
673                  zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1)
674                  zew   = zwsink2(ji,jj,jk+1)
675                  psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
676               END DO
677            END DO
678         END DO
679         !
680         ! Boundary conditions
681         psinkflx(:,:,1  ) = 0.e0
682         psinkflx(:,:,jpk) = 0.e0
683         
684         DO jk=1,jpkm1
685            DO jj = 1,jpj
686               DO ji = 1, jpi
687                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
688                  trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx
689               END DO
690            END DO
691         END DO
692
693      ENDDO
694
695      DO jk=1,jpkm1
696         DO jj = 1,jpj
697            DO ji = 1, jpi
698               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
699               ztrb(ji,jj,jk) = ztrb(ji,jj,jk) + 2. * zflx
700            END DO
701         END DO
702      END DO
703
704      trn     (:,:,:,jp_tra) = ztrb(:,:,:)
705      psinkflx(:,:,:)        = 2. * psinkflx(:,:,:)
706      !
707      CALL wrk_dealloc( jpi, jpj, jpk, ztraz, zakz, zwsink2, ztrb )
708      !
709      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink2')
710      !
711   END SUBROUTINE p4z_sink2
712
713
714   INTEGER FUNCTION p4z_sink_alloc()
715      !!----------------------------------------------------------------------
716      !!                     ***  ROUTINE p4z_sink_alloc  ***
717      !!----------------------------------------------------------------------
718      ALLOCATE( wsbio3 (jpi,jpj,jpk) , wsbio4  (jpi,jpj,jpk) , wscal(jpi,jpj,jpk) ,     &
719         &      sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                      ,     &               
720         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                      ,     &               
721#if defined key_kriest
722         &      xnumm(jpk)                                                        ,     &               
723#else
724         &      sinkfer2(jpi,jpj,jpk)                                             ,     &               
725#endif
726         &      sinkfer(jpi,jpj,jpk)                                              , STAT=p4z_sink_alloc )               
727         !
728      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
729      !
730   END FUNCTION p4z_sink_alloc
731   
732#else
733   !!======================================================================
734   !!  Dummy module :                                   No PISCES bio-model
735   !!======================================================================
736CONTAINS
737   SUBROUTINE p4z_sink                    ! Empty routine
738   END SUBROUTINE p4z_sink
739#endif 
740
741   !!======================================================================
742END MODULE  p4zsink
Note: See TracBrowser for help on using the repository browser.