source: trunk/SRC/ToBeReviewed/WIDGET/COMPOUND_WIDGET/cw_droplist_pm.pro @ 114

;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME: cw_droplist_pm
;
; PURPOSE: widget equivalent a WIDGET_DROPLIST sauf qu'en plus on
; dispose de 2 bouttons + et - pour deplacer le widget de +/- 1.
;
; CATEGORY: compound widget (aide a l''ecriture des widgets)
;
; CALLING SEQUENCE: id=cw_droplist_pm(parent)
; 
; INPUTS:
;         Parent: The widget ID of the parent widget.
;
; KEYWORD PARAMETERS:tous ceux de WIDGET_DROPLIST
;
; OUTPUTS:
;         The returned value of this function is the widget ID of the
;         newly-created animation widget.
;
; COMMON BLOCKS: none
;
; SIDE EFFECTS:
;
;     Widget Events Returned by Droplist Widgets
;
;   Pressing the mouse button while the mouse cursor is over an
;   element of a droplist widget causes the widget to change the label
;   on the droplist button and to generate an event. The appearance of
;   any previously selected element is restored to normal at the same
;   time. The event structure returned by the WIDGET_EVENT function is
;   defined by the following statement:
;
;   { CW_DROPLIST_PM, ID:0L, TOP:0L, HANDLER:0L, INDEX:0L, OUT:0 }
;
;   The first three fields are the standard fields found in every
;   widget event.
;   INDEX returns the index of the selected item. This can be used to
;   index the array of names originally used to set the widget''s
;   value
;   OUT:c''est un entier qui peut prendre 3 valeurs:
;       1 : si on appuie sur + alors que l''index est deja aux max. rq:
;       ds ce cas l''index reste au max
;       -1: si on appuie sur - alors que l''index est deja aux min. rq:
;       ds ce cas l''index reste au min
;       0 : ds les autres cas!
;
;   Keywords to WIDGET_CONTROL
;
;   A number of keywords to the WIDGET_CONTROL procedure affect the
;   behavior of cw_slider_pm widget: GET_VALUE and SET_VALUE.
;       1) GET_VALUE
;   widget_control,wid_id,get_value=resultat
;   retourne ds la variable resultat une structure de 3 elements dont
;   les noms sont inspires des mots cles que l''on peut passer a
;   widget_control qd on utilise WIDGET_DROPLIST:
;            DROPLIST_NUMBER: the number of elements currently
;            contained in the specified droplist widget.
;            DROPLIST_SELECT: the zero-based number of the
;            currently-selected element (i.e., the currently-displayed
;            element) in the specified droplist widget.
;            DYNAMIC_RESIZE: a True value (1) if the widget specified
;            by Widget_ID is a button, droplist, or label widget that
;            has had its DYNAMIC_RESIZE attribute set. Otherwise,
;            False (0) is returned.
;       2) SET_VALUE
;   widget_control,wid_id,set_value=impose
;   permet de modifier l''etat de la droplist comme on peut le faire
;   pour WIDGET_DROPLIST Impose peut etre:
;       a) The contents of the list widget (string or string array)
;       b) une structure qui peut avoir comme elements (de 1 a 3):
;            DYNAMIC_RESIZE:Set this keyword to activate (if set to 1)
;            or deactivate (if set to 0) dynamic resizing of the
;            specified CW_DROPLIST_PM widget (see the documentation
;            for the DYNAMIC_RESIZE keyword to WIDGET_DROPLIST
;            procedure for more information about dynamic widget
;            resizing).
;            DROPLIST_SELECT:Set this keyword to return the zero-based
;            number of the currently-selected element (i.e., the
;            currently-displayed element) in the specified droplist
;            widget.
;            VALUE: The contents of the list widget (string or string
;            array)
;
; RESTRICTIONS:
;
; EXAMPLE: cf utiliser le programme founit i-dessous: testwid et la
; procedure associee, testwid_event.
;
; MODIFICATION HISTORY:Sebastien Masson (smasson@lodyc.jussieu.fr)
;                      6/9/1999
;
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
; PRO testwid_event, event
; ;   help, event, /STRUCT
;    DroplistId = widget_info(event.top,find_by_uname = 'c''est lui')
;    widget_control, event.id, get_uvalue=uval
;    if n_elements(uval) EQ 0 then return
;    case uval of
;       'done':widget_control, event.top, /destroy
;       'dynamic_resize':BEGIN 
;          widget_control, event.id, get_value = value
;          widget_control, DroplistId, set_value = {dynamic_resize:value}
;       END
;       'droplist_select':BEGIN 
;          widget_control, event.id, get_value = value
;          widget_control, DroplistId, set_value = {droplist_select:value}
;       END
;       'value':BEGIN 
;          widget_control, event.id, get_value = value
;          widget_control, DroplistId, set_value = value
;       END
;       'get':BEGIN 
;          widget_control, DroplistId, get_value = value
;          help,  value, /struct
;       END
;       ELSE:
;    endcase
;    return
; end
; PRO testwid, _extra = ex
;    base=widget_base(/COLUMN)
; print, 'base=', base
;    nothing = widget_label(base, value = 'beginning of the test')
; ;
;    nothing = cw_droplist_pm(base, _extra = ex, uname = 'c''est lui', uvalue = 'c''est lui')
; print, 'cw_droplist_pm ID =', nothing
; ;
;    nothing = widget_label(base, value = 'end of the test')
;    nothing = widget_text(base, value = '0', uvalue = 'dynamic_resize', /editable)
;    nothing = widget_text(base, value = '10', uvalue = 'droplist_select', /editable)
;    nothing = widget_text(base, value = '5', uvalue = 'value', /editable)
;    nothing = widget_button(base, value = 'get', uvalue = 'get')
;    nothing = widget_button(base, value = 'done', uvalue = 'done')
;    widget_control, base, /REALIZE
;    xmanager,'testwid', base
;    return
; end
;----------------------------------------------------------------------
PRO cw_droplist_pm_set_value, id, value
;
  compile_opt idl2, strictarrsubs
