source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY/bdylib.F90 @ 11048

Last change on this file since 11048 was 11048, checked in by girrmann, 19 months ago

dev_r10984_HPC-13 : Step 1, boundary is now detected all over the local domain, this does not change the result. Improve bdy treatment for bdy_rnf in bdytra.F90, this changes the result when keyword runoff is specified in namelist

  • Property svn:keywords set to Id
File size: 27.5 KB
Line 
1MODULE bdylib
2   !!======================================================================
3   !!                       ***  MODULE  bdylib  ***
4   !! Unstructured Open Boundary Cond. :  Library module of generic boundary algorithms.
5   !!======================================================================
6   !! History :  3.6  !  2013     (D. Storkey) original code
7   !!            4.0  !  2014     (T. Lovato) Generalize OBC structure
8   !!----------------------------------------------------------------------
9   !!----------------------------------------------------------------------
10   !!   bdy_orlanski_2d
11   !!   bdy_orlanski_3d
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE bdy_oce        ! ocean open boundary conditions
16   USE phycst         ! physical constants
17   !
18   USE in_out_manager !
19   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
20   USE lib_mpp, ONLY: ctl_stop
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   bdy_frs, bdy_spe, bdy_nmn, bdy_orl
26   PUBLIC   bdy_orlanski_2d
27   PUBLIC   bdy_orlanski_3d
28
29   !!----------------------------------------------------------------------
30   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
31   !! $Id$
32   !! Software governed by the CeCILL license (see ./LICENSE)
33   !!----------------------------------------------------------------------
34CONTAINS
35
36   SUBROUTINE bdy_frs( idx, pta, dta )
37      !!----------------------------------------------------------------------
38      !!                 ***  SUBROUTINE bdy_frs  ***
39      !!
40      !! ** Purpose : Apply the Flow Relaxation Scheme for tracers at open boundaries.
41      !!
42      !! Reference : Engedahl H., 1995, Tellus, 365-382.
43      !!----------------------------------------------------------------------
44      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
45      REAL(wp), DIMENSION(:,:),            INTENT(in) ::   dta  ! OBC external data
46      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
47      !!
48      REAL(wp) ::   zwgt           ! boundary weight
49      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
50      INTEGER  ::   ii, ij         ! 2D addresses
51      !!----------------------------------------------------------------------
52      !
53      igrd = 1                       ! Everything is at T-points here
54      DO ib = 1, idx%nblen(igrd)
55         DO ik = 1, jpkm1
56            ii = idx%nbi(ib,igrd) 
57            ij = idx%nbj(ib,igrd)
58            IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )  CYCLE   ! to remove
59            zwgt = idx%nbw(ib,igrd)
60            pta(ii,ij,ik) = ( pta(ii,ij,ik) + zwgt * (dta(ib,ik) - pta(ii,ij,ik) ) ) * tmask(ii,ij,ik)
61         END DO
62      END DO
63      !
64   END SUBROUTINE bdy_frs
65
66
67   SUBROUTINE bdy_spe( idx, pta, dta )
68      !!----------------------------------------------------------------------
69      !!                 ***  SUBROUTINE bdy_spe  ***
70      !!
71      !! ** Purpose : Apply a specified value for tracers at open boundaries.
72      !!
73      !!----------------------------------------------------------------------
74      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
75      REAL(wp), DIMENSION(:,:),            INTENT(in) ::   dta  ! OBC external data
76      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
77      !!
78      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
79      INTEGER  ::   ii, ij         ! 2D addresses
80      !!----------------------------------------------------------------------
81      !
82      igrd = 1                       ! Everything is at T-points here
83      DO ib = 1, idx%nblenrim(igrd)
84         ii = idx%nbi(ib,igrd)
85         ij = idx%nbj(ib,igrd)
86         IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )  CYCLE   ! to remove
87         DO ik = 1, jpkm1
88            pta(ii,ij,ik) = dta(ib,ik) * tmask(ii,ij,ik)
89         END DO
90      END DO
91      !
92   END SUBROUTINE bdy_spe
93
94
95   SUBROUTINE bdy_orl( idx, ptb, pta, dta, ll_npo )
96      !!----------------------------------------------------------------------
97      !!                 ***  SUBROUTINE bdy_orl  ***
98      !!
99      !! ** Purpose : Apply Orlanski radiation for tracers at open boundaries.
100      !!              This is a wrapper routine for bdy_orlanski_3d below
101      !!
102      !!----------------------------------------------------------------------
103      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
104      REAL(wp), DIMENSION(:,:),            INTENT(in) ::   dta  ! OBC external data
105      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   ptb  ! before tracer field
106      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
107      LOGICAL,                             INTENT(in) ::   ll_npo  ! switch for NPO version
108      !!
109      INTEGER  ::   igrd                                    ! grid index
110      !!----------------------------------------------------------------------
111      !
112      igrd = 1                       ! Everything is at T-points here
113      !
114      CALL bdy_orlanski_3d( idx, igrd, ptb(:,:,:), pta(:,:,:), dta, ll_npo )
115      !
116   END SUBROUTINE bdy_orl
117
118
119   SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext, ll_npo )
120      !!----------------------------------------------------------------------
121      !!                 ***  SUBROUTINE bdy_orlanski_2d  ***
122      !!             
123      !!              - Apply Orlanski radiation condition adaptively to 2D fields:
124      !!                  - radiation plus weak nudging at outflow points
125      !!                  - no radiation and strong nudging at inflow points
126      !!
127      !!
128      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
129      !!----------------------------------------------------------------------
130      TYPE(OBC_INDEX),          INTENT(in   ) ::   idx      ! BDY indices
131      INTEGER ,                 INTENT(in   ) ::   igrd     ! grid index
132      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   phib     ! model before 2D field
133      REAL(wp), DIMENSION(:,:), INTENT(inout) ::   phia     ! model after 2D field (to be updated)
134      REAL(wp), DIMENSION(:)  , INTENT(in   ) ::   phi_ext  ! external forcing data
135      LOGICAL ,                 INTENT(in   ) ::   ll_npo   ! switch for NPO version
136      !
137      INTEGER  ::   jb                                     ! dummy loop indices
138      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
139      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
140      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
141      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
142      INTEGER  ::   flagu, flagv                           ! short cuts
143      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
144      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
145      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
146      REAL(wp) ::   zout, zwgt, zdy_centred
147      REAL(wp) ::   zdy_1, zdy_2, zsign_ups
148      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
149      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask      ! land/sea mask for field
150      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_xdif ! land/sea mask for x-derivatives
151      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_ydif ! land/sea mask for y-derivatives
152      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
153      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
154      !!----------------------------------------------------------------------
155      !
156      ! ----------------------------------!
157      ! Orlanski boundary conditions     :!
158      ! ----------------------------------!
159     
160      SELECT CASE(igrd)
161         CASE(1)
162            pmask      => tmask(:,:,1)
163            pmask_xdif => umask(:,:,1)
164            pmask_ydif => vmask(:,:,1)
165            pe_xdif    => e1u(:,:)
166            pe_ydif    => e2v(:,:)
167            ii_offset = 0
168            ij_offset = 0
169         CASE(2)
170            pmask      => umask(:,:,1)
171            pmask_xdif => tmask(:,:,1)
172            pmask_ydif => fmask(:,:,1)
173            pe_xdif    => e1t(:,:)
174            pe_ydif    => e2f(:,:)
175            ii_offset = 1
176            ij_offset = 0
177         CASE(3)
178            pmask      => vmask(:,:,1)
179            pmask_xdif => fmask(:,:,1)
180            pmask_ydif => tmask(:,:,1)
181            pe_xdif    => e1f(:,:)
182            pe_ydif    => e2t(:,:)
183            ii_offset = 0
184            ij_offset = 1
185         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
186      END SELECT
187      !
188      DO jb = 1, idx%nblenrim(igrd)
189         ii  = idx%nbi(jb,igrd)
190         ij  = idx%nbj(jb,igrd) 
191         flagu = int( idx%flagu(jb,igrd) )
192         flagv = int( idx%flagv(jb,igrd) )
193         !
194         ! Calculate positions of b-1 and b-2 points for this rim point
195         ! also (b-1,j-1) and (b-1,j+1) points
196         iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
197         ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
198          !
199         iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
200         ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
201         !
202         iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
203         ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
204         !
205         ! Calculate scale factors for calculation of spatial derivatives.       
206         zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1          )         &
207        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
208         zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
209        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
210         zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
211        &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
212         zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
213        &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
214         ! make sure scale factors are nonzero
215         if( zey1 .lt. rsmall ) zey1 = zey2
216         if( zey2 .lt. rsmall ) zey2 = zey1
217         zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall)
218         zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
219         !
220         ! Calculate masks for calculation of spatial derivatives.       
221         zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          )         &
222        &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset) ) 
223         zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
224        &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
225         zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1)                  &
226        &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset) ) 
227
228         ! Calculation of terms required for both versions of the scheme.
229         ! Mask derivatives to ensure correct land boundary conditions for each variable.
230         ! Centred derivative is calculated as average of "left" and "right" derivatives for
231         ! this reason.
232         ! Note no rdt factor in expression for zdt because it cancels in the expressions for
233         ! zrx and zry.
234         zdt = phia(iibm1,ijbm1) - phib(iibm1,ijbm1)
235         zdx = ( ( phia(iibm1,ijbm1) - phia(iibm2,ijbm2) ) / zex2 ) * zmask_x 
236         zdy_1 = ( ( phib(iibm1   ,ijbm1   ) - phib(iibm1jm1,ijbm1jm1) ) / zey1 ) * zmask_y1   
237         zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1) - phib(iibm1   ,ijbm1)    ) / zey2 ) * zmask_y2 
238         zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
239!!$         zdy_centred = phib(iibm1jp1,ijbm1jp1) - phib(iibm1jm1,ijbm1jm1)
240         ! upstream differencing for tangential derivatives
241         zsign_ups = sign( 1., zdt * zdy_centred )
242         zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
243         zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
244         znor2 = zdx * zdx + zdy * zdy
245         znor2 = max(znor2,zepsilon)
246         !
247         zrx = zdt * zdx / ( zex1 * znor2 ) 
248!!$         zrx = min(zrx,2.0_wp)
249         zout = sign( 1., zrx )
250         zout = 0.5*( zout + abs(zout) )
251         zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
252         ! only apply radiation on outflow points
253         if( ll_npo ) then     !! NPO version !!
254            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
255           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
256           &                            + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
257         else                  !! full oblique radiation !!
258            zsign_ups = sign( 1., zdt * zdy )
259            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
260            zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
261            zry = zdt * zdy / ( zey * znor2 ) 
262            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
263           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
264           &                    - zsign_ups      * zry * ( phib(ii   ,ij   ) - phib(iijm1,ijjm1 ) ) &
265           &                    - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1) - phib(ii   ,ij    ) ) &
266           &                    + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
267         end if
268         phia(ii,ij) = phia(ii,ij) * pmask(ii,ij)
269      END DO
270      !
271   END SUBROUTINE bdy_orlanski_2d
272
273
274   SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext, ll_npo )
275      !!----------------------------------------------------------------------
276      !!                 ***  SUBROUTINE bdy_orlanski_3d  ***
277      !!             
278      !!              - Apply Orlanski radiation condition adaptively to 3D fields:
279      !!                  - radiation plus weak nudging at outflow points
280      !!                  - no radiation and strong nudging at inflow points
281      !!
282      !!
283      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
284      !!----------------------------------------------------------------------
285      TYPE(OBC_INDEX),            INTENT(in   ) ::   idx      ! BDY indices
286      INTEGER ,                   INTENT(in   ) ::   igrd     ! grid index
287      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   phib     ! model before 3D field
288      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phia     ! model after 3D field (to be updated)
289      REAL(wp), DIMENSION(:,:)  , INTENT(in   ) ::   phi_ext  ! external forcing data
290      LOGICAL ,                   INTENT(in   ) ::   ll_npo   ! switch for NPO version
291      !
292      INTEGER  ::   jb, jk                                 ! dummy loop indices
293      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
294      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
295      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
296      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
297      INTEGER  ::   flagu, flagv                           ! short cuts
298      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
299      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
300      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
301      REAL(wp) ::   zout, zwgt, zdy_centred
302      REAL(wp) ::   zdy_1, zdy_2,  zsign_ups
303      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
304      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask      ! land/sea mask for field
305      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_xdif ! land/sea mask for x-derivatives
306      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_ydif ! land/sea mask for y-derivatives
307      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
308      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
309      !!----------------------------------------------------------------------
310      !
311      ! ----------------------------------!
312      ! Orlanski boundary conditions     :!
313      ! ----------------------------------!
314      !
315      SELECT CASE(igrd)
316         CASE(1)
317            pmask      => tmask(:,:,:)
318            pmask_xdif => umask(:,:,:)
319            pmask_ydif => vmask(:,:,:)
320            pe_xdif    => e1u(:,:)
321            pe_ydif    => e2v(:,:)
322            ii_offset = 0
323            ij_offset = 0
324         CASE(2)
325            pmask      => umask(:,:,:)
326            pmask_xdif => tmask(:,:,:)
327            pmask_ydif => fmask(:,:,:)
328            pe_xdif    => e1t(:,:)
329            pe_ydif    => e2f(:,:)
330            ii_offset = 1
331            ij_offset = 0
332         CASE(3)
333            pmask      => vmask(:,:,:)
334            pmask_xdif => fmask(:,:,:)
335            pmask_ydif => tmask(:,:,:)
336            pe_xdif    => e1f(:,:)
337            pe_ydif    => e2t(:,:)
338            ii_offset = 0
339            ij_offset = 1
340         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
341      END SELECT
342
343      DO jk = 1, jpk
344         !           
345         DO jb = 1, idx%nblenrim(igrd)
346            ii  = idx%nbi(jb,igrd)
347            ij  = idx%nbj(jb,igrd) 
348            flagu = int( idx%flagu(jb,igrd) )
349            flagv = int( idx%flagv(jb,igrd) )
350            !
351            ! calculate positions of b-1 and b-2 points for this rim point
352            ! also (b-1,j-1) and (b-1,j+1) points
353            iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
354            ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
355            !
356            iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
357            ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
358            !
359            iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
360            ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
361            !
362            ! Calculate scale factors for calculation of spatial derivatives.       
363            zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1          )         &
364           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
365            zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
366           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
367            zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
368           &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
369            zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
370           &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
371            ! make sure scale factors are nonzero
372            if( zey1 .lt. rsmall ) zey1 = zey2
373            if( zey2 .lt. rsmall ) zey2 = zey1
374            zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall); 
375            zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
376            !
377            ! Calculate masks for calculation of spatial derivatives.       
378            zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          ,jk)          &
379           &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset,jk) ) 
380            zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          ,jk)   & 
381           &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset,jk) ) 
382            zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1          ,jk)         &
383           &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset,jk) ) 
384            !
385            ! Calculate normal (zrx) and tangential (zry) components of radiation velocities.
386            ! Mask derivatives to ensure correct land boundary conditions for each variable.
387            ! Centred derivative is calculated as average of "left" and "right" derivatives for
388            ! this reason.
389            zdt = phia(iibm1,ijbm1,jk) - phib(iibm1,ijbm1,jk)
390            zdx = ( ( phia(iibm1,ijbm1,jk) - phia(iibm2,ijbm2,jk) ) / zex2 ) * zmask_x                 
391            zdy_1 = ( ( phib(iibm1   ,ijbm1   ,jk) - phib(iibm1jm1,ijbm1jm1,jk) ) / zey1 ) * zmask_y1 
392            zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1   ,ijbm1   ,jk) ) / zey2 ) * zmask_y2     
393            zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
394!!$            zdy_centred = phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1jm1,ijbm1jm1,jk)
395            ! upstream differencing for tangential derivatives
396            zsign_ups = sign( 1., zdt * zdy_centred )
397            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
398            zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
399            znor2 = zdx * zdx + zdy * zdy
400            znor2 = max(znor2,zepsilon)
401            !
402            ! update boundary value:
403            zrx = zdt * zdx / ( zex1 * znor2 )
404!!$            zrx = min(zrx,2.0_wp)
405            zout = sign( 1., zrx )
406            zout = 0.5*( zout + abs(zout) )
407            zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
408            ! only apply radiation on outflow points
409            if( ll_npo ) then     !! NPO version !!
410               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) &
411              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                     &
412              &                            + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
413            else                  !! full oblique radiation !!
414               zsign_ups = sign( 1., zdt * zdy )
415               zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
416               zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
417               zry = zdt * zdy / ( zey * znor2 ) 
418               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) )    &
419              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                        &
420              &                       - zsign_ups      * zry * ( phib(ii   ,ij   ,jk) - phib(iijm1,ijjm1,jk) ) &
421              &                       - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1,jk) - phib(ii   ,ij   ,jk) ) &
422              &                       + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
423            end if
424            phia(ii,ij,jk) = phia(ii,ij,jk) * pmask(ii,ij,jk)
425         END DO
426         !
427      END DO
428      !
429   END SUBROUTINE bdy_orlanski_3d
430
431   SUBROUTINE bdy_nmn( idx, igrd, phia )
432      !!----------------------------------------------------------------------
433      !!                 ***  SUBROUTINE bdy_nmn  ***
434      !!                   
435      !! ** Purpose : Duplicate the value at open boundaries, zero gradient.
436      !!
437      !!
438      !! ** Method  : - take the average of free ocean neighbours
439      !!
440      !!      ___   !   |_____|   !   ___|    !   __|x o   !   |_   _|     ! |     
441      !!   __|x     !      x      !     x o   !      o     !     |_|       ! |x o   
442      !!      o     !      o      !     o     !            !    o x o      ! |x_x_
443      !!                                                   !      o     
444      !!----------------------------------------------------------------------
445      INTEGER,                    INTENT(in)     ::   igrd     ! grid index
446      REAL(wp), DIMENSION(:,:,:), INTENT(inout)  ::   phia     ! model after 3D field (to be updated), must be masked
447      TYPE(OBC_INDEX), INTENT(in) ::   idx  ! OBC indices
448      !!
449      REAL(wp) ::   zweight
450      REAL(wp), POINTER, DIMENSION(:,:,:)      :: pmask         ! land/sea mask for field
451      INTEGER  ::   ib, ik   ! dummy loop indices
452      INTEGER  ::   ii, ij   ! 2D addresses
453      INTEGER  ::   ipkm1    ! size of phia third dimension minus 1
454      INTEGER  ::   flagu, flagv                        ! short cuts
455      INTEGER  ::   ii1, ii2, ii3, ij1, ij2, ij3
456      !!----------------------------------------------------------------------
457      !
458      ipkm1 = MAX( SIZE(phia,3) - 1, 1 ) 
459      !
460      SELECT CASE(igrd)
461         CASE(1)   ;   pmask => tmask(:,:,:)
462         CASE(2)   ;   pmask => umask(:,:,:)
463         CASE(3)   ;   pmask => vmask(:,:,:)
464         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_nmn' )
465      END SELECT
466      !
467      DO ib = 1, idx%nblenrim(igrd)
468         ii = idx%nbi(ib,igrd)
469         ij = idx%nbj(ib,igrd)
470         IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )  CYCLE   ! to remove
471         SELECT CASE( idx%ntreat(ib,igrd) )   ! select free ocean neighbours
472            !     o
473            !  ___x___         ! either flagu or flagv = 0
474            CASE( 0 )   ;   flagu = NINT( idx%flagu(ib,igrd) )   ;   ii1 = ii+flagu
475                            flagv = NINT( idx%flagv(ib,igrd) )   ;   ij1 = ij+flagv
476            !               !              !     _____     !     _____     
477            !  1 |   o      !  2  o   |    !  3 | x        !  4     x |   
478            !    |_x_ _     !    _ _x_|    !    |   o      !      o   |
479            CASE( 1 )   ;   ii1 = ii+1   ;   ij1 = ij+1
480            CASE( 2 )   ;   ii1 = ii-1   ;   ij1 = ij+1
481            CASE( 3 )   ;   ii1 = ii+1   ;   ij1 = ij-1
482            CASE( 4 )   ;   ii1 = ii-1   ;   ij1 = ij-1
483            !        o      !        o      !    _____|       !       |_____ 
484            !  5 ____x o    !  6   o x___   ! 7      x o      !  8   o x     
485            !         |     !       |       !        o        !        o     
486            CASE( 5 )   ;   ii1 = ii   ;   ij1 = ij+1   ;   ii2 = ii+1   ;   ij2 = ij   
487            CASE( 6 )   ;   ii1 = ii   ;   ij1 = ij+1   ;   ii2 = ii-1   ;   ij2 = ij
488            CASE( 7 )   ;   ii1 = ii   ;   ij1 = ij-1   ;   ii2 = ii+1   ;   ij2 = ij 
489            CASE( 8 )   ;   ii1 = ii   ;   ij1 = ij-1   ;   ii2 = ii-1   ;   ij2 = ij 
490            !    |_  o      !        o  _|  !     ¨¨|_|¨¨   !       o         
491            !  9  _| x o    !  10  o x |_   !  11  o x o    ! 12  o x o       
492            !    |   o      !        o   |  !        o      !    __|¨|__
493            CASE( 9  )   ;   ii1 = ii     ;   ij1 = ij+1   ;   ii2 = ii+1   ;   ij2 = ij     ;   ii3 = ii     ;   ij3 = ij-1   
494            CASE( 10 )   ;   ii1 = ii     ;   ij1 = ij+1   ;   ii2 = ii-1   ;   ij2 = ij     ;   ii3 = ii     ;   ij3 = ij-1 
495            CASE( 11 )   ;   ii1 = ii-1   ;   ij1 = ij     ;   ii2 = ii     ;   ij2 = ij-1   ;   ii3 = ii+1   ;   ij3 = ij   
496            CASE( 12 )   ;   ii1 = ii-1   ;   ij1 = ij     ;   ii2 = ii     ;   ij2 = ij+1   ;   ii3 = ii+1   ;   ij3 = ij
497         END SELECT
498         !
499         SELECT CASE( idx%ntreat(ib,igrd) )
500            CASE( 0:4 )
501               DO ik = 1, ipkm1
502                  IF( pmask(ii1,ij1,ik) /= 0. )   phia(ii,ij,ik) = phia(ii1,ij1,ik) 
503               END DO
504            CASE( 5:8 )
505               DO ik = 1, ipkm1
506                  zweight = pmask(ii1,ij1,ik) + pmask(ii2,ij2,ik)
507                  IF( zweight /= 0. )   phia(ii,ij,ik) = ( phia(ii1,ij1,ik) + phia (ii2,ij2,ik) ) / zweight
508               END DO
509            CASE( 9:12 )
510               DO ik = 1, ipkm1
511                  zweight = pmask(ii1,ij1,ik) + pmask(ii2,ij2,ik) + pmask(ii3,ij3,ik)
512                  IF( zweight /= 0. )   phia(ii,ij,ik) = ( phia(ii1,ij1,ik) + phia (ii2,ij2,ik) + phia (ii3,ij3,ik) ) / zweight
513               END DO
514         END SELECT
515         !
516      END DO
517      !
518   END SUBROUTINE bdy_nmn
519
520   !!======================================================================
521END MODULE bdylib
Note: See TracBrowser for help on using the repository browser.