source: NEMO/branches/2018/dev_r9838_ENHANCE04_RK3/src/OCE/nemogcm.F90 @ 9939

Last change on this file since 9939 was 9939, checked in by gm, 2 years ago

#1911 (ENHANCE-04): RK3 branche phased with MLF@9937 branche

  • Property svn:keywords set to Id
File size: 31.5 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE step           ! NEMO time-stepping                 (stp     routine)
62   USE icbini         ! handle bergs, initialisation
63   USE icbstp         ! handle bergs, calving, themodynamics and transport
64   USE cpl_oasis3     ! OASIS3 coupling
65   USE c1d            ! 1D configuration
66   USE step_c1d       ! Time stepping loop for the 1D configuration
67   USE dyndmp         ! Momentum damping
68   USE stopar         ! Stochastic param.: ???
69   USE stopts         ! Stochastic param.: ???
70   USE diurnal_bulk   ! diurnal bulk SST
71   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
72   USE crsini         ! initialise grid coarsening utility
73   USE diatmb         ! Top,middle,bottom output
74   USE dia25h         ! 25h mean output
75   USE sbc_oce , ONLY : lk_oasis
76   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
77#if defined key_top
78   USE trcini         ! passive tracer initialisation
79#endif
80#if defined key_nemocice_decomp
81   USE ice_domain_size, only: nx_global, ny_global
82#endif
83   !
84   USE lib_mpp        ! distributed memory computing
85   USE mppini         ! shared/distributed memory setting (mpp_init routine)
86   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
87   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
88#if defined key_iomput
89   USE xios           ! xIOserver
90#endif
91#if defined key_agrif
92   USE agrif_all_update   ! Master Agrif update
93#endif
94
95   IMPLICIT NONE
96   PRIVATE
97
98   PUBLIC   nemo_gcm    ! called by model.F90
99   PUBLIC   nemo_init   ! needed by AGRIF
100   PUBLIC   nemo_alloc  ! needed by TAM
101
102   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
103
104   !!----------------------------------------------------------------------
105   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
106   !! $Id$
107   !! Software governed by the CeCILL licence     (./LICENSE)
108   !!----------------------------------------------------------------------
109CONTAINS
110
111   SUBROUTINE nemo_gcm
112      !!----------------------------------------------------------------------
113      !!                     ***  ROUTINE nemo_gcm  ***
114      !!
115      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
116      !!              curvilinear mesh on the sphere.
117      !!
118      !! ** Method  : - model general initialization
119      !!              - launch the time-stepping (stp routine)
120      !!              - finalize the run by closing files and communications
121      !!
122      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
123      !!              Madec, 2008, internal report, IPSL.
124      !!----------------------------------------------------------------------
125      INTEGER ::   istp   ! time step index
126      !!----------------------------------------------------------------------
127      !
128#if defined key_agrif
129      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
130#endif
131      !                            !-----------------------!
132      CALL nemo_init               !==  Initialisations  ==!
133      !                            !-----------------------!
134#if defined key_agrif
135      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
136      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
137# if defined key_top
138      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
139# endif
140# if defined key_si3
141      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
142# endif
143#endif
144      ! check that all process are still there... If some process have an error,
145      ! they will never enter in step and other processes will wait until the end of the cpu time!
146      IF( lk_mpp )   CALL mpp_max( nstop )
147
148      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
149
150      !                            !-----------------------!
151      !                            !==   time stepping   ==!
152      !                            !-----------------------!
153      !
154      !                                               !== set the model time-step  ==!
155      !
156      IF( l_1st_euler ) THEN   ;   rDt =         rn_Dt   ;   l_1st_euler = .TRUE.    ! start or restart with Euler 1st time-step
157      ELSE                     ;   rDt = 2._wp * rn_Dt   ;   l_1st_euler = .FALSE.   ! restart with leapfrog
158      ENDIF
159      r1_Dt = 1._wp / rDt
160      ! NB: if l_1st_euler=T, rDt will be set to 2*rn_Dt at the end of the 1st time-step (in step.F90)
161      !     Done here (not in domain.F90) as in ASM initialization an Euler 1st time step can be forced
162      !
163      !
164      istp = nit000
165      !
166#if defined key_c1d
167      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
168         CALL stp_c1d( istp )
169         istp = istp + 1
170      END DO
171#else
172      !
173# if defined key_agrif
174      !                                               !==  AGRIF time-stepping  ==!
175      CALL Agrif_Regrid()
176      !
177      ! Recursive update from highest nested level to lowest:
178      CALL Agrif_step_child_adj(Agrif_Update_All)
179      !
180      DO WHILE( istp <= nitend .AND. nstop == 0 )
181         CALL stp
182         istp = istp + 1
183      END DO
184      !
185      IF( .NOT. Agrif_Root() ) THEN
186         CALL Agrif_ParentGrid_To_ChildGrid()
187         IF( ln_diaobs )   CALL dia_obs_wri
188         IF( ln_timing )   CALL timing_finalize
189         CALL Agrif_ChildGrid_To_ParentGrid()
190      ENDIF
191      !
192# else
193      !
194      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
195         !
196         DO WHILE( istp <= nitend .AND. nstop == 0 )
197            CALL stp        ( istp ) 
198            istp = istp + 1
199         END DO
200         !
201      ELSE                                            !==  diurnal SST time-steeping only  ==!
202         !
203         DO WHILE( istp <= nitend .AND. nstop == 0 )
204            CALL stp_diurnal( istp )   ! time step only the diurnal SST
205            istp = istp + 1
206         END DO
207         !
208      ENDIF
209      !
210# endif
211      !
212#endif
213      !
214      IF( ln_diaobs   )   CALL dia_obs_wri
215      !
216      IF( ln_icebergs )   CALL icb_end( nitend )
217
218      !                            !------------------------!
219      !                            !==  finalize the run  ==!
220      !                            !------------------------!
221      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
222      !
223      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
224         WRITE(numout,cform_err)
225         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
226         WRITE(numout,*)
227      ENDIF
228      !
229      IF( ln_timing )   CALL timing_finalize
230      !
231      CALL nemo_closefile
232      !
233#if defined key_iomput
234                                    CALL xios_finalize  ! end mpp communications with xios
235      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
236#else
237      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
238      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
239      ENDIF
240#endif
241      !
242   END SUBROUTINE nemo_gcm
243
244
245   SUBROUTINE nemo_init
246      !!----------------------------------------------------------------------
247      !!                     ***  ROUTINE nemo_init  ***
248      !!
249      !! ** Purpose :   initialization of the NEMO GCM
250      !!----------------------------------------------------------------------
251      INTEGER  ::   ji                 ! dummy loop indices
252      INTEGER  ::   ios, ilocal_comm   ! local integers
253      CHARACTER(len=120), DIMENSION(60) ::   cltxt, cltxt2, clnam
254      !!
255      NAMELIST/namctl/ ln_ctl   , nn_print, nn_ictls, nn_ictle,   &
256         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,   &
257         &             ln_timing, ln_diacfl
258      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
259      !!----------------------------------------------------------------------
260      !
261      cltxt  = ''
262      cltxt2 = ''
263      clnam  = '' 
264      cxios_context = 'nemo'
265      !
266      !                             ! Open reference namelist and configuration namelist files
267      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
268      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
269      !
270      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
271      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
272901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
273      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
274      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
275902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
276      !
277      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
278      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
279903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
280      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
281      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
282904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
283
284      !                             !--------------------------!
285      !                             !  Set global domain size  !   (control print return in cltxt2)
286      !                             !--------------------------!
287      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
288         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
289         !
290      ELSE                                ! user-defined namelist
291         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
292      ENDIF
293      !
294      !
295      !                             !--------------------------------------------!
296      !                             !  set communicator & select the local node  !
297      !                             !  NB: mynode also opens output.namelist.dyn !
298      !                             !      on unit number numond on first proc   !
299      !                             !--------------------------------------------!
300#if defined key_iomput
301      IF( Agrif_Root() ) THEN
302         IF( lk_oasis ) THEN
303            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
304            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
305         ELSE
306            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
307         ENDIF
308      ENDIF
309      ! Nodes selection (control print return in cltxt)
310      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
311#else
312      IF( lk_oasis ) THEN
313         IF( Agrif_Root() ) THEN
314            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
315         ENDIF
316         ! Nodes selection (control print return in cltxt)
317         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
318      ELSE
319         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
320         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
321      ENDIF
322#endif
323
324      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
325
326      lwm = (narea == 1)                                    ! control of output namelists
327      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
328
329      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
330         !                       ! now that the file has been opened in call to mynode.
331         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
332         WRITE( numond, namctl )
333         WRITE( numond, namcfg )
334         IF( .NOT.ln_read_cfg ) THEN
335            DO ji = 1, SIZE(clnam)
336               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
337            END DO
338         ENDIF
339      ENDIF
340
341      IF(lwp) THEN                            ! open listing units
342         !
343         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
344         !
345         WRITE(numout,*)
346         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
347         WRITE(numout,*) '                       NEMO team'
348         WRITE(numout,*) '            Ocean General Circulation Model'
349         WRITE(numout,*) '                NEMO version 4.0  (2017) '
350         WRITE(numout,*)
351         WRITE(numout,*)
352         DO ji = 1, SIZE(cltxt)
353            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) cltxt(ji)    ! control print of mynode
354         END DO
355         WRITE(numout,*)
356         WRITE(numout,*)
357         DO ji = 1, SIZE(cltxt2)
358            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) cltxt2(ji)   ! control print of domain size
359         END DO
360         !
361         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
362         !
363      ENDIF
364      !                                      ! Domain decomposition
365      CALL mpp_init                          ! MPP
366
367      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
368      CALL nemo_alloc()
369
370      !                             !-------------------------------!
371      !                             !  NEMO general initialization  !
372      !                             !-------------------------------!
373
374      CALL nemo_ctl                          ! Control prints
375      !
376      !                                      ! General initialization
377      IF( ln_timing    )   CALL timing_init     ! timing
378      IF( ln_timing    )   CALL timing_start( 'nemo_init')
379      !
380                           CALL     phy_cst         ! Physical constants
381                           CALL     eos_init        ! Equation of state
382      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
383                           CALL     wad_init        ! Wetting and drying options
384                           CALL     dom_init("OPA") ! Domain
385      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
386      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
387     
388      CALL diurnal_sst_bulk_init                ! diurnal sst
389      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
390      !                           
391      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
392         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
393         CALL     sbc_init                            ! Forcings : surface module
394         CALL tra_qsr_init                            ! penetrative solar radiation qsr
395         IF( ln_diaobs ) THEN                         ! Observation & model comparison
396            CALL dia_obs_init                            ! Initialize observational data
397            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
398         ENDIF     
399         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
400         !
401         RETURN                                       ! end of initialization
402      ENDIF
403     
404                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
405
406      !                                      ! external forcing
407                           CALL    tide_init    ! tidal harmonics
408                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
409                           CALL     bdy_init    ! Open boundaries initialisation
410
411      !                                      ! Ocean physics
412                           CALL zdf_phy_init    ! Vertical physics
413                                     
414      !                                         ! Lateral physics
415                           CALL ldf_tra_init      ! Lateral ocean tracer physics
416                           CALL ldf_eiv_init      ! eddy induced velocity param.
417                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
418
419      !                                      ! Active tracers
420      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
421                           CALL tra_bbc_init      ! bottom heat flux
422      IF( ln_trabbl    )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
423                           CALL tra_dmp_init      ! internal tracer damping
424                           CALL tra_adv_init      ! horizontal & vertical advection
425                           CALL tra_ldf_init      ! lateral mixing
426
427      !                                      ! Dynamics
428      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
429                           CALL dyn_adv_init      ! advection (vector or flux form)
430                           CALL dyn_vor_init      ! vorticity term including Coriolis
431                           CALL dyn_ldf_init      ! lateral mixing
432                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
433                           CALL dyn_spg_init      ! surface pressure gradient
434
435#if defined key_top
436      !                                      ! Passive tracers
437                           CALL     trc_init
438#endif
439      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
440
441      !                                      ! Icebergs
442                           CALL icb_init( rn_Dt, nit000 )   ! initialise icebergs instance
443
444      !                                      ! Misc. options
445                           CALL sto_par_init    ! Stochastic parametrization
446      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
447     
448      !                                      ! Diagnostics
449      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
450      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
451                           CALL dia_ptr_init    ! Poleward TRansports initialization
452      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
453                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
454                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
455                           CALL dia_obs_init    ! Initialize observational data
456                           CALL dia_tmb_init    ! TMB outputs
457                           CALL dia_25h_init    ! 25h mean  outputs
458      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
459
460      !                                      ! Assimilation increments
461      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
462      !
463      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
464      !
465      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
466      !
467   END SUBROUTINE nemo_init
468
469
470   SUBROUTINE nemo_ctl
471      !!----------------------------------------------------------------------
472      !!                     ***  ROUTINE nemo_ctl  ***
473      !!
474      !! ** Purpose :   control print setting
475      !!
476      !! ** Method  : - print namctl information and check some consistencies
477      !!----------------------------------------------------------------------
478      !
479      IF(lwp) THEN                  ! control print
480         WRITE(numout,*)
481         WRITE(numout,*) 'nemo_ctl: Control prints'
482         WRITE(numout,*) '~~~~~~~~'
483         WRITE(numout,*) '   Namelist namctl'
484         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
485         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
486         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
487         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
488         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
489         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
490         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
491         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
492         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
493         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
494      ENDIF
495      !
496      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
497      nictls    = nn_ictls
498      nictle    = nn_ictle
499      njctls    = nn_jctls
500      njctle    = nn_jctle
501      isplt     = nn_isplt
502      jsplt     = nn_jsplt
503
504      IF(lwp) THEN                  ! control print
505         WRITE(numout,*)
506         WRITE(numout,*) '   Namelist namcfg'
507         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
508         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
509         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
510         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
511         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
512         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
513      ENDIF
514      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
515      !
516      !                             ! Parameter control
517      !
518      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
519         IF( lk_mpp .AND. jpnij > 1 ) THEN
520            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
521         ELSE
522            IF( isplt == 1 .AND. jsplt == 1  ) THEN
523               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
524                  &           ' - the print control will be done over the whole domain' )
525            ENDIF
526            ijsplt = isplt * jsplt            ! total number of processors ijsplt
527         ENDIF
528         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
529         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
530         !
531         !                              ! indices used for the SUM control
532         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
533            lsp_area = .FALSE.
534         ELSE                                             ! print control done over a specific  area
535            lsp_area = .TRUE.
536            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
537               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
538               nictls = 1
539            ENDIF
540            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
541               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
542               nictle = jpiglo
543            ENDIF
544            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
545               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
546               njctls = 1
547            ENDIF
548            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
549               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
550               njctle = jpjglo
551            ENDIF
552         ENDIF
553      ENDIF
554      !
555      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
556         &                                                'Compile with key_nosignedzero enabled' )
557      !
558#if defined key_agrif
559      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
560#endif
561      !
562   END SUBROUTINE nemo_ctl
563
564
565   SUBROUTINE nemo_closefile
566      !!----------------------------------------------------------------------
567      !!                     ***  ROUTINE nemo_closefile  ***
568      !!
569      !! ** Purpose :   Close the files
570      !!----------------------------------------------------------------------
571      !
572      IF( lk_mpp )   CALL mppsync
573      !
574      CALL iom_close                                 ! close all input/output files managed by iom_*
575      !
576      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
577      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
578      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
579      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
580      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
581      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
582      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
583      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
584      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
585      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
586      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
587      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
588      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
589      !
590      numout = 6                                     ! redefine numout in case it is used after this point...
591      !
592   END SUBROUTINE nemo_closefile
593
594
595   SUBROUTINE nemo_alloc
596      !!----------------------------------------------------------------------
597      !!                     ***  ROUTINE nemo_alloc  ***
598      !!
599      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
600      !!
601      !! ** Method  :
602      !!----------------------------------------------------------------------
603      USE diawri    , ONLY : dia_wri_alloc
604      USE dom_oce   , ONLY : dom_oce_alloc
605      USE trc_oce   , ONLY : trc_oce_alloc
606      USE bdy_oce   , ONLY : bdy_oce_alloc
607#if defined key_diadct 
608      USE diadct    , ONLY : diadct_alloc 
609#endif 
610      !
611      INTEGER :: ierr
612      !!----------------------------------------------------------------------
613      !
614      ierr =        oce_alloc    ()    ! ocean
615      ierr = ierr + dia_wri_alloc()
616      ierr = ierr + dom_oce_alloc()    ! ocean domain
617      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
618      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
619      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
620      !
621#if defined key_diadct 
622      ierr = ierr + diadct_alloc ()    !
623#endif 
624      !
625      IF( lk_mpp    )   CALL mpp_sum( ierr )
626      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
627      !
628   END SUBROUTINE nemo_alloc
629
630   !!======================================================================
631END MODULE nemogcm
632
Note: See TracBrowser for help on using the repository browser.