source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/PISCES/P4Z/p4zligand.F90 @ 10419

Last change on this file since 10419 was 10419, checked in by smasson, 22 months ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: merge with trunk@10418, see #2133

  • Property svn:keywords set to Id
File size: 6.7 KB
Line 
1MODULE p4zligand
2   !!======================================================================
3   !!                         ***  MODULE p4zligand  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic ligands
5   !!=========================================================================
6   !! History :   3.6  !  2016-03  (O. Aumont, A. Tagliabue) Quota model and reorganization
7   !!----------------------------------------------------------------------
8   !!   p4z_ligand     :  Compute remineralization/dissolution of organic ligands
9   !!   p4z_ligand_init:  Initialisation of parameters for remineralisation
10   !!----------------------------------------------------------------------
11   USE oce_trc         ! shared variables between ocean and passive tracers
12   USE trc             ! passive tracers common variables
13   USE sms_pisces      ! PISCES Source Minus Sink variables
14   USE prtctl_trc      ! print control for debugging
15   USE iom             !  I/O manager
16
17   IMPLICIT NONE
18   PRIVATE
19
20   PUBLIC   p4z_ligand         ! called in p4zbio.F90
21   PUBLIC   p4z_ligand_init    ! called in trcsms_pisces.F90
22
23   REAL(wp), PUBLIC ::  rlgw     !: lifetime (years) of weak ligands
24   REAL(wp), PUBLIC ::  rlgs     !: lifetime (years) of strong ligands
25   REAL(wp), PUBLIC ::  rlig     !: Remin ligand production
26   REAL(wp), PUBLIC ::  prlgw    !: Photochemical of weak ligand
27
28   !!----------------------------------------------------------------------
29   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
30   !! $Id$
31   !! Software governed by the CeCILL license (see ./LICENSE)
32   !!----------------------------------------------------------------------
33CONTAINS
34
35   SUBROUTINE p4z_ligand( kt, knt )
36      !!---------------------------------------------------------------------
37      !!                     ***  ROUTINE p4z_ligand  ***
38      !!
39      !! ** Purpose :   Compute remineralization/scavenging of organic ligands
40      !!---------------------------------------------------------------------
41      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
42      !
43      INTEGER  ::   ji, jj, jk
44      REAL(wp) ::   zlgwp, zlgwpr, zlgwr, zlablgw
45      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zligrem, zligpr, zrligprod
46      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zw3d
47      CHARACTER (len=25) ::   charout
48      !!---------------------------------------------------------------------
49      !
50      IF( ln_timing )   CALL timing_start('p4z_ligand')
51      !
52      DO jk = 1, jpkm1
53         DO jj = 1, jpj
54            DO ji = 1, jpi
55               !
56               ! ------------------------------------------------------------------
57               ! Remineralization of iron ligands
58               ! ------------------------------------------------------------------
59               ! production from remineralisation of organic matter
60               zlgwp = orem(ji,jj,jk) * rlig
61               ! decay of weak ligand
62               ! This is based on the idea that as LGW is lower
63               ! there is a larger fraction of refractory OM
64               zlgwr = max( rlgs , rlgw * exp( -2 * (trb(ji,jj,jk,jplgw)*1e9) ) ) ! years
65               zlgwr = 1. / zlgwr * tgfunc(ji,jj,jk) * ( xstep / nyear_len(1) ) * blim(ji,jj,jk) * trb(ji,jj,jk,jplgw)
66               ! photochem loss of weak ligand
67               zlgwpr = prlgw * xstep * etot(ji,jj,jk) * trb(ji,jj,jk,jplgw) * (1. - fr_i(ji,jj))
68               tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zlgwp - zlgwr - zlgwpr
69               zligrem(ji,jj,jk)   = zlgwr
70               zligpr(ji,jj,jk)    = zlgwpr
71               zrligprod(ji,jj,jk) = zlgwp
72               !
73            END DO
74         END DO
75      END DO
76      !
77      !  Output of some diagnostics variables
78      !     ---------------------------------
79      IF( lk_iomput .AND. knt == nrdttrc ) THEN
80         ALLOCATE( zw3d(jpi,jpj,jpk) )
81         IF( iom_use( "LIGREM" ) ) THEN
82            zw3d(:,:,:) = zligrem(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
83            CALL iom_put( "LIGREM", zw3d )
84         ENDIF
85         IF( iom_use( "LIGPR" ) ) THEN
86            zw3d(:,:,:) = zligpr(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) 
87            CALL iom_put( "LIGPR", zw3d )
88         ENDIF
89         IF( iom_use( "LPRODR" ) ) THEN
90            zw3d(:,:,:) = zrligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) 
91            CALL iom_put( "LPRODR", zw3d )
92         ENDIF
93         DEALLOCATE( zw3d )
94      ENDIF
95      !
96      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
97         WRITE(charout, FMT="('ligand1')")
98         CALL prt_ctl_trc_info(charout)
99         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
100      ENDIF
101      !
102      IF( ln_timing )   CALL timing_stop('p4z_ligand')
103      !
104   END SUBROUTINE p4z_ligand
105
106
107   SUBROUTINE p4z_ligand_init
108      !!----------------------------------------------------------------------
109      !!                  ***  ROUTINE p4z_ligand_init  ***
110      !!
111      !! ** Purpose :   Initialization of remineralization parameters
112      !!
113      !! ** Method  :   Read the nampislig namelist and check the parameters
114      !!
115      !! ** input   :   Namelist nampislig
116      !!----------------------------------------------------------------------
117      INTEGER ::   ios   ! Local integer
118      !
119      NAMELIST/nampislig/ rlgw, prlgw, rlgs, rlig
120      !!----------------------------------------------------------------------
121      !
122      IF(lwp) THEN
123         WRITE(numout,*)
124         WRITE(numout,*) 'p4z_ligand_init : remineralization/scavenging of organic ligands'
125         WRITE(numout,*) '~~~~~~~~~~~~~~~'
126      ENDIF
127      REWIND( numnatp_ref )              ! Namelist nampislig in reference namelist : Pisces remineralization
128      READ  ( numnatp_ref, nampislig, IOSTAT = ios, ERR = 901)
129901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampislig in reference namelist', lwp )
130      REWIND( numnatp_cfg )              ! Namelist nampislig in configuration namelist : Pisces remineralization
131      READ  ( numnatp_cfg, nampislig, IOSTAT = ios, ERR = 902 )
132902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampislig in configuration namelist', lwp )
133      IF(lwm) WRITE ( numonp, nampislig )
134      !
135      IF(lwp) THEN                         ! control print
136         WRITE(numout,*) '   Namelist : nampislig'
137         WRITE(numout,*) '      Lifetime (years) of weak ligands             rlgw  =', rlgw
138         WRITE(numout,*) '      Remin ligand production per unit C           rlig  =', rlig
139         WRITE(numout,*) '      Photolysis of weak ligand                    prlgw =', prlgw
140         WRITE(numout,*) '      Lifetime (years) of strong ligands           rlgs  =', rlgs
141      ENDIF
142      !
143   END SUBROUTINE p4z_ligand_init
144
145   !!======================================================================
146END MODULE p4zligand
Note: See TracBrowser for help on using the repository browser.