New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaharm.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/DIA – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/DIA/diaharm.F90 @ 10965

Last change on this file since 10965 was 10965, checked in by davestorkey, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : DIA and stpctl.F90. Just testing in ORCA1 so far.
  • Property svn:keywords set to Id
File size: 19.0 KB
Line 
1MODULE diaharm 
2   !!======================================================================
3   !!                       ***  MODULE  diaharm  ***
4   !! Harmonic analysis of tidal constituents
5   !!======================================================================
6   !! History :  3.1  !  2007  (O. Le Galloudec, J. Chanut)  Original code
7   !!----------------------------------------------------------------------
8#if defined key_diaharm
9   !!----------------------------------------------------------------------
10   !!   'key_diaharm'
11   !!----------------------------------------------------------------------
12   USE oce             ! ocean dynamics and tracers variables
13   USE dom_oce         ! ocean space and time domain
14   USE phycst
15   USE daymod
16   USE tide_mod
17   USE sbctide         ! Tidal forcing or not
18   !
19   USE in_out_manager  ! I/O units
20   USE iom             ! I/0 library
21   USE ioipsl          ! NetCDF IPSL library
22   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
23   USE timing          ! preformance summary
24   USE lib_mpp           ! MPP library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   LOGICAL, PUBLIC, PARAMETER :: lk_diaharm  = .TRUE.
30   
31   INTEGER, PARAMETER :: jpincomax    = 2.*jpmax_harmo
32   INTEGER, PARAMETER :: jpdimsparse  = jpincomax*300*24
33
34   !                         !!** namelist variables **
35   INTEGER ::   nit000_han    ! First time step used for harmonic analysis
36   INTEGER ::   nitend_han    ! Last time step used for harmonic analysis
37   INTEGER ::   nstep_han     ! Time step frequency for harmonic analysis
38   INTEGER ::   nb_ana        ! Number of harmonics to analyse
39
40   INTEGER , ALLOCATABLE, DIMENSION(:)       ::   name
41   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ana_temp
42   REAL(wp), ALLOCATABLE, DIMENSION(:)       ::   ana_freq, ut   , vt   , ft
43   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   out_eta , out_u, out_v
44
45   INTEGER ::   ninco, nsparse
46   INTEGER ,       DIMENSION(jpdimsparse)         ::   njsparse, nisparse
47   INTEGER , SAVE, DIMENSION(jpincomax)           ::   ipos1
48   REAL(wp),       DIMENSION(jpdimsparse)         ::   valuesparse
49   REAL(wp),       DIMENSION(jpincomax)           ::   ztmp4 , ztmp7
50   REAL(wp), SAVE, DIMENSION(jpincomax,jpincomax) ::   ztmp3 , zpilier
51   REAL(wp), SAVE, DIMENSION(jpincomax)           ::   zpivot
52
53   CHARACTER (LEN=4), DIMENSION(jpmax_harmo) ::   tname   ! Names of tidal constituents ('M2', 'K1',...)
54
55   PUBLIC   dia_harm   ! routine called by step.F90
56
57   !!----------------------------------------------------------------------
58   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
59   !! $Id$
60   !! Software governed by the CeCILL license (see ./LICENSE)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE dia_harm_init 
65      !!----------------------------------------------------------------------
66      !!                 ***  ROUTINE dia_harm_init  ***
67      !!         
68      !! ** Purpose :   Initialization of tidal harmonic analysis
69      !!
70      !! ** Method  :   Initialize frequency array and  nodal factor for nit000_han
71      !!
72      !!--------------------------------------------------------------------
73      INTEGER :: jh, nhan, jk, ji
74      INTEGER ::   ios                 ! Local integer output status for namelist read
75
76      NAMELIST/nam_diaharm/ nit000_han, nitend_han, nstep_han, tname
77      !!----------------------------------------------------------------------
78
79      IF(lwp) THEN
80         WRITE(numout,*)
81         WRITE(numout,*) 'dia_harm_init: Tidal harmonic analysis initialization'
82         WRITE(numout,*) '~~~~~~~ '
83      ENDIF
84      !
85      IF( .NOT. ln_tide )   CALL ctl_stop( 'dia_harm_init : ln_tide must be true for harmonic analysis')
86      !
87      CALL tide_init_Wave
88      !
89      REWIND( numnam_ref )              ! Namelist nam_diaharm in reference namelist : Tidal harmonic analysis
90      READ  ( numnam_ref, nam_diaharm, IOSTAT = ios, ERR = 901)
91901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nam_diaharm in reference namelist', lwp )
92      REWIND( numnam_cfg )              ! Namelist nam_diaharm in configuration namelist : Tidal harmonic analysis
93      READ  ( numnam_cfg, nam_diaharm, IOSTAT = ios, ERR = 902 )
94902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nam_diaharm in configuration namelist', lwp )
95      IF(lwm) WRITE ( numond, nam_diaharm )
96      !
97      IF(lwp) THEN
98         WRITE(numout,*) 'First time step used for analysis:  nit000_han= ', nit000_han
99         WRITE(numout,*) 'Last  time step used for analysis:  nitend_han= ', nitend_han
100         WRITE(numout,*) 'Time step frequency for harmonic analysis:  nstep_han= ', nstep_han
101      ENDIF
102
103      ! Basic checks on harmonic analysis time window:
104      ! ----------------------------------------------
105      IF( nit000 > nit000_han )   CALL ctl_stop( 'dia_harm_init : nit000_han must be greater than nit000',   &
106         &                                       ' restart capability not implemented' )
107      IF( nitend < nitend_han )   CALL ctl_stop( 'dia_harm_init : nitend_han must be lower than nitend',   &
108         &                                       'restart capability not implemented' )
109
110      IF( MOD( nitend_han-nit000_han+1 , nstep_han ) /= 0 )   &
111         &                        CALL ctl_stop( 'dia_harm_init : analysis time span must be a multiple of nstep_han' )
112
113      nb_ana = 0
114      DO jk=1,jpmax_harmo
115         DO ji=1,jpmax_harmo
116            IF(TRIM(tname(jk)) == Wave(ji)%cname_tide) THEN
117               nb_ana=nb_ana+1
118            ENDIF
119         END DO
120      END DO
121      !
122      IF(lwp) THEN
123         WRITE(numout,*) '        Namelist nam_diaharm'
124         WRITE(numout,*) '        nb_ana    = ', nb_ana
125         CALL flush(numout)
126      ENDIF
127      !
128      IF (nb_ana > jpmax_harmo) THEN
129         WRITE(ctmp1,*) 'Can not use XIOS in iom_g0d, file: '//TRIM(clname)//', var:'//TRIM(cdvar)
130         WRITE(ctmp2,*) ' jpmax_harmo= ', jpmax_harmo
131         CALL ctl_stop( 'dia_harm_init', ctmp1, ctmp2 )
132      ENDIF
133
134      ALLOCATE(name    (nb_ana))
135      DO jk=1,nb_ana
136       DO ji=1,jpmax_harmo
137          IF (TRIM(tname(jk)) ==  Wave(ji)%cname_tide) THEN
138             name(jk) = ji
139             EXIT
140          END IF
141       END DO
142      END DO
143
144      ! Initialize frequency array:
145      ! ---------------------------
146      ALLOCATE( ana_freq(nb_ana), ut(nb_ana), vt(nb_ana), ft(nb_ana) )
147
148      CALL tide_harmo( ana_freq, vt, ut, ft, name, nb_ana )
149
150      IF(lwp) WRITE(numout,*) 'Analysed frequency  : ',nb_ana ,'Frequency '
151
152      DO jh = 1, nb_ana
153        IF(lwp) WRITE(numout,*) '                    : ',tname(jh),' ',ana_freq(jh)
154      END DO
155
156      ! Initialize temporary arrays:
157      ! ----------------------------
158      ALLOCATE( ana_temp(jpi,jpj,2*nb_ana,3) )
159      ana_temp(:,:,:,:) = 0._wp
160
161   END SUBROUTINE dia_harm_init
162
163
164   SUBROUTINE dia_harm ( kt, Kmm )
165      !!----------------------------------------------------------------------
166      !!                 ***  ROUTINE dia_harm  ***
167      !!         
168      !! ** Purpose :   Tidal harmonic analysis main routine
169      !!
170      !! ** Action  :   Sums ssh/u/v over time analysis [nit000_han,nitend_han]
171      !!
172      !!--------------------------------------------------------------------
173      INTEGER, INTENT( IN ) :: kt
174      INTEGER, INTENT( IN ) :: Kmm     ! time level index
175      !
176      INTEGER  :: ji, jj, jh, jc, nhc
177      REAL(wp) :: ztime, ztemp
178      !!--------------------------------------------------------------------
179      IF( ln_timing )   CALL timing_start('dia_harm')
180      !
181      IF( kt == nit000 )   CALL dia_harm_init
182      !
183      IF( kt >= nit000_han .AND. kt <= nitend_han .AND. MOD(kt,nstep_han) == 0 ) THEN
184         !
185         ztime = (kt-nit000+1) * rdt 
186         !
187         nhc = 0
188         DO jh = 1, nb_ana
189            DO jc = 1, 2
190               nhc = nhc+1
191               ztemp =(     MOD(jc,2) * ft(jh) *COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))  &
192                  &    +(1.-MOD(jc,2))* ft(jh) *SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)))
193                  !
194               DO jj = 1,jpj
195                  DO ji = 1,jpi
196                     ! Elevation
197                     ana_temp(ji,jj,nhc,1) = ana_temp(ji,jj,nhc,1) + ztemp*ssh(ji,jj,Kmm)*ssmask (ji,jj)       
198                     ana_temp(ji,jj,nhc,2) = ana_temp(ji,jj,nhc,2) + ztemp*uu_b(ji,jj,Kmm)*ssumask(ji,jj)
199                     ana_temp(ji,jj,nhc,3) = ana_temp(ji,jj,nhc,3) + ztemp*vv_b(ji,jj,Kmm)*ssvmask(ji,jj)
200                  END DO
201               END DO
202               !
203            END DO
204         END DO
205         !       
206      END IF
207      !
208      IF( kt == nitend_han )   CALL dia_harm_end
209      !
210      IF( ln_timing )   CALL timing_stop('dia_harm')
211      !
212   END SUBROUTINE dia_harm
213
214
215   SUBROUTINE dia_harm_end
216      !!----------------------------------------------------------------------
217      !!                 ***  ROUTINE diaharm_end  ***
218      !!         
219      !! ** Purpose :  Compute the Real and Imaginary part of tidal constituents
220      !!
221      !! ** Action  :  Decompose the signal on the harmonic constituents
222      !!
223      !!--------------------------------------------------------------------
224      INTEGER :: ji, jj, jh, jc, jn, nhan, jl
225      INTEGER :: ksp, kun, keq
226      REAL(wp) :: ztime, ztime_ini, ztime_end
227      REAL(wp) :: X1, X2
228      REAL(wp), DIMENSION(jpi,jpj,jpmax_harmo,2) ::   ana_amp   ! workspace
229      !!--------------------------------------------------------------------
230      !
231      IF(lwp) WRITE(numout,*)
232      IF(lwp) WRITE(numout,*) 'anharmo_end: kt=nitend_han: Perform harmonic analysis'
233      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
234
235      ztime_ini = nit000_han*rdt                 ! Initial time in seconds at the beginning of analysis
236      ztime_end = nitend_han*rdt                 ! Final time in seconds at the end of analysis
237      nhan = (nitend_han-nit000_han+1)/nstep_han ! Number of dumps used for analysis
238
239      ninco = 2*nb_ana
240
241      ksp = 0
242      keq = 0       
243      DO jn = 1, nhan
244         ztime=( (nhan-jn)*ztime_ini + (jn-1)*ztime_end )/FLOAT(nhan-1)
245         keq = keq + 1
246         kun = 0
247         DO jh = 1, nb_ana
248            DO jc = 1, 2
249               kun = kun + 1
250               ksp = ksp + 1
251               nisparse(ksp) = keq
252               njsparse(ksp) = kun
253               valuesparse(ksp) = (   MOD(jc,2) * ft(jh) * COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))   &
254                  &             + (1.-MOD(jc,2))* ft(jh) * SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)) )
255            END DO
256         END DO
257      END DO
258
259      nsparse = ksp
260
261      ! Elevation:
262      DO jj = 1, jpj
263         DO ji = 1, jpi
264            ! Fill input array
265            kun = 0
266            DO jh = 1, nb_ana
267               DO jc = 1, 2
268                  kun = kun + 1
269                  ztmp4(kun)=ana_temp(ji,jj,kun,1)
270               END DO
271            END DO
272
273            CALL SUR_DETERMINE(jj)
274
275            ! Fill output array
276            DO jh = 1, nb_ana
277               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
278               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
279            END DO
280         END DO
281      END DO
282
283      ALLOCATE( out_eta(jpi,jpj,2*nb_ana),   & 
284         &      out_u  (jpi,jpj,2*nb_ana),   &
285         &      out_v  (jpi,jpj,2*nb_ana)  )
286
287      DO jj = 1, jpj
288         DO ji = 1, jpi
289            DO jh = 1, nb_ana 
290               X1 = ana_amp(ji,jj,jh,1)
291               X2 =-ana_amp(ji,jj,jh,2)
292               out_eta(ji,jj,jh       ) = X1 * tmask_i(ji,jj)
293               out_eta(ji,jj,jh+nb_ana) = X2 * tmask_i(ji,jj)
294            END DO
295         END DO
296      END DO
297
298      ! ubar:
299      DO jj = 1, jpj
300         DO ji = 1, jpi
301            ! Fill input array
302            kun=0
303            DO jh = 1,nb_ana
304               DO jc = 1,2
305                  kun = kun + 1
306                  ztmp4(kun)=ana_temp(ji,jj,kun,2)
307               END DO
308            END DO
309
310            CALL SUR_DETERMINE(jj+1)
311
312            ! Fill output array
313            DO jh = 1, nb_ana
314               ana_amp(ji,jj,jh,1) = ztmp7((jh-1)*2+1)
315               ana_amp(ji,jj,jh,2) = ztmp7((jh-1)*2+2)
316            END DO
317
318         END DO
319      END DO
320
321      DO jj = 1, jpj
322         DO ji = 1, jpi
323            DO jh = 1, nb_ana 
324               X1= ana_amp(ji,jj,jh,1)
325               X2=-ana_amp(ji,jj,jh,2)
326               out_u(ji,jj,       jh) = X1 * ssumask(ji,jj)
327               out_u(ji,jj,nb_ana+jh) = X2 * ssumask(ji,jj)
328            ENDDO
329         ENDDO
330      ENDDO
331
332      ! vbar:
333      DO jj = 1, jpj
334         DO ji = 1, jpi
335            ! Fill input array
336            kun=0
337            DO jh = 1,nb_ana
338               DO jc = 1,2
339                  kun = kun + 1
340                  ztmp4(kun)=ana_temp(ji,jj,kun,3)
341               END DO
342            END DO
343
344            CALL SUR_DETERMINE(jj+1)
345
346            ! Fill output array
347            DO jh = 1, nb_ana
348               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
349               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
350            END DO
351
352         END DO
353      END DO
354
355      DO jj = 1, jpj
356         DO ji = 1, jpi
357            DO jh = 1, nb_ana 
358               X1=ana_amp(ji,jj,jh,1)
359               X2=-ana_amp(ji,jj,jh,2)
360               out_v(ji,jj,       jh)=X1 * ssvmask(ji,jj)
361               out_v(ji,jj,nb_ana+jh)=X2 * ssvmask(ji,jj)
362            END DO
363         END DO
364      END DO
365      !
366      CALL dia_wri_harm ! Write results in files
367      !
368   END SUBROUTINE dia_harm_end
369
370
371   SUBROUTINE dia_wri_harm
372      !!--------------------------------------------------------------------
373      !!                 ***  ROUTINE dia_wri_harm  ***
374      !!         
375      !! ** Purpose : Write tidal harmonic analysis results in a netcdf file
376      !!--------------------------------------------------------------------
377      CHARACTER(LEN=lc) :: cltext
378      CHARACTER(LEN=lc) ::   &
379         cdfile_name_T   ,   & ! name of the file created (T-points)
380         cdfile_name_U   ,   & ! name of the file created (U-points)
381         cdfile_name_V         ! name of the file created (V-points)
382      INTEGER  ::   jh
383      !!----------------------------------------------------------------------
384
385      IF(lwp) WRITE(numout,*) '  '
386      IF(lwp) WRITE(numout,*) 'dia_wri_harm : Write harmonic analysis results'
387      IF(lwp) WRITE(numout,*) '  '
388
389      ! A) Elevation
390      !/////////////
391      !
392      DO jh = 1, nb_ana
393      CALL iom_put( TRIM(tname(jh))//'x', out_eta(:,:,jh) )
394      CALL iom_put( TRIM(tname(jh))//'y', out_eta(:,:,nb_ana+jh) )
395      END DO
396
397      ! B) ubar
398      !/////////
399      !
400      DO jh = 1, nb_ana
401      CALL iom_put( TRIM(tname(jh))//'x_u', out_u(:,:,jh) )
402      CALL iom_put( TRIM(tname(jh))//'y_u', out_u(:,:,nb_ana+jh) )
403      END DO
404
405      ! C) vbar
406      !/////////
407      !
408      DO jh = 1, nb_ana
409         CALL iom_put( TRIM(tname(jh))//'x_v', out_v(:,:,jh       ) )
410         CALL iom_put( TRIM(tname(jh))//'y_v', out_v(:,:,jh+nb_ana) )
411      END DO
412      !
413   END SUBROUTINE dia_wri_harm
414
415
416   SUBROUTINE SUR_DETERMINE(init)
417      !!---------------------------------------------------------------------------------
418      !!                      *** ROUTINE SUR_DETERMINE ***
419      !!   
420      !!   
421      !!       
422      !!---------------------------------------------------------------------------------
423      INTEGER, INTENT(in) ::   init 
424      !
425      INTEGER                         :: ji_sd, jj_sd, ji1_sd, ji2_sd, jk1_sd, jk2_sd
426      REAL(wp)                        :: zval1, zval2, zx1
427      REAL(wp), DIMENSION(jpincomax) :: ztmpx, zcol1, zcol2
428      INTEGER , DIMENSION(jpincomax) :: ipos2, ipivot
429      !---------------------------------------------------------------------------------
430      !           
431      IF( init == 1 ) THEN
432         IF( nsparse > jpdimsparse )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : nsparse .GT. jpdimsparse')
433         IF( ninco   > jpincomax   )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : ninco .GT. jpincomax')
434         !
435         ztmp3(:,:) = 0._wp
436         !
437         DO jk1_sd = 1, nsparse
438            DO jk2_sd = 1, nsparse
439               nisparse(jk2_sd) = nisparse(jk2_sd)
440               njsparse(jk2_sd) = njsparse(jk2_sd)
441               IF( nisparse(jk2_sd) == nisparse(jk1_sd) ) THEN
442                  ztmp3(njsparse(jk1_sd),njsparse(jk2_sd)) = ztmp3(njsparse(jk1_sd),njsparse(jk2_sd))  &
443                     &                                     + valuesparse(jk1_sd)*valuesparse(jk2_sd)
444               ENDIF
445            END DO
446         END DO
447         !
448         DO jj_sd = 1 ,ninco
449            ipos1(jj_sd) = jj_sd
450            ipos2(jj_sd) = jj_sd
451         END DO
452         !
453         DO ji_sd = 1 , ninco
454            !
455            !find greatest non-zero pivot:
456            zval1 = ABS(ztmp3(ji_sd,ji_sd))
457            !
458            ipivot(ji_sd) = ji_sd
459            DO jj_sd = ji_sd, ninco
460               zval2 = ABS(ztmp3(ji_sd,jj_sd))
461               IF( zval2 >= zval1 )THEN
462                  ipivot(ji_sd) = jj_sd
463                  zval1         = zval2
464               ENDIF
465            END DO
466            !
467            DO ji1_sd = 1, ninco
468               zcol1(ji1_sd)               = ztmp3(ji1_sd,ji_sd)
469               zcol2(ji1_sd)               = ztmp3(ji1_sd,ipivot(ji_sd))
470               ztmp3(ji1_sd,ji_sd)         = zcol2(ji1_sd)
471               ztmp3(ji1_sd,ipivot(ji_sd)) = zcol1(ji1_sd)
472            END DO
473            !
474            ipos2(ji_sd)         = ipos1(ipivot(ji_sd))
475            ipos2(ipivot(ji_sd)) = ipos1(ji_sd)
476            ipos1(ji_sd)         = ipos2(ji_sd)
477            ipos1(ipivot(ji_sd)) = ipos2(ipivot(ji_sd))
478            zpivot(ji_sd)        = ztmp3(ji_sd,ji_sd)
479            DO jj_sd = 1, ninco
480               ztmp3(ji_sd,jj_sd) = ztmp3(ji_sd,jj_sd) / zpivot(ji_sd)
481            END DO
482            !
483            DO ji2_sd = ji_sd+1, ninco
484               zpilier(ji2_sd,ji_sd)=ztmp3(ji2_sd,ji_sd)
485               DO jj_sd=1,ninco
486                  ztmp3(ji2_sd,jj_sd)=  ztmp3(ji2_sd,jj_sd) - ztmp3(ji_sd,jj_sd) * zpilier(ji2_sd,ji_sd)
487               END DO
488            END DO
489            !
490         END DO
491         !
492      ENDIF ! End init==1
493
494      DO ji_sd = 1, ninco
495         ztmp4(ji_sd) = ztmp4(ji_sd) / zpivot(ji_sd)
496         DO ji2_sd = ji_sd+1, ninco
497            ztmp4(ji2_sd) = ztmp4(ji2_sd) - ztmp4(ji_sd) * zpilier(ji2_sd,ji_sd)
498         END DO
499      END DO
500
501      !system solving:
502      ztmpx(ninco) = ztmp4(ninco) / ztmp3(ninco,ninco)
503      ji_sd = ninco
504      DO ji_sd = ninco-1, 1, -1
505         zx1 = 0._wp
506         DO jj_sd = ji_sd+1, ninco
507            zx1 = zx1 + ztmpx(jj_sd) * ztmp3(ji_sd,jj_sd)
508         END DO
509         ztmpx(ji_sd) = ztmp4(ji_sd)-zx1
510      END DO
511
512      DO jj_sd =1, ninco
513         ztmp7(ipos1(jj_sd))=ztmpx(jj_sd)
514      END DO
515      !
516   END SUBROUTINE SUR_DETERMINE
517
518#else
519   !!----------------------------------------------------------------------
520   !!   Default case :   Empty module
521   !!----------------------------------------------------------------------
522   LOGICAL, PUBLIC, PARAMETER ::   lk_diaharm = .FALSE.
523CONTAINS
524   SUBROUTINE dia_harm ( kt, Kmm )     ! Empty routine
525      INTEGER, INTENT( IN ) :: kt 
526      INTEGER, INTENT( IN ) :: Kmm 
527      WRITE(*,*) 'dia_harm: you should not have seen this print'
528   END SUBROUTINE dia_harm
529#endif
530
531   !!======================================================================
532END MODULE diaharm
Note: See TracBrowser for help on using the repository browser.