source: trunk/WIDGET/AUTOUR_de_XXX/scanfile.pro @ 2

;
;  liste des presupposes:
;       1) le fichier a lire est un fichier netcdf
;       2) le nom de ce fichier finit
;       par U.nc, V.nc, W.nc, T.nc ou F.nc, la lettre avant le
;       nc designant la grille a laquelle se rapporte la champ.
;       Si tel n''est pas la cas, le fichier est attribue a la grille
;       T.
;       3) ce fichier contient une dimension infinie qui doit etre
;       celle qui se rapporte au temps et au mois 2 autres dimensions
;       dont les noms sont 'x','lon','longitude' et 'y','lat' ou
;       'latitude' ou bien en majuscule.
;       4) il doit exiter ds ce fichier une unique variable n''ayant
;       qu''une dimension et etant la dimension temporelle. cette
;       variable sera prise comme axe des temps. Rq: si plusieurs
;       variables verifient ces criteres on considere la premiere
;       variable
;       5) Cette variable axe des temps doit contenir l''attribut
;       'units'qui doit etre ecrit suivant la syntaxe:
;               "seconds since 0001-01-01 00:00:00" 
;               "hours since 0001-01-01 00:00:00" 
;               "days since 1979-01-01 00:59:59" 
;               "months since 1979-01-01 00:59:59" 
;               "years since 1979-01-01 00:59:59" 
;
; je crois que c''est tout!
;
;
;------------------------------------------------------------
FUNCTION scanfile, nomficher, IODIRECTORY = iodirectory
@common
;------------------------------------------------------------
; bidouille pour utiliser les mots cles (on passe par des variables
; declarees ds un common)
;------------------------------------------------------------
   res = -1
;------------------------------------------------------------
; choix du nom du fichier
;------------------------------------------------------------
   if NOT keyword_set(iodirectory) then iodirectory = iodir
   nom = isafile(filename = nomficher, IODIRECTORY = iodirectory)
;------------------------------------------------------------
; ouverture du fichier nom
;------------------------------------------------------------
   cdfid=ncdf_open(nom)
;------------------------------------------------------------
; que contient le fichier??
;------------------------------------------------------------
   contient=ncdf_inquire(cdfid)
   vargrid = strupcase(strmid(nom, strlen(nom)-9))
   if vargrid EQ 'GRID.T.NC' OR vargrid EQ 'GRID.U.NC' $
    OR vargrid EQ 'GRID.V.NC' OR vargrid EQ 'GRID.F.NC' $
    OR vargrid eq 'GRID.W.NC' $
    OR vargrid EQ 'GRID_T.NC' OR vargrid EQ 'GRID_U.NC' $
    OR vargrid EQ 'GRID_V.NC' OR vargrid EQ 'GRID_F.NC' $
    OR vargrid eq 'GRID_W.NC' then $
    vargrid = strupcase(strmid(nom, strlen(nom)-4, 1)) ELSE vargrid='T'
;------------------------------------------------------------
; nom des differentes variables
;------------------------------------------------------------
; on ne garde les noms de variable uniquement si cette variable
; contient au moins les dimensions qui doivent etre appelles x et y
; et la dimension infinie
   nomdim   =strarr(contient.ndims)
   for dimiq=0,contient.ndims-1 do begin
      ncdf_diminq,cdfid,dimiq,name,value ; nom et valeur de la dimension
      nomdim[dimiq]=strlowcase(name)
   ENDFOR
   indexdimx = where(nomdim EQ 'x' OR nomdim EQ 'lon' OR nomdim EQ 'longitude')
   indexdimx = indexdimx[0]
   if indexdimx EQ -1 then begin
      print, 'one of the dimensions must have the name: ''x'' or ''lon'' or ''longitude'''
      stop
   endif
   indexdimy = where(nomdim EQ 'y' OR nomdim EQ 'lat' OR nomdim EQ 'latitude')
   indexdimy = indexdimy[0]
   if indexdimy EQ -1 then begin
      print, 'one of the dimensions must have the name: ''y'' or ''lat'' or ''latitude'''
      stop
   endif
;
   namevar = strarr(contient.nvars)
   for varid=0,contient.nvars-1 do begin
      varcontient=ncdf_varinq(cdfid,varid) ; que contient la variable
      if (where(varcontient.dim EQ indexdimx))[0] NE -1 AND $
       (where(varcontient.dim EQ indexdimy))[0] NE -1 AND $
       (where(varcontient.dim EQ contient.recdim))[0] NE -1 THEN namevar[varid]=varcontient.name 
   ENDFOR
   namevar = namevar[where(namevar NE '')]
   listgrid = replicate(vargrid,  n_elements(namevar))
;------------------------------------------------------------
; on recupere l''axe des temps
;------------------------------------------------------------
; on recupere le nom de la variable contenant l''axe des temps
   varid = 0
   repeat BEGIN                 ; tant que l''on a pas trouve une variable qui n''a qu''
                                ; une dimension: la dimension infinie
      varcontient=ncdf_varinq(cdfid,varid) ; que contient la variable
      varid = varid+1
   endrep until n_elements(varcontient.dim) EQ 1 AND varcontient.dim[0] EQ contient.recdim
; on lit l''axe des temps
   varid = varid-1
   ncdf_varget, cdfid, varid, time
   time = long(time)
   ncdf_attget,cdfid,varid,'units',value
; time_counter:units = "seconds since 0001-01-01 00:00:00" ;
; time_counter:units = "hours since 0001-01-01 00:00:00" ;
; time_counter:units = "days since 1979-01-01 00:00:00" ;
; time_counter:units = "months since 1979-01-01 00:00:00" ;
; time_counter:units = "years since 1979-01-01 00:00:00" ;
   value = strtrim(strcompress(string(value)), 2)
   mots = str_sep(value, ' ')
   unite = mots[0]
   debut = str_sep(mots[2], '-')
;
;
; ATTENTION il faut recuperer l''atribut calendar et ajuster time en
; consequense...
;
;
; on passe time en jour julien d''idl 
; on suppose qu''on utilise le vrai calendrier.
;
   case strlowcase(unite) of
      'seconds':time = julday(debut[1], debut[2], debut[0])+time/(long(24)*3600)
      'hours':time = julday(debut[1], debut[2], debut[0])+time/(long(24))
      'days':time = julday(debut[1], debut[2], debut[0])+time
      'months':BEGIN 
         for t = 0, n_elements(time)-1  do begin
            time[t] = julday(debut[1]+time[t], debut[2], debut[0])
         endfor
      END
      'years':BEGIN
         for t = 0, n_elements(time)-1  do begin
            time[t] = julday(debut[1], debut[2], debut[0]+time[t])
         endfor
      END
   ENDCASE
;------------------------------------------------------------
   return, {filename:nom, time_counter:time, listvar:namevar, listgrid:strupcase(listgrid)}
end