New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OFF – NEMO

Context Navigation

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OFF/nemogcm.F90 @ 10825

Last change on this file since 10825 was 10756, checked in by acc, 5 years ago
Branch 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. Changes to OFF, SAO and SAS to enable SETTE testing. SAS/step.F90 is based on the yet-to-be-finalised version of OCE/step.F90 and so may need updating later
Property svn:keywords set to `Id`
File size: 28.7 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Off-line Ocean : passive tracer evolution, dynamics read in files
5	!!======================================================================
6	!! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line
7	!! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8	!! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface
9	!!----------------------------------------------------------------------
10
11	!!----------------------------------------------------------------------
12	!! nemo_gcm : off-line: solve ocean tracer only
13	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14	!! nemo_init : initialization of the NEMO system
15	!! nemo_ctl : initialisation of the contol print
16	!! nemo_closefile: close remaining open files
17	!! nemo_alloc : dynamical allocation
18	!! istate_init : simple initialization to zero of ocean fields
19	!! stp_ctl : reduced step control (no dynamics in off-line)
20	!!----------------------------------------------------------------------
21	USE dom_oce ! ocean space domain variables
22	USE oce ! dynamics and tracers variables
23	USE trc_oce ! Shared ocean/passive tracers variables
24	USE c1d ! 1D configuration
25	USE domain ! domain initialization from coordinate & bathymetry (dom_init routine)
26	USE closea ! treatment of closed seas (for ln_closea)
27	USE usrdef_nam ! user defined configuration
28	USE eosbn2 ! equation of state (eos bn2 routine)
29	! ! ocean physics
30	USE ldftra ! lateral diffusivity setting (ldf_tra_init routine)
31	USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine)
32	USE traqsr ! solar radiation penetration (tra_qsr_init routine)
33	USE trabbl ! bottom boundary layer (tra_bbl_init routine)
34	USE traldf ! lateral physics (tra_ldf_init routine)
35	USE sbcmod ! surface boundary condition (sbc_init routine)
36	USE phycst ! physical constant (par_cst routine)
37	USE dtadyn ! Lecture and Interpolation of the dynamical fields
38	USE trcini ! Initilization of the passive tracers
39	USE daymod ! calendar (day routine)
40	USE trcstp ! passive tracer time-stepping (trc_stp routine)
41	USE step , ONLY : update_pointers ! RK3 development only. (stp routine)
42	USE dtadyn ! Lecture and interpolation of the dynamical fields
43	! ! Passive tracers needs
44	USE trc ! passive tracer : variables
45	USE trcnam ! passive tracer : namelist
46	USE trcrst ! passive tracer restart
47	USE diaptr ! Need to initialise this as some variables are used in if statements later
48	USE sbc_oce , ONLY : ln_rnf
49	USE sbcrnf ! surface boundary condition : runoffs
50	! ! I/O & MPP
51	USE iom ! I/O library
52	USE in_out_manager ! I/O manager
53	USE mppini ! shared/distributed memory setting (mpp_init routine)
54	USE lib_mpp ! distributed memory computing
55	#if defined key_iomput
56	USE xios ! xIOserver
57	#endif
58	USE prtctl ! Print control (prt_ctl_init routine)
59	USE timing ! Timing
60	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
61	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
62
63	IMPLICIT NONE
64	PRIVATE
65
66	PUBLIC nemo_gcm ! called by nemo.F90
67
68	CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
69
70	!!----------------------------------------------------------------------
71	!! NEMO/OFF 4.0 , NEMO Consortium (2018)
72	!! $Id$
73	!! Software governed by the CeCILL license (see ./LICENSE)
74	!!----------------------------------------------------------------------
75	CONTAINS
76
77	SUBROUTINE nemo_gcm
78	!!----------------------------------------------------------------------
79	!! * ROUTINE nemo_gcm *
80	!!
81	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
82	!! curvilinear mesh on the sphere.
83	!!
84	!! ** Method : - model general initialization
85	!! - launch the time-stepping (dta_dyn and trc_stp)
86	!! - finalize the run by closing files and communications
87	!!
88	!! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL.
89	!! Madec, 2008, internal report, IPSL.
90	!!----------------------------------------------------------------------
91	INTEGER :: istp, indic ! time step index
92	!!----------------------------------------------------------------------
93
94	CALL nemo_init ! Initializations
95
96	! check that all process are still there... If some process have an error,
97	! they will never enter in step and other processes will wait until the end of the cpu time!
98	CALL mpp_max( 'nemogcm', nstop )
99
100	! !-----------------------!
101	! !== time stepping ==!
102	! !-----------------------!
103	istp = nit000
104	!
105	IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization
106	!
107	CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
108	!
109	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==!
110	!
111	IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init)
112	CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp
113	#if defined key_sed_off
114	CALL dta_dyn_sed( istp ) ! Interpolation of the dynamical fields
115	#else
116	CALL dta_dyn ( istp ) ! Interpolation of the dynamical fields
117	IF( .NOT.ln_linssh ) CALL dta_dyn_swp( istp ) ! swap of sea surface height and vertical scale factors
118	#endif
119	CALL trc_stp ( istp ) ! time-stepping
120	CALL stp_ctl ( istp, indic ) ! Time loop: control and print
121	istp = istp + 1
122	END DO
123	!
124	#if defined key_iomput
125	CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
126	#endif
127
128	! !------------------------!
129	! !== finalize the run ==!
130	! !------------------------!
131	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
132
133	IF( nstop /= 0 .AND. lwp ) THEN ! error print
134	WRITE(numout,cform_err)
135	WRITE(numout,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
136	WRITE(numout,*)
137	ENDIF
138	!
139	IF( ln_timing ) CALL timing_finalize
140	!
141	CALL nemo_closefile
142	!
143	#if defined key_iomput
144	CALL xios_finalize ! end mpp communications with xios
145	#else
146	IF( lk_mpp ) CALL mppstop ! end mpp communications
147	#endif
148	!
149	END SUBROUTINE nemo_gcm
150
151
152	SUBROUTINE nemo_init
153	!!----------------------------------------------------------------------
154	!! * ROUTINE nemo_init *
155	!!
156	!! ** Purpose : initialization of the nemo model in off-line mode
157	!!----------------------------------------------------------------------
158	INTEGER :: ji ! dummy loop indices
159	INTEGER :: ios, ilocal_comm ! local integers
160	CHARACTER(len=120), DIMENSION(30) :: cltxt, cltxt2, clnam
161	!!
162	NAMELIST/namctl/ ln_ctl , sn_cfctl, nn_print, nn_ictls, nn_ictle, &
163	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
164	& ln_timing, ln_diacfl
165	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
166	!!----------------------------------------------------------------------
167	!
168	cltxt = ''
169	cltxt2 = ''
170	clnam = ''
171	cxios_context = 'nemo'
172	!
173	! ! Open reference namelist and configuration namelist files
174	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
175	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
176	!
177	REWIND( numnam_ref ) ! Namelist namctl in reference namelist
178	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
179	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
180	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
181	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
182	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
183	!
184	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist
185	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
186	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
187	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist
188	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
189	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
190
191	! !--------------------------!
192	! ! Set global domain size ! (control print return in cltxt2)
193	! !--------------------------!
194	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
195	CALL domain_cfg ( cltxt2, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
196	!
197	ELSE ! user-defined namelist
198	CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
199	ENDIF
200	!
201	l_offline = .true. ! passive tracers are run offline
202	!
203	! !--------------------------------------------!
204	! ! set communicator & select the local node !
205	! ! NB: mynode also opens output.namelist.dyn !
206	! ! on unit number numond on first proc !
207	! !--------------------------------------------!
208	#if defined key_iomput
209	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )
210	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) ! Nodes selection
211	#else
212	ilocal_comm = 0
213	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop ) ! Nodes selection (control print return in cltxt)
214	#endif
215
216	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
217
218	IF( sn_cfctl%l_config ) THEN
219	! Activate finer control of report outputs
220	! optionally switch off output from selected areas (note this only
221	! applies to output which does not involve global communications)
222	IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax ) .OR. &
223	& ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) ) &
224	& CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
225	ELSE
226	! Use ln_ctl to turn on or off all options.
227	CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
228	ENDIF
229
230	lwm = (narea == 1) ! control of output namelists
231	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
232
233	IF(lwm) THEN ! write merged namelists from earlier to output namelist
234	! ! now that the file has been opened in call to mynode.
235	! ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
236	WRITE( numond, namctl )
237	WRITE( numond, namcfg )
238	IF( .NOT.ln_read_cfg ) THEN
239	DO ji = 1, SIZE(clnam)
240	IF( TRIM(clnam(ji)) /= '' ) WRITE(numond, * ) clnam(ji) ! namusr_def print
241	END DO
242	ENDIF
243	ENDIF
244
245	IF(lwp) THEN ! open listing units
246	!
247	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
248	!
249	WRITE(numout,*)
250	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
251	WRITE(numout,*) ' NEMO team'
252	WRITE(numout,*) ' Off-line TOP Model'
253	WRITE(numout,*) ' NEMO version 4.0 (2019) '
254	WRITE(numout,*)
255	WRITE(numout,*) " ._ ._ ._ ._ ._ "
256	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
257	WRITE(numout,*)
258	WRITE(numout,*) " o _, _, "
259	WRITE(numout,*) " o .' ( .-' / "
260	WRITE(numout,*) " o _/..._'. .' / "
261	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
262	WRITE(numout,*) " ) ( o) ;= <_ ( "
263	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
264	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
265	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
266	WRITE(numout,*) " ) ) ` ( ( "
267	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
268	WRITE(numout,*)
269	DO ji = 1, SIZE(cltxt)
270	IF( TRIM(cltxt (ji)) /= '' ) WRITE(numout,*) TRIM(cltxt(ji)) ! control print of mynode
271	END DO
272	WRITE(numout,*)
273	WRITE(numout,*)
274	DO ji = 1, SIZE(cltxt2)
275	IF( TRIM(cltxt2(ji)) /= '' ) WRITE(numout,*) TRIM(cltxt2(ji)) ! control print of domain size
276	END DO
277	!
278	WRITE(numout,cform_aaa) ! Flag AAAAAAA
279	!
280	ENDIF
281	! open /dev/null file to be able to supress output write easily
282	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
283	!
284	! ! Domain decomposition
285	CALL mpp_init ! MPP
286
287	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
288	CALL nemo_alloc()
289
290	! Initialise time level indices
291	Nm1 = 1; Nnn = 2; Np1 = 3; Nrhs = Np1
292	Nm1_2lev = 1; Nnn_2lev = 2
293
294	! Initialisation of temporary pointers (to be deleted after development finished)
295	CALL update_pointers()
296
297	! !-------------------------------!
298	! ! NEMO general initialization !
299	! !-------------------------------!
300
301	CALL nemo_ctl ! Control prints
302	!
303	! ! General initialization
304	IF( ln_timing ) CALL timing_init
305	IF( ln_timing ) CALL timing_start( 'nemo_init')
306	!
307	CALL phy_cst ! Physical constants
308	CALL eos_init ! Equation of state
309	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
310	CALL dom_init("OPA") ! Domain
311	IF( ln_ctl ) CALL prt_ctl_init ! Print control
312
313	CALL istate_init ! ocean initial state (Dynamics and tracers)
314
315	CALL sbc_init ! Forcings : surface module
316
317	! ! Tracer physics
318	CALL ldf_tra_init ! Lateral ocean tracer physics
319	CALL ldf_eiv_init ! Eddy induced velocity param
320	CALL tra_ldf_init ! lateral mixing
321	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
322	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation
323	IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
324
325	! ! Passive tracers
326	CALL trc_nam_run ! Needed to get restart parameters for passive tracers
327	CALL trc_rst_cal( nit000, 'READ' ) ! calendar
328	#if defined key_sed_off
329	CALL dta_dyn_sed_init ! Initialization for the dynamics
330	#else
331	CALL dta_dyn_init ! Initialization for the dynamics
332	#endif
333
334	CALL trc_init ! Passive tracers initialization
335	CALL dia_ptr_init ! Poleward TRansports initialization
336
337	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
338	!
339	IF( ln_timing ) CALL timing_stop( 'nemo_init')
340	!
341	END SUBROUTINE nemo_init
342
343
344	SUBROUTINE nemo_ctl
345	!!----------------------------------------------------------------------
346	!! * ROUTINE nemo_ctl *
347	!!
348	!! ** Purpose : control print setting
349	!!
350	!! ** Method : - print namctl information and check some consistencies
351	!!----------------------------------------------------------------------
352	!
353	IF(lwp) THEN ! control print
354	WRITE(numout,*)
355	WRITE(numout,*) 'nemo_ctl: Control prints'
356	WRITE(numout,*) '~~~~~~~~'
357	WRITE(numout,*) ' Namelist namctl'
358	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
359	WRITE(numout,*) ' finer control over o/p sn_cfctl%l_config = ', sn_cfctl%l_config
360	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
361	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
362	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
363	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
364	WRITE(numout,*) ' sn_cfctl%l_mppout = ', sn_cfctl%l_mppout
365	WRITE(numout,*) ' sn_cfctl%l_mpptop = ', sn_cfctl%l_mpptop
366	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
367	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
368	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
369	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
370	WRITE(numout,*) ' level of print nn_print = ', nn_print
371	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
372	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
373	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
374	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
375	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
376	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
377	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
378	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
379	ENDIF
380	!
381	nprint = nn_print ! convert DOCTOR namelist names into OLD names
382	nictls = nn_ictls
383	nictle = nn_ictle
384	njctls = nn_jctls
385	njctle = nn_jctle
386	isplt = nn_isplt
387	jsplt = nn_jsplt
388
389	IF(lwp) THEN ! control print
390	WRITE(numout,*)
391	WRITE(numout,*) ' Namelist namcfg'
392	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
393	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
394	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
395	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
396	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
397	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
398	ENDIF
399	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
400	!
401	! ! Parameter control
402	!
403	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
404	IF( lk_mpp .AND. jpnij > 1 ) THEN
405	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
406	ELSE
407	IF( isplt == 1 .AND. jsplt == 1 ) THEN
408	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
409	& ' - the print control will be done over the whole domain' )
410	ENDIF
411	ijsplt = isplt * jsplt ! total number of processors ijsplt
412	ENDIF
413	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
414	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
415	!
416	! ! indices used for the SUM control
417	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
418	lsp_area = .FALSE.
419	ELSE ! print control done over a specific area
420	lsp_area = .TRUE.
421	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
422	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
423	nictls = 1
424	ENDIF
425	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
426	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
427	nictle = jpiglo
428	ENDIF
429	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
430	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
431	njctls = 1
432	ENDIF
433	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
434	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
435	njctle = jpjglo
436	ENDIF
437	ENDIF
438	ENDIF
439	!
440	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
441	& 'Compile with key_nosignedzero enabled' )
442	!
443	END SUBROUTINE nemo_ctl
444
445
446	SUBROUTINE nemo_closefile
447	!!----------------------------------------------------------------------
448	!! * ROUTINE nemo_closefile *
449	!!
450	!! ** Purpose : Close the files
451	!!----------------------------------------------------------------------
452	!
453	IF( lk_mpp ) CALL mppsync
454	!
455	CALL iom_close ! close all input/output files managed by iom_*
456	!
457	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
458	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
459	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
460	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
461	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
462	!
463	numout = 6 ! redefine numout in case it is used after this point...
464	!
465	END SUBROUTINE nemo_closefile
466
467
468	SUBROUTINE nemo_alloc
469	!!----------------------------------------------------------------------
470	!! * ROUTINE nemo_alloc *
471	!!
472	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
473	!!
474	!! ** Method :
475	!!----------------------------------------------------------------------
476	USE diawri , ONLY : dia_wri_alloc
477	USE dom_oce, ONLY : dom_oce_alloc
478	USE zdf_oce, ONLY : zdf_oce_alloc
479	USE trc_oce, ONLY : trc_oce_alloc
480	!
481	INTEGER :: ierr
482	!!----------------------------------------------------------------------
483	!
484	ierr = oce_alloc () ! ocean
485	ierr = ierr + dia_wri_alloc()
486	ierr = ierr + dom_oce_alloc() ! ocean domain
487	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
488	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
489	!
490	CALL mpp_sum( 'nemogcm', ierr )
491	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
492	!
493	END SUBROUTINE nemo_alloc
494
495	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
496	!!----------------------------------------------------------------------
497	!! * ROUTINE nemo_set_cfctl *
498	!!
499	!! ** Purpose : Set elements of the output control structure to setto.
500	!! for_all should be .false. unless all areas are to be
501	!! treated identically.
502	!!
503	!! ** Method : Note this routine can be used to switch on/off some
504	!! types of output for selected areas but any output types
505	!! that involve global communications (e.g. mpp_max, glob_sum)
506	!! should be protected from selective switching by the
507	!! for_all argument
508	!!----------------------------------------------------------------------
509	LOGICAL :: setto, for_all
510	TYPE(sn_ctl) :: sn_cfctl
511	!!----------------------------------------------------------------------
512	IF( for_all ) THEN
513	sn_cfctl%l_runstat = setto
514	sn_cfctl%l_trcstat = setto
515	ENDIF
516	sn_cfctl%l_oceout = setto
517	sn_cfctl%l_layout = setto
518	sn_cfctl%l_mppout = setto
519	sn_cfctl%l_mpptop = setto
520	END SUBROUTINE nemo_set_cfctl
521
522	SUBROUTINE istate_init
523	!!----------------------------------------------------------------------
524	!! * ROUTINE istate_init *
525	!!
526	!! ** Purpose : Initialization to zero of the dynamics and tracers.
527	!!----------------------------------------------------------------------
528	!
529	! now fields ! after fields !
530	un (:,:,:) = 0._wp ; ua(:,:,:) = 0._wp !
531	vn (:,:,:) = 0._wp ; va(:,:,:) = 0._wp !
532	wn (:,:,:) = 0._wp ! !
533	hdivn(:,:,:) = 0._wp ! !
534	tsn (:,:,:,:) = 0._wp ! !
535	!
536	rhd (:,:,:) = 0.e0
537	rhop (:,:,:) = 0.e0
538	rn2 (:,:,:) = 0.e0
539	!
540	END SUBROUTINE istate_init
541
542
543	SUBROUTINE stp_ctl( kt, kindic )
544	!!----------------------------------------------------------------------
545	!! * ROUTINE stp_ctl *
546	!!
547	!! ** Purpose : Control the run
548	!!
549	!! ** Method : - Save the time step in numstp
550	!!
551	!! ** Actions : 'time.step' file containing the last ocean time-step
552	!!----------------------------------------------------------------------
553	INTEGER, INTENT(in ) :: kt ! ocean time-step index
554	INTEGER, INTENT(inout) :: kindic ! indicator of solver convergence
555	!!----------------------------------------------------------------------
556	!
557	IF( kt == nit000 .AND. lwm ) THEN
558	WRITE(numout,*)
559	WRITE(numout,*) 'stp_ctl : time-stepping control'
560	WRITE(numout,*) '~~~~~~~'
561	! open time.step file
562	CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
563	ENDIF
564	!
565	IF(lwm) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp
566	IF(lwm) REWIND( numstp ) ! --------------------------
567	!
568	END SUBROUTINE stp_ctl
569	!!======================================================================
570	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: