source: trunk/ToBeReviewed/WIDGET/COMPOUND_WIDGET/cw_slider_pm.pro @ 51

;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
;+
; NAME: cw_slider_pm
;
; PURPOSE: widget equivalent a WIDGET_SLIDER sauf qu'en plus on
; dispose de 2 bouttons + et - pour deplacer le widget de +/- 1.
;
; CATEGORY: compound widget (aide a l''ecriture des widgets)
;
; CALLING SEQUENCE: id=cw_slider_pm(parent)
; 
; INPUTS:
;         Parent: The widget ID of the parent widget.
;
; KEYWORD PARAMETERS:tous ceux de WIDGET_SLIDER
;
; OUTPUTS:
;         The returned value of this function is the widget ID of the
;         newly-created animation widget.
;
; COMMON BLOCKS: none
;
; SIDE EFFECTS: 
;
;  Widget Events Returned by the CW_SLIDER_PM Widget
;
;  Slider widgets generate events when the mouse is used to change
;  their value. The event structure returned by the WIDGET_EVENT
;  function is defined by the following statement:
;
;  {CW_SLIDER_PM, ID:0L, TOP:0L, HANDLER:0L, VALUE:0L, DRAG:0, OUT:0}
;
;  ID is the widget ID of the button generating the event. TOP is the
;  widget ID of the top level widget containing ID.
;  HANDLER contains the widget ID of the widget associated with the
;  handler routine.
;  VALUE returns the new value of the slider.
;  DRAG returns integer 1 if the slider event was generated as part of
;  a drag operation, or zero if the event was generated when the user
;  had finished positioning the slider. Note that the slider widget
;  only generates events during the drag operation if the DRAG keyword
;  is set, and if the application is running under Motif. When the
;  DRAG keyword is set, the DRAG field can be used to avoid
;  computationally expensive operations until the user releases the
;  slider.
;  OUT:c''est un entier qui peut prendre 3 valeurs:
;      1 : si on appuie sur + alors que le slider est deja aux max. rq:
;      ds ce cas le slider reste au max
;      -1: si on appuie sur - alors que le slider est deja aux min. rq:
;      ds ce cas le slider reste au min
;      0 : ds les autres cas!
;
;   Keywords to WIDGET_CONTROL
;
;   A number of keywords to the WIDGET_CONTROL procedure affect the
;   behavior of cw_slider_pm widget: GET_VALUE and SET_VALUE.
;       1) GET_VALUE
;   widget_control,wid_id,get_value=resultat
;   retourne ds la variable resultat une structure de 2 elements dont
;   les noms sont inspires des mots cles que l''on peut passer a
;   widget_control qd on utilise WIDGET_SLIDER:
;            VALUE:the value setting of the widget
;            SLIDER_MIN_MAX: a 2 elements array: The minimum and the
;            maximum value of the range encompassed by the slider
;       2) SET_VALUE
;   widget_control,wid_id,set_value=impose
;   permet de modifier l''etat de la slider bar comme on peut le faire
;   pour WIDGET_SLIDER. Impose peut etre:
;       a) un entier: donne la nouvelle  position of the slider.
;       b) une structure qui peut avoir comme elements (de 1 a 3):
;            VALUE:un entier qui donne la nouvelle  position of the slider.
;            SLIDER_MIN:Set to a new minimum value for the specified
;            slider widget.
;            SLIDER_MAX:Set to a new minimum value for the specified
;            slider widget.
;
; RESTRICTIONS:
;
; EXAMPLE: cf utiliser le programme founit i-dessous: testwid et la
; procedure associee, testwid_event.
;
; MODIFICATION HISTORY:Sebastien Masson (smasson@lodyc.jussieu.fr)
;                      5/9/1999
;-
;------------------------------------------------------------
;------------------------------------------------------------
;------------------------------------------------------------
; PRO testwid_event, event
; ;   help, event, /STRUCT
;    SliderBarId = widget_info(event.top,find_by_uname = 'c''est lui')
;    widget_control, event.id, get_uvalue=uval
;    if n_elements(uval) EQ 0 then return
;    case uval of
;       'done':widget_control, event.top, /destroy
;       'slider_min':BEGIN 
;          widget_control, event.id, get_value = value
;          widget_control, SliderBarId, set_value = {slider_min:value}
;       END
;       'slider_max':BEGIN 
;          widget_control, event.id, get_value = value
;          widget_control, SliderBarId, set_value = {slider_max:value}
;       END
;       'slider_value':BEGIN 
;          widget_control, event.id, get_value = value
;          widget_control, SliderBarId, set_value = value
;       END
;       'get':BEGIN 
;          widget_control, SliderBarId, get_value = value
;          help,  value, /struct
;          print, value.slider_min_max
;       END
;       ELSE:
;    endcase
;    return
; end
; PRO testwid, _extra = ex
;    base=widget_base(/COLUMN)
; print, 'base=', base
;    nothing = widget_label(base, value = 'beginning of the test')
; ;
;    nothing = cw_slider_pm(base, _extra = ex, uname = 'c''est lui', uvalue = 'c''est lui')
; print, 'cw_slider_pm ID =', nothing
; ;
;    nothing = widget_label(base, value = 'end of the test')
;    nothing = widget_text(base, value = '0', uvalue = 'slider_min', /editable)
;    nothing = widget_text(base, value = '10', uvalue = 'slider_max', /editable)
;    nothing = widget_text(base, value = '5', uvalue = 'slider_value', /editable)
;    nothing = widget_button(base, value = 'get', uvalue = 'get')
;    nothing = widget_button(base, value = 'done', uvalue = 'done')
;    widget_control, base, /REALIZE
;    xmanager,'testwid', base
;    return
; end
;----------------------------------------------------------------------
PRO cw_slider_pm_set_value, id, value
   SliderBarId = widget_info(id,find_by_uname = 'SliderBar')
   if size(value, /type) eq 8 then BEGIN ; this is a structure
      tagnames = tag_names(value)
      for tag = 0, n_tags(value)-1 do begin
         case strtrim(strlowcase(tagnames[tag]), 2) of
            'slider_min':widget_control, SliderBarId, set_slider_min = value.slider_min
            'slider_max':widget_control, SliderBarId, set_slider_max = value.slider_max
            'value':widget_control, SliderBarId, set_value = value.value
            ELSE:ras = report('mauvais nom de l''argument de la structure ds cw_slider_pm_set_value')
         endcase
      endfor
   ENDIF ELSE widget_control, SliderBarId, set_value = value[0]
   return
