| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !! 3.6 ! 2014-11 (P. Mathiot, C. Harris) add ice shelves melting |
|---|
| 16 | !! 4.0 ! 2016-06 (L. Brodeau) new general bulk formulation |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! sbc_init : read namsbc namelist |
|---|
| 21 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 22 | !! sbc_final : Finalize CICE ice model (if used) |
|---|
| 23 | !!---------------------------------------------------------------------- |
|---|
| 24 | USE oce ! ocean dynamics and tracers |
|---|
| 25 | USE dom_oce ! ocean space and time domain |
|---|
| 26 | USE closea ! closed seas |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 29 | USE trc_oce ! shared ocean-passive tracers variables |
|---|
| 30 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 31 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 32 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 33 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 34 | USE sbcblk ! surface boundary condition: bulk formulation |
|---|
| 35 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 36 | #if defined key_si3 |
|---|
| 37 | USE icestp ! surface boundary condition: SI3 sea-ice model |
|---|
| 38 | #endif |
|---|
| 39 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 40 | USE sbcisf ! surface boundary condition: ice-shelf |
|---|
| 41 | USE sbccpl ! surface boundary condition: coupled formulation |
|---|
| 42 | USE cpl_oasis3 ! OASIS routines for coupling |
|---|
| 43 | USE sbcclo ! surface boundary condition: closed sea correction |
|---|
| 44 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 45 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 46 | USE sbcapr ! surface boundary condition: atmo pressure |
|---|
| 47 | USE sbcisf ! surface boundary condition: ice shelf |
|---|
| 48 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 49 | USE icbstp ! Icebergs |
|---|
| 50 | USE icb_oce , ONLY : ln_passive_mode ! iceberg interaction mode |
|---|
| 51 | USE traqsr ! active tracers: light penetration |
|---|
| 52 | USE sbcwave ! Wave module |
|---|
| 53 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 54 | USE usrdef_sbc ! user defined: surface boundary condition |
|---|
| 55 | USE closea ! closed sea |
|---|
| 56 | ! |
|---|
| 57 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 58 | USE iom ! IOM library |
|---|
| 59 | USE in_out_manager ! I/O manager |
|---|
| 60 | USE lib_mpp ! MPP library |
|---|
| 61 | USE timing ! Timing |
|---|
| 62 | USE wet_dry |
|---|
| 63 | USE diurnal_bulk, ONLY: ln_diurnal_only ! diurnal SST diagnostic |
|---|
| 64 | |
|---|
| 65 | IMPLICIT NONE |
|---|
| 66 | PRIVATE |
|---|
| 67 | |
|---|
| 68 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 69 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 70 | |
|---|
| 71 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 72 | |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 75 | !! $Id$ |
|---|
| 76 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 77 | !!---------------------------------------------------------------------- |
|---|
| 78 | CONTAINS |
|---|
| 79 | |
|---|
| 80 | SUBROUTINE sbc_init |
|---|
| 81 | !!--------------------------------------------------------------------- |
|---|
| 82 | !! *** ROUTINE sbc_init *** |
|---|
| 83 | !! |
|---|
| 84 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 85 | !! |
|---|
| 86 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 87 | !! Call init routines for all other SBC modules that have one |
|---|
| 88 | !! |
|---|
| 89 | !! ** Action : - read namsbc parameters |
|---|
| 90 | !! - nsbc: type of sbc |
|---|
| 91 | !!---------------------------------------------------------------------- |
|---|
| 92 | INTEGER :: ios, icpt ! local integer |
|---|
| 93 | LOGICAL :: ll_purecpl, ll_opa, ll_not_nemo ! local logical |
|---|
| 94 | !! |
|---|
| 95 | NAMELIST/namsbc/ nn_fsbc , & |
|---|
| 96 | & ln_usr , ln_flx , ln_blk , & |
|---|
| 97 | & ln_cpl , ln_mixcpl, nn_components, & |
|---|
| 98 | & nn_ice , ln_ice_embd, & |
|---|
| 99 | & ln_traqsr, ln_dm2dc , & |
|---|
| 100 | & ln_rnf , nn_fwb , ln_ssr , ln_isf , ln_apr_dyn , & |
|---|
| 101 | & ln_wave , ln_cdgw , ln_sdw , ln_tauwoc , ln_stcor , & |
|---|
| 102 | & ln_tauw , nn_lsm, nn_sdrift |
|---|
| 103 | !!---------------------------------------------------------------------- |
|---|
| 104 | ! |
|---|
| 105 | IF(lwp) THEN |
|---|
| 106 | WRITE(numout,*) |
|---|
| 107 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 108 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 109 | ENDIF |
|---|
| 110 | ! |
|---|
| 111 | ! !** read Surface Module namelist |
|---|
| 112 | REWIND( numnam_ref ) !* Namelist namsbc in reference namelist : Surface boundary |
|---|
| 113 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 114 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist' ) |
|---|
| 115 | REWIND( numnam_cfg ) !* Namelist namsbc in configuration namelist : Parameters of the run |
|---|
| 116 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 117 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist' ) |
|---|
| 118 | IF(lwm) WRITE( numond, namsbc ) |
|---|
| 119 | ! |
|---|
| 120 | #if defined key_mpp_mpi |
|---|
| 121 | ncom_fsbc = nn_fsbc ! make nn_fsbc available for lib_mpp |
|---|
| 122 | #endif |
|---|
| 123 | ! !* overwrite namelist parameter using CPP key information |
|---|
| 124 | #if defined key_agrif |
|---|
| 125 | IF( Agrif_Root() ) THEN ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid) |
|---|
| 126 | IF( lk_si3 ) nn_ice = 2 |
|---|
| 127 | IF( lk_cice ) nn_ice = 3 |
|---|
| 128 | ENDIF |
|---|
| 129 | #else |
|---|
| 130 | IF( lk_si3 ) nn_ice = 2 |
|---|
| 131 | IF( lk_cice ) nn_ice = 3 |
|---|
| 132 | #endif |
|---|
| 133 | ! |
|---|
| 134 | IF(lwp) THEN !* Control print |
|---|
| 135 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 136 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 137 | WRITE(numout,*) ' Type of air-sea fluxes : ' |
|---|
| 138 | WRITE(numout,*) ' user defined formulation ln_usr = ', ln_usr |
|---|
| 139 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 140 | WRITE(numout,*) ' bulk formulation ln_blk = ', ln_blk |
|---|
| 141 | WRITE(numout,*) ' Type of coupling (Ocean/Ice/Atmosphere) : ' |
|---|
| 142 | WRITE(numout,*) ' ocean-atmosphere coupled formulation ln_cpl = ', ln_cpl |
|---|
| 143 | WRITE(numout,*) ' mixed forced-coupled formulation ln_mixcpl = ', ln_mixcpl |
|---|
| 144 | !!gm lk_oasis is controlled by key_oasis3 ===>>> It shoud be removed from the namelist |
|---|
| 145 | WRITE(numout,*) ' OASIS coupling (with atm or sas) lk_oasis = ', lk_oasis |
|---|
| 146 | WRITE(numout,*) ' components of your executable nn_components = ', nn_components |
|---|
| 147 | WRITE(numout,*) ' Sea-ice : ' |
|---|
| 148 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 149 | WRITE(numout,*) ' ice embedded into ocean ln_ice_embd = ', ln_ice_embd |
|---|
| 150 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 151 | WRITE(numout,*) ' Light penetration in temperature Eq. ln_traqsr = ', ln_traqsr |
|---|
| 152 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 153 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 154 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 155 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 156 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 157 | WRITE(numout,*) ' iceshelf formulation ln_isf = ', ln_isf |
|---|
| 158 | WRITE(numout,*) ' nb of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 159 | WRITE(numout,*) ' surface wave ln_wave = ', ln_wave |
|---|
| 160 | WRITE(numout,*) ' Stokes drift corr. to vert. velocity ln_sdw = ', ln_sdw |
|---|
| 161 | WRITE(numout,*) ' vertical parametrization nn_sdrift = ', nn_sdrift |
|---|
| 162 | WRITE(numout,*) ' wave modified ocean stress ln_tauwoc = ', ln_tauwoc |
|---|
| 163 | WRITE(numout,*) ' wave modified ocean stress component ln_tauw = ', ln_tauw |
|---|
| 164 | WRITE(numout,*) ' Stokes coriolis term ln_stcor = ', ln_stcor |
|---|
| 165 | WRITE(numout,*) ' neutral drag coefficient (CORE,NCAR) ln_cdgw = ', ln_cdgw |
|---|
| 166 | ENDIF |
|---|
| 167 | ! |
|---|
| 168 | IF( .NOT.ln_wave ) THEN |
|---|
| 169 | ln_sdw = .false. ; ln_cdgw = .false. ; ln_tauwoc = .false. ; ln_tauw = .false. ; ln_stcor = .false. |
|---|
| 170 | ENDIF |
|---|
| 171 | IF( ln_sdw ) THEN |
|---|
| 172 | IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) & |
|---|
| 173 | CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' ) |
|---|
| 174 | ENDIF |
|---|
| 175 | ll_st_bv2014 = ( nn_sdrift==jp_breivik_2014 ) |
|---|
| 176 | ll_st_li2017 = ( nn_sdrift==jp_li_2017 ) |
|---|
| 177 | ll_st_bv_li = ( ll_st_bv2014 .OR. ll_st_li2017 ) |
|---|
| 178 | ll_st_peakfr = ( nn_sdrift==jp_peakfr ) |
|---|
| 179 | IF( ln_tauwoc .AND. ln_tauw ) & |
|---|
| 180 | CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', & |
|---|
| 181 | '(ln_tauwoc=.true. and ln_tauw=.true.)' ) |
|---|
| 182 | IF( ln_tauwoc ) & |
|---|
| 183 | CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' ) |
|---|
| 184 | IF( ln_tauw ) & |
|---|
| 185 | CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', & |
|---|
| 186 | 'This will override any other specification of the ocean stress' ) |
|---|
| 187 | ! |
|---|
| 188 | IF( .NOT.ln_usr ) THEN ! the model calendar needs some specificities (except in user defined case) |
|---|
| 189 | IF( MOD( rday , rdt ) /= 0. ) CALL ctl_stop( 'the time step must devide the number of second of in a day' ) |
|---|
| 190 | IF( MOD( rday , 2. ) /= 0. ) CALL ctl_stop( 'the number of second of in a day must be an even number' ) |
|---|
| 191 | IF( MOD( rdt , 2. ) /= 0. ) CALL ctl_stop( 'the time step (in second) must be an even number' ) |
|---|
| 192 | ENDIF |
|---|
| 193 | ! !** check option consistency |
|---|
| 194 | ! |
|---|
| 195 | IF(lwp) WRITE(numout,*) !* Single / Multi - executable (NEMO / OPA+SAS) |
|---|
| 196 | SELECT CASE( nn_components ) |
|---|
| 197 | CASE( jp_iam_nemo ) |
|---|
| 198 | IF(lwp) WRITE(numout,*) ' ==>>> NEMO configured as a single executable (i.e. including both OPA and Surface module)' |
|---|
| 199 | CASE( jp_iam_opa ) |
|---|
| 200 | IF(lwp) WRITE(numout,*) ' ==>>> Multi executable configuration. Here, OPA component' |
|---|
| 201 | IF( .NOT.lk_oasis ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 202 | IF( ln_cpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' ) |
|---|
| 203 | IF( ln_mixcpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 204 | CASE( jp_iam_sas ) |
|---|
| 205 | IF(lwp) WRITE(numout,*) ' ==>>> Multi executable configuration. Here, SAS component' |
|---|
| 206 | IF( .NOT.lk_oasis ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 207 | IF( ln_mixcpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 208 | CASE DEFAULT |
|---|
| 209 | CALL ctl_stop( 'sbc_init : unsupported value for nn_components' ) |
|---|
| 210 | END SELECT |
|---|
| 211 | ! !* coupled options |
|---|
| 212 | IF( ln_cpl ) THEN |
|---|
| 213 | IF( .NOT. lk_oasis ) CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)', & |
|---|
| 214 | & ' required to defined key_oasis3' ) |
|---|
| 215 | ENDIF |
|---|
| 216 | IF( ln_mixcpl ) THEN |
|---|
| 217 | IF( .NOT. lk_oasis ) CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ', & |
|---|
| 218 | & ' required to defined key_oasis3' ) |
|---|
| 219 | IF( .NOT.ln_cpl ) CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' ) |
|---|
| 220 | IF( nn_components /= jp_iam_nemo ) & |
|---|
| 221 | & CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ', & |
|---|
| 222 | & ' not yet working with sas-opa coupling via oasis' ) |
|---|
| 223 | ENDIF |
|---|
| 224 | ! !* sea-ice |
|---|
| 225 | SELECT CASE( nn_ice ) |
|---|
| 226 | CASE( 0 ) !- no ice in the domain |
|---|
| 227 | CASE( 1 ) !- Ice-cover climatology ("Ice-if" model) |
|---|
| 228 | CASE( 2 ) !- SI3 ice model |
|---|
| 229 | CASE( 3 ) !- CICE ice model |
|---|
| 230 | IF( .NOT.( ln_blk .OR. ln_cpl ) ) CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' ) |
|---|
| 231 | IF( lk_agrif ) CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 232 | CASE DEFAULT !- not supported |
|---|
| 233 | END SELECT |
|---|
| 234 | ! |
|---|
| 235 | ! !** allocate and set required variables |
|---|
| 236 | ! |
|---|
| 237 | ! !* allocate sbc arrays |
|---|
| 238 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 239 | #if ! defined key_si3 && ! defined key_cice |
|---|
| 240 | IF( sbc_ice_alloc() /= 0 ) CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' ) |
|---|
| 241 | #endif |
|---|
| 242 | ! |
|---|
| 243 | IF( .NOT.ln_isf ) THEN !* No ice-shelf in the domain : allocate and set to zero |
|---|
| 244 | IF( sbc_isf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' ) |
|---|
| 245 | fwfisf (:,:) = 0._wp ; risf_tsc (:,:,:) = 0._wp |
|---|
| 246 | fwfisf_b(:,:) = 0._wp ; risf_tsc_b(:,:,:) = 0._wp |
|---|
| 247 | END IF |
|---|
| 248 | IF( nn_ice == 0 ) THEN !* No sea-ice in the domain : ice fraction is always zero |
|---|
| 249 | IF( nn_components /= jp_iam_opa ) fr_i(:,:) = 0._wp ! except for OPA in SAS-OPA coupled case |
|---|
| 250 | ENDIF |
|---|
| 251 | ! |
|---|
| 252 | sfx (:,:) = 0._wp !* salt flux due to freezing/melting |
|---|
| 253 | fmmflx(:,:) = 0._wp !* freezing minus melting flux |
|---|
| 254 | |
|---|
| 255 | taum(:,:) = 0._wp !* wind stress module (needed in GLS in case of reduced restart) |
|---|
| 256 | |
|---|
| 257 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 258 | IF( ln_dm2dc ) THEN !* daily mean to diurnal cycle |
|---|
| 259 | nday_qsr = -1 ! allow initialization at the 1st call |
|---|
| 260 | IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa ) & |
|---|
| 261 | & CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' ) |
|---|
| 262 | ENDIF |
|---|
| 263 | ! !* Choice of the Surface Boudary Condition |
|---|
| 264 | ! (set nsbc) |
|---|
| 265 | ! |
|---|
| 266 | ll_purecpl = ln_cpl .AND. .NOT.ln_mixcpl |
|---|
| 267 | ll_opa = nn_components == jp_iam_opa |
|---|
| 268 | ll_not_nemo = nn_components /= jp_iam_nemo |
|---|
| 269 | icpt = 0 |
|---|
| 270 | ! |
|---|
| 271 | IF( ln_usr ) THEN ; nsbc = jp_usr ; icpt = icpt + 1 ; ENDIF ! user defined formulation |
|---|
| 272 | IF( ln_flx ) THEN ; nsbc = jp_flx ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 273 | IF( ln_blk ) THEN ; nsbc = jp_blk ; icpt = icpt + 1 ; ENDIF ! bulk formulation |
|---|
| 274 | IF( ll_purecpl ) THEN ; nsbc = jp_purecpl ; icpt = icpt + 1 ; ENDIF ! Pure Coupled formulation |
|---|
| 275 | IF( ll_opa ) THEN ; nsbc = jp_none ; icpt = icpt + 1 ; ENDIF ! opa coupling via SAS module |
|---|
| 276 | ! |
|---|
| 277 | IF( icpt /= 1 ) CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' ) |
|---|
| 278 | ! |
|---|
| 279 | IF(lwp) THEN !- print the choice of surface flux formulation |
|---|
| 280 | WRITE(numout,*) |
|---|
| 281 | SELECT CASE( nsbc ) |
|---|
| 282 | CASE( jp_usr ) ; WRITE(numout,*) ' ==>>> user defined forcing formulation' |
|---|
| 283 | CASE( jp_flx ) ; WRITE(numout,*) ' ==>>> flux formulation' |
|---|
| 284 | CASE( jp_blk ) ; WRITE(numout,*) ' ==>>> bulk formulation' |
|---|
| 285 | CASE( jp_purecpl ) ; WRITE(numout,*) ' ==>>> pure coupled formulation' |
|---|
| 286 | !!gm abusive use of jp_none ?? ===>>> need to be check and changed by adding a jp_sas parameter |
|---|
| 287 | CASE( jp_none ) ; WRITE(numout,*) ' ==>>> OPA coupled to SAS via oasis' |
|---|
| 288 | IF( ln_mixcpl ) WRITE(numout,*) ' + forced-coupled mixed formulation' |
|---|
| 289 | END SELECT |
|---|
| 290 | IF( ll_not_nemo ) WRITE(numout,*) ' + OASIS coupled SAS' |
|---|
| 291 | ENDIF |
|---|
| 292 | ! |
|---|
| 293 | ! !* OASIS initialization |
|---|
| 294 | ! |
|---|
| 295 | IF( lk_oasis ) CALL sbc_cpl_init( nn_ice ) ! Must be done before: (1) first time step |
|---|
| 296 | ! ! (2) the use of nn_fsbc |
|---|
| 297 | ! nn_fsbc initialization if OPA-SAS coupling via OASIS |
|---|
| 298 | ! SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly |
|---|
| 299 | IF( nn_components /= jp_iam_nemo ) THEN |
|---|
| 300 | IF( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt) |
|---|
| 301 | IF( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt) |
|---|
| 302 | ! |
|---|
| 303 | IF(lwp)THEN |
|---|
| 304 | WRITE(numout,*) |
|---|
| 305 | WRITE(numout,*)" OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc |
|---|
| 306 | WRITE(numout,*) |
|---|
| 307 | ENDIF |
|---|
| 308 | ENDIF |
|---|
| 309 | ! |
|---|
| 310 | ! !* check consistency between model timeline and nn_fsbc |
|---|
| 311 | IF( ln_rst_list .OR. nn_stock /= -1 ) THEN ! we will do restart files |
|---|
| 312 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 ) THEN |
|---|
| 313 | WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 314 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 315 | ENDIF |
|---|
| 316 | IF( .NOT. ln_rst_list .AND. MOD( nn_stock, nn_fsbc) /= 0 ) THEN ! we don't use nn_stock if ln_rst_list |
|---|
| 317 | WRITE(ctmp1,*) 'sbc_init : nn_stock (', nn_stock, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 318 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 319 | ENDIF |
|---|
| 320 | ENDIF |
|---|
| 321 | ! |
|---|
| 322 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 323 | & CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 324 | ! |
|---|
| 325 | IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8 ) & |
|---|
| 326 | & CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 327 | ! |
|---|
| 328 | |
|---|
| 329 | ! !** associated modules : initialization |
|---|
| 330 | ! |
|---|
| 331 | IF( l_sbc_clo ) CALL sbc_clo_init ! closed sea surface initialisation |
|---|
| 332 | ! |
|---|
| 333 | CALL sbc_ssm_init ! Sea-surface mean fields initialization |
|---|
| 334 | ! |
|---|
| 335 | IF( ln_blk ) CALL sbc_blk_init ! bulk formulae initialization |
|---|
| 336 | |
|---|
| 337 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialization |
|---|
| 338 | ! |
|---|
| 339 | IF( ln_isf ) CALL sbc_isf_init ! Compute iceshelves |
|---|
| 340 | ! |
|---|
| 341 | CALL sbc_rnf_init ! Runof initialization |
|---|
| 342 | ! |
|---|
| 343 | IF( ln_apr_dyn ) CALL sbc_apr_init ! Atmo Pressure Forcing initialization |
|---|
| 344 | ! |
|---|
| 345 | #if defined key_si3 |
|---|
| 346 | IF( lk_agrif .AND. nn_ice == 0 ) THEN ! allocate ice arrays in case agrif + ice-model + no-ice in child grid |
|---|
| 347 | IF( sbc_ice_alloc() /= 0 ) CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' ) |
|---|
| 348 | ELSEIF( nn_ice == 2 ) THEN |
|---|
| 349 | CALL ice_init ! ICE initialization |
|---|
| 350 | ENDIF |
|---|
| 351 | #endif |
|---|
| 352 | IF( nn_ice == 3 ) CALL cice_sbc_init( nsbc ) ! CICE initialization |
|---|
| 353 | ! |
|---|
| 354 | IF( ln_wave ) CALL sbc_wave_init ! surface wave initialisation |
|---|
| 355 | ! |
|---|
| 356 | IF( lwxios ) THEN |
|---|
| 357 | CALL iom_set_rstw_var_active('utau_b') |
|---|
| 358 | CALL iom_set_rstw_var_active('vtau_b') |
|---|
| 359 | CALL iom_set_rstw_var_active('qns_b') |
|---|
| 360 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 361 | ! CALL iom_set_rstw_var_active('qsr_b') |
|---|
| 362 | CALL iom_set_rstw_var_active('emp_b') |
|---|
| 363 | CALL iom_set_rstw_var_active('sfx_b') |
|---|
| 364 | ENDIF |
|---|
| 365 | |
|---|
| 366 | END SUBROUTINE sbc_init |
|---|
| 367 | |
|---|
| 368 | |
|---|
| 369 | SUBROUTINE sbc( kt ) |
|---|
| 370 | !!--------------------------------------------------------------------- |
|---|
| 371 | !! *** ROUTINE sbc *** |
|---|
| 372 | !! |
|---|
| 373 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 374 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 375 | !! |
|---|
| 376 | !! ** Method : blah blah to be written ????????? |
|---|
| 377 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 378 | !! |
|---|
| 379 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 380 | !! time step, i.e. |
|---|
| 381 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 382 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 383 | !! - updte the ice fraction : fr_i |
|---|
| 384 | !!---------------------------------------------------------------------- |
|---|
| 385 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 386 | ! |
|---|
| 387 | LOGICAL :: ll_sas, ll_opa ! local logical |
|---|
| 388 | ! |
|---|
| 389 | REAL(wp) :: zthscl ! wd tanh scale |
|---|
| 390 | REAL(wp), DIMENSION(jpi,jpj) :: zwdht, zwght ! wd dep over wd limit, wgt |
|---|
| 391 | |
|---|
| 392 | !!--------------------------------------------------------------------- |
|---|
| 393 | ! |
|---|
| 394 | IF( ln_timing ) CALL timing_start('sbc') |
|---|
| 395 | ! |
|---|
| 396 | ! ! ---------------------------------------- ! |
|---|
| 397 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 398 | ! ! ---------------------------------------- ! |
|---|
| 399 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 400 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 401 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 402 | emp_b (:,:) = emp (:,:) |
|---|
| 403 | sfx_b (:,:) = sfx (:,:) |
|---|
| 404 | IF ( ln_rnf ) THEN |
|---|
| 405 | rnf_b (:,: ) = rnf (:,: ) |
|---|
| 406 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) |
|---|
| 407 | ENDIF |
|---|
| 408 | IF( ln_isf ) THEN |
|---|
| 409 | fwfisf_b (:,: ) = fwfisf (:,: ) |
|---|
| 410 | risf_tsc_b(:,:,:) = risf_tsc(:,:,:) |
|---|
| 411 | ENDIF |
|---|
| 412 | ! |
|---|
| 413 | ENDIF |
|---|
| 414 | ! ! ---------------------------------------- ! |
|---|
| 415 | ! ! forcing field computation ! |
|---|
| 416 | ! ! ---------------------------------------- ! |
|---|
| 417 | ! |
|---|
| 418 | ll_sas = nn_components == jp_iam_sas ! component flags |
|---|
| 419 | ll_opa = nn_components == jp_iam_opa |
|---|
| 420 | ! |
|---|
| 421 | IF( .NOT.ll_sas ) CALL sbc_ssm ( kt ) ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 422 | IF( ln_wave ) CALL sbc_wave( kt ) ! surface waves |
|---|
| 423 | |
|---|
| 424 | ! |
|---|
| 425 | ! !== sbc formulation ==! |
|---|
| 426 | ! |
|---|
| 427 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 428 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 429 | CASE( jp_usr ) ; CALL usrdef_sbc_oce( kt ) ! user defined formulation |
|---|
| 430 | CASE( jp_flx ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 431 | CASE( jp_blk ) |
|---|
| 432 | IF( ll_sas ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: SAS receiving fields from OPA |
|---|
| 433 | CALL sbc_blk ( kt ) ! bulk formulation for the ocean |
|---|
| 434 | ! |
|---|
| 435 | CASE( jp_purecpl ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! pure coupled formulation |
|---|
| 436 | CASE( jp_none ) |
|---|
| 437 | IF( ll_opa ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: OPA receiving fields from SAS |
|---|
| 438 | END SELECT |
|---|
| 439 | ! |
|---|
| 440 | IF( ln_mixcpl ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! forced-coupled mixed formulation after forcing |
|---|
| 441 | ! |
|---|
| 442 | IF ( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( ) ! Wind stress provided by waves |
|---|
| 443 | ! |
|---|
| 444 | ! !== Misc. Options ==! |
|---|
| 445 | ! |
|---|
| 446 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 447 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 448 | #if defined key_si3 |
|---|
| 449 | CASE( 2 ) ; CALL ice_stp ( kt, nsbc ) ! SI3 ice model |
|---|
| 450 | #endif |
|---|
| 451 | CASE( 3 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 452 | END SELECT |
|---|
| 453 | |
|---|
| 454 | IF( ln_icebergs ) THEN |
|---|
| 455 | CALL icb_stp( kt ) ! compute icebergs |
|---|
| 456 | ! icebergs may advect into haloes during the icb step and alter emp. |
|---|
| 457 | ! A lbc_lnk is necessary here to ensure restartability (#2113) |
|---|
| 458 | IF( .NOT. ln_passive_mode ) CALL lbc_lnk( 'sbcmod', emp, 'T', 1. ) ! ensure restartability with icebergs |
|---|
| 459 | ENDIF |
|---|
| 460 | |
|---|
| 461 | IF( ln_isf ) CALL sbc_isf( kt ) ! compute iceshelves |
|---|
| 462 | |
|---|
| 463 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 464 | |
|---|
| 465 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 466 | |
|---|
| 467 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 468 | |
|---|
| 469 | ! Special treatment of freshwater fluxes over closed seas in the model domain |
|---|
| 470 | ! Should not be run if ln_diurnal_only |
|---|
| 471 | IF( l_sbc_clo ) CALL sbc_clo( kt ) |
|---|
| 472 | |
|---|
| 473 | !!$!RBbug do not understand why see ticket 667 |
|---|
| 474 | !!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why. |
|---|
| 475 | !!$ CALL lbc_lnk( 'sbcmod', emp, 'T', 1. ) |
|---|
| 476 | IF ( ll_wd ) THEN ! If near WAD point limit the flux for now |
|---|
| 477 | zthscl = atanh(rn_wd_sbcfra) ! taper frac default is .999 |
|---|
| 478 | zwdht(:,:) = sshn(:,:) + ht_0(:,:) - rn_wdmin1 ! do this calc of water |
|---|
| 479 | ! depth above wd limit once |
|---|
| 480 | WHERE( zwdht(:,:) <= 0.0 ) |
|---|
| 481 | taum(:,:) = 0.0 |
|---|
| 482 | utau(:,:) = 0.0 |
|---|
| 483 | vtau(:,:) = 0.0 |
|---|
| 484 | qns (:,:) = 0.0 |
|---|
| 485 | qsr (:,:) = 0.0 |
|---|
| 486 | emp (:,:) = min(emp(:,:),0.0) !can allow puddles to grow but not shrink |
|---|
| 487 | sfx (:,:) = 0.0 |
|---|
| 488 | END WHERE |
|---|
| 489 | zwght(:,:) = tanh(zthscl*zwdht(:,:)) |
|---|
| 490 | WHERE( zwdht(:,:) > 0.0 .and. zwdht(:,:) < rn_wd_sbcdep ) ! 5 m hard limit here is arbitrary |
|---|
| 491 | qsr (:,:) = qsr(:,:) * zwght(:,:) |
|---|
| 492 | qns (:,:) = qns(:,:) * zwght(:,:) |
|---|
| 493 | taum (:,:) = taum(:,:) * zwght(:,:) |
|---|
| 494 | utau (:,:) = utau(:,:) * zwght(:,:) |
|---|
| 495 | vtau (:,:) = vtau(:,:) * zwght(:,:) |
|---|
| 496 | sfx (:,:) = sfx(:,:) * zwght(:,:) |
|---|
| 497 | emp (:,:) = emp(:,:) * zwght(:,:) |
|---|
| 498 | END WHERE |
|---|
| 499 | ENDIF |
|---|
| 500 | ! |
|---|
| 501 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 502 | ! ! ---------------------------------------- ! |
|---|
| 503 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 504 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 505 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 506 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, ldxios = lrxios ) ! before i-stress (U-point) |
|---|
| 507 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, ldxios = lrxios ) ! before j-stress (V-point) |
|---|
| 508 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b, ldxios = lrxios ) ! before non solar heat flux (T-point) |
|---|
| 509 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 510 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, ldxios = lrxios ) ! before solar heat flux (T-point) |
|---|
| 511 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, ldxios = lrxios ) ! before freshwater flux (T-point) |
|---|
| 512 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 513 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 514 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, ldxios = lrxios ) ! before salt flux (T-point) |
|---|
| 515 | ELSE |
|---|
| 516 | sfx_b (:,:) = sfx(:,:) |
|---|
| 517 | ENDIF |
|---|
| 518 | ELSE !* no restart: set from nit000 values |
|---|
| 519 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 520 | utau_b(:,:) = utau(:,:) |
|---|
| 521 | vtau_b(:,:) = vtau(:,:) |
|---|
| 522 | qns_b (:,:) = qns (:,:) |
|---|
| 523 | emp_b (:,:) = emp (:,:) |
|---|
| 524 | sfx_b (:,:) = sfx (:,:) |
|---|
| 525 | ENDIF |
|---|
| 526 | ENDIF |
|---|
| 527 | ! ! ---------------------------------------- ! |
|---|
| 528 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 529 | ! ! ---------------------------------------- ! |
|---|
| 530 | IF(lwp) WRITE(numout,*) |
|---|
| 531 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 532 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 533 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 534 | IF( lwxios ) CALL iom_swap( cwxios_context ) |
|---|
| 535 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios ) |
|---|
| 536 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios ) |
|---|
| 537 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns, ldxios = lwxios ) |
|---|
| 538 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 539 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 540 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp, ldxios = lwxios ) |
|---|
| 541 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx, ldxios = lwxios ) |
|---|
| 542 | IF( lwxios ) CALL iom_swap( cxios_context ) |
|---|
| 543 | ENDIF |
|---|
| 544 | ! ! ---------------------------------------- ! |
|---|
| 545 | ! ! Outputs and control print ! |
|---|
| 546 | ! ! ---------------------------------------- ! |
|---|
| 547 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 548 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 549 | CALL iom_put( "empbmr" , emp_b - rnf ) ! before upward water flux ( needed to recalculate the time evolution of ssh in offline ) |
|---|
| 550 | CALL iom_put( "saltflx", sfx ) ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case) |
|---|
| 551 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 552 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 553 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 554 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 555 | IF( nn_ice > 0 .OR. ll_opa ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 556 | CALL iom_put( "taum" , taum ) ! wind stress module |
|---|
| 557 | CALL iom_put( "wspd" , wndm ) ! wind speed module over free ocean or leads in presence of sea-ice |
|---|
| 558 | ENDIF |
|---|
| 559 | ! |
|---|
| 560 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at each time step in sea-ice) |
|---|
| 561 | CALL iom_put( "vtau", vtau ) ! j-wind stress |
|---|
| 562 | ! |
|---|
| 563 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 564 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask ) |
|---|
| 565 | CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask ) |
|---|
| 566 | CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask ) |
|---|
| 567 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask ) |
|---|
| 568 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask ) |
|---|
| 569 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, kdim=jpk ) |
|---|
| 570 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, kdim=1 ) |
|---|
| 571 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, kdim=1 ) |
|---|
| 572 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 573 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask ) |
|---|
| 574 | ENDIF |
|---|
| 575 | |
|---|
| 576 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 577 | ! |
|---|
| 578 | IF( ln_timing ) CALL timing_stop('sbc') |
|---|
| 579 | ! |
|---|
| 580 | END SUBROUTINE sbc |
|---|
| 581 | |
|---|
| 582 | |
|---|
| 583 | SUBROUTINE sbc_final |
|---|
| 584 | !!--------------------------------------------------------------------- |
|---|
| 585 | !! *** ROUTINE sbc_final *** |
|---|
| 586 | !! |
|---|
| 587 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 588 | !!--------------------------------------------------------------------- |
|---|
| 589 | ! |
|---|
| 590 | IF( nn_ice == 3 ) CALL cice_sbc_final |
|---|
| 591 | ! |
|---|
| 592 | END SUBROUTINE sbc_final |
|---|
| 593 | |
|---|
| 594 | !!====================================================================== |
|---|
| 595 | END MODULE sbcmod |
|---|
