| 1 | ;+ |
|---|
| 2 | ; |
|---|
| 3 | ; @file_comments |
|---|
| 4 | ; Allows to pass from a 2d level array to a 2d depth array corresponding to these levels |
|---|
| 5 | ; |
|---|
| 6 | ; @categories |
|---|
| 7 | ; Without loop |
|---|
| 8 | ; |
|---|
| 9 | ; @param TAB {in}{required}{type=2d array} |
|---|
| 10 | ; 2d level array of sill levels (or a structure respecting <pro>litchamp</pro> criterions) |
|---|
| 11 | ; |
|---|
| 12 | ; @keyword NOMASK |
|---|
| 13 | ; To do not mask land points. |
|---|
| 14 | ; |
|---|
| 15 | ; @returns |
|---|
| 16 | ; 2d array containing depths |
|---|
| 17 | ; |
|---|
| 18 | ; @uses |
|---|
| 19 | ; common.pro |
|---|
| 20 | ; |
|---|
| 21 | ; @history |
|---|
| 22 | ; Sebastien Masson (smasson\@lodyc.jussieu.fr) |
|---|
| 23 | ; 17/6/1999 |
|---|
| 24 | ; 14/6/2000 accepte !values.f_nan |
|---|
| 25 | ; |
|---|
| 26 | ; @version |
|---|
| 27 | ; $Id$ |
|---|
| 28 | ; |
|---|
| 29 | ;- |
|---|
| 30 | FUNCTION level2depth, tab, NOMASK=nomask |
|---|
| 31 | ; |
|---|
| 32 | compile_opt idl2, strictarrsubs |
|---|
| 33 | ; |
|---|
| 34 | tempsun = systime(1) ; To key_performance |
|---|
| 35 | @common |
|---|
| 36 | ;------------------------------------------------------------ |
|---|
| 37 | ; Reading of the input field and recovery of the used subdomain's size |
|---|
| 38 | ;------------------------------------------------------------ |
|---|
| 39 | niveaux = litchamp(tab) |
|---|
| 40 | grille,mask, -1, -1,gdep,nx,ny,nz,firstx,firsty,firstz,lastx,lasty,lastz |
|---|
| 41 | ;--------------------------------------------------------------- |
|---|
| 42 | ; verification of the coherence between array's size and the domain defined by domdef |
|---|
| 43 | ;--------------------------------------------------------------- |
|---|
| 44 | taille = size(niveaux) |
|---|
| 45 | if taille[0] NE 2 then return, report('input field must be a 2d array') |
|---|
| 46 | case 1 of |
|---|
| 47 | taille[1] eq jpi and taille[2] eq jpj:niveaux=niveaux[firstx:lastx, firsty:lasty] |
|---|
| 48 | taille[1] eq nx and taille[2] eq ny: |
|---|
| 49 | else:return, report('Probleme d''adequation entre les tailles du domaine et celle du champ.') |
|---|
| 50 | endcase |
|---|
| 51 | ;--------------------------------------------------------------- |
|---|
| 52 | |
|---|
| 53 | wherenan = where(finite(niveaux, /nan) EQ 1) |
|---|
| 54 | if wherenan[0] NE -1 then niveaux[wherenan] = 0 |
|---|
| 55 | niveaux = 0 > niveaux < (jpk-1) |
|---|
| 56 | ;--------------------------------------------------------------- |
|---|
| 57 | gdep = replicate(1, nx*ny)#gdep |
|---|
| 58 | niveaux = lindgen(nx*ny)+(nx*ny)*niveaux |
|---|
| 59 | gdep = reform(gdep[niveaux], nx, ny) |
|---|
| 60 | ; |
|---|
| 61 | if wherenan[0] NE -1 then gdep[wherenan] = !values.f_nan |
|---|
| 62 | if NOT keyword_set(nomask) then begin |
|---|
| 63 | if n_elements(valmask) EQ 0 then valmask = 1e20 |
|---|
| 64 | terre = where(mask[*, *, 0] EQ 0) |
|---|
| 65 | if terre[0] NE -1 then gdep[terre] = valmask |
|---|
| 66 | endif |
|---|
| 67 | ; |
|---|
| 68 | if keyword_set(key_performance) THEN print, 'temps level2depth', systime(1)-tempsun |
|---|
| 69 | return, gdep |
|---|
| 70 | end |
|---|
