source: NEMO/branches/2019/dev_ASINTER-01-05_merged/src/OCE/SBC/sbcmod.F90 @ 12147

Last change on this file since 12147 was 12147, checked in by gsamson, 10 months ago

update dev_ASINTER-01-05_merged to trunk@r12072 + bugfix for ICE_AGRIF test case

  • Property svn:keywords set to Id
File size: 35.8 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!            4.0  ! 2019-03  (F. Lemarié & G. Samson)  add ABL compatibility (ln_abl=TRUE)
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   sbc_init      : read namsbc namelist
22   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
23   !!   sbc_final     : Finalize CICE ice model (if used)
24   !!----------------------------------------------------------------------
25   USE oce            ! ocean dynamics and tracers
26   USE dom_oce        ! ocean space and time domain
27   USE phycst         ! physical constants
28   USE sbc_oce        ! Surface boundary condition: ocean fields
29   USE trc_oce        ! shared ocean-passive tracers variables
30   USE sbc_ice        ! Surface boundary condition: ice fields
31   USE sbcdcy         ! surface boundary condition: diurnal cycle
32   USE sbcssm         ! surface boundary condition: sea-surface mean variables
33   USE sbcflx         ! surface boundary condition: flux formulation
34   USE sbcblk         ! surface boundary condition: bulk formulation
35   USE sbcabl         ! atmospheric boundary layer
36   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
37#if defined key_si3
38   USE icestp         ! surface boundary condition: SI3 sea-ice model
39#endif
40   USE sbcice_cice    ! surface boundary condition: CICE sea-ice model
41   USE sbcisf         ! surface boundary condition: ice-shelf
42   USE sbccpl         ! surface boundary condition: coupled formulation
43   USE cpl_oasis3     ! OASIS routines for coupling
44   USE sbcssr         ! surface boundary condition: sea surface restoring
45   USE sbcrnf         ! surface boundary condition: runoffs
46   USE sbcapr         ! surface boundary condition: atmo pressure
47   USE sbcisf         ! surface boundary condition: ice shelf
48   USE sbcfwb         ! surface boundary condition: freshwater budget
49   USE icbstp         ! Icebergs
50   USE icb_oce  , ONLY : ln_passive_mode      ! iceberg interaction mode
51   USE traqsr         ! active tracers: light penetration
52   USE sbcwave        ! Wave module
53   USE bdy_oce   , ONLY: ln_bdy
54   USE usrdef_sbc     ! user defined: surface boundary condition
55   USE closea         ! closed sea
56   !
57   USE prtctl         ! Print control                    (prt_ctl routine)
58   USE iom            ! IOM library
59   USE in_out_manager ! I/O manager
60   USE lib_mpp        ! MPP library
61   USE timing         ! Timing
62   USE wet_dry
63   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
64
65   IMPLICIT NONE
66   PRIVATE
67
68   PUBLIC   sbc        ! routine called by step.F90
69   PUBLIC   sbc_init   ! routine called by opa.F90
70
71   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
72
73   !!----------------------------------------------------------------------
74   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
75   !! $Id$
76   !! Software governed by the CeCILL license (see ./LICENSE)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE sbc_init
81      !!---------------------------------------------------------------------
82      !!                    ***  ROUTINE sbc_init ***
83      !!
84      !! ** Purpose :   Initialisation of the ocean surface boundary computation
85      !!
86      !! ** Method  :   Read the namsbc namelist and set derived parameters
87      !!                Call init routines for all other SBC modules that have one
88      !!
89      !! ** Action  : - read namsbc parameters
90      !!              - nsbc: type of sbc
91      !!----------------------------------------------------------------------
92      INTEGER ::   ios, icpt                         ! local integer
93      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
94      !!
95      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
96         &             ln_usr   , ln_flx   , ln_blk   , ln_abl,                      &
97         &             ln_cpl   , ln_mixcpl, nn_components,                          &
98         &             nn_ice   , ln_ice_embd,                                       &
99         &             ln_traqsr, ln_dm2dc ,                                         &
100         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_isf    , ln_apr_dyn ,     &
101         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauwoc  , ln_stcor  ,     &
102         &             ln_tauw  , nn_lsm, nn_sdrift
103      !!----------------------------------------------------------------------
104      !
105      IF(lwp) THEN
106         WRITE(numout,*)
107         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
108         WRITE(numout,*) '~~~~~~~~ '
109      ENDIF
110      !
111      !                       !**  read Surface Module namelist
112      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
113      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
114901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist' )
115      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
116      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
117902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist' )
118      IF(lwm) WRITE( numond, namsbc )
119      !
120#if defined key_mpp_mpi
121      ncom_fsbc = nn_fsbc    ! make nn_fsbc available for lib_mpp
122#endif
123      !                             !* overwrite namelist parameter using CPP key information
124#if defined key_agrif
125      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
126         IF( lk_si3  )   nn_ice      = 2
127         IF( lk_cice )   nn_ice      = 3
128      ENDIF
129!!GS: TBD
130!#else
131!      IF( lk_si3  )   nn_ice      = 2
132!      IF( lk_cice )   nn_ice      = 3
133#endif
134      !
135      IF(lwp) THEN                  !* Control print
136         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
137         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
138         WRITE(numout,*) '      Type of air-sea fluxes : '
139         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
140         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
141         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
142         WRITE(numout,*) '         ABL          formulation                   ln_abl        = ', ln_abl
143         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
144         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
145         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
146!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
147         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
148         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
149         WRITE(numout,*) '      Sea-ice : '
150         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
151         WRITE(numout,*) '         ice embedded into ocean                    ln_ice_embd   = ', ln_ice_embd
152         WRITE(numout,*) '      Misc. options of sbc : '
153         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
154         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
155         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
156         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
157         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
158         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
159         WRITE(numout,*) '         iceshelf formulation                       ln_isf        = ', ln_isf
160         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
161         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
162         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
163         WRITE(numout,*) '                  vertical parametrization          nn_sdrift     = ', nn_sdrift
164         WRITE(numout,*) '               wave modified ocean stress           ln_tauwoc     = ', ln_tauwoc
165         WRITE(numout,*) '               wave modified ocean stress component ln_tauw       = ', ln_tauw
166         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
167         WRITE(numout,*) '               neutral drag coefficient (CORE,NCAR) ln_cdgw       = ', ln_cdgw
168      ENDIF
169      !
170      IF( .NOT.ln_wave ) THEN
171         ln_sdw = .false. ; ln_cdgw = .false. ; ln_tauwoc = .false. ; ln_tauw = .false. ; ln_stcor = .false.
172      ENDIF
173      IF( ln_sdw ) THEN
174         IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) &
175            CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' )
176      ENDIF
177      ll_st_bv2014  = ( nn_sdrift==jp_breivik_2014 )
178      ll_st_li2017  = ( nn_sdrift==jp_li_2017 )
179      ll_st_bv_li   = ( ll_st_bv2014 .OR. ll_st_li2017 )
180      ll_st_peakfr  = ( nn_sdrift==jp_peakfr )
181      IF( ln_tauwoc .AND. ln_tauw ) &
182         CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', &
183                                  '(ln_tauwoc=.true. and ln_tauw=.true.)' )
184      IF( ln_tauwoc ) &
185         CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' )
186      IF( ln_tauw ) &
187         CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', &
188                              'This will override any other specification of the ocean stress' )
189      !
190      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
191         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
192         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
193         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
194      ENDIF
195      !                       !**  check option consistency
196      !
197      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
198      SELECT CASE( nn_components )
199      CASE( jp_iam_nemo )
200         IF(lwp) WRITE(numout,*) '   ==>>>   NEMO configured as a single executable (i.e. including both OPA and Surface module)'
201      CASE( jp_iam_opa  )
202         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, OPA component'
203         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
204         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
205         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
206      CASE( jp_iam_sas  )
207         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, SAS component'
208         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
209         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
210      CASE DEFAULT
211         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
212      END SELECT
213      !                             !* coupled options
214      IF( ln_cpl ) THEN
215         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
216            &                                  '           required to defined key_oasis3' )
217      ENDIF
218      IF( ln_mixcpl ) THEN
219         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
220            &                                  '           required to defined key_oasis3' )
221         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
222         IF( nn_components /= jp_iam_nemo )    &
223            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
224            &                                   '          not yet working with sas-opa coupling via oasis' )
225      ENDIF
226      !                             !* sea-ice
227      SELECT CASE( nn_ice )
228      CASE( 0 )                        !- no ice in the domain
229      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
230      CASE( 2 )                        !- SI3  ice model
231         IF( .NOT.( ln_blk .OR. ln_cpl .OR. ln_abl .OR. ln_usr ) )   &
232            &                   CALL ctl_stop( 'sbc_init : SI3 sea-ice model requires ln_blk or ln_cpl or ln_abl or ln_usr = T' )
233      CASE( 3 )                        !- CICE ice model
234         IF( .NOT.( ln_blk .OR. ln_cpl .OR. ln_abl .OR. ln_usr ) )   &
235            &                   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl or ln_abl or ln_usr = T' )
236         IF( lk_agrif                                )   &
237            &                   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
238      CASE DEFAULT                     !- not supported
239      END SELECT
240      !
241      !                       !**  allocate and set required variables
242      !
243      !                             !* allocate sbc arrays
244      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
245#if ! defined key_si3 && ! defined key_cice
246      IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' )
247#endif
248      !
249      IF( .NOT.ln_isf ) THEN        !* No ice-shelf in the domain : allocate and set to zero
250         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
251         fwfisf  (:,:)   = 0._wp   ;   risf_tsc  (:,:,:) = 0._wp
252         fwfisf_b(:,:)   = 0._wp   ;   risf_tsc_b(:,:,:) = 0._wp
253      ENDIF
254      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
255         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
256      ENDIF
257      !
258      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
259      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
260
261      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
262
263      !                          ! Choice of the Surface Boudary Condition (set nsbc)
264      nday_qsr = -1   ! allow initialization at the 1st call !LB: now warm-layer of COARE* calls "sbc_dcy_param" of sbcdcy.F90!
265      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
266         !LB:nday_qsr = -1   ! allow initialization at the 1st call
267         IF( .NOT.( ln_flx .OR. ln_blk .OR. ln_abl ) .AND. nn_components /= jp_iam_opa )   &
268            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires flux, bulk or abl formulation' )
269      ENDIF
270      !                             !* Choice of the Surface Boudary Condition
271      !                             (set nsbc)
272      !
273      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
274      ll_opa      = nn_components == jp_iam_opa
275      ll_not_nemo = nn_components /= jp_iam_nemo
276      icpt = 0
277      !
278      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
279      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
280      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
281      IF( ln_abl          ) THEN   ;   nsbc = jp_abl     ; icpt = icpt + 1   ;   ENDIF       ! ABL                  formulation
282      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
283      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
284      !
285      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
286      !
287      IF(lwp) THEN                     !- print the choice of surface flux formulation
288         WRITE(numout,*)
289         SELECT CASE( nsbc )
290         CASE( jp_usr     )   ;   WRITE(numout,*) '   ==>>>   user defined forcing formulation'
291         CASE( jp_flx     )   ;   WRITE(numout,*) '   ==>>>   flux formulation'
292         CASE( jp_blk     )   ;   WRITE(numout,*) '   ==>>>   bulk formulation'
293         CASE( jp_abl     )   ;   WRITE(numout,*) '   ==>>>   ABL  formulation'
294         CASE( jp_purecpl )   ;   WRITE(numout,*) '   ==>>>   pure coupled formulation'
295!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
296         CASE( jp_none    )   ;   WRITE(numout,*) '   ==>>>   OPA coupled to SAS via oasis'
297            IF( ln_mixcpl )       WRITE(numout,*) '               + forced-coupled mixed formulation'
298         END SELECT
299         IF( ll_not_nemo  )       WRITE(numout,*) '               + OASIS coupled SAS'
300      ENDIF
301      !
302      !                             !* OASIS initialization
303      !
304      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
305      !                                              !                      (2) the use of nn_fsbc
306      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
307      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
308      IF( nn_components /= jp_iam_nemo ) THEN
309         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
310         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
311         !
312         IF(lwp)THEN
313            WRITE(numout,*)
314            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
315            WRITE(numout,*)
316         ENDIF
317      ENDIF
318      !
319      !                             !* check consistency between model timeline and nn_fsbc
320      IF( ln_rst_list .OR. nn_stock /= -1 ) THEN   ! we will do restart files
321         IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 ) THEN
322            WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
323            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
324         ENDIF
325         IF( .NOT. ln_rst_list .AND. MOD( nn_stock, nn_fsbc) /= 0 ) THEN   ! we don't use nn_stock if ln_rst_list
326            WRITE(ctmp1,*) 'sbc_init : nn_stock (', nn_stock, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
327            CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
328         ENDIF
329      ENDIF
330      !
331      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
332         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
333      !
334      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
335         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
336      !
337   
338      !                       !**  associated modules : initialization
339      !
340                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
341      !
342      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
343
344      IF( ln_abl      )   CALL sbc_abl_init            ! Atmospheric Boundary Layer (ABL)
345
346      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
347      !
348      IF( ln_isf      )   CALL sbc_isf_init            ! Compute iceshelves
349      !
350                          CALL sbc_rnf_init            ! Runof initialization
351      !
352      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
353      !
354#if defined key_si3
355      IF( lk_agrif .AND. nn_ice == 0 ) THEN            ! allocate ice arrays in case agrif + ice-model + no-ice in child grid
356                          IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' )
357      ELSEIF( nn_ice == 2 ) THEN
358                          CALL ice_init                ! ICE initialization
359      ENDIF
360#endif
361      IF( nn_ice == 3 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
362      !
363      IF( ln_wave     )   CALL sbc_wave_init           ! surface wave initialisation
364      !
365      IF( lwxios ) THEN
366         CALL iom_set_rstw_var_active('utau_b')
367         CALL iom_set_rstw_var_active('vtau_b')
368         CALL iom_set_rstw_var_active('qns_b')
369         ! The 3D heat content due to qsr forcing is treated in traqsr
370         ! CALL iom_set_rstw_var_active('qsr_b')
371         CALL iom_set_rstw_var_active('emp_b')
372         CALL iom_set_rstw_var_active('sfx_b')
373      ENDIF
374
375   END SUBROUTINE sbc_init
376
377
378   SUBROUTINE sbc( kt )
379      !!---------------------------------------------------------------------
380      !!                    ***  ROUTINE sbc  ***
381      !!
382      !! ** Purpose :   provide at each time-step the ocean surface boundary
383      !!                condition (momentum, heat and freshwater fluxes)
384      !!
385      !! ** Method  :   blah blah  to be written ?????????
386      !!                CAUTION : never mask the surface stress field (tke sbc)
387      !!
388      !! ** Action  : - set the ocean surface boundary condition at before and now
389      !!                time step, i.e.
390      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
391      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
392      !!              - updte the ice fraction : fr_i
393      !!----------------------------------------------------------------------
394      INTEGER, INTENT(in) ::   kt   ! ocean time step
395      !
396      LOGICAL ::   ll_sas, ll_opa   ! local logical
397      !
398      REAL(wp) ::     zthscl        ! wd  tanh scale
399      REAL(wp), DIMENSION(jpi,jpj) ::  zwdht, zwght  ! wd dep over wd limit, wgt 
400
401      !!---------------------------------------------------------------------
402      !
403      IF( ln_timing )   CALL timing_start('sbc')
404      !
405      !                                            ! ---------------------------------------- !
406      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
407         !                                         ! ---------------------------------------- !
408         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
409         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
410         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
411         emp_b (:,:) = emp (:,:)
412         sfx_b (:,:) = sfx (:,:)
413         IF( ln_rnf ) THEN
414            rnf_b    (:,:  ) = rnf    (:,:  )
415            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
416         ENDIF
417         IF( ln_isf )  THEN
418            fwfisf_b  (:,:  ) = fwfisf  (:,:  )               
419            risf_tsc_b(:,:,:) = risf_tsc(:,:,:)             
420         ENDIF
421        !
422      ENDIF
423      !                                            ! ---------------------------------------- !
424      !                                            !        forcing field computation         !
425      !                                            ! ---------------------------------------- !
426      !
427      ll_sas = nn_components == jp_iam_sas               ! component flags
428      ll_opa = nn_components == jp_iam_opa
429      !
430      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
431      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
432
433      !
434      !                                            !==  sbc formulation  ==!
435      !                                                   
436      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
437      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
438      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
439      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
440      CASE( jp_blk     )
441         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
442                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
443                               !
444      CASE( jp_abl     )
445         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
446                               CALL sbc_abl       ( kt )                    ! ABL  formulation for the ocean
447                               !
448      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
449      CASE( jp_none    )
450         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
451      END SELECT
452      !
453      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
454      !
455      IF( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( )      ! Wind stress provided by waves
456      !
457      !                                            !==  Misc. Options  ==!
458      !
459      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
460      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )             ! Ice-cover climatology ("Ice-if" model)
461#if defined key_si3
462      CASE(  2 )   ;         CALL ice_stp  ( kt, nsbc )           ! SI3 ice model
463#endif
464      CASE(  3 )   ;         CALL sbc_ice_cice ( kt, nsbc )       ! CICE ice model
465      END SELECT
466
467      IF( ln_icebergs    )   THEN
468                                     CALL icb_stp( kt )           ! compute icebergs
469         ! icebergs may advect into haloes during the icb step and alter emp.
470         ! A lbc_lnk is necessary here to ensure restartability (#2113)
471         IF( .NOT. ln_passive_mode ) CALL lbc_lnk( 'sbcmod', emp, 'T', 1. ) ! ensure restartability with icebergs
472      ENDIF
473
474      IF( ln_isf         )   CALL sbc_isf( kt )                   ! compute iceshelves
475
476      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
477
478      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
479
480      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
481
482      ! Special treatment of freshwater fluxes over closed seas in the model domain
483      ! Should not be run if ln_diurnal_only
484      IF( l_sbc_clo .AND. (.NOT. ln_diurnal_only) )   CALL sbc_clo( kt )   
485
486!!$!RBbug do not understand why see ticket 667
487!!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
488!!$      CALL lbc_lnk( 'sbcmod', emp, 'T', 1. )
489      IF( ll_wd ) THEN     ! If near WAD point limit the flux for now
490         zthscl = atanh(rn_wd_sbcfra)                     ! taper frac default is .999
491         zwdht(:,:) = sshn(:,:) + ht_0(:,:) - rn_wdmin1   ! do this calc of water
492                                                     ! depth above wd limit once
493         WHERE( zwdht(:,:) <= 0.0 )
494            taum(:,:) = 0.0
495            utau(:,:) = 0.0
496            vtau(:,:) = 0.0
497            qns (:,:) = 0.0
498            qsr (:,:) = 0.0
499            emp (:,:) = min(emp(:,:),0.0) !can allow puddles to grow but not shrink
500            sfx (:,:) = 0.0
501         END WHERE
502         zwght(:,:) = tanh(zthscl*zwdht(:,:))
503         WHERE( zwdht(:,:) > 0.0  .and. zwdht(:,:) < rn_wd_sbcdep ) !  5 m hard limit here is arbitrary
504            qsr  (:,:) =  qsr(:,:)  * zwght(:,:)
505            qns  (:,:) =  qns(:,:)  * zwght(:,:)
506            taum (:,:) =  taum(:,:) * zwght(:,:)
507            utau (:,:) =  utau(:,:) * zwght(:,:)
508            vtau (:,:) =  vtau(:,:) * zwght(:,:)
509            sfx  (:,:) =  sfx(:,:)  * zwght(:,:)
510            emp  (:,:) =  emp(:,:)  * zwght(:,:)
511         END WHERE
512      ENDIF
513      !
514      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
515         !                                             ! ---------------------------------------- !
516         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
517            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
518            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
519            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, ldxios = lrxios )   ! before i-stress  (U-point)
520            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, ldxios = lrxios )   ! before j-stress  (V-point)
521            CALL iom_get( numror, jpdom_autoglo,  'qns_b',  qns_b, ldxios = lrxios )   ! before non solar heat flux (T-point)
522            ! The 3D heat content due to qsr forcing is treated in traqsr
523            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, ldxios = lrxios  ) ! before     solar heat flux (T-point)
524            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, ldxios = lrxios  )    ! before     freshwater flux (T-point)
525            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
526            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
527               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, ldxios = lrxios )  ! before salt flux (T-point)
528            ELSE
529               sfx_b (:,:) = sfx(:,:)
530            ENDIF
531         ELSE                                                   !* no restart: set from nit000 values
532            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
533            utau_b(:,:) = utau(:,:)
534            vtau_b(:,:) = vtau(:,:)
535            qns_b (:,:) = qns (:,:)
536            emp_b (:,:) = emp (:,:)
537            sfx_b (:,:) = sfx (:,:)
538         ENDIF
539      ENDIF
540      !                                                ! ---------------------------------------- !
541      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
542         !                                             ! ---------------------------------------- !
543         IF(lwp) WRITE(numout,*)
544         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
545            &                    'at it= ', kt,' date= ', ndastp
546         IF(lwp) WRITE(numout,*) '~~~~'
547         IF( lwxios ) CALL iom_swap(      cwxios_context          )
548         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios )
549         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios )
550         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns, ldxios = lwxios  )
551         ! The 3D heat content due to qsr forcing is treated in traqsr
552         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
553         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp, ldxios = lwxios  )
554         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx, ldxios = lwxios  )
555         IF( lwxios ) CALL iom_swap(      cxios_context          )
556      ENDIF
557      !                                                ! ---------------------------------------- !
558      !                                                !        Outputs and control print         !
559      !                                                ! ---------------------------------------- !
560      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
561         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
562         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
563         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
564         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
565         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
566         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
567         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
568         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
569         CALL iom_put( "taum"  , taum       )                   ! wind stress module
570         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
571      ENDIF
572      !
573      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
574      CALL iom_put( "vtau", vtau )   ! j-wind stress
575      !
576      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
577         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i    - : ', mask1=tmask )
578         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask )
579         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask )
580         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask )
581         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask )
582         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, kdim=jpk )
583         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, kdim=1   )
584         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, kdim=1   )
585         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
586            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask )
587      ENDIF
588
589      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
590      !
591      IF( ln_timing )   CALL timing_stop('sbc')
592      !
593   END SUBROUTINE sbc
594
595
596   SUBROUTINE sbc_final
597      !!---------------------------------------------------------------------
598      !!                    ***  ROUTINE sbc_final  ***
599      !!
600      !! ** Purpose :   Finalize CICE (if used)
601      !!---------------------------------------------------------------------
602      !
603      IF( nn_ice == 3 )   CALL cice_sbc_final
604      !
605   END SUBROUTINE sbc_final
606
607   !!======================================================================
608END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.