end
;----------------------------------------------------------------------
FUNCTION cw_slider_pm_get_value, id
   SliderBarId = widget_info(id,find_by_uname = 'SliderBar')
   widget_control, SliderBarId, get_value = value
   return, {value:value, slider_min_max:widget_info(SliderBarId, /slider_min_max)}
end
;----------------------------------------------------------------------
FUNCTION cw_slider_pm_event, event
   widget_control, event.id, get_uvalue=uval
;
   if uval EQ 'SliderBar' then $
    return, {CW_SLIDER_PM, ID:event.handler, TOP:event.top, HANDLER:0L $
             , VALUE:event.value, OUT:0}
;
   SliderBarId = widget_info(event.handler,find_by_uname = 'SliderBar')
   minmax = widget_info(SliderBarId, /SLIDER_MIN_MAX)
   widget_control, SliderBarId, get_value = value
   case uval OF
      'plus':BEGIN
         if value NE minmax[1] then widget_control, SliderBarId,set_value = value+1
         return, {CW_SLIDER_PM, ID:event.handler, TOP:event.top, HANDLER:0L $
                  , VALUE:(value+1) < minmax[1], OUT:long(value eq minmax[1])}
      END
      'minus':BEGIN
         if value NE minmax[0] then widget_control, SliderBarId,set_value = value-1
         return, {CW_SLIDER_PM, ID:event.handler, TOP:event.top, HANDLER:0L $
                  , VALUE:0 > (value-1), OUT:-long(value EQ minmax[0])}
      END
   endcase
end
;----------------------------------------------------------------------
FUNCTION cw_slider_pm, parent, ROW = row, COLUMN = column, VERTICAL = vertical, UVALUE = uvalue, UNAME = uname, _extra = ex

   IF (N_PARAMS() NE 1) THEN MESSAGE, 'Incorrect number of arguments'
   ON_ERROR, 2                  ;return to caller
;
; cheking exclusive keywords
   column = (keyword_set(column)*(1-keyword_set(row))+keyword_set(vertical)) < 1
   row = keyword_set(row)*(1-keyword_set(column)) +(keyword_set(row) EQ column) 
   if NOT keyword_set(uvalue) then uvalue = ''
   if NOT keyword_set(uname) then uname = ''
   base = widget_base(parent, space = 1, xpad = 1, ypad = 1 $
                      , EVENT_FUNC = 'cw_slider_pm_event' $
                      , FUNC_GET_VALUE='cw_slider_pm_get_value' $
                      , PRO_SET_VALUE='cw_slider_pm_set_value' $
                      , ROW = row, COLUMN = column, UVALUE = uvalue, UNAME = uname, _extra = ex)   
;
   if keyword_set(vertical) then BEGIN
      if keyword_set(row) then begin
         nothing = widget_slider(base, /VERTICAL, UVALUE = 'SliderBar', UNAME = 'SliderBar', _extra = ex)
         base1 = widget_base(base, space = 1, xpad = 1, ypad = 1 $
                             , /column, /align_center)
         nothing = widget_button(base1,value= '+', uvalue='plus', xsize = 15, ysize = 15)
         nothing = widget_button(base1,value= '-', uvalue='minus', xsize = 15, ysize = 15)
      ENDIF ELSE BEGIN 
         nothing = widget_button(base,value= '+', uvalue='plus', xsize = 15, ysize = 15)
         nothing = widget_slider(base, /VERTICAL, UVALUE = 'SliderBar', UNAME = 'SliderBar', _extra = ex)
         nothing = widget_button(base,value= '-', uvalue='minus', xsize = 15, ysize = 15)
      ENDELSE
   ENDIF ELSE BEGIN
      if keyword_set(row) then begin
         nothing = widget_button(base,value= '-', uvalue='minus', xsize = 15, ysize = 15)
         nothing = widget_slider(base, UVALUE = 'SliderBar', UNAME = 'SliderBar', _extra = ex)
         nothing = widget_button(base,value= '+', uvalue='plus', xsize = 15, ysize = 15)
      ENDIF ELSE BEGIN 
         nothing = widget_slider(base, UVALUE = 'SliderBar', UNAME = 'SliderBar', _extra = ex)
         base1 = widget_base(base, space = 1, xpad = 1, ypad = 1 $
                             , /row, /align_center)
         nothing = widget_button(base1,value= '-', uvalue='minus', xsize = 15, ysize = 15)
         nothing = widget_button(base1,value= '+', uvalue='plus', xsize = 15, ysize = 15)
      ENDELSE
   ENDELSE
;
;
   return, base
end