New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icedyn.F90 in NEMO/branches/2018/dev_r9947_SI3_advection/tests/ICEADV/MY_SRC – NEMO

source: NEMO/branches/2018/dev_r9947_SI3_advection/tests/ICEADV/MY_SRC/icedyn.F90 @ 10277

Last change on this file since 10277 was 10277, checked in by clem, 5 years ago

add a test case from Lipscomb2004
File size: 15.5 KB
Line 
1MODULE icedyn
2   !!======================================================================
3   !!                     ***  MODULE  icedyn  ***
4   !!   Sea-Ice dynamics : master routine for sea ice dynamics
5   !!======================================================================
6   !! history :  4.0  ! 2018  (C. Rousset)  original code SI3 [aka Sea Ice cube]
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_dyn       : dynamics of sea ice
13   !!   ice_dyn_init  : initialization and namelist read
14   !!----------------------------------------------------------------------
15   USE phycst         ! physical constants
16   USE dom_oce        ! ocean space and time domain
17   USE ice            ! sea-ice: variables
18   USE icedyn_rhg     ! sea-ice: rheology
19   USE icedyn_adv     ! sea-ice: advection
20   USE icedyn_rdgrft  ! sea-ice: ridging/rafting
21   USE icecor         ! sea-ice: corrections
22   USE icevar         ! sea-ice: operations
23   !
24   USE in_out_manager ! I/O manager
25   USE iom            ! I/O manager library
26   USE lib_mpp        ! MPP library
27   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
28   USE lbclnk         ! lateral boundary conditions (or mpp links)
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   ice_dyn        ! called by icestp.F90
35   PUBLIC   ice_dyn_init   ! called by icestp.F90
36   
37   INTEGER ::              nice_dyn   ! choice of the type of dynamics
38   !                                        ! associated indices:
39   INTEGER, PARAMETER ::   np_dynFULL    = 1   ! full ice dynamics               (rheology + advection + ridging/rafting + correction)
40   INTEGER, PARAMETER ::   np_dynRHGADV  = 2   ! pure dynamics                   (rheology + advection)
41   INTEGER, PARAMETER ::   np_dynADV     = 3   ! only advection w prescribed vel.(rn_uvice + advection)
42   !
43   ! ** namelist (namdyn) **
44   LOGICAL  ::   ln_dynFULL       ! full ice dynamics               (rheology + advection + ridging/rafting + correction)
45   LOGICAL  ::   ln_dynRHGADV     ! no ridge/raft & no corrections  (rheology + advection)
46   LOGICAL  ::   ln_dynADV        ! only advection w prescribed vel.(rn_uvice + advection)
47   REAL(wp) ::   rn_uice          !    prescribed u-vel (case np_dynADV)
48   REAL(wp) ::   rn_vice          !    prescribed v-vel (case np_dynADV)
49   
50   !! * Substitutions
51#  include "vectopt_loop_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
54   !! $Id: icedyn.F90 8378 2017-07-26 13:55:59Z clem $
55   !! Software governed by the CeCILL licence     (./LICENSE)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE ice_dyn( kt )
60      !!-------------------------------------------------------------------
61      !!               ***  ROUTINE ice_dyn  ***
62      !!               
63      !! ** Purpose :   this routine manages sea ice dynamics
64      !!
65      !! ** Action : - calculation of friction in case of landfast ice
66      !!             - call ice_dyn_rhg    = rheology
67      !!             - call ice_dyn_adv    = advection
68      !!             - call ice_dyn_rdgrft = ridging/rafting
69      !!             - call ice_cor        = corrections if fields are out of bounds
70      !!--------------------------------------------------------------------
71      INTEGER, INTENT(in) ::   kt     ! ice time step
72      !!
73      INTEGER  ::   ji, jj, jl        ! dummy loop indices
74      REAL(wp) ::   zcoefu, zcoefv
75      REAL(wp),              DIMENSION(jpi,jpj,jpl) ::   zhmax
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:)         ::   zdivu_i
77      !!--------------------------------------------------------------------
78      !
79      IF( ln_timing )   CALL timing_start('icedyn')
80      !
81      IF( kt == nit000 .AND. lwp ) THEN
82         WRITE(numout,*)
83         WRITE(numout,*)'ice_dyn: sea-ice dynamics'
84         WRITE(numout,*)'~~~~~~~'
85      ENDIF
86
87      !                     
88      IF( ln_landfast ) THEN            !-- Landfast ice parameterization: define max bottom friction
89         tau_icebfr(:,:) = 0._wp
90         DO jl = 1, jpl
91            WHERE( h_i(:,:,jl) > ht_n(:,:) * rn_gamma )   tau_icebfr(:,:) = tau_icebfr(:,:) + a_i(:,:,jl) * rn_icebfr
92         END DO
93         IF( iom_use('tau_icebfr') )   CALL iom_put( 'tau_icebfr', tau_icebfr ) 
94      ENDIF
95
96      zhmax(:,:,:) = h_i_b(:,:,:)      !-- Record max of the surrounding 9-pts ice thick. (for CALL Hbig)
97      DO jl = 1, jpl
98         DO jj = 2, jpjm1
99            DO ji = 2, jpim1
100!!gm use of MAXVAL here is very probably less efficient than expending the 9 values
101               zhmax(ji,jj,jl) = MAX( epsi20, MAXVAL( h_i_b(ji-1:ji+1,jj-1:jj+1,jl) ) )
102            END DO
103         END DO
104      END DO
105      CALL lbc_lnk( zhmax(:,:,:), 'T', 1. )
106      !
107      !
108      SELECT CASE( nice_dyn )           !-- Set which dynamics is running
109
110      CASE ( np_dynFULL )          !==  all dynamical processes  ==!
111         CALL ice_dyn_rhg   ( kt )                            ! -- rheology 
112         CALL ice_dyn_adv   ( kt )   ;   CALL Hbig( zhmax )   ! -- advection of ice + correction on ice thickness
113         CALL ice_dyn_rdgrft( kt )                            ! -- ridging/rafting
114         CALL ice_cor       ( kt , 1 )                        ! -- Corrections
115
116      CASE ( np_dynRHGADV  )       !==  no ridge/raft & no corrections ==!
117         CALL ice_dyn_rhg   ( kt )                            ! -- rheology 
118         CALL ice_dyn_adv   ( kt )                            ! -- advection of ice
119         CALL Hpiling                                         ! -- simple pile-up (replaces ridging/rafting)
120
121      CASE ( np_dynADV )           !==  pure advection ==!   (prescribed velocities)
122
123         ALLOCATE( zdivu_i(jpi,jpj) )
124
125         !u_ice(:,:) = rn_uice * umask(:,:,1)
126         !v_ice(:,:) = rn_vice * vmask(:,:,1)
127         !CALL RANDOM_NUMBER(u_ice(:,:)) ; u_ice(:,:) = u_ice(:,:) * 0.1 + rn_uice * umask(:,:,1)
128         !CALL RANDOM_NUMBER(v_ice(:,:)) ; v_ice(:,:) = v_ice(:,:) * 0.1 + rn_vice * vmask(:,:,1)
129         ! --- monotonicity test from Lipscomb et al 2004 --- !
130         ! CFL = 0.5 at a distance from the bound of 1/6 of the basin length
131         ! Then for dx = 2m and dt = 1s => rn_uice = u (1/6th) = 1m/s
132         DO jj = 1, jpj
133            DO ji = 1, jpi
134            !   IF( (ji+nimpp-1) < ((jpiglo+1)/6)-5 .OR. (ji+nimpp-1) > (5*(jpiglo+1)/6)+5 ) THEN
135            !      u_ice(ji,jj) = 0._wp
136            !      v_ice(ji,jj) = 0._wp
137            !   ELSE
138                  zcoefu = ( REAL(jpiglo+1)*0.5 - REAL(ji+nimpp-1) ) / ( REAL(jpiglo+1)*0.5 - 1. )
139                  zcoefv = ( REAL(jpjglo+1)*0.5 - REAL(jj+njmpp-1) ) / ( REAL(jpjglo+1)*0.5 - 1. )
140                  u_ice(ji,jj) = rn_uice * 1.5 * SIGN( 1., zcoefu ) * ABS( zcoefu ) * umask(ji,jj,1)
141                  v_ice(ji,jj) = rn_vice * 1.5 * SIGN( 1., zcoefv ) * ABS( zcoefv ) * vmask(ji,jj,1)
142             !  ENDIF
143            END DO
144         END DO
145         ! ---
146         CALL ice_dyn_adv   ( kt )                            ! -- advection of ice
147
148         ! diagnostics: divergence at T points
149         DO jj = 2, jpjm1
150            DO ji = 2, jpim1
151               zdivu_i(ji,jj) = ( e2u(ji,jj) * u_ice(ji,jj) - e2u(ji-1,jj) * u_ice(ji-1,jj)   &
152                  &             + e1v(ji,jj) * v_ice(ji,jj) - e1v(ji,jj-1) * v_ice(ji,jj-1) ) * r1_e1e2t(ji,jj)
153            END DO
154         END DO
155         CALL lbc_lnk( zdivu_i, 'T', 1. )
156         IF( iom_use('icediv') )   CALL iom_put( "icediv" , zdivu_i(:,:) )
157
158         DEALLOCATE( zdivu_i )
159
160      END SELECT
161      !
162      IF( ln_timing )   CALL timing_stop('icedyn')
163      !
164   END SUBROUTINE ice_dyn
165
166
167   SUBROUTINE Hbig( phmax )
168      !!-------------------------------------------------------------------
169      !!                  ***  ROUTINE Hbig  ***
170      !!
171      !! ** Purpose : Thickness correction in case advection scheme creates
172      !!              abnormally tick ice
173      !!
174      !! ** Method  : 1- check whether ice thickness resulting from advection is
175      !!                 larger than the surrounding 9-points before advection
176      !!                 and reduce it if a) divergence or b) convergence & at_i>0.8
177      !!              2- bound ice thickness with hi_max (99m)
178      !!
179      !! ** input   : Max thickness of the surrounding 9-points
180      !!-------------------------------------------------------------------
181      REAL(wp), DIMENSION(:,:,:), INTENT(in) ::   phmax   ! max ice thick from surrounding 9-pts
182      !
183      INTEGER  ::   ji, jj, jl         ! dummy loop indices
184      REAL(wp) ::   zh, zdv
185      !!-------------------------------------------------------------------
186      !
187      CALL ice_var_zapsmall                       !-- zap small areas
188      !
189      DO jl = 1, jpl
190         DO jj = 1, jpj
191            DO ji = 1, jpi
192               IF ( v_i(ji,jj,jl) > 0._wp ) THEN  !-- bound to hmax
193                  !
194                  zh  = v_i (ji,jj,jl) / a_i(ji,jj,jl)
195                  zdv = v_i(ji,jj,jl) - v_i_b(ji,jj,jl) 
196                  !
197                  IF ( ( zdv >  0.0 .AND. zh > phmax(ji,jj,jl) .AND. at_i_b(ji,jj) < 0.80 ) .OR. &
198                     & ( zdv <= 0.0 .AND. zh > phmax(ji,jj,jl) ) ) THEN
199                     a_i (ji,jj,jl) = v_i(ji,jj,jl) / MIN( phmax(ji,jj,jl), hi_max(jpl) )   !-- bound h_i to hi_max (99 m)
200                  ENDIF
201                  !
202               ENDIF
203            END DO
204         END DO
205      END DO 
206      !                                           !-- correct pond fraction to avoid a_ip > a_i
207      WHERE( a_ip(:,:,:) > a_i(:,:,:) )   a_ip(:,:,:) = a_i(:,:,:)
208      !
209   END SUBROUTINE Hbig
210
211
212   SUBROUTINE Hpiling
213      !!-------------------------------------------------------------------
214      !!                  ***  ROUTINE Hpiling  ***
215      !!
216      !! ** Purpose : Simple conservative piling comparable with 1-cat models
217      !!
218      !! ** Method  : pile-up ice when no ridging/rafting
219      !!
220      !! ** input   : a_i
221      !!-------------------------------------------------------------------
222      INTEGER ::   jl         ! dummy loop indices
223      !!-------------------------------------------------------------------
224      !
225      CALL ice_var_zapsmall                       !-- zap small areas
226      !
227      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
228      DO jl = 1, jpl
229         WHERE( at_i(:,:) > epsi20 )
230            a_i(:,:,jl) = a_i(:,:,jl) * (  1._wp + MIN( rn_amax_2d(:,:) - at_i(:,:) , 0._wp ) / at_i(:,:)  )
231         END WHERE
232      END DO
233      !
234   END SUBROUTINE Hpiling
235
236
237   SUBROUTINE ice_dyn_init
238      !!-------------------------------------------------------------------
239      !!                  ***  ROUTINE ice_dyn_init  ***
240      !!
241      !! ** Purpose : Physical constants and parameters linked to the ice
242      !!      dynamics
243      !!
244      !! ** Method  :  Read the namdyn namelist and check the ice-dynamic
245      !!       parameter values called at the first timestep (nit000)
246      !!
247      !! ** input   :   Namelist namdyn
248      !!-------------------------------------------------------------------
249      INTEGER ::   ios, ioptio   ! Local integer output status for namelist read
250      !!
251      NAMELIST/namdyn/ ln_dynFULL, ln_dynRHGADV, ln_dynADV, rn_uice, rn_vice,  &
252         &             rn_ishlat  ,                                            &
253         &             ln_landfast, rn_gamma , rn_icebfr, rn_lfrelax
254      !!-------------------------------------------------------------------
255      !
256      REWIND( numnam_ice_ref )         ! Namelist namdyn in reference namelist : Ice dynamics
257      READ  ( numnam_ice_ref, namdyn, IOSTAT = ios, ERR = 901)
258901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn in reference namelist', lwp )
259      REWIND( numnam_ice_cfg )         ! Namelist namdyn in configuration namelist : Ice dynamics
260      READ  ( numnam_ice_cfg, namdyn, IOSTAT = ios, ERR = 902 )
261902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn in configuration namelist', lwp )
262      IF(lwm) WRITE( numoni, namdyn )
263      !
264      IF(lwp) THEN                     ! control print
265         WRITE(numout,*)
266         WRITE(numout,*) 'ice_dyn_init: ice parameters for ice dynamics '
267         WRITE(numout,*) '~~~~~~~~~~~~'
268         WRITE(numout,*) '   Namelist namdyn:'
269         WRITE(numout,*) '      Full ice dynamics      (rhg + adv + ridge/raft + corr)  ln_dynFULL   = ', ln_dynFULL
270         WRITE(numout,*) '      No ridge/raft & No cor (rhg + adv)                      ln_dynRHGADV = ', ln_dynRHGADV
271         WRITE(numout,*) '      Advection only         (rn_uvice + adv)                 ln_dynADV    = ', ln_dynADV
272         WRITE(numout,*) '         with prescribed velocity given by   (u,v)_ice = (rn_uice,rn_vice) = (', rn_uice,',', rn_vice,')'
273         WRITE(numout,*) '      lateral boundary condition for sea ice dynamics         rn_ishlat    = ', rn_ishlat
274         WRITE(numout,*) '      Landfast: param (T or F)                                ln_landfast  = ', ln_landfast
275         WRITE(numout,*) '         fraction of ocean depth that ice must reach          rn_gamma     = ', rn_gamma
276         WRITE(numout,*) '         maximum bottom stress per unit area of contact       rn_icebfr    = ', rn_icebfr
277         WRITE(numout,*) '         relax time scale (s-1) to reach static friction      rn_lfrelax   = ', rn_lfrelax
278         WRITE(numout,*)
279      ENDIF
280      !                             !== set the choice of ice dynamics ==!
281      ioptio = 0 
282      !      !--- full dynamics                               (rheology + advection + ridging/rafting + correction)
283      IF( ln_dynFULL   ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynFULL      ;   ENDIF
284      !      !--- dynamics without ridging/rafting and corr   (rheology + advection)
285      IF( ln_dynRHGADV ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynRHGADV    ;   ENDIF
286      !      !--- advection only with prescribed ice velocities (from namelist)
287      IF( ln_dynADV    ) THEN   ;   ioptio = ioptio + 1   ;   nice_dyn = np_dynADV       ;   ENDIF
288      !
289      IF( ioptio /= 1 )    CALL ctl_stop( 'ice_dyn_init: one and only one ice dynamics option has to be defined ' )
290      !
291      !                                      !--- Lateral boundary conditions
292      IF     (      rn_ishlat == 0.                ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  free-slip'
293      ELSEIF (      rn_ishlat == 2.                ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  no-slip'
294      ELSEIF ( 0. < rn_ishlat .AND. rn_ishlat < 2. ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  partial-slip'
295      ELSEIF ( 2. < rn_ishlat                      ) THEN   ;   IF(lwp) WRITE(numout,*) '   ===>>>   ice lateral  strong-slip'
296      ENDIF
297      !                                      !--- NO Landfast ice : set to zero once for all
298      IF( .NOT.ln_landfast )   tau_icebfr(:,:) = 0._wp
299      !
300      CALL ice_dyn_rdgrft_init          ! set ice ridging/rafting parameters
301      CALL ice_dyn_rhg_init             ! set ice rheology parameters
302      CALL ice_dyn_adv_init             ! set ice advection parameters
303      !
304   END SUBROUTINE ice_dyn_init
305
306#else
307   !!----------------------------------------------------------------------
308   !!   Default option         Empty module           NO SI3 sea-ice model
309   !!----------------------------------------------------------------------
310#endif 
311
312   !!======================================================================
313END MODULE icedyn
Note: See TracBrowser for help on using the repository browser.