1 | MODULE isfdiags |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE isfdiags *** |
---|
4 | !! ice shelf diagnostics module : manage the 2d and 3d flux outputs from the ice shelf module |
---|
5 | !!====================================================================== |
---|
6 | !! History : 3.2 ! 2011-02 (C.Harris ) Original code isf cav |
---|
7 | !! X.X ! 2006-02 (C. Wang ) Original code bg03 |
---|
8 | !! 3.4 ! 2013-03 (P. Mathiot) Merging + parametrization |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! sbc_isf : update sbc under ice shelf |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | |
---|
15 | USE in_out_manager ! I/O manager |
---|
16 | USE dom_oce |
---|
17 | USE isf_oce ! ice shelf variable |
---|
18 | USE iom ! |
---|
19 | |
---|
20 | IMPLICIT NONE |
---|
21 | |
---|
22 | PRIVATE |
---|
23 | |
---|
24 | PUBLIC isf_diags_flx |
---|
25 | |
---|
26 | !!---------------------------------------------------------------------- |
---|
27 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
28 | !! $Id: sbcisf.F90 10536 2019-01-16 19:21:09Z mathiot $ |
---|
29 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
30 | !!---------------------------------------------------------------------- |
---|
31 | |
---|
32 | CONTAINS |
---|
33 | |
---|
34 | SUBROUTINE isf_diags_flx(Kmm, ktop, kbot, phtbl, pfrac, cdisf, pqfwf, pqoce, pqlat, pqhc) |
---|
35 | !!--------------------------------------------------------------------- |
---|
36 | !! *** ROUTINE isf_diags_flx *** |
---|
37 | !! |
---|
38 | !! ** Purpose : manage the 2d and 3d flux outputs of the ice shelf module |
---|
39 | !! fwf, latent heat flux, heat content flux, oce->ice heat flux |
---|
40 | !! |
---|
41 | !!---------------------------------------------------------------------- |
---|
42 | !!-------------------------- OUT ------------------------------------- |
---|
43 | !!-------------------------- IN ------------------------------------- |
---|
44 | INTEGER, INTENT(in) :: Kmm ! ocean time level index |
---|
45 | INTEGER , DIMENSION(jpi,jpj), INTENT(in) :: ktop , kbot ! top and bottom level of the tbl |
---|
46 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: phtbl, pfrac ! thickness of the tbl and fraction of last cell affected by the tbl |
---|
47 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pqfwf, pqoce, pqlat, pqhc ! 2d var to map in 3d |
---|
48 | CHARACTER(LEN=3), INTENT(in) :: cdisf ! parametrisation or interactive melt |
---|
49 | !!--------------------------------------------------------------------- |
---|
50 | CHARACTER(LEN=256) :: cvarqfwf , cvarqoce , cvarqlat , cvarqhc |
---|
51 | CHARACTER(LEN=256) :: cvarqfwf3d, cvarqoce3d, cvarqlat3d, cvarqhc3d |
---|
52 | !!--------------------------------------------------------------------- |
---|
53 | ! |
---|
54 | ! output melt |
---|
55 | cvarqfwf = 'fwfisf_'//cdisf ; cvarqfwf3d = 'fwfisf3d_'//cdisf |
---|
56 | cvarqoce = 'qoceisf_'//cdisf ; cvarqoce3d = 'qoceisf3d_'//cdisf |
---|
57 | cvarqlat = 'qlatisf_'//cdisf ; cvarqlat3d = 'qlatisf3d_'//cdisf |
---|
58 | cvarqhc = 'qhcisf_'//cdisf ; cvarqhc3d = 'qhcisf3d_'//cdisf |
---|
59 | ! |
---|
60 | ! output 2d melt rate, latent heat and heat content flux from the injected water |
---|
61 | CALL iom_put( TRIM(cvarqfwf), pqfwf(:,:) ) ! mass flux ( >0 out ) |
---|
62 | CALL iom_put( TRIM(cvarqoce), pqoce(:,:) ) ! oce to ice flux ( >0 out ) |
---|
63 | CALL iom_put( TRIM(cvarqlat), pqlat(:,:) ) ! latent heat flux ( >0 out ) |
---|
64 | CALL iom_put( TRIM(cvarqhc) , pqhc (:,:) ) ! heat content flux ( >0 out ) |
---|
65 | ! |
---|
66 | ! output 3d Diagnostics |
---|
67 | IF ( iom_use( TRIM(cvarqfwf3d) ) ) CALL isf_diags_2dto3d( Kmm, ktop, kbot, phtbl, pfrac, TRIM(cvarqfwf3d) , pqfwf(:,:)) |
---|
68 | IF ( iom_use( TRIM(cvarqoce3d) ) ) CALL isf_diags_2dto3d( Kmm, ktop, kbot, phtbl, pfrac, TRIM(cvarqoce3d) , pqoce(:,:)) |
---|
69 | IF ( iom_use( TRIM(cvarqlat3d) ) ) CALL isf_diags_2dto3d( Kmm, ktop, kbot, phtbl, pfrac, TRIM(cvarqlat3d) , pqoce(:,:)) |
---|
70 | IF ( iom_use( TRIM(cvarqhc3d) ) ) CALL isf_diags_2dto3d( Kmm, ktop, kbot, phtbl, pfrac, TRIM(cvarqhc3d) , pqhc (:,:)) |
---|
71 | ! |
---|
72 | END SUBROUTINE |
---|
73 | |
---|
74 | SUBROUTINE isf_diags_2dto3d(Kmm, ktop, kbot, phtbl, pfrac, cdvar, pvar2d) |
---|
75 | !!--------------------------------------------------------------------- |
---|
76 | !! *** ROUTINE isf_diags_2dto3d *** |
---|
77 | !! |
---|
78 | !! ** Purpose : compute the 3d flux outputs as they are injected into NEMO |
---|
79 | !! (ie uniformaly spread into the top boundary layer or parametrisation layer) |
---|
80 | !! |
---|
81 | !!---------------------------------------------------------------------- |
---|
82 | !!-------------------------- OUT ------------------------------------- |
---|
83 | !!-------------------------- IN ------------------------------------- |
---|
84 | INTEGER, INTENT(in) :: Kmm ! ocean time level index |
---|
85 | INTEGER , DIMENSION(jpi,jpj), INTENT(in) :: ktop , kbot ! top and bottom level of the tbl |
---|
86 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: phtbl, pfrac ! thickness of the tbl and fraction of last cell affected by the tbl |
---|
87 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pvar2d ! 2d var to map in 3d |
---|
88 | CHARACTER(LEN=256), INTENT(in) :: cdvar |
---|
89 | !!--------------------------------------------------------------------- |
---|
90 | INTEGER :: ji, jj, jk ! loop indices |
---|
91 | INTEGER :: ikt, ikb ! top and bottom level of the tbl |
---|
92 | REAL(wp), DIMENSION(jpi,jpj) :: zvar2d ! |
---|
93 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zvar3d ! 3d var to output |
---|
94 | !!--------------------------------------------------------------------- |
---|
95 | ! |
---|
96 | ! compute 3d output |
---|
97 | zvar2d(:,:) = pvar2d(:,:) / phtbl(:,:) |
---|
98 | zvar3d(:,:,:) = 0._wp |
---|
99 | ! |
---|
100 | DO jj = 1,jpj |
---|
101 | DO ji = 1,jpi |
---|
102 | ikt = ktop(ji,jj) |
---|
103 | ikb = kbot(ji,jj) |
---|
104 | DO jk = ikt, ikb - 1 |
---|
105 | zvar3d(ji,jj,jk) = zvar2d(ji,jj) * e3t(ji,jj,jk,Kmm) |
---|
106 | END DO |
---|
107 | zvar3d(ji,jj,ikb) = zvar2d(ji,jj) * e3t(ji,jj,ikb,Kmm) * pfrac(ji,jj) |
---|
108 | END DO |
---|
109 | END DO |
---|
110 | ! |
---|
111 | CALL iom_put( TRIM(cdvar) , zvar3d(:,:,:)) |
---|
112 | ! |
---|
113 | END SUBROUTINE isf_diags_2dto3d |
---|
114 | |
---|
115 | END MODULE isfdiags |
---|