source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z/p4zsms.F90 @ 10963

Last change on this file since 10963 was 10963, checked in by acc, 19 months ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Convert TOP routines in top-level TOP directory and all knock on effects of these conversions. SETTE tested.

  • Property svn:keywords set to Id
File size: 25.1 KB
Line 
1MODULE p4zsms
2   !!======================================================================
3   !!                         ***  MODULE p4zsms  ***
4   !! TOP :   PISCES Source Minus Sink manager
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9   !!   p4z_sms        : Time loop of passive tracers sms
10   !!----------------------------------------------------------------------
11   USE oce_trc         ! shared variables between ocean and passive tracers
12   USE trc             ! passive tracers common variables
13   USE trcdta          !
14   USE sms_pisces      ! PISCES Source Minus Sink variables
15   USE p4zbio          ! Biological model
16   USE p4zche          ! Chemical model
17   USE p4zlys          ! Calcite saturation
18   USE p4zflx          ! Gas exchange
19   USE p4zsbc          ! External source of nutrients
20   USE p4zsed          ! Sedimentation
21   USE p4zint          ! time interpolation
22   USE p4zrem          ! remineralisation
23   USE iom             ! I/O manager
24   USE trd_oce         ! Ocean trends variables
25   USE trdtrc          ! TOP trends variables
26   USE sedmodel        ! Sediment model
27   USE prtctl_trc      ! print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sms_init   ! called in p4zsms.F90
33   PUBLIC   p4z_sms        ! called in p4zsms.F90
34
35   INTEGER ::    numco2, numnut, numnit      ! logical unit for co2 budget
36   REAL(wp) ::   alkbudget, no3budget, silbudget, ferbudget, po4budget
37   REAL(wp) ::   xfact1, xfact2, xfact3
38
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xnegtr     ! Array used to indicate negative tracer values
40
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE p4z_sms( kt, Kmm )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p4z_sms  ***
51      !!
52      !! ** Purpose :   Managment of the call to Biological sources and sinks
53      !!              routines of PISCES bio-model
54      !!
55      !! ** Method  : - at each new day ...
56      !!              - several calls of bio and sed ???
57      !!              - ...
58      !!---------------------------------------------------------------------
59      !
60      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
61      INTEGER, INTENT( in ) ::   Kmm     ! time level index
62      !!
63      INTEGER ::   ji, jj, jk, jnt, jn, jl
64      REAL(wp) ::  ztra
65      CHARACTER (len=25) :: charout
66      !!---------------------------------------------------------------------
67      !
68      IF( ln_timing )   CALL timing_start('p4z_sms')
69      !
70      IF( kt == nittrc000 ) THEN
71        !
72        ALLOCATE( xnegtr(jpi,jpj,jpk) )
73        !
74        IF( .NOT. ln_rsttr ) THEN
75            CALL p4z_che                              ! initialize the chemical constants
76            CALL ahini_for_at(hi)   !  set PH at kt=nit000
77            t_oce_co2_flx_cum = 0._wp
78        ELSE
79            CALL p4z_rst( nittrc000, 'READ' )  !* read or initialize all required fields
80        ENDIF
81        !
82      ENDIF
83      !
84      IF( ln_pisdmp .AND. MOD( kt - nn_dttrc, nn_pisdmp ) == 0 )   CALL p4z_dmp( kt )      ! Relaxation of some tracers
85      !
86      rfact = r2dttrc
87      !
88      IF( ( ln_top_euler .AND. kt == nittrc000 )  .OR. ( .NOT.ln_top_euler .AND. kt <= nittrc000 + nn_dttrc ) ) THEN
89         rfactr  = 1. / rfact
90         rfact2  = rfact / REAL( nrdttrc, wp )
91         rfact2r = 1. / rfact2
92         xstep = rfact2 / rday         ! Time step duration for biology
93         IF(lwp) WRITE(numout,*) 
94         IF(lwp) WRITE(numout,*) '    Passive Tracer  time step    rfact  = ', rfact, ' rdt = ', rdt
95         IF(lwp) write(numout,*) '    PISCES  Biology time step    rfact2 = ', rfact2
96         IF(lwp) WRITE(numout,*)
97      ENDIF
98
99      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN
100         DO jn = jp_pcs0, jp_pcs1              !   SMS on tracer without Asselin time-filter
101            trb(:,:,:,jn) = trn(:,:,:,jn)
102         END DO
103      ENDIF
104      !
105      IF( ll_sbc ) CALL p4z_sbc( kt )   ! external sources of nutrients
106      !
107#if ! defined key_sed_off
108      CALL p4z_che              ! computation of chemical constants
109      CALL p4z_int( kt )        ! computation of various rates for biogeochemistry
110      !
111      DO jnt = 1, nrdttrc          ! Potential time splitting if requested
112         !
113         CALL p4z_bio( kt, jnt )   ! Biology
114         CALL p4z_lys( kt, jnt )   ! Compute CaCO3 saturation
115         CALL p4z_sed( kt, jnt )   ! Surface and Bottom boundary conditions
116         CALL p4z_flx( kt, jnt )   ! Compute surface fluxes
117         !
118         xnegtr(:,:,:) = 1.e0
119         DO jn = jp_pcs0, jp_pcs1
120            DO jk = 1, jpk
121               DO jj = 1, jpj
122                  DO ji = 1, jpi
123                     IF( ( trb(ji,jj,jk,jn) + tra(ji,jj,jk,jn) ) < 0.e0 ) THEN
124                        ztra             = ABS( trb(ji,jj,jk,jn) ) / ( ABS( tra(ji,jj,jk,jn) ) + rtrn )
125                        xnegtr(ji,jj,jk) = MIN( xnegtr(ji,jj,jk),  ztra )
126                     ENDIF
127                 END DO
128               END DO
129            END DO
130         END DO
131         !                                ! where at least 1 tracer concentration becomes negative
132         !                                !
133         DO jn = jp_pcs0, jp_pcs1
134           trb(:,:,:,jn) = trb(:,:,:,jn) + xnegtr(:,:,:) * tra(:,:,:,jn)
135         END DO
136        !
137         DO jn = jp_pcs0, jp_pcs1
138            tra(:,:,:,jn) = 0._wp
139         END DO
140         !
141         IF( ln_top_euler ) THEN
142            DO jn = jp_pcs0, jp_pcs1
143               trn(:,:,:,jn) = trb(:,:,:,jn)
144            END DO
145         ENDIF
146      END DO
147
148      !
149      IF( l_trdtrc ) THEN
150         DO jn = jp_pcs0, jp_pcs1
151           CALL trd_trc( tra(:,:,:,jn), jn, jptra_sms, kt )   ! save trends
152         END DO
153      END IF
154#endif
155      !
156      IF( ln_sediment ) THEN 
157         !
158         CALL sed_model( kt, Kmm )     !  Main program of Sediment model
159         !
160         IF( ln_top_euler ) THEN
161            DO jn = jp_pcs0, jp_pcs1
162               trn(:,:,:,jn) = trb(:,:,:,jn)
163            END DO
164         ENDIF
165         !
166      ENDIF
167      !
168      IF( lrst_trc )  CALL p4z_rst( kt, 'WRITE' )  !* Write PISCES informations in restart file
169      !
170
171      IF( lk_iomput .OR. ln_check_mass )  CALL p4z_chk_mass( kt )    ! Mass conservation checking
172
173      IF( lwm .AND. kt == nittrc000    )  CALL FLUSH( numonp )       ! flush output namelist PISCES
174      !
175      IF( ln_timing )  CALL timing_stop('p4z_sms')
176      !
177   END SUBROUTINE p4z_sms
178
179
180   SUBROUTINE p4z_sms_init
181      !!----------------------------------------------------------------------
182      !!                     ***  p4z_sms_init  *** 
183      !!
184      !! ** Purpose :   read PISCES namelist
185      !!
186      !! ** input   :   file 'namelist.trc.s' containing the following
187      !!             namelist: natext, natbio, natsms
188      !!----------------------------------------------------------------------
189      INTEGER :: ios                 ! Local integer output status for namelist read
190      !!
191      NAMELIST/nampisbio/ nrdttrc, wsbio, xkmort, ferat3, wsbio2, wsbio2max, wsbio2scale,    &
192         &                   ldocp, ldocz, lthet, no3rat3, po4rat3
193         !
194      NAMELIST/nampisdmp/ ln_pisdmp, nn_pisdmp
195      NAMELIST/nampismass/ ln_check_mass
196      !!----------------------------------------------------------------------
197      !
198      IF(lwp) THEN
199         WRITE(numout,*)
200         WRITE(numout,*) 'p4z_sms_init : PISCES initialization'
201         WRITE(numout,*) '~~~~~~~~~~~~'
202      ENDIF
203
204      REWIND( numnatp_ref )              ! Namelist nampisbio in reference namelist : Pisces variables
205      READ  ( numnatp_ref, nampisbio, IOSTAT = ios, ERR = 901)
206901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisbio in reference namelist', lwp )
207      REWIND( numnatp_cfg )              ! Namelist nampisbio in configuration namelist : Pisces variables
208      READ  ( numnatp_cfg, nampisbio, IOSTAT = ios, ERR = 902 )
209902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisbio in configuration namelist', lwp )
210      IF(lwm) WRITE( numonp, nampisbio )
211      !
212      IF(lwp) THEN                         ! control print
213         WRITE(numout,*) '   Namelist : nampisbio'
214         WRITE(numout,*) '      frequency for the biology                 nrdttrc     =', nrdttrc
215         WRITE(numout,*) '      POC sinking speed                         wsbio       =', wsbio
216         WRITE(numout,*) '      half saturation constant for mortality    xkmort      =', xkmort 
217         IF( ln_p5z ) THEN
218            WRITE(numout,*) '      N/C in zooplankton                        no3rat3     =', no3rat3
219            WRITE(numout,*) '      P/C in zooplankton                        po4rat3     =', po4rat3
220         ENDIF
221         WRITE(numout,*) '      Fe/C in zooplankton                       ferat3      =', ferat3
222         WRITE(numout,*) '      Big particles sinking speed               wsbio2      =', wsbio2
223         WRITE(numout,*) '      Big particles maximum sinking speed       wsbio2max   =', wsbio2max
224         WRITE(numout,*) '      Big particles sinking speed length scale  wsbio2scale =', wsbio2scale
225         IF( ln_ligand ) THEN
226            IF( ln_p4z ) THEN
227               WRITE(numout,*) '      Phyto ligand production per unit doc           ldocp  =', ldocp
228               WRITE(numout,*) '      Zoo ligand production per unit doc             ldocz  =', ldocz
229               WRITE(numout,*) '      Proportional loss of ligands due to Fe uptake  lthet  =', lthet
230            ENDIF
231         ENDIF
232      ENDIF
233
234
235      REWIND( numnatp_ref )              ! Namelist nampisdmp in reference namelist : Pisces damping
236      READ  ( numnatp_ref, nampisdmp, IOSTAT = ios, ERR = 905)
237905   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisdmp in reference namelist', lwp )
238      REWIND( numnatp_cfg )              ! Namelist nampisdmp in configuration namelist : Pisces damping
239      READ  ( numnatp_cfg, nampisdmp, IOSTAT = ios, ERR = 906 )
240906   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisdmp in configuration namelist', lwp )
241      IF(lwm) WRITE( numonp, nampisdmp )
242      !
243      IF(lwp) THEN                         ! control print
244         WRITE(numout,*)
245         WRITE(numout,*) '   Namelist : nampisdmp --- relaxation to GLODAP'
246         WRITE(numout,*) '      Relaxation of tracer to glodap mean value   ln_pisdmp =', ln_pisdmp
247         WRITE(numout,*) '      Frequency of Relaxation                     nn_pisdmp =', nn_pisdmp
248      ENDIF
249
250      REWIND( numnatp_ref )              ! Namelist nampismass in reference namelist : Pisces mass conservation check
251      READ  ( numnatp_ref, nampismass, IOSTAT = ios, ERR = 907)
252907   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampismass in reference namelist', lwp )
253      REWIND( numnatp_cfg )              ! Namelist nampismass in configuration namelist : Pisces mass conservation check
254      READ  ( numnatp_cfg, nampismass, IOSTAT = ios, ERR = 908 )
255908   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampismass in configuration namelist', lwp )
256      IF(lwm) WRITE( numonp, nampismass )
257
258      IF(lwp) THEN                         ! control print
259         WRITE(numout,*)
260         WRITE(numout,*) '   Namelist : nampismass  --- mass conservation checking'
261         WRITE(numout,*) '      Flag to check mass conservation of NO3/Si/TALK   ln_check_mass = ', ln_check_mass
262      ENDIF
263      !
264   END SUBROUTINE p4z_sms_init
265
266
267   SUBROUTINE p4z_rst( kt, cdrw )
268      !!---------------------------------------------------------------------
269      !!                   ***  ROUTINE p4z_rst  ***
270      !!
271      !!  ** Purpose : Read or write variables in restart file:
272      !!
273      !!  WRITE(READ) mode:
274      !!       kt        : number of time step since the begining of the experiment at the
275      !!                   end of the current(previous) run
276      !!---------------------------------------------------------------------
277      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
278      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
279      !!---------------------------------------------------------------------
280      !
281      IF( TRIM(cdrw) == 'READ' ) THEN
282         !
283         IF(lwp) WRITE(numout,*)
284         IF(lwp) WRITE(numout,*) ' p4z_rst : Read specific variables from pisces model '
285         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
286         !
287         IF( iom_varid( numrtr, 'PH', ldstop = .FALSE. ) > 0 ) THEN
288            CALL iom_get( numrtr, jpdom_autoglo, 'PH' , hi(:,:,:)  )
289         ELSE
290            CALL p4z_che                              ! initialize the chemical constants
291            CALL ahini_for_at(hi)
292         ENDIF
293         CALL iom_get( numrtr, jpdom_autoglo, 'Silicalim', xksi(:,:) )
294         IF( iom_varid( numrtr, 'Silicamax', ldstop = .FALSE. ) > 0 ) THEN
295            CALL iom_get( numrtr, jpdom_autoglo, 'Silicamax' , xksimax(:,:)  )
296         ELSE
297            xksimax(:,:) = xksi(:,:)
298         ENDIF
299         !
300         IF( iom_varid( numrtr, 'tcflxcum', ldstop = .FALSE. ) > 0 ) THEN  ! cumulative total flux of carbon
301            CALL iom_get( numrtr, 'tcflxcum' , t_oce_co2_flx_cum  )
302         ELSE
303            t_oce_co2_flx_cum = 0._wp
304         ENDIF
305         !
306         IF( ln_p5z ) THEN
307            IF( iom_varid( numrtr, 'sized', ldstop = .FALSE. ) > 0 ) THEN
308               CALL iom_get( numrtr, jpdom_autoglo, 'sizep' , sizep(:,:,:)  )
309               CALL iom_get( numrtr, jpdom_autoglo, 'sizen' , sizen(:,:,:)  )
310               CALL iom_get( numrtr, jpdom_autoglo, 'sized' , sized(:,:,:)  )
311            ELSE
312               sizep(:,:,:) = 1.
313               sizen(:,:,:) = 1.
314               sized(:,:,:) = 1.
315            ENDIF
316        ENDIF
317        !
318      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
319         IF( kt == nitrst ) THEN
320            IF(lwp) WRITE(numout,*)
321            IF(lwp) WRITE(numout,*) 'p4z_rst : write pisces restart file  kt =', kt
322            IF(lwp) WRITE(numout,*) '~~~~~~~'
323         ENDIF
324         CALL iom_rstput( kt, nitrst, numrtw, 'PH', hi(:,:,:) )
325         CALL iom_rstput( kt, nitrst, numrtw, 'Silicalim', xksi(:,:) )
326         CALL iom_rstput( kt, nitrst, numrtw, 'Silicamax', xksimax(:,:) )
327         CALL iom_rstput( kt, nitrst, numrtw, 'tcflxcum', t_oce_co2_flx_cum )
328         IF( ln_p5z ) THEN
329            CALL iom_rstput( kt, nitrst, numrtw, 'sizep', sizep(:,:,:) )
330            CALL iom_rstput( kt, nitrst, numrtw, 'sizen', sizen(:,:,:) )
331            CALL iom_rstput( kt, nitrst, numrtw, 'sized', sized(:,:,:) )
332         ENDIF
333      ENDIF
334      !
335   END SUBROUTINE p4z_rst
336
337
338   SUBROUTINE p4z_dmp( kt )
339      !!----------------------------------------------------------------------
340      !!                    ***  p4z_dmp  ***
341      !!
342      !! ** purpose  : Relaxation of some tracers
343      !!----------------------------------------------------------------------
344      !
345      INTEGER, INTENT( in )  ::     kt ! time step
346      !
347      REAL(wp) ::  alkmean = 2426.     ! mean value of alkalinity ( Glodap ; for Goyet 2391. )
348      REAL(wp) ::  po4mean = 2.165     ! mean value of phosphates
349      REAL(wp) ::  no3mean = 30.90     ! mean value of nitrate
350      REAL(wp) ::  silmean = 91.51     ! mean value of silicate
351      !
352      REAL(wp) :: zarea, zalksumn, zpo4sumn, zno3sumn, zsilsumn
353      REAL(wp) :: zalksumb, zpo4sumb, zno3sumb, zsilsumb
354      !!---------------------------------------------------------------------
355
356      IF(lwp)  WRITE(numout,*)
357      IF(lwp)  WRITE(numout,*) ' p4z_dmp : Restoring of nutrients at time-step kt = ', kt
358      IF(lwp)  WRITE(numout,*)
359
360      IF( cn_cfg == "ORCA" .OR. cn_cfg == "orca") THEN
361         IF( .NOT. lk_c1d ) THEN      ! ORCA configuration (not 1D) !
362            !                                                ! --------------------------- !
363            ! set total alkalinity, phosphate, nitrate & silicate
364            zarea          = 1._wp / glob_sum( 'p4zsms', cvol(:,:,:) ) * 1e6             
365
366            zalksumn = glob_sum( 'p4zsms', trn(:,:,:,jptal) * cvol(:,:,:)  ) * zarea
367            zpo4sumn = glob_sum( 'p4zsms', trn(:,:,:,jppo4) * cvol(:,:,:)  ) * zarea * po4r
368            zno3sumn = glob_sum( 'p4zsms', trn(:,:,:,jpno3) * cvol(:,:,:)  ) * zarea * rno3
369            zsilsumn = glob_sum( 'p4zsms', trn(:,:,:,jpsil) * cvol(:,:,:)  ) * zarea
370 
371            IF(lwp) WRITE(numout,*) '       TALKN mean : ', zalksumn
372            trn(:,:,:,jptal) = trn(:,:,:,jptal) * alkmean / zalksumn
373
374            IF(lwp) WRITE(numout,*) '       PO4N  mean : ', zpo4sumn
375            trn(:,:,:,jppo4) = trn(:,:,:,jppo4) * po4mean / zpo4sumn
376
377            IF(lwp) WRITE(numout,*) '       NO3N  mean : ', zno3sumn
378            trn(:,:,:,jpno3) = trn(:,:,:,jpno3) * no3mean / zno3sumn
379
380            IF(lwp) WRITE(numout,*) '       SiO3N mean : ', zsilsumn
381            trn(:,:,:,jpsil) = MIN( 400.e-6,trn(:,:,:,jpsil) * silmean / zsilsumn )
382            !
383            !
384            IF( .NOT. ln_top_euler ) THEN
385               zalksumb = glob_sum( 'p4zsms', trb(:,:,:,jptal) * cvol(:,:,:)  ) * zarea
386               zpo4sumb = glob_sum( 'p4zsms', trb(:,:,:,jppo4) * cvol(:,:,:)  ) * zarea * po4r
387               zno3sumb = glob_sum( 'p4zsms', trb(:,:,:,jpno3) * cvol(:,:,:)  ) * zarea * rno3
388               zsilsumb = glob_sum( 'p4zsms', trb(:,:,:,jpsil) * cvol(:,:,:)  ) * zarea
389 
390               IF(lwp) WRITE(numout,*) ' '
391               IF(lwp) WRITE(numout,*) '       TALKB mean : ', zalksumb
392               trb(:,:,:,jptal) = trb(:,:,:,jptal) * alkmean / zalksumb
393
394               IF(lwp) WRITE(numout,*) '       PO4B  mean : ', zpo4sumb
395               trb(:,:,:,jppo4) = trb(:,:,:,jppo4) * po4mean / zpo4sumb
396
397               IF(lwp) WRITE(numout,*) '       NO3B  mean : ', zno3sumb
398               trb(:,:,:,jpno3) = trb(:,:,:,jpno3) * no3mean / zno3sumb
399
400               IF(lwp) WRITE(numout,*) '       SiO3B mean : ', zsilsumb
401               trb(:,:,:,jpsil) = MIN( 400.e-6,trb(:,:,:,jpsil) * silmean / zsilsumb )
402           ENDIF
403        ENDIF
404        !
405      ENDIF
406        !
407   END SUBROUTINE p4z_dmp
408
409
410   SUBROUTINE p4z_chk_mass( kt )
411      !!----------------------------------------------------------------------
412      !!                  ***  ROUTINE p4z_chk_mass  ***
413      !!
414      !! ** Purpose :  Mass conservation check
415      !!
416      !!---------------------------------------------------------------------
417      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
418      REAL(wp)             ::  zrdenittot, zsdenittot, znitrpottot
419      CHARACTER(LEN=100)   ::   cltxt
420      INTEGER :: jk
421      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwork
422      !!----------------------------------------------------------------------
423      !
424      IF( kt == nittrc000 ) THEN
425         xfact1 = rfact2r * 12. / 1.e15 * ryyss    ! conversion molC/kt --> PgC/yr
426         xfact2 = 1.e+3 * rno3 * 14. / 1.e12 * ryyss   ! conversion molC/l/s ----> TgN/m3/yr
427         xfact3 = 1.e+3 * rfact2r * rno3   ! conversion molC/l/kt ----> molN/m3/s
428         IF( ln_check_mass .AND. lwp) THEN      !   Open budget file of NO3, ALK, Si, Fer
429            CALL ctl_opn( numco2, 'carbon.budget'  , 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
430            CALL ctl_opn( numnut, 'nutrient.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
431            CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
432            cltxt='time-step   Alkalinity        Nitrate        Phosphorus         Silicate           Iron'
433            IF( lwp ) WRITE(numnut,*)  TRIM(cltxt)
434            IF( lwp ) WRITE(numnut,*) 
435         ENDIF
436      ENDIF
437
438      IF( iom_use( "pno3tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
439         !   Compute the budget of NO3, ALK, Si, Fer
440         IF( ln_p4z ) THEN
441            zwork(:,:,:) =    trn(:,:,:,jpno3) + trn(:,:,:,jpnh4)                      &
442               &          +   trn(:,:,:,jpphy) + trn(:,:,:,jpdia)                      &
443               &          +   trn(:,:,:,jppoc) + trn(:,:,:,jpgoc)  + trn(:,:,:,jpdoc)  &       
444               &          +   trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) 
445        ELSE
446            zwork(:,:,:) =    trn(:,:,:,jpno3) + trn(:,:,:,jpnh4) + trn(:,:,:,jpnph)   &
447               &          +   trn(:,:,:,jpndi) + trn(:,:,:,jpnpi)                      & 
448               &          +   trn(:,:,:,jppon) + trn(:,:,:,jpgon) + trn(:,:,:,jpdon)   &
449               &          + ( trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) ) * no3rat3 
450        ENDIF
451        !
452        no3budget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
453        no3budget = no3budget / areatot
454        CALL iom_put( "pno3tot", no3budget )
455      ENDIF
456      !
457      IF( iom_use( "ppo4tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
458         IF( ln_p4z ) THEN
459            zwork(:,:,:) =    trn(:,:,:,jppo4)                                         &
460               &          +   trn(:,:,:,jpphy) + trn(:,:,:,jpdia)                      &
461               &          +   trn(:,:,:,jppoc) + trn(:,:,:,jpgoc)  + trn(:,:,:,jpdoc)  &       
462               &          +   trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) 
463        ELSE
464            zwork(:,:,:) =    trn(:,:,:,jppo4) + trn(:,:,:,jppph)                      &
465               &          +   trn(:,:,:,jppdi) + trn(:,:,:,jpppi)                      & 
466               &          +   trn(:,:,:,jppop) + trn(:,:,:,jpgop) + trn(:,:,:,jpdop)   &
467               &          + ( trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) ) * po4rat3 
468        ENDIF
469        !
470        po4budget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
471        po4budget = po4budget / areatot
472        CALL iom_put( "ppo4tot", po4budget )
473      ENDIF
474      !
475      IF( iom_use( "psiltot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
476         zwork(:,:,:) =  trn(:,:,:,jpsil) + trn(:,:,:,jpgsi) + trn(:,:,:,jpdsi) 
477         !
478         silbudget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
479         silbudget = silbudget / areatot
480         CALL iom_put( "psiltot", silbudget )
481      ENDIF
482      !
483      IF( iom_use( "palktot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
484         zwork(:,:,:) =  trn(:,:,:,jpno3) * rno3 + trn(:,:,:,jptal) + trn(:,:,:,jpcal) * 2.             
485         !
486         alkbudget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  )         !
487         alkbudget = alkbudget / areatot
488         CALL iom_put( "palktot", alkbudget )
489      ENDIF
490      !
491      IF( iom_use( "pfertot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
492         zwork(:,:,:) =   trn(:,:,:,jpfer) + trn(:,:,:,jpnfe) + trn(:,:,:,jpdfe)   &
493            &         +   trn(:,:,:,jpbfe) + trn(:,:,:,jpsfe)                      &
494            &         + ( trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) )  * ferat3   
495         !
496         ferbudget = glob_sum( 'p4zsms', zwork(:,:,:) * cvol(:,:,:)  ) 
497         ferbudget = ferbudget / areatot
498         CALL iom_put( "pfertot", ferbudget )
499      ENDIF
500      !
501      ! Global budget of N SMS : denitrification in the water column and in the sediment
502      !                          nitrogen fixation by the diazotrophs
503      ! --------------------------------------------------------------------------------
504      IF( iom_use( "tnfix" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
505         znitrpottot  = glob_sum ( 'p4zsms', nitrpot(:,:,:) * nitrfix * cvol(:,:,:) )
506         CALL iom_put( "tnfix"  , znitrpottot * xfact3 )  ! Global  nitrogen fixation molC/l  to molN/m3
507      ENDIF
508      !
509      IF( iom_use( "tdenit" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
510         zrdenittot = glob_sum ( 'p4zsms', denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
511         zsdenittot = glob_sum ( 'p4zsms', sdenit(:,:) * e1e2t(:,:) * tmask(:,:,1) )
512         CALL iom_put( "tdenit" , ( zrdenittot + zsdenittot ) * xfact3 )  ! Total denitrification molC/l to molN/m3
513      ENDIF
514      !
515      IF( ln_check_mass .AND. kt == nitend ) THEN   ! Compute the budget of NO3, ALK, Si, Fer
516         t_atm_co2_flx  = t_atm_co2_flx / glob_sum( 'p4zsms', e1e2t(:,:) )
517         t_oce_co2_flx  = t_oce_co2_flx         * xfact1 * (-1 )
518         tpp            = tpp           * 1000. * xfact1
519         t_oce_co2_exp  = t_oce_co2_exp * 1000. * xfact1
520         IF( lwp ) WRITE(numco2,9000) ndastp, t_atm_co2_flx, t_oce_co2_flx, tpp, t_oce_co2_exp
521         IF( lwp ) WRITE(numnut,9100) ndastp, alkbudget        * 1.e+06, &
522             &                                no3budget * rno3 * 1.e+06, &
523             &                                po4budget * po4r * 1.e+06, &
524             &                                silbudget        * 1.e+06, &
525             &                                ferbudget        * 1.e+09
526         !
527         IF( lwp ) WRITE(numnit,9200) ndastp, znitrpottot * xfact2  , &
528            &                             zrdenittot  * xfact2  , &
529            &                             zsdenittot  * xfact2
530      ENDIF
531      !
532 9000  FORMAT(i8,f10.5,e18.10,f10.5,f10.5)
533 9100  FORMAT(i8,5e18.10)
534 9200  FORMAT(i8,3f10.5)
535       !
536   END SUBROUTINE p4z_chk_mass
537
538   !!======================================================================
539END MODULE p4zsms 
Note: See TracBrowser for help on using the repository browser.