New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zfechem.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z/p4zfechem.F90 @ 11504

Last change on this file since 11504 was 10975, checked in by acc, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Finish converting all TOP routines and knock-on effects of these conversions. Fully SETTE tested (SETTE tests 1-6 and 9). This completes the first stage conversion of TRA and TOP but need to revisit and pass ts and tr arrays through the argument lists where appropriate.

  • Property svn:keywords set to Id
File size: 14.1 KB
RevLine 
[3443]1MODULE p4zfechem
2   !!======================================================================
3   !!                         ***  MODULE p4zfechem  ***
4   !! TOP :   PISCES Compute iron chemistry and scavenging
5   !!======================================================================
[3461]6   !! History :   3.5  !  2012-07 (O. Aumont, A. Tagliabue, C. Ethe) Original code
[7646]7   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
[3443]8   !!----------------------------------------------------------------------
[9169]9   !!   p4z_fechem       : Compute remineralization/scavenging of iron
10   !!   p4z_fechem_init  : Initialisation of parameters for remineralisation
11   !!   p4z_fechem_alloc : Allocate remineralisation variables
[3443]12   !!----------------------------------------------------------------------
[9169]13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zche          ! chemical model
17   USE p4zsbc          ! Boundary conditions from sediments
18   USE prtctl_trc      ! print control for debugging
19   USE iom             ! I/O manager
[3443]20
21   IMPLICIT NONE
22   PRIVATE
23
[9169]24   PUBLIC   p4z_fechem        ! called in p4zbio.F90
25   PUBLIC   p4z_fechem_init   ! called in trcsms_pisces.F90
[3443]26
[9169]27   LOGICAL          ::   ln_ligvar    !: boolean for variable ligand concentration following Tagliabue and voelker
28   REAL(wp), PUBLIC ::   xlam1        !: scavenging rate of Iron
29   REAL(wp), PUBLIC ::   xlamdust     !: scavenging rate of Iron by dust
30   REAL(wp), PUBLIC ::   ligand       !: ligand concentration in the ocean
31   REAL(wp), PUBLIC ::   kfep         !: rate constant for nanoparticle formation
[3443]32
33   !!----------------------------------------------------------------------
[10067]34   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
[10069]35   !! $Id$
[10068]36   !! Software governed by the CeCILL license (see ./LICENSE)
[3443]37   !!----------------------------------------------------------------------
38CONTAINS
39
[10975]40   SUBROUTINE p4z_fechem( kt, knt, Kbb, Kmm, Krhs )
[3443]41      !!---------------------------------------------------------------------
42      !!                     ***  ROUTINE p4z_fechem  ***
43      !!
44      !! ** Purpose :   Compute remineralization/scavenging of iron
45      !!
[10401]46      !! ** Method  :   A simple chemistry model of iron from Aumont and Bopp (2006)
47      !!                based on one ligand and one inorganic form
[3443]48      !!---------------------------------------------------------------------
[9169]49      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step
[10975]50      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
[3443]51      !
[7646]52      INTEGER  ::   ji, jj, jk, jic, jn
[3446]53      REAL(wp) ::   zdep, zlam1a, zlam1b, zlamfac
[7646]54      REAL(wp) ::   zkeq, zfeequi, zfesatur, zfecoll, fe3sol
[3446]55      REAL(wp) ::   zdenom1, zscave, zaggdfea, zaggdfeb, zcoag
[3443]56      REAL(wp) ::   ztrc, zdust
[7646]57      REAL(wp) ::   zdenom2
58      REAL(wp) ::   zzFeL1, zzFeL2, zzFe2, zzFeP, zzFe3, zzstrn2
59      REAL(wp) ::   zrum, zcodel, zargu, zlight
[9169]60      REAL(wp) ::   zkox, zkph1, zkph2, zph, zionic, ztligand
61      REAL(wp) ::   za, zb, zc, zkappa1, zkappa2, za0, za1, za2
62      REAL(wp) ::   zxs, zfunc, zp, zq, zd, zr, zphi, zfff, zp3, zq2
[10362]63      REAL(wp) ::   ztfe, zoxy, zhplus, zxlam
[9169]64      REAL(wp) ::   zaggliga, zaggligb
65      REAL(wp) ::   dissol, zligco
[10362]66      REAL(wp) :: zrfact2
[7646]67      CHARACTER (len=25) :: charout
[9169]68      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zTL1, zFe3, ztotlig, precip, zFeL1
[10362]69      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zcoll3d, zscav3d, zlcoll3d
[3443]70      !!---------------------------------------------------------------------
71      !
[9124]72      IF( ln_timing )   CALL timing_start('p4z_fechem')
[3443]73      !
[7753]74      zFe3 (:,:,:) = 0.
75      zFeL1(:,:,:) = 0.
76      zTL1 (:,:,:) = 0.
[3461]77
[3443]78      ! Total ligand concentration : Ligands can be chosen to be constant or variable
79      ! Parameterization from Tagliabue and Voelker (2011)
80      ! -------------------------------------------------
81      IF( ln_ligvar ) THEN
[10975]82         ztotlig(:,:,:) =  0.09 * tr(:,:,:,jpdoc,Kbb) * 1E6 + ligand * 1E9
[7753]83         ztotlig(:,:,:) =  MIN( ztotlig(:,:,:), 10. )
[3443]84      ELSE
[10975]85        IF( ln_ligand ) THEN  ;   ztotlig(:,:,:) = tr(:,:,:,jplgw,Kbb) * 1E9
[7753]86        ELSE                  ;   ztotlig(:,:,:) = ligand * 1E9
[7646]87        ENDIF
[3443]88      ENDIF
89
[10401]90      ! ------------------------------------------------------------
91      !  from Aumont and Bopp (2006)
92      ! This model is based on one ligand and Fe'
93      ! Chemistry is supposed to be fast enough to be at equilibrium
94      ! ------------------------------------------------------------
95      DO jk = 1, jpkm1
[7646]96         DO jj = 1, jpj
97            DO ji = 1, jpi
[10401]98               zTL1(ji,jj,jk)  = ztotlig(ji,jj,jk)
99               zkeq            = fekeq(ji,jj,jk)
100               zfesatur        = zTL1(ji,jj,jk) * 1E-9
[10975]101               ztfe            = tr(ji,jj,jk,jpfer,Kbb) 
[10401]102               ! Fe' is the root of a 2nd order polynom
103               zFe3 (ji,jj,jk) = ( -( 1. + zfesatur * zkeq - zkeq * ztfe )               &
104                  &              + SQRT( ( 1. + zfesatur * zkeq - zkeq * ztfe )**2       &
105                  &              + 4. * ztfe * zkeq) ) / ( 2. * zkeq )
106               zFe3 (ji,jj,jk) = zFe3(ji,jj,jk) * 1E9
[10975]107               zFeL1(ji,jj,jk) = MAX( 0., tr(ji,jj,jk,jpfer,Kbb) * 1E9 - zFe3(ji,jj,jk) )
[10401]108           END DO
[7646]109         END DO
[10401]110      END DO
[3443]111         !
[7646]112
[3531]113      zdust = 0.         ! if no dust available
[3443]114      DO jk = 1, jpkm1
115         DO jj = 1, jpj
116            DO ji = 1, jpi
117               ! Scavenging rate of iron. This scavenging rate depends on the load of particles of sea water.
118               ! This parameterization assumes a simple second order kinetics (k[Particles][Fe]).
119               ! Scavenging onto dust is also included as evidenced from the DUNE experiments.
120               ! --------------------------------------------------------------------------------------
[10362]121               zhplus  = max( rtrn, hi(ji,jj,jk) )
122               fe3sol  = fesol(ji,jj,jk,1) * ( zhplus**3 + fesol(ji,jj,jk,2) * zhplus**2  &
123               &         + fesol(ji,jj,jk,3) * zhplus + fesol(ji,jj,jk,4)     &
124               &         + fesol(ji,jj,jk,5) / zhplus )
[10401]125               !
126               zfeequi = zFe3(ji,jj,jk) * 1E-9
127               zhplus  = max( rtrn, hi(ji,jj,jk) )
128               fe3sol  = fesol(ji,jj,jk,1) * ( zhplus**3 + fesol(ji,jj,jk,2) * zhplus**2  &
[10362]129                  &         + fesol(ji,jj,jk,3) * zhplus + fesol(ji,jj,jk,4)     &
130                  &         + fesol(ji,jj,jk,5) / zhplus )
[10401]131               zfecoll = 0.5 * zFeL1(ji,jj,jk) * 1E-9
132               ! precipitation of Fe3+, creation of nanoparticles
133               precip(ji,jj,jk) = MAX( 0., ( zFe3(ji,jj,jk) * 1E-9 - fe3sol ) ) * kfep * xstep
[7646]134               !
[10975]135               ztrc   = ( tr(ji,jj,jk,jppoc,Kbb) + tr(ji,jj,jk,jpgoc,Kbb) + tr(ji,jj,jk,jpcal,Kbb) + tr(ji,jj,jk,jpgsi,Kbb) ) * 1.e6 
[10362]136               IF( ln_dust )  zdust  = dust(ji,jj) / ( wdust / rday ) * tmask(ji,jj,jk) &
[10975]137               &  * EXP( -gdept(ji,jj,jk,Kmm) / 540. )
[10362]138               IF (ln_ligand) THEN
[10975]139                  zxlam  = xlam1 * MAX( 1.E-3, EXP(-2 * etot(ji,jj,jk) / 10. ) * (1. - EXP(-2 * tr(ji,jj,jk,jpoxy,Kbb) / 100.E-6 ) ))
[10362]140               ELSE
141                  zxlam  = xlam1 * 1.0
142               ENDIF
143               zlam1b = 3.e-5 + xlamdust * zdust + zxlam * ztrc
[7646]144               zscave = zfeequi * zlam1b * xstep
[3443]145
146               ! Compute the different ratios for scavenging of iron
147               ! to later allocate scavenged iron to the different organic pools
148               ! ---------------------------------------------------------
[10975]149               zdenom1 = zxlam * tr(ji,jj,jk,jppoc,Kbb) / zlam1b
150               zdenom2 = zxlam * tr(ji,jj,jk,jpgoc,Kbb) / zlam1b
[3443]151
152               !  Increased scavenging for very high iron concentrations found near the coasts
153               !  due to increased lithogenic particles and let say it is unknown processes (precipitation, ...)
154               !  -----------------------------------------------------------
[3475]155               zlamfac = MAX( 0.e0, ( gphit(ji,jj) + 55.) / 30. )
156               zlamfac = MIN( 1.  , zlamfac )
[10975]157               zdep    = MIN( 1., 1000. / gdept(ji,jj,jk,Kmm) )
158               zcoag   = 1E-4 * ( 1. - zlamfac ) * zdep * xstep * tr(ji,jj,jk,jpfer,Kbb)
[3443]159
160               !  Compute the coagulation of colloidal iron. This parameterization
161               !  could be thought as an equivalent of colloidal pumping.
162               !  It requires certainly some more work as it is very poorly constrained.
163               !  ----------------------------------------------------------------
[10975]164               zlam1a   = ( 0.369  * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) + 102.4  * tr(ji,jj,jk,jppoc,Kbb) ) * xdiss(ji,jj,jk)    &
165                   &      + ( 114.   * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) )
[7646]166               zaggdfea = zlam1a * xstep * zfecoll
[3446]167               !
[10975]168               zlam1b   = 3.53E3 * tr(ji,jj,jk,jpgoc,Kbb) * xdiss(ji,jj,jk)
[7646]169               zaggdfeb = zlam1b * xstep * zfecoll
[3446]170               !
[10975]171               tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - zscave - zaggdfea - zaggdfeb &
[7646]172               &                     - zcoag - precip(ji,jj,jk)
[10975]173               tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zscave * zdenom1 + zaggdfea
174               tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + zscave * zdenom2 + zaggdfeb
[10362]175               zscav3d(ji,jj,jk)   = zscave
176               zcoll3d(ji,jj,jk)   = zaggdfea + zaggdfeb
[7646]177               !
[3443]178            END DO
179         END DO
180      END DO
181      !
[3446]182      !  Define the bioavailable fraction of iron
183      !  ----------------------------------------
[10975]184      biron(:,:,:) = tr(:,:,:,jpfer,Kbb) 
[7646]185      !
186      IF( ln_ligand ) THEN
187         !
188         DO jk = 1, jpkm1
189            DO jj = 1, jpj
190               DO ji = 1, jpi
[10975]191                  zlam1a   = ( 0.369  * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) + 102.4  * tr(ji,jj,jk,jppoc,Kbb) ) * xdiss(ji,jj,jk)    &
192                      &    + ( 114.   * 0.3 * tr(ji,jj,jk,jpdoc,Kbb) )
[7646]193                  !
[10975]194                  zlam1b   = 3.53E3 *   tr(ji,jj,jk,jpgoc,Kbb) * xdiss(ji,jj,jk)
195                  zligco   = 0.5 * tr(ji,jj,jk,jplgw,Kmm)
[7646]196                  zaggliga = zlam1a * xstep * zligco
197                  zaggligb = zlam1b * xstep * zligco
[10975]198                  tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) - zaggliga - zaggligb
[10362]199                  zlcoll3d(ji,jj,jk)  = zaggliga + zaggligb
[7646]200               END DO
201            END DO
202         END DO
203         !
[10975]204         plig(:,:,:) =  MAX( 0., ( ( zFeL1(:,:,:) * 1E-9 ) / ( tr(:,:,:,jpfer,Kbb) +rtrn ) ) )
[7646]205         !
206      ENDIF
[3443]207      !  Output of some diagnostics variables
208      !     ---------------------------------
[7646]209      IF( lk_iomput ) THEN
210         IF( knt == nrdttrc ) THEN
[10401]211            zrfact2 = 1.e3 * rfact2r  ! conversion from mol/L/timestep into mol/m3/s
212            IF( iom_use("Fe3")    )  CALL iom_put("Fe3"    , zFe3   (:,:,:)       * tmask(:,:,:) )   ! Fe3+
213            IF( iom_use("FeL1")   )  CALL iom_put("FeL1"   , zFeL1  (:,:,:)       * tmask(:,:,:) )   ! FeL1
214            IF( iom_use("TL1")    )  CALL iom_put("TL1"    , zTL1   (:,:,:)       * tmask(:,:,:) )   ! TL1
215            IF( iom_use("Totlig") )  CALL iom_put("Totlig" , ztotlig(:,:,:)       * tmask(:,:,:) )   ! TL
216            IF( iom_use("Biron")  )  CALL iom_put("Biron"  , biron  (:,:,:)  * 1e9 * tmask(:,:,:) )   ! biron
217            IF( iom_use("FESCAV") )  CALL iom_put("FESCAV" , zscav3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
218            IF( iom_use("FECOLL") )  CALL iom_put("FECOLL" , zcoll3d(:,:,:)  * 1e9 * tmask(:,:,:) * zrfact2 )
219            IF( iom_use("LGWCOLL"))  CALL iom_put("LGWCOLL", zlcoll3d(:,:,:) * 1e9 * tmask(:,:,:) * zrfact2 )
[3443]220         ENDIF
221      ENDIF
222
223      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
[3449]224         WRITE(charout, FMT="('fechem')")
[3443]225         CALL prt_ctl_trc_info(charout)
[10975]226         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
[3443]227      ENDIF
228      !
[9124]229      IF( ln_timing )   CALL timing_stop('p4z_fechem')
[3443]230      !
231   END SUBROUTINE p4z_fechem
232
233
234   SUBROUTINE p4z_fechem_init
235      !!----------------------------------------------------------------------
236      !!                  ***  ROUTINE p4z_fechem_init  ***
237      !!
238      !! ** Purpose :   Initialization of iron chemistry parameters
239      !!
240      !! ** Method  :   Read the nampisfer namelist and check the parameters
241      !!      called at the first timestep
242      !!
243      !! ** input   :   Namelist nampisfer
244      !!
245      !!----------------------------------------------------------------------
[9124]246      INTEGER ::   ios   ! Local integer
247      !!
[10401]248      NAMELIST/nampisfer/ ln_ligvar, xlam1, xlamdust, ligand, kfep 
[9124]249      !!----------------------------------------------------------------------
[9169]250      !
251      IF(lwp) THEN
252         WRITE(numout,*)
253         WRITE(numout,*) 'p4z_rem_init : Initialization of iron chemistry parameters'
254         WRITE(numout,*) '~~~~~~~~~~~~'
255      ENDIF
256      !
257      REWIND( numnatp_ref )            ! Namelist nampisfer in reference namelist : Pisces iron chemistry
[4147]258      READ  ( numnatp_ref, nampisfer, IOSTAT = ios, ERR = 901)
[9169]259901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisfer in reference namelist', lwp )
260      REWIND( numnatp_cfg )            ! Namelist nampisfer in configuration namelist : Pisces iron chemistry
[4147]261      READ  ( numnatp_cfg, nampisfer, IOSTAT = ios, ERR = 902 )
[9169]262902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisfer in configuration namelist', lwp )
263      IF(lwm) WRITE( numonp, nampisfer )
[4147]264
[9169]265      IF(lwp) THEN                     ! control print
266         WRITE(numout,*) '   Namelist : nampisfer'
267         WRITE(numout,*) '      variable concentration of ligand          ln_ligvar    =', ln_ligvar
268         WRITE(numout,*) '      scavenging rate of Iron                   xlam1        =', xlam1
269         WRITE(numout,*) '      scavenging rate of Iron by dust           xlamdust     =', xlamdust
270         WRITE(numout,*) '      ligand concentration in the ocean         ligand       =', ligand
271         WRITE(numout,*) '      rate constant for nanoparticle formation  kfep         =', kfep
[3443]272      ENDIF
[10362]273      !
[3443]274   END SUBROUTINE p4z_fechem_init
[9124]275   
[3443]276   !!======================================================================
277END MODULE p4zfechem
Note: See TracBrowser for help on using the repository browser.