| 1 | MODULE p4zopt |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zopt *** |
|---|
| 4 | !! TOP - PISCES : Compute the light availability in the water column |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004 (O. Aumont) Original code |
|---|
| 7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 8 | !! 3.2 ! 2009-04 (C. Ethe, G. Madec) optimisation |
|---|
| 9 | !! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Improve light availability of nano & diat |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | #if defined key_pisces |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! 'key_pisces' PISCES bio-model |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! p4z_opt : light availability in the water column |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE trc ! tracer variables |
|---|
| 18 | USE oce_trc ! tracer-ocean share variables |
|---|
| 19 | USE sms_pisces ! Source Minus Sink of PISCES |
|---|
| 20 | USE iom ! I/O manager |
|---|
| 21 | USE fldread ! time interpolation |
|---|
| 22 | USE prtctl_trc ! print control for debugging |
|---|
| 23 | |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC p4z_opt ! called in p4zbio.F90 module |
|---|
| 29 | PUBLIC p4z_opt_init ! called in trcsms_pisces.F90 module |
|---|
| 30 | PUBLIC p4z_opt_alloc |
|---|
| 31 | |
|---|
| 32 | !! * Shared module variables |
|---|
| 33 | |
|---|
| 34 | LOGICAL :: ln_varpar !: boolean for variable PAR fraction |
|---|
| 35 | REAL(wp) :: parlux !: Fraction of shortwave as PAR |
|---|
| 36 | REAL(wp) :: xparsw !: parlux/3 |
|---|
| 37 | REAL(wp) :: xsi0r !: 1. /rn_si0 |
|---|
| 38 | |
|---|
| 39 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_par ! structure of input par |
|---|
| 40 | INTEGER , PARAMETER :: nbtimes = 365 !: maximum number of times record in a file |
|---|
| 41 | INTEGER :: ntimes_par ! number of time steps in a file |
|---|
| 42 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: par_varsw !: PAR fraction of shortwave |
|---|
| 43 | |
|---|
| 44 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: enano, ediat !: PAR for phyto, nano and diat |
|---|
| 45 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: etot_ndcy !: PAR over 24h in case of diurnal cycle |
|---|
| 46 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: emoy !: averaged PAR in the mixed layer |
|---|
| 47 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ekb, ekg, ekr !: wavelength (Red-Green-Blue) |
|---|
| 48 | |
|---|
| 49 | INTEGER :: nksrp ! levels below which the light cannot penetrate ( depth larger than 391 m) |
|---|
| 50 | |
|---|
| 51 | REAL(wp), DIMENSION(3,61), PUBLIC :: xkrgb !: tabulated attenuation coefficients for RGB absorption |
|---|
| 52 | |
|---|
| 53 | !!* Substitution |
|---|
| 54 | # include "top_substitute.h90" |
|---|
| 55 | !!---------------------------------------------------------------------- |
|---|
| 56 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 57 | !! $Id: p4zopt.F90 3160 2011-11-20 14:27:18Z cetlod $ |
|---|
| 58 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | CONTAINS |
|---|
| 61 | |
|---|
| 62 | SUBROUTINE p4z_opt( kt, knt ) |
|---|
| 63 | !!--------------------------------------------------------------------- |
|---|
| 64 | !! *** ROUTINE p4z_opt *** |
|---|
| 65 | !! |
|---|
| 66 | !! ** Purpose : Compute the light availability in the water column |
|---|
| 67 | !! depending on the depth and the chlorophyll concentration |
|---|
| 68 | !! |
|---|
| 69 | !! ** Method : - ??? |
|---|
| 70 | !!--------------------------------------------------------------------- |
|---|
| 71 | ! |
|---|
| 72 | INTEGER, INTENT(in) :: kt, knt ! ocean time step |
|---|
| 73 | ! |
|---|
| 74 | INTEGER :: ji, jj, jk |
|---|
| 75 | INTEGER :: irgb |
|---|
| 76 | REAL(wp) :: zchl |
|---|
| 77 | REAL(wp) :: zc0 , zc1 , zc2, zc3, z1_dep |
|---|
| 78 | REAL(wp), POINTER, DIMENSION(:,: ) :: zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4, zqsr100, zqsr_corr |
|---|
| 79 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zpar, ze0, ze1, ze2, ze3 |
|---|
| 80 | !!--------------------------------------------------------------------- |
|---|
| 81 | ! |
|---|
| 82 | IF( nn_timing == 1 ) CALL timing_start('p4z_opt') |
|---|
| 83 | ! |
|---|
| 84 | ! Allocate temporary workspace |
|---|
| 85 | CALL wrk_alloc( jpi, jpj, zqsr100, zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4, zqsr_corr ) |
|---|
| 86 | CALL wrk_alloc( jpi, jpj, jpk, zpar, ze0, ze1, ze2, ze3 ) |
|---|
| 87 | |
|---|
| 88 | IF( knt == 1 .AND. ln_varpar ) CALL p4z_opt_sbc( kt ) |
|---|
| 89 | |
|---|
| 90 | ! Initialisation of variables used to compute PAR |
|---|
| 91 | ! ----------------------------------------------- |
|---|
| 92 | ze1(:,:,:) = 0._wp |
|---|
| 93 | ze2(:,:,:) = 0._wp |
|---|
| 94 | ze3(:,:,:) = 0._wp |
|---|
| 95 | ! !* attenuation coef. function of Chlorophyll and wavelength (Red-Green-Blue) |
|---|
| 96 | DO jk = 1, jpkm1 ! -------------------------------------------------------- |
|---|
| 97 | !CDIR NOVERRCHK |
|---|
| 98 | DO jj = 1, jpj |
|---|
| 99 | !CDIR NOVERRCHK |
|---|
| 100 | DO ji = 1, jpi |
|---|
| 101 | zchl = ( trb(ji,jj,jk,jpnch) + trb(ji,jj,jk,jpdch) + rtrn ) * 1.e6 |
|---|
| 102 | zchl = MIN( 10. , MAX( 0.05, zchl ) ) |
|---|
| 103 | irgb = NINT( 41 + 20.* LOG10( zchl ) + rtrn ) |
|---|
| 104 | ! |
|---|
| 105 | ekb(ji,jj,jk) = xkrgb(1,irgb) * fse3t(ji,jj,jk) |
|---|
| 106 | ekg(ji,jj,jk) = xkrgb(2,irgb) * fse3t(ji,jj,jk) |
|---|
| 107 | ekr(ji,jj,jk) = xkrgb(3,irgb) * fse3t(ji,jj,jk) |
|---|
| 108 | END DO |
|---|
| 109 | END DO |
|---|
| 110 | END DO |
|---|
| 111 | ! !* Photosynthetically Available Radiation (PAR) |
|---|
| 112 | ! ! -------------------------------------- |
|---|
| 113 | IF( l_trcdm2dc ) THEN ! diurnal cycle |
|---|
| 114 | ! 1% of qsr to compute euphotic layer |
|---|
| 115 | zqsr100(:,:) = 0.01 * qsr_mean(:,:) ! daily mean qsr |
|---|
| 116 | ! |
|---|
| 117 | zqsr_corr(:,:) = qsr_mean(:,:) / ( 1. - fr_i(:,:) + rtrn ) |
|---|
| 118 | CALL p4z_opt_par( kt, qsr_corr, ze1, ze2, ze3 ) |
|---|
| 119 | ! |
|---|
| 120 | DO jk = 1, nksrp |
|---|
| 121 | etot_ndcy(:,:,jk) = ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk) |
|---|
| 122 | enano (:,:,jk) = 2.1 * ze1(:,:,jk) + 0.42 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk) |
|---|
| 123 | ediat (:,:,jk) = 1.6 * ze1(:,:,jk) + 0.69 * ze2(:,:,jk) + 0.7 * ze3(:,:,jk) |
|---|
| 124 | END DO |
|---|
| 125 | ! |
|---|
| 126 | zqsr_corr(:,:) = qsr(:,:) / ( 1. - fr_i(:,:) + rtrn ) |
|---|
| 127 | CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3 ) |
|---|
| 128 | ! |
|---|
| 129 | DO jk = 1, nksrp |
|---|
| 130 | etot(:,:,jk) = ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk) |
|---|
| 131 | END DO |
|---|
| 132 | ! |
|---|
| 133 | ELSE |
|---|
| 134 | ! 1% of qsr to compute euphotic layer |
|---|
| 135 | zqsr100(:,:) = 0.01 * qsr(:,:) |
|---|
| 136 | ! |
|---|
| 137 | zqsr_corr(:,:) = qsr(:,:) / ( 1. - fr_i(:,:) + rtrn ) |
|---|
| 138 | CALL p4z_opt_par( kt, zqsr_corr, ze1, ze2, ze3 ) |
|---|
| 139 | ! |
|---|
| 140 | DO jk = 1, nksrp |
|---|
| 141 | etot (:,:,jk) = ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk) |
|---|
| 142 | enano(:,:,jk) = 2.1 * ze1(:,:,jk) + 0.42 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk) |
|---|
| 143 | ediat(:,:,jk) = 1.6 * ze1(:,:,jk) + 0.69 * ze2(:,:,jk) + 0.7 * ze3(:,:,jk) |
|---|
| 144 | END DO |
|---|
| 145 | etot_ndcy(:,:,:) = etot(:,:,:) |
|---|
| 146 | ENDIF |
|---|
| 147 | |
|---|
| 148 | |
|---|
| 149 | IF( ln_qsr_bio ) THEN !* heat flux accros w-level (used in the dynamics) |
|---|
| 150 | ! ! ------------------------ |
|---|
| 151 | CALL p4z_opt_par( kt, qsr, ze1, ze2, ze3, pe0=ze0 ) |
|---|
| 152 | ! |
|---|
| 153 | etot3(:,:,1) = qsr(:,:) * tmask(:,:,1) |
|---|
| 154 | DO jk = 2, nksrp + 1 |
|---|
| 155 | etot3(:,:,jk) = ( ze0(:,:,jk) + ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk) ) * tmask(:,:,jk) |
|---|
| 156 | END DO |
|---|
| 157 | ! ! ------------------------ |
|---|
| 158 | ENDIF |
|---|
| 159 | ! !* Euphotic depth and level |
|---|
| 160 | neln(:,:) = 1 ! ------------------------ |
|---|
| 161 | heup(:,:) = 300. |
|---|
| 162 | |
|---|
| 163 | DO jk = 2, nksrp |
|---|
| 164 | DO jj = 1, jpj |
|---|
| 165 | DO ji = 1, jpi |
|---|
| 166 | IF( etot_ndcy(ji,jj,jk) * tmask(ji,jj,jk) >= 0.43 * zqsr100(ji,jj) ) THEN |
|---|
| 167 | neln(ji,jj) = jk+1 ! Euphotic level : 1rst T-level strictly below Euphotic layer |
|---|
| 168 | ! ! nb: ensure the compatibility with nmld_trc definition in trd_mld_trc_zint |
|---|
| 169 | heup(ji,jj) = fsdepw(ji,jj,jk+1) ! Euphotic layer depth |
|---|
| 170 | ENDIF |
|---|
| 171 | END DO |
|---|
| 172 | END DO |
|---|
| 173 | END DO |
|---|
| 174 | ! |
|---|
| 175 | heup(:,:) = MIN( 300., heup(:,:) ) |
|---|
| 176 | ! !* mean light over the mixed layer |
|---|
| 177 | zdepmoy(:,:) = 0.e0 ! ------------------------------- |
|---|
| 178 | zetmp1 (:,:) = 0.e0 |
|---|
| 179 | zetmp2 (:,:) = 0.e0 |
|---|
| 180 | zetmp3 (:,:) = 0.e0 |
|---|
| 181 | zetmp4 (:,:) = 0.e0 |
|---|
| 182 | |
|---|
| 183 | DO jk = 1, nksrp |
|---|
| 184 | !CDIR NOVERRCHK |
|---|
| 185 | DO jj = 1, jpj |
|---|
| 186 | !CDIR NOVERRCHK |
|---|
| 187 | DO ji = 1, jpi |
|---|
| 188 | IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN |
|---|
| 189 | zetmp1 (ji,jj) = zetmp1 (ji,jj) + etot (ji,jj,jk) * fse3t(ji,jj,jk) ! remineralisation |
|---|
| 190 | zetmp2 (ji,jj) = zetmp2 (ji,jj) + etot_ndcy(ji,jj,jk) * fse3t(ji,jj,jk) ! production |
|---|
| 191 | zetmp3 (ji,jj) = zetmp3 (ji,jj) + enano (ji,jj,jk) * fse3t(ji,jj,jk) ! production |
|---|
| 192 | zetmp4 (ji,jj) = zetmp4 (ji,jj) + ediat (ji,jj,jk) * fse3t(ji,jj,jk) ! production |
|---|
| 193 | zdepmoy(ji,jj) = zdepmoy(ji,jj) + fse3t(ji,jj,jk) |
|---|
| 194 | ENDIF |
|---|
| 195 | END DO |
|---|
| 196 | END DO |
|---|
| 197 | END DO |
|---|
| 198 | ! |
|---|
| 199 | emoy(:,:,:) = etot(:,:,:) ! remineralisation |
|---|
| 200 | zpar(:,:,:) = etot_ndcy(:,:,:) ! diagnostic : PAR with no diurnal cycle |
|---|
| 201 | ! |
|---|
| 202 | DO jk = 1, nksrp |
|---|
| 203 | !CDIR NOVERRCHK |
|---|
| 204 | DO jj = 1, jpj |
|---|
| 205 | !CDIR NOVERRCHK |
|---|
| 206 | DO ji = 1, jpi |
|---|
| 207 | IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN |
|---|
| 208 | z1_dep = 1. / ( zdepmoy(ji,jj) + rtrn ) |
|---|
| 209 | emoy (ji,jj,jk) = zetmp1(ji,jj) * z1_dep |
|---|
| 210 | zpar (ji,jj,jk) = zetmp2(ji,jj) * z1_dep |
|---|
| 211 | enano(ji,jj,jk) = zetmp3(ji,jj) * z1_dep |
|---|
| 212 | ediat(ji,jj,jk) = zetmp4(ji,jj) * z1_dep |
|---|
| 213 | ENDIF |
|---|
| 214 | END DO |
|---|
| 215 | END DO |
|---|
| 216 | END DO |
|---|
| 217 | ! |
|---|
| 218 | IF( lk_iomput ) THEN |
|---|
| 219 | IF( knt == nrdttrc ) THEN |
|---|
| 220 | IF( iom_use( "Heup" ) ) CALL iom_put( "Heup" , heup(:,: ) * tmask(:,:,1) ) ! euphotic layer deptht |
|---|
| 221 | IF( iom_use( "PARDM" ) ) CALL iom_put( "PARDM", zpar(:,:,:) * tmask(:,:,:) ) ! Photosynthetically Available Radiation |
|---|
| 222 | IF( iom_use( "PAR" ) ) CALL iom_put( "PAR" , emoy(:,:,:) * tmask(:,:,:) ) ! Photosynthetically Available Radiation |
|---|
| 223 | ENDIF |
|---|
| 224 | ELSE |
|---|
| 225 | IF( ln_diatrc ) THEN ! save output diagnostics |
|---|
| 226 | trc2d(:,:, jp_pcs0_2d + 10) = heup(:,: ) * tmask(:,:,1) |
|---|
| 227 | trc3d(:,:,:,jp_pcs0_3d + 3) = etot(:,:,:) * tmask(:,:,:) |
|---|
| 228 | ENDIF |
|---|
| 229 | ENDIF |
|---|
| 230 | ! |
|---|
| 231 | CALL wrk_dealloc( jpi, jpj, zqsr100, zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4, zqsr_corr ) |
|---|
| 232 | CALL wrk_dealloc( jpi, jpj, jpk, zpar, ze0, ze1, ze2, ze3 ) |
|---|
| 233 | ! |
|---|
| 234 | IF( nn_timing == 1 ) CALL timing_stop('p4z_opt') |
|---|
| 235 | ! |
|---|
| 236 | END SUBROUTINE p4z_opt |
|---|
| 237 | |
|---|
| 238 | SUBROUTINE p4z_opt_par( kt, pqsr, pe1, pe2, pe3, pe0 ) |
|---|
| 239 | !!---------------------------------------------------------------------- |
|---|
| 240 | !! *** routine p4z_opt_par *** |
|---|
| 241 | !! |
|---|
| 242 | !! ** purpose : compute PAR of each wavelength (Red-Green-Blue) |
|---|
| 243 | !! for a given shortwave radiation |
|---|
| 244 | !! |
|---|
| 245 | !!---------------------------------------------------------------------- |
|---|
| 246 | !! * arguments |
|---|
| 247 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 248 | REAL(wp), DIMENSION(jpi,jpj) , INTENT(in) :: pqsr ! shortwave |
|---|
| 249 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: pe1 , pe2 , pe3 ! PAR ( R-G-B) |
|---|
| 250 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout), OPTIONAL :: pe0 |
|---|
| 251 | !! * local variables |
|---|
| 252 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 253 | REAL(wp), DIMENSION(jpi,jpj) :: zqsr ! shortwave |
|---|
| 254 | !!---------------------------------------------------------------------- |
|---|
| 255 | |
|---|
| 256 | ! Real shortwave |
|---|
| 257 | IF( ln_varpar ) THEN ; zqsr(:,:) = par_varsw(:,:) * pqsr(:,:) |
|---|
| 258 | ELSE ; zqsr(:,:) = xparsw * pqsr(:,:) |
|---|
| 259 | ENDIF |
|---|
| 260 | ! |
|---|
| 261 | IF( PRESENT( pe0 ) ) THEN ! W-level |
|---|
| 262 | ! |
|---|
| 263 | pe0(:,:,1) = pqsr(:,:) - 3. * zqsr(:,:) ! ( 1 - 3 * alpha ) * q |
|---|
| 264 | pe1(:,:,1) = zqsr(:,:) |
|---|
| 265 | pe2(:,:,1) = zqsr(:,:) |
|---|
| 266 | pe3(:,:,1) = zqsr(:,:) |
|---|
| 267 | ! |
|---|
| 268 | DO jk = 2, nksrp + 1 |
|---|
| 269 | !CDIR NOVERRCHK |
|---|
| 270 | DO jj = 1, jpj |
|---|
| 271 | !CDIR NOVERRCHK |
|---|
| 272 | DO ji = 1, jpi |
|---|
| 273 | pe0(ji,jj,jk) = pe0(ji,jj,jk-1) * EXP( -fse3t(ji,jj,jk-1) * xsi0r ) |
|---|
| 274 | pe1(ji,jj,jk) = pe1(ji,jj,jk-1) * EXP( -ekb(ji,jj,jk-1 ) ) |
|---|
| 275 | pe2(ji,jj,jk) = pe2(ji,jj,jk-1) * EXP( -ekg(ji,jj,jk-1 ) ) |
|---|
| 276 | pe3(ji,jj,jk) = pe3(ji,jj,jk-1) * EXP( -ekr(ji,jj,jk-1 ) ) |
|---|
| 277 | END DO |
|---|
| 278 | ! |
|---|
| 279 | END DO |
|---|
| 280 | ! |
|---|
| 281 | END DO |
|---|
| 282 | ! |
|---|
| 283 | ELSE ! T- level |
|---|
| 284 | ! |
|---|
| 285 | pe1(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekb(:,:,1) ) |
|---|
| 286 | pe2(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekg(:,:,1) ) |
|---|
| 287 | pe3(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekr(:,:,1) ) |
|---|
| 288 | ! |
|---|
| 289 | DO jk = 2, nksrp |
|---|
| 290 | !CDIR NOVERRCHK |
|---|
| 291 | DO jj = 1, jpj |
|---|
| 292 | !CDIR NOVERRCHK |
|---|
| 293 | DO ji = 1, jpi |
|---|
| 294 | pe1(ji,jj,jk) = pe1(ji,jj,jk-1) * EXP( -0.5 * ( ekb(ji,jj,jk-1) + ekb(ji,jj,jk) ) ) |
|---|
| 295 | pe2(ji,jj,jk) = pe2(ji,jj,jk-1) * EXP( -0.5 * ( ekg(ji,jj,jk-1) + ekg(ji,jj,jk) ) ) |
|---|
| 296 | pe3(ji,jj,jk) = pe3(ji,jj,jk-1) * EXP( -0.5 * ( ekr(ji,jj,jk-1) + ekr(ji,jj,jk) ) ) |
|---|
| 297 | END DO |
|---|
| 298 | END DO |
|---|
| 299 | END DO |
|---|
| 300 | ! |
|---|
| 301 | ENDIF |
|---|
| 302 | ! |
|---|
| 303 | END SUBROUTINE p4z_opt_par |
|---|
| 304 | |
|---|
| 305 | |
|---|
| 306 | SUBROUTINE p4z_opt_sbc( kt ) |
|---|
| 307 | !!---------------------------------------------------------------------- |
|---|
| 308 | !! *** routine p4z_opt_sbc *** |
|---|
| 309 | !! |
|---|
| 310 | !! ** purpose : read and interpolate the variable PAR fraction |
|---|
| 311 | !! of shortwave radiation |
|---|
| 312 | !! |
|---|
| 313 | !! ** method : read the files and interpolate the appropriate variables |
|---|
| 314 | !! |
|---|
| 315 | !! ** input : external netcdf files |
|---|
| 316 | !! |
|---|
| 317 | !!---------------------------------------------------------------------- |
|---|
| 318 | !! * arguments |
|---|
| 319 | INTEGER , INTENT(in) :: kt ! ocean time step |
|---|
| 320 | |
|---|
| 321 | !! * local declarations |
|---|
| 322 | INTEGER :: ji,jj |
|---|
| 323 | REAL(wp) :: zcoef |
|---|
| 324 | !!--------------------------------------------------------------------- |
|---|
| 325 | ! |
|---|
| 326 | IF( nn_timing == 1 ) CALL timing_start('p4z_optsbc') |
|---|
| 327 | ! |
|---|
| 328 | ! Compute par_varsw at nit000 or only if there is more than 1 time record in par coefficient file |
|---|
| 329 | IF( ln_varpar ) THEN |
|---|
| 330 | IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_par > 1 ) ) THEN |
|---|
| 331 | CALL fld_read( kt, 1, sf_par ) |
|---|
| 332 | par_varsw(:,:) = ( sf_par(1)%fnow(:,:,1) ) / 3.0 |
|---|
| 333 | ENDIF |
|---|
| 334 | ENDIF |
|---|
| 335 | ! |
|---|
| 336 | IF( nn_timing == 1 ) CALL timing_stop('p4z_optsbc') |
|---|
| 337 | ! |
|---|
| 338 | END SUBROUTINE p4z_opt_sbc |
|---|
| 339 | |
|---|
| 340 | SUBROUTINE p4z_opt_init |
|---|
| 341 | !!---------------------------------------------------------------------- |
|---|
| 342 | !! *** ROUTINE p4z_opt_init *** |
|---|
| 343 | !! |
|---|
| 344 | !! ** Purpose : Initialization of tabulated attenuation coef |
|---|
| 345 | !! and of the percentage of PAR in Shortwave |
|---|
| 346 | !! |
|---|
| 347 | !! ** Input : external ascii and netcdf files |
|---|
| 348 | !!---------------------------------------------------------------------- |
|---|
| 349 | ! |
|---|
| 350 | INTEGER :: numpar |
|---|
| 351 | INTEGER :: ierr |
|---|
| 352 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 353 | REAL(wp), DIMENSION(nbtimes) :: zsteps ! times records |
|---|
| 354 | ! |
|---|
| 355 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 356 | TYPE(FLD_N) :: sn_par ! informations about the fields to be read |
|---|
| 357 | ! |
|---|
| 358 | NAMELIST/nampisopt/cn_dir, sn_par, ln_varpar, parlux |
|---|
| 359 | |
|---|
| 360 | !!---------------------------------------------------------------------- |
|---|
| 361 | |
|---|
| 362 | IF( nn_timing == 1 ) CALL timing_start('p4z_opt_init') |
|---|
| 363 | |
|---|
| 364 | REWIND( numnatp_ref ) ! Namelist nampisopt in reference namelist : Pisces attenuation coef. and PAR |
|---|
| 365 | READ ( numnatp_ref, nampisopt, IOSTAT = ios, ERR = 901) |
|---|
| 366 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisopt in reference namelist', lwp ) |
|---|
| 367 | |
|---|
| 368 | REWIND( numnatp_cfg ) ! Namelist nampisopt in configuration namelist : Pisces attenuation coef. and PAR |
|---|
| 369 | READ ( numnatp_cfg, nampisopt, IOSTAT = ios, ERR = 902 ) |
|---|
| 370 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisopt in configuration namelist', lwp ) |
|---|
| 371 | IF(lwm) WRITE ( numonp, nampisopt ) |
|---|
| 372 | |
|---|
| 373 | IF(lwp) THEN |
|---|
| 374 | WRITE(numout,*) ' ' |
|---|
| 375 | WRITE(numout,*) ' namelist : nampisopt ' |
|---|
| 376 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~ ' |
|---|
| 377 | WRITE(numout,*) ' PAR as a variable fraction of SW ln_varpar = ', ln_varpar |
|---|
| 378 | WRITE(numout,*) ' Default value for the PAR fraction parlux = ', parlux |
|---|
| 379 | ENDIF |
|---|
| 380 | ! |
|---|
| 381 | xparsw = parlux / 3.0 |
|---|
| 382 | xsi0r = 1.e0 / rn_si0 |
|---|
| 383 | ! |
|---|
| 384 | ! Variable PAR at the surface of the ocean |
|---|
| 385 | ! ---------------------------------------- |
|---|
| 386 | IF( ln_varpar ) THEN |
|---|
| 387 | IF(lwp) WRITE(numout,*) ' initialize variable par fraction ' |
|---|
| 388 | IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
|---|
| 389 | ! |
|---|
| 390 | ALLOCATE( par_varsw(jpi,jpj) ) |
|---|
| 391 | ! |
|---|
| 392 | ALLOCATE( sf_par(1), STAT=ierr ) !* allocate and fill sf_sst (forcing structure) with sn_sst |
|---|
| 393 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'p4z_opt_init: unable to allocate sf_par structure' ) |
|---|
| 394 | ! |
|---|
| 395 | CALL fld_fill( sf_par, (/ sn_par /), cn_dir, 'p4z_opt_init', 'Variable PAR fraction ', 'nampisopt' ) |
|---|
| 396 | ALLOCATE( sf_par(1)%fnow(jpi,jpj,1) ) |
|---|
| 397 | IF( sn_par%ln_tint ) ALLOCATE( sf_par(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 398 | |
|---|
| 399 | CALL iom_open ( TRIM( sn_par%clname ) , numpar ) |
|---|
| 400 | CALL iom_gettime( numpar, zsteps, kntime=ntimes_par) ! get number of record in file |
|---|
| 401 | ENDIF |
|---|
| 402 | ! |
|---|
| 403 | CALL trc_oce_rgb( xkrgb ) ! tabulated attenuation coefficients |
|---|
| 404 | nksrp = trc_oce_ext_lev( r_si2, 0.33e2 ) ! max level of light extinction (Blue Chl=0.01) |
|---|
| 405 | ! |
|---|
| 406 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksrp, ' ref depth = ', gdepw_1d(nksrp+1), ' m' |
|---|
| 407 | ! |
|---|
| 408 | ekr (:,:,:) = 0._wp |
|---|
| 409 | ekb (:,:,:) = 0._wp |
|---|
| 410 | ekg (:,:,:) = 0._wp |
|---|
| 411 | etot (:,:,:) = 0._wp |
|---|
| 412 | etot_ndcy(:,:,:) = 0._wp |
|---|
| 413 | enano (:,:,:) = 0._wp |
|---|
| 414 | ediat (:,:,:) = 0._wp |
|---|
| 415 | IF( ln_qsr_bio ) etot3 (:,:,:) = 0._wp |
|---|
| 416 | ! |
|---|
| 417 | IF( nn_timing == 1 ) CALL timing_stop('p4z_opt_init') |
|---|
| 418 | ! |
|---|
| 419 | END SUBROUTINE p4z_opt_init |
|---|
| 420 | |
|---|
| 421 | |
|---|
| 422 | INTEGER FUNCTION p4z_opt_alloc() |
|---|
| 423 | !!---------------------------------------------------------------------- |
|---|
| 424 | !! *** ROUTINE p4z_opt_alloc *** |
|---|
| 425 | !!---------------------------------------------------------------------- |
|---|
| 426 | ALLOCATE( ekb(jpi,jpj,jpk) , ekr(jpi,jpj,jpk), ekg(jpi,jpj,jpk), & |
|---|
| 427 | & enano(jpi,jpj,jpk) , ediat(jpi,jpj,jpk), & |
|---|
| 428 | & etot_ndcy(jpi,jpj,jpk), emoy (jpi,jpj,jpk), STAT=p4z_opt_alloc ) |
|---|
| 429 | ! |
|---|
| 430 | IF( p4z_opt_alloc /= 0 ) CALL ctl_warn('p4z_opt_alloc : failed to allocate arrays.') |
|---|
| 431 | ! |
|---|
| 432 | END FUNCTION p4z_opt_alloc |
|---|
| 433 | |
|---|
| 434 | #else |
|---|
| 435 | !!---------------------------------------------------------------------- |
|---|
| 436 | !! Dummy module : No PISCES bio-model |
|---|
| 437 | !!---------------------------------------------------------------------- |
|---|
| 438 | CONTAINS |
|---|
| 439 | SUBROUTINE p4z_opt ! Empty routine |
|---|
| 440 | END SUBROUTINE p4z_opt |
|---|
| 441 | #endif |
|---|
| 442 | |
|---|
| 443 | !!====================================================================== |
|---|
| 444 | END MODULE p4zopt |
|---|
