source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/TOP/PISCES/P4Z/p4zsink.F90 @ 10368

Last change on this file since 10368 was 10368, checked in by smasson, 22 months ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: merge with trunk@10365, see #2133

  • Property svn:keywords set to Id
File size: 16.8 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!             3.5  !  2012-07  (O. Aumont) Introduce potential time-splitting
10   !!----------------------------------------------------------------------
11   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
12   !!   p4z_sink_init  :  Unitialisation of sinking speed parameters
13   !!   p4z_sink_alloc :  Allocate sinking speed variables
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE prtctl_trc      !  print control for debugging
19   USE iom             !  I/O manager
20   USE lib_mpp
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sink         ! called in p4zbio.F90
26   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
27   PUBLIC   p4z_sink_alloc
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
30   !                                                          !  (different meanings depending on the parameterization)
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkingn, sinking2n  !: POC sinking fluxes
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkingp, sinking2p  !: POC sinking fluxes
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfep      !: Fep sinking fluxes
37
38   INTEGER  :: ik100
39
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   !!----------------------------------------------------------------------
48   !!   'standard sinking parameterisation'                  ???
49   !!----------------------------------------------------------------------
50
51   SUBROUTINE p4z_sink ( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_sink  ***
54      !!
55      !! ** Purpose :   Compute vertical flux of particulate matter due to
56      !!                gravitational sinking
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      INTEGER, INTENT(in) :: kt, knt
61      INTEGER  ::   ji, jj, jk, jit
62      INTEGER  ::   iiter1, iiter2
63      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
64      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2, zaggdoc3
65      REAL(wp) ::   zfact, zwsmax, zmax
66      CHARACTER (len=25) :: charout
67      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
68      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zw2d
69      !!---------------------------------------------------------------------
70      !
71      IF( ln_timing )   CALL timing_start('p4z_sink')
72
73
74      ! Initialization of some global variables
75      ! ---------------------------------------
76      prodpoc(:,:,:) = 0.
77      conspoc(:,:,:) = 0.
78      prodgoc(:,:,:) = 0.
79      consgoc(:,:,:) = 0.
80
81      !
82      !    Sinking speeds of detritus is increased with depth as shown
83      !    by data and from the coagulation theory
84      !    -----------------------------------------------------------
85      DO jk = 1, jpkm1
86         DO jj = 1, jpj
87            DO ji = 1,jpi
88               zmax  = MAX( heup_01(ji,jj), hmld(ji,jj) )
89               zfact = MAX( 0., gdepw_n(ji,jj,jk+1) - zmax ) / wsbio2scale
90               wsbio4(ji,jj,jk) = wsbio2 + MAX(0., ( wsbio2max - wsbio2 )) * zfact
91            END DO
92         END DO
93      END DO
94
95      ! limit the values of the sinking speeds to avoid numerical instabilities 
96      wsbio3(:,:,:) = wsbio
97
98      !
99      ! OA This is (I hope) a temporary solution for the problem that may
100      ! OA arise in specific situation where the CFL criterion is broken
101      ! OA for vertical sedimentation of particles. To avoid this, a time
102      ! OA splitting algorithm has been coded. A specific maximum
103      ! OA iteration number is provided and may be specified in the namelist
104      ! OA This is to avoid very large iteration number when explicit free
105      ! OA surface is used (for instance). When niter?max is set to 1,
106      ! OA this computation is skipped. The crude old threshold method is
107      ! OA then applied. This also happens when niter exceeds nitermax.
108      IF( MAX( niter1max, niter2max ) == 1 ) THEN
109        iiter1 = 1
110        iiter2 = 1
111      ELSE
112        iiter1 = 1
113        iiter2 = 1
114        DO jk = 1, jpkm1
115          DO jj = 1, jpj
116             DO ji = 1, jpi
117                IF( tmask(ji,jj,jk) == 1) THEN
118                   zwsmax =  0.5 * e3t_n(ji,jj,jk) / xstep
119                   iiter1 =  MAX( iiter1, INT( wsbio3(ji,jj,jk) / zwsmax ) )
120                   iiter2 =  MAX( iiter2, INT( wsbio4(ji,jj,jk) / zwsmax ) )
121                ENDIF
122             END DO
123          END DO
124        END DO
125        IF( lk_mpp ) THEN
126           CALL mpp_max( 'p4zsink', iiter1 )
127           CALL mpp_max( 'p4zsink', iiter2 )
128        ENDIF
129        iiter1 = MIN( iiter1, niter1max )
130        iiter2 = MIN( iiter2, niter2max )
131      ENDIF
132
133      DO jk = 1,jpkm1
134         DO jj = 1, jpj
135            DO ji = 1, jpi
136               IF( tmask(ji,jj,jk) == 1 ) THEN
137                 zwsmax = 0.5 * e3t_n(ji,jj,jk) / xstep
138                 wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax * REAL( iiter1, wp ) )
139                 wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax * REAL( iiter2, wp ) )
140               ENDIF
141            END DO
142         END DO
143      END DO
144
145      !  Initializa to zero all the sinking arrays
146      !   -----------------------------------------
147      sinking (:,:,:) = 0.e0
148      sinking2(:,:,:) = 0.e0
149      sinkcal (:,:,:) = 0.e0
150      sinkfer (:,:,:) = 0.e0
151      sinksil (:,:,:) = 0.e0
152      sinkfer2(:,:,:) = 0.e0
153
154      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
155      !   -----------------------------------------------------
156      DO jit = 1, iiter1
157        CALL p4z_sink2( wsbio3, sinking , jppoc, iiter1 )
158        CALL p4z_sink2( wsbio3, sinkfer , jpsfe, iiter1 )
159      END DO
160
161      DO jit = 1, iiter2
162        CALL p4z_sink2( wsbio4, sinking2, jpgoc, iiter2 )
163        CALL p4z_sink2( wsbio4, sinkfer2, jpbfe, iiter2 )
164        CALL p4z_sink2( wsbio4, sinksil , jpgsi, iiter2 )
165        CALL p4z_sink2( wsbio4, sinkcal , jpcal, iiter2 )
166      END DO
167
168      IF( ln_p5z ) THEN
169         sinkingn (:,:,:) = 0.e0
170         sinking2n(:,:,:) = 0.e0
171         sinkingp (:,:,:) = 0.e0
172         sinking2p(:,:,:) = 0.e0
173
174         !   Compute the sedimentation term using p4zsink2 for all the sinking particles
175         !   -----------------------------------------------------
176         DO jit = 1, iiter1
177           CALL p4z_sink2( wsbio3, sinkingn , jppon, iiter1 )
178           CALL p4z_sink2( wsbio3, sinkingp , jppop, iiter1 )
179         END DO
180
181         DO jit = 1, iiter2
182           CALL p4z_sink2( wsbio4, sinking2n, jpgon, iiter2 )
183           CALL p4z_sink2( wsbio4, sinking2p, jpgop, iiter2 )
184         END DO
185      ENDIF
186
187      IF( ln_ligand ) THEN
188         wsfep (:,:,:) = wfep
189         DO jk = 1,jpkm1
190            DO jj = 1, jpj
191               DO ji = 1, jpi
192                  IF( tmask(ji,jj,jk) == 1 ) THEN
193                    zwsmax = 0.5 * e3t_n(ji,jj,jk) / xstep
194                    wsfep(ji,jj,jk) = MIN( wsfep(ji,jj,jk), zwsmax * REAL( iiter1, wp ) )
195                  ENDIF
196               END DO
197            END DO
198         END DO
199         !
200         sinkfep(:,:,:) = 0.e0
201         DO jit = 1, iiter1
202           CALL p4z_sink2( wsfep, sinkfep , jpfep, iiter1 )
203         END DO
204      ENDIF
205
206     ! Total carbon export per year
207     IF( iom_use( "tcexp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
208        &   t_oce_co2_exp = glob_sum( 'p4zsink', ( sinking(:,:,ik100) + sinking2(:,:,ik100) ) * e1e2t(:,:) * tmask(:,:,1) )
209     !
210     IF( lk_iomput ) THEN
211       IF( knt == nrdttrc ) THEN
212          ALLOCATE( zw2d(jpi,jpj), zw3d(jpi,jpj,jpk) )
213          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
214          !
215          IF( iom_use( "EPC100" ) )  THEN
216              zw2d(:,:) = ( sinking(:,:,ik100) + sinking2(:,:,ik100) ) * zfact * tmask(:,:,1) ! Export of carbon at 100m
217              CALL iom_put( "EPC100"  , zw2d )
218          ENDIF
219          IF( iom_use( "EPFE100" ) )  THEN
220              zw2d(:,:) = ( sinkfer(:,:,ik100) + sinkfer2(:,:,ik100) ) * zfact * tmask(:,:,1) ! Export of iron at 100m
221              CALL iom_put( "EPFE100"  , zw2d )
222          ENDIF
223          IF( iom_use( "EPCAL100" ) )  THEN
224              zw2d(:,:) = sinkcal(:,:,ik100) * zfact * tmask(:,:,1) ! Export of calcite at 100m
225              CALL iom_put( "EPCAL100"  , zw2d )
226          ENDIF
227          IF( iom_use( "EPSI100" ) )  THEN
228              zw2d(:,:) =  sinksil(:,:,ik100) * zfact * tmask(:,:,1) ! Export of bigenic silica at 100m
229              CALL iom_put( "EPSI100"  , zw2d )
230          ENDIF
231          IF( iom_use( "EXPC" ) )  THEN
232              zw3d(:,:,:) = ( sinking(:,:,:) + sinking2(:,:,:) ) * zfact * tmask(:,:,:) ! Export of carbon in the water column
233              CALL iom_put( "EXPC"  , zw3d )
234          ENDIF
235          IF( iom_use( "EXPFE" ) )  THEN
236              zw3d(:,:,:) = ( sinkfer(:,:,:) + sinkfer2(:,:,:) ) * zfact * tmask(:,:,:) ! Export of iron
237              CALL iom_put( "EXPFE"  , zw3d )
238          ENDIF
239          IF( iom_use( "EXPCAL" ) )  THEN
240              zw3d(:,:,:) = sinkcal(:,:,:) * zfact * tmask(:,:,:) ! Export of calcite
241              CALL iom_put( "EXPCAL"  , zw3d )
242          ENDIF
243          IF( iom_use( "EXPSI" ) )  THEN
244              zw3d(:,:,:) = sinksil(:,:,:) * zfact * tmask(:,:,:) ! Export of bigenic silica
245              CALL iom_put( "EXPSI"  , zw3d )
246          ENDIF
247          IF( iom_use( "tcexp" ) )  CALL iom_put( "tcexp" , t_oce_co2_exp * zfact )   ! molC/s
248          !
249          DEALLOCATE( zw2d, zw3d )
250        ENDIF
251      ENDIF
252      !
253      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
254         WRITE(charout, FMT="('sink')")
255         CALL prt_ctl_trc_info(charout)
256         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
257      ENDIF
258      !
259      IF( ln_timing )   CALL timing_stop('p4z_sink')
260      !
261   END SUBROUTINE p4z_sink
262
263
264   SUBROUTINE p4z_sink_init
265      !!----------------------------------------------------------------------
266      !!                  ***  ROUTINE p4z_sink_init  ***
267      !!----------------------------------------------------------------------
268      INTEGER :: jk
269      !!----------------------------------------------------------------------
270      !
271      ik100 = 10        !  last level where depth less than 100 m
272      DO jk = jpkm1, 1, -1
273         IF( gdept_1d(jk) > 100. )  ik100 = jk - 1
274      END DO
275      IF (lwp) WRITE(numout,*)
276      IF (lwp) WRITE(numout,*) ' Level corresponding to 100m depth ',  ik100 + 1
277      IF (lwp) WRITE(numout,*)
278      !
279      t_oce_co2_exp = 0._wp
280      !
281   END SUBROUTINE p4z_sink_init
282
283
284   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra, kiter )
285      !!---------------------------------------------------------------------
286      !!                     ***  ROUTINE p4z_sink2  ***
287      !!
288      !! ** Purpose :   Compute the sedimentation terms for the various sinking
289      !!     particles. The scheme used to compute the trends is based
290      !!     on MUSCL.
291      !!
292      !! ** Method  : - this ROUTINE compute not exactly the advection but the
293      !!      transport term, i.e.  div(u*tra).
294      !!---------------------------------------------------------------------
295      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
296      INTEGER , INTENT(in   )                         ::   kiter     ! number of iterations for time-splitting
297      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
298      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
299      !
300      INTEGER  ::   ji, jj, jk, jn
301      REAL(wp) ::   zigma,zew,zign, zflx, zstep
302      REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztraz, zakz, zwsink2, ztrb 
303      !!---------------------------------------------------------------------
304      !
305      IF( ln_timing )   CALL timing_start('p4z_sink2')
306      !
307      zstep = rfact2 / REAL( kiter, wp ) / 2.
308
309      ztraz(:,:,:) = 0.e0
310      zakz (:,:,:) = 0.e0
311      ztrb (:,:,:) = trb(:,:,:,jp_tra)
312
313      DO jk = 1, jpkm1
314         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
315      END DO
316      zwsink2(:,:,1) = 0.e0
317
318
319      ! Vertical advective flux
320      DO jn = 1, 2
321         !  first guess of the slopes interior values
322         DO jk = 2, jpkm1
323            ztraz(:,:,jk) = ( trb(:,:,jk-1,jp_tra) - trb(:,:,jk,jp_tra) ) * tmask(:,:,jk)
324         END DO
325         ztraz(:,:,1  ) = 0.0
326         ztraz(:,:,jpk) = 0.0
327
328         ! slopes
329         DO jk = 2, jpkm1
330            DO jj = 1,jpj
331               DO ji = 1, jpi
332                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
333                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
334               END DO
335            END DO
336         END DO
337         
338         ! Slopes limitation
339         DO jk = 2, jpkm1
340            DO jj = 1, jpj
341               DO ji = 1, jpi
342                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
343                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
344               END DO
345            END DO
346         END DO
347         
348         ! vertical advective flux
349         DO jk = 1, jpkm1
350            DO jj = 1, jpj     
351               DO ji = 1, jpi   
352                  zigma = zwsink2(ji,jj,jk+1) * zstep / e3w_n(ji,jj,jk+1)
353                  zew   = zwsink2(ji,jj,jk+1)
354                  psinkflx(ji,jj,jk+1) = -zew * ( trb(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
355               END DO
356            END DO
357         END DO
358         !
359         ! Boundary conditions
360         psinkflx(:,:,1  ) = 0.e0
361         psinkflx(:,:,jpk) = 0.e0
362         
363         DO jk=1,jpkm1
364            DO jj = 1,jpj
365               DO ji = 1, jpi
366                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / e3t_n(ji,jj,jk)
367                  trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + zflx
368               END DO
369            END DO
370         END DO
371
372      ENDDO
373
374      DO jk = 1,jpkm1
375         DO jj = 1,jpj
376            DO ji = 1, jpi
377               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / e3t_n(ji,jj,jk)
378               ztrb(ji,jj,jk) = ztrb(ji,jj,jk) + 2. * zflx
379            END DO
380         END DO
381      END DO
382
383      trb(:,:,:,jp_tra) = ztrb(:,:,:)
384      psinkflx(:,:,:)   = 2. * psinkflx(:,:,:)
385      !
386      IF( ln_timing )  CALL timing_stop('p4z_sink2')
387      !
388   END SUBROUTINE p4z_sink2
389
390
391   INTEGER FUNCTION p4z_sink_alloc()
392      !!----------------------------------------------------------------------
393      !!                     ***  ROUTINE p4z_sink_alloc  ***
394      !!----------------------------------------------------------------------
395      INTEGER :: ierr(3)
396      !!----------------------------------------------------------------------
397      !
398      ierr(:) = 0
399      !
400      ALLOCATE( sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                    ,     &               
401         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                    ,     &               
402         &      sinkfer2(jpi,jpj,jpk)                                           ,     &               
403         &      sinkfer(jpi,jpj,jpk)                                            , STAT=ierr(1) )               
404         !
405      IF( ln_ligand ) ALLOCATE( sinkfep(jpi,jpj,jpk)                            , STAT=ierr(2) ) 
406         
407      IF( ln_p5z    ) ALLOCATE( sinkingn(jpi,jpj,jpk), sinking2n(jpi,jpj,jpk)   ,     &
408         &                      sinkingp(jpi,jpj,jpk), sinking2p(jpi,jpj,jpk)   , STAT=ierr(3) )
409      !
410      p4z_sink_alloc = MAXVAL( ierr )
411      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
412      !
413   END FUNCTION p4z_sink_alloc
414   
415   !!======================================================================
416END MODULE p4zsink
Note: See TracBrowser for help on using the repository browser.