New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p2zexp.F90 in NEMO/branches/2018/dev_r9838_ENHANCE04_MLF/src/TOP/PISCES/P2Z – NEMO

source: NEMO/branches/2018/dev_r9838_ENHANCE04_MLF/src/TOP/PISCES/P2Z/p2zexp.F90 @ 9923

Last change on this file since 9923 was 9923, checked in by gm, 6 years ago

#1911 (ENHANCE-04): step I.2: dev_r9838_ENHANCE04_MLF
  • Property svn:keywords set to Id
File size: 10.2 KB
Line 
1MODULE p2zexp
2   !!======================================================================
3   !!                         ***  MODULE p2zsed  ***
4   !! TOP :   LOBSTER Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   -   !  1999    (O. Aumont, C. Le Quere)  original code
7   !!             -   !  2001-05 (O. Aumont, E. Kestenare) add sediment computations
8   !!            1.0  !  2005-06 (A.-S. Kremeur) new temporal integration for sedpoc
9   !!            2.0  !  2007-12  (C. Deltel, G. Madec)  F90
10   !!            3.5  !  2012-03  (C. Ethe)  Merge PISCES-LOBSTER
11   !!----------------------------------------------------------------------
12   !!   p2z_exp       :  Compute loss of organic matter in the sediments
13   !!----------------------------------------------------------------------
14   USE oce_trc        !
15   USE trc            !
16   USE sms_pisces     !
17   USE p2zsed         !
18   USE lbclnk         !
19   USE prtctl_trc     ! Print control for debbuging
20   USE trd_oce        !
21   USE trdtrc         !
22   USE iom            !
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p2z_exp   
28   PUBLIC   p2z_exp_init 
29   PUBLIC   p2z_exp_alloc
30
31   !
32   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   dminl     ! fraction of sinking POC released in sediments
33   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   dmin3     ! fraction of sinking POC released at each level
34   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocb   ! mass of POC in sediments
35   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocn   ! mass of POC in sediments
36   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   cmask     ! Coastal mask area
37   REAL(wp)                                ::   areacot   ! surface coastal area
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 3.3 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL licence (./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE p2z_exp( kt )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p2z_exp  ***
51      !!
52      !! ** Purpose :   MODELS EXPORT OF BIOGENIC MATTER (POC ''SOFT
53      !!              TISSUE'') AND ITS DISTRIBUTION IN WATER COLUMN
54      !!
55      !! ** Method  : - IN THE SURFACE LAYER POC IS PRODUCED ACCORDING TO
56      !!              NURTRIENTS AVAILABLE AND GROWTH CONDITIONS. NUTRIENT UPTAKE
57      !!              KINETICS FOLLOW MICHAELIS-MENTON FORMULATION.
58      !!              THE TOTAL PARTICLE AMOUNT PRODUCED, IS DISTRIBUTED IN THE WATER
59      !!              COLUMN BELOW THE SURFACE LAYER.
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index     
62      !!
63      INTEGER  ::   ji, jj, jk, jl, ikt
64      REAL(wp) ::   zgeolpoc, zfact, zwork, ze3t, zsedpocd, zmaskt
65      REAL(wp), DIMENSION(jpi,jpj)   ::  zsedpoca
66      CHARACTER (len=25) ::   charout
67      !!---------------------------------------------------------------------
68      !
69      IF( ln_timing )   CALL timing_start('p2z_exp')
70      !
71      IF( kt == nittrc000 )   CALL p2z_exp_init
72
73      zsedpoca(:,:) = 0._wp
74
75
76      ! VERTICAL DISTRIBUTION OF NEWLY PRODUCED BIOGENIC POC IN THE WATER COLUMN
77      ! (PARTS OF NEWLY FORMED MATTER REMAINING IN THE DIFFERENT
78      ! LAYERS IS DETERMINED BY DMIN3 DEFINED IN sms_p2z.F90
79      ! ----------------------------------------------------------------------
80      DO jk = 1, jpkm1
81         DO jj = 2, jpjm1
82            DO ji = fs_2, fs_jpim1
83               ze3t = 1. / e3t_n(ji,jj,jk)
84               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + ze3t * dmin3(ji,jj,jk) * xksi(ji,jj)
85            END DO
86         END DO
87      END DO
88
89      ! Find the last level of the water column
90      ! Compute fluxes due to sinking particles (slow)
91   
92
93      zgeolpoc = 0._wp        !     Initialization
94      DO jj = 2, jpjm1           ! Release of nutrients from the "simple" sediment
95         DO ji = fs_2, fs_jpim1
96            ikt = mbkt(ji,jj) 
97            tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) + sedlam * sedpocn(ji,jj) / e3t_n(ji,jj,ikt) 
98            ! Deposition of organic matter in the sediment
99            zwork = vsed * trn(ji,jj,ikt,jpdet)
100            zsedpoca(ji,jj) = ( zwork + dminl(ji,jj) * xksi(ji,jj)   &
101               &           - sedlam * sedpocn(ji,jj) - sedlostpoc * sedpocn(ji,jj) ) * rn_Dt
102            zgeolpoc = zgeolpoc + sedlostpoc * sedpocn(ji,jj) * e1e2t(ji,jj)
103         END DO
104      END DO
105
106      DO jj = 2, jpjm1
107         DO ji = fs_2, fs_jpim1
108            tra(ji,jj,1,jpno3) = tra(ji,jj,1,jpno3) + zgeolpoc * cmask(ji,jj) / areacot / e3t_n(ji,jj,1)
109         END DO
110      END DO
111
112      CALL lbc_lnk( sedpocn, 'T', 1. )
113 
114      ! Oa & Ek: diagnostics depending on jpdia2d !          left as example
115      IF( lk_iomput )  CALL iom_put( "SEDPOC" , sedpocn )
116
117     
118      ! Time filter and swap of arrays
119      ! ------------------------------
120      IF( l_1st_euler ) THEN        ! Euler time-stepping at first time-step   (only swap)
121        sedpocn(:,:) = zsedpoca(:,:)
122        !                                             
123      ELSE                          ! Leap-Frog + Asselin filter
124        !
125        DO jj = 1, jpj
126           DO ji = 1, jpi
127              zsedpocd = zsedpoca(ji,jj) - 2. * sedpocn(ji,jj) + sedpocb(ji,jj)     ! time laplacian on tracers
128              sedpocb(ji,jj) = sedpocn(ji,jj) + rn_atfp * zsedpocd                  ! sedpocb <-- filtered sedpocn
129              sedpocn(ji,jj) = zsedpoca(ji,jj)                                      ! sedpocn <-- sedpoca
130           END DO
131        END DO
132        !
133      ENDIF
134      !
135      IF( lrst_trc ) THEN
136         IF(lwp) WRITE(numout,*)
137         IF(lwp) WRITE(numout,*) 'p2z_exp : POC in sediment fields written in ocean restart file ',   &
138            &                    'at it= ', kt,' date= ', ndastp
139         IF(lwp) WRITE(numout,*) '~~~~'
140         CALL iom_rstput( kt, nitrst, numrtw, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
141         CALL iom_rstput( kt, nitrst, numrtw, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
142      ENDIF
143      !
144      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
145         WRITE(charout, FMT="('exp')")
146         CALL prt_ctl_trc_info(charout)
147         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
148      ENDIF
149      !
150      IF( ln_timing )  CALL timing_stop('p2z_exp')
151      !
152   END SUBROUTINE p2z_exp
153
154
155   SUBROUTINE p2z_exp_init
156      !!----------------------------------------------------------------------
157      !!                    ***  ROUTINE p4z_exp_init  ***
158      !! ** purpose :   specific initialisation for export
159      !!----------------------------------------------------------------------
160      INTEGER  ::   ji, jj, jk
161      REAL(wp) ::   zmaskt, zfluo, zfluu
162      REAL(wp), DIMENSION(jpi,jpj    ) :: zrro
163      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdm0
164      !!---------------------------------------------------------------------
165      !
166      IF(lwp) THEN
167         WRITE(numout,*)
168         WRITE(numout,*) ' p2z_exp: LOBSTER export'
169         WRITE(numout,*) ' ~~~~~~~'
170         WRITE(numout,*) '  compute remineralisation-damping arrays for tracers'
171      ENDIF
172      !
173
174      ! Calculate vertical distribution of newly formed biogenic poc
175      ! in the water column in the case of max. possible bottom depth
176      ! ------------------------------------------------------------
177      zdm0 = 0._wp
178      zrro = 1._wp
179      DO jk = jpkb, jpkm1
180         DO jj = 1, jpj
181            DO ji = 1, jpi
182               zfluo = ( gdepw_n(ji,jj,jk  ) / gdepw_n(ji,jj,jpkb) )**xhr
183               zfluu = ( gdepw_n(ji,jj,jk+1) / gdepw_n(ji,jj,jpkb) )**xhr
184               IF( zfluo.GT.1. )   zfluo = 1._wp
185               zdm0(ji,jj,jk) = zfluo - zfluu
186               IF( jk <= jpkb-1 )   zdm0(ji,jj,jk) = 0._wp
187               zrro(ji,jj) = zrro(ji,jj) - zdm0(ji,jj,jk)
188            END DO
189         END DO
190      END DO
191      !
192      zdm0(:,:,jpk) = zrro(:,:)
193
194      ! Calculate vertical distribution of newly formed biogenic poc
195      ! in the water column with realistic topography (first "dry" layer
196      ! contains total fraction, which has passed to the upper layers)
197      ! ----------------------------------------------------------------------
198      dminl(:,:)   = 0._wp
199      dmin3(:,:,:) = zdm0
200      DO jk = 1, jpk
201         DO jj = 1, jpj
202            DO ji = 1, jpi
203               IF( tmask(ji,jj,jk) == 0._wp ) THEN
204                  dminl(ji,jj) = dminl(ji,jj) + dmin3(ji,jj,jk)
205                  dmin3(ji,jj,jk) = 0._wp
206               ENDIF
207            END DO
208         END DO
209      END DO
210
211      DO jj = 1, jpj
212         DO ji = 1, jpi
213            IF( tmask(ji,jj,1) == 0 )   dmin3(ji,jj,1) = 0._wp
214         END DO
215      END DO
216
217      ! Coastal mask
218      cmask(:,:) = 0._wp
219      DO jj = 2, jpjm1
220         DO ji = fs_2, fs_jpim1
221            IF( tmask(ji,jj,1) /= 0. ) THEN
222               zmaskt = tmask(ji+1,jj,1) * tmask(ji-1,jj,1) * tmask(ji,jj+1,1) * tmask(ji,jj-1,1) 
223               IF( zmaskt == 0. )   cmask(ji,jj) = 1._wp
224            END IF
225         END DO
226      END DO
227      CALL lbc_lnk( cmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
228      areacot = glob_sum( e1e2t(:,:) * cmask(:,:) )
229      !
230      IF( ln_rsttr ) THEN
231         CALL iom_get( numrtr, jpdom_autoglo, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
232         CALL iom_get( numrtr, jpdom_autoglo, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
233      ELSE
234         sedpocb(:,:) = 0._wp
235         sedpocn(:,:) = 0._wp
236      ENDIF
237      !
238   END SUBROUTINE p2z_exp_init
239
240   INTEGER FUNCTION p2z_exp_alloc()
241      !!----------------------------------------------------------------------
242      !!                     ***  ROUTINE p2z_exp_alloc  ***
243      !!----------------------------------------------------------------------
244      ALLOCATE( cmask(jpi,jpj) , dminl(jpi,jpj) , dmin3(jpi,jpj,jpk), &
245         &      sedpocb(jpi,jpj) , sedpocn(jpi,jpj),   STAT=p2z_exp_alloc )
246      IF( p2z_exp_alloc /= 0 ) CALL ctl_warn('p2z_exp_alloc : failed to allocate arrays.')
247      !
248   END FUNCTION p2z_exp_alloc
249
250   !!======================================================================
251END MODULE p2zexp
Note: See TracBrowser for help on using the repository browser.