source: trunk/SRC/ToBeReviewed/PLOTS/plotsym.pro @ 261

;+
;
; @file_comments
; function to make plotting symbols much easier.
;
; @categories
; Graphics
;
; @keyword CIRCLE
; circle symbol
;
; @keyword TRIANGLE
; triangle symbol
;
; @keyword DIAMOND
; diamond symbol
;
; @keyword BOX
; box symbol
;
; @keyword LINE
; line symbol
;
; @keyword SCALE
; scales the symbol
;
; @keyword ANGLE
; angle the symbol should be rotated
;
; @keyword _EXTRA
; Used to pass keywords to <proidl>USERSYM</proidl>.
; These are thick, color and fill.
;
; @history
; Written by:
; Ronn Kling
; Ronn Kling Consulting
; 7038 Westmoreland Dr.
; Warrenton, VA 20187
; klingrl\@juno.com
; copyright 1999, all rights reserved
;
; @version
; $Id$
;
;-
;
FUNCTION plotsym, circle=circle, triangle=triangle, diamond=diamond, $
                  angle=angle, box=box, line=line, scale=scale, $
                  _EXTRA=extra
;
  compile_opt idl2, strictarrsubs
;
if not keyword_set(scale) then scale=1.0
if not keyword_set(angle) then angle=0.0

if keyword_set(circle) then begin
  theta = findgen(30)/29.*360.
endif else if keyword_set(triangle) then begin
  theta = [-30.,90.,210., -30.]
endif else if keyword_set(diamond) then begin
  theta = [0.,90.,180.,270.,0.]
endif else if keyword_set(box) then begin
  theta = [315.,45.,135.,225.,315.]
endif else if keyword_set(line) then begin
  theta = [-180.,0.]
endif

theta = theta + angle
x = cos(theta * !dtor) * scale
y = sin(theta * !dtor) * scale

usersym, x,y, _extra=extra
return,8
end