;
   DroplistId = widget_info(id,find_by_uname = 'Droplist')
   if size(value, /type) eq 8 then BEGIN ; this is a structure
      tagnames = tag_names(value)
      for tag = 0, n_tags(value)-1 do begin
         case strtrim(strlowcase(tagnames[tag]), 2) of
            'dynamic_resize':widget_control, DroplistId, dynamic_resize = value.dynamic_resize
            'droplist_select':widget_control, DroplistId, set_droplist_select = value.droplist_select
            'value':widget_control, DroplistId, set_value = value.value
            ELSE:ras = report('mauvais nom de l''argument de la structure ds cw_droplist_pm_set_value')
         endcase
      endfor
   ENDIF ELSE widget_control, DroplistId, set_value = value
   return
end
;----------------------------------------------------------------------
FUNCTION cw_droplist_pm_get_value, id
;
  compile_opt idl2, strictarrsubs
;
   DroplistId = widget_info(id,find_by_uname = 'Droplist')
   return, {droplist_number:widget_info(DroplistId, /droplist_number) $
            , droplist_select:widget_info(DroplistId, /droplist_select) $
            , dynamic_resize:widget_info(DroplistId, /dynamic_resize)}
end
;----------------------------------------------------------------------
FUNCTION cw_droplist_pm_event, event
;
  compile_opt idl2, strictarrsubs
;
   widget_control, event.id, get_uvalue=uval
;
   if uval EQ 'Droplist' then $
    return, {CW_DROPLIST_PM, ID:event.handler, TOP:event.top, HANDLER:0L $
             , INDEX:event.index, OUT:0}
;
   DroplistId = widget_info(event.handler,find_by_uname = 'Droplist')
   index = widget_info(DroplistId, /droplist_select)
   case uval OF
      'plus':BEGIN
         indexmax = widget_info(DroplistId, /droplist_number)-1
         if index NE indexmax then widget_control, DroplistId,set_droplist_select = index+1
         return, {CW_DROPLIST_PM, ID:event.handler, TOP:event.top, HANDLER:0L $
                  , INDEX:(index+1) < indexmax, OUT:long(index EQ indexmax)}
      END
      'minus':BEGIN
         if index NE 0 then widget_control, DroplistId,set_droplist_select = index-1
         return, {CW_DROPLIST_PM, ID:event.handler, TOP:event.top, HANDLER:0L $
                  , INDEX:0 > (index-1), OUT:-long(index EQ 0)}
      END
   endcase
end
;----------------------------------------------------------------------
FUNCTION cw_droplist_pm, parent,UVALUE = uvalue, UNAME = uname, ROW = row, COLUMN = column, _extra = ex
;
  compile_opt idl2, strictarrsubs
;

   IF (N_PARAMS() NE 1) THEN MESSAGE, 'Incorrect number of arguments'
   ON_ERROR, 2                  ;return to caller
; cheking for row and column keywords
   row = keyword_set(row)*(1-keyword_set(column)) 
   column = keyword_set(column)*(1-keyword_set(row))+(keyword_set(column) EQ row) 
   if NOT keyword_set(uvalue) then uvalue = ''
   if NOT keyword_set(uname) then uname = ''
;
   base = widget_base(parent, space = 1, xpad = 1, ypad = 1, ROW = row, COLUMN = column  $
                      , EVENT_FUNC = 'cw_droplist_pm_event' $
                      , FUNC_GET_VALUE='cw_droplist_pm_get_value' $
                      , PRO_SET_VALUE='cw_droplist_pm_set_value' $
                      , UVALUE = uvalue, UNAME = uname, _extra = ex)   
;
   if keyword_set(row) THEN nothing = widget_button(base,value= '-', uvalue= 'minus')
   nothing = widget_droplist(base, UVALUE = 'Droplist', UNAME = 'Droplist', _extra = ex)
   if keyword_set(column) then begin
      base1 = widget_base(base, /row, /align_center, space = 1, xpad = 1, ypad = 1)
      nothing = widget_button(base1,value= '-', uvalue= 'minus', xsize = 20, ysize = 20)
      nothing = widget_button(base1,value= '+', uvalue= 'plus', xsize = 20, ysize = 20)
   ENDIF ELSE nothing = widget_button(base,value= '+', uvalue= 'plus')
;
;   widget_control,base,/realize
;
   return, base
end