source: NEMO/branches/2019/ENHANCE-03_domcfg/src/domngb.F90 @ 11201

Last change on this file since 11201 was 11201, checked in by mathiot, 15 months ago

ENHANCE-03_domcfg : add management of closed seas in domain cfg by flood filling and lat/lon seed instead of i/j box definition (ticket #2143)

File size: 4.4 KB
Line 
1MODULE domngb
2   !!======================================================================
3   !!                       ***  MODULE  domngb  ***
4   !! Grid search:  find the closest grid point from a given on/lat position
5   !!======================================================================
6   !! History : 3.2  !  2009-11  (S. Masson)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   dom_ngb       : find the closest grid point from a given lon/lat position
11   !!----------------------------------------------------------------------
12   USE dom_oce        ! ocean space and time domain
13   USE phycst
14   !
15   USE in_out_manager ! I/O manager
16   USE lib_mpp        ! for mppsum
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   dom_ngb   ! routine called in iom.F90 and domclo.F90 module
22   PUBLIC   dist
23
24   !!----------------------------------------------------------------------
25   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
26   !! $Id: domngb.F90 10425 2018-12-19 21:54:16Z smasson $
27   !! Software governed by the CeCILL license (see ./LICENSE)
28   !!----------------------------------------------------------------------
29CONTAINS
30
31   SUBROUTINE dom_ngb( plon, plat, kii, kjj, rdist, cdgrid, kkk )
32      !!----------------------------------------------------------------------
33      !!                    ***  ROUTINE dom_ngb  ***
34      !!
35      !! ** Purpose :   find the closest grid point from a given lon/lat position
36      !!
37      !! ** Method  :   look for minimum distance in cylindrical projection
38      !!                -> not good if located at too high latitude...
39      !!----------------------------------------------------------------------
40      REAL(wp)        , INTENT(in   ) ::   plon, plat   ! longitude,latitude of the point
41      REAL(wp)        , INTENT(  out) ::   rdist        ! distance between the located point and the source
42      INTEGER         , INTENT(  out) ::   kii, kjj     ! i-,j-index of the closes grid point
43      INTEGER         , INTENT(in   ), OPTIONAL :: kkk  ! k-index of the mask level used
44      CHARACTER(len=1), INTENT(in   ) ::   cdgrid       ! grid name 'T', 'U', 'V', 'W'
45      !
46      INTEGER :: ik         ! working level
47      INTEGER , DIMENSION(2) ::   iloc
48      REAL(wp), DIMENSION(jpi,jpj) ::   zglam, zgphi, zmask, zdist
49      !!--------------------------------------------------------------------
50      !
51      zmask(:,:) = 0._wp
52      ik = 1
53      IF ( PRESENT(kkk) ) ik=kkk
54      SELECT CASE( cdgrid )
55      CASE( 'U' )  ; zglam(:,:) = glamu(:,:) ; zgphi(:,:) = gphiu(:,:) ; zmask(nldi:nlei,nldj:nlej) = umask(nldi:nlei,nldj:nlej,ik)
56      CASE( 'V' )  ; zglam(:,:) = glamv(:,:) ; zgphi(:,:) = gphiv(:,:) ; zmask(nldi:nlei,nldj:nlej) = vmask(nldi:nlei,nldj:nlej,ik)
57      CASE( 'F' )  ; zglam(:,:) = glamf(:,:) ; zgphi(:,:) = gphif(:,:) ; zmask(nldi:nlei,nldj:nlej) = fmask(nldi:nlei,nldj:nlej,ik)
58      CASE DEFAULT ; zglam(:,:) = glamt(:,:) ; zgphi(:,:) = gphit(:,:) ; zmask(nldi:nlei,nldj:nlej) = tmask(nldi:nlei,nldj:nlej,ik)
59      END SELECT
60
61      zdist = dist(plon, plat, zglam, zgphi)
62     
63      IF( lk_mpp ) THEN 
64         CALL mpp_minloc( 'domngb', zdist(:,:), zmask, rdist, iloc)
65         kii = iloc(1) ; kjj = iloc(2)
66      ELSE
67         iloc(:) = MINLOC( zdist(:,:), mask = zmask(:,:) == 1.e0 )
68         rdist = MINVAL( zdist(:,:) )
69         kii = iloc(1) + nimpp - 1
70         kjj = iloc(2) + njmpp - 1
71      ENDIF
72      !
73   END SUBROUTINE dom_ngb
74
75   FUNCTION dist(plonsrc, platsrc, plontrg, plattrg)
76      REAL(wp), INTENT(in) :: plonsrc, platsrc                     ! lat/lon of the source point
77      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: plontrg, plattrg ! lat/lon of the target (2d in this case)
78
79      REAL(wp) :: zxs, zys, zzs
80      REAL(wp), DIMENSION(jpi,jpj) :: zxt, zyt, zzt
81
82      REAL(wp), DIMENSION(jpi,jpj) :: dist ! distance between src and trg
83
84      zxs = COS( rad * platsrc ) * COS( rad * plonsrc )
85      zys = COS( rad * platsrc ) * SIN( rad * plonsrc )
86      zzs = SIN( rad * platsrc )
87
88      zxt = COS( rad * plattrg ) * COS( rad * plontrg )
89      zyt = COS( rad * plattrg ) * SIN( rad * plontrg )
90      zzt = SIN( rad * plattrg )
91
92      dist(:,:) = ( zxs - zxt(:,:) )**2   &
93         &      + ( zys - zyt(:,:) )**2   &
94         &      + ( zzs - zzt(:,:) )**2
95
96      dist = ra * SQRT( dist )
97
98   END FUNCTION dist
99
100   !!======================================================================
101END MODULE domngb
Note: See TracBrowser for help on using the repository browser.