source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/LBC/mpp_nfd_generic.h90 @ 11317

Last change on this file since 11317 was 11317, checked in by smasson, 14 months ago

dev_r10984_HPC-13 : improve error handling, see #2307 and #2285

  • Property svn:keywords set to Id
  • Property svn:mime-type set to text/x-fortran
File size: 13.2 KB
Line 
1#if defined MULTI
2#   define NAT_IN(k)                cd_nat(k)   
3#   define SGN_IN(k)                psgn(k)
4#   define F_SIZE(ptab)             kfld
5#   define LBC_ARG                  (jf)
6#   if defined DIM_2d
7#      define ARRAY_TYPE(i,j,k,l,f)    TYPE(PTR_2D)     , INTENT(inout) ::   ptab(f)
8#      define ARRAY_IN(i,j,k,l,f)      ptab(f)%pt2d(i,j)
9#      define K_SIZE(ptab)             1
10#      define L_SIZE(ptab)             1
11#   endif
12#   if defined DIM_3d
13#      define ARRAY_TYPE(i,j,k,l,f)    TYPE(PTR_3D)     , INTENT(inout) ::   ptab(f)
14#      define ARRAY_IN(i,j,k,l,f)      ptab(f)%pt3d(i,j,k)
15#      define K_SIZE(ptab)             SIZE(ptab(1)%pt3d,3)
16#      define L_SIZE(ptab)             1
17#   endif
18#   if defined DIM_4d
19#      define ARRAY_TYPE(i,j,k,l,f)    TYPE(PTR_4D)     , INTENT(inout) ::   ptab(f)
20#      define ARRAY_IN(i,j,k,l,f)      ptab(f)%pt4d(i,j,k,l)
21#      define K_SIZE(ptab)             SIZE(ptab(1)%pt4d,3)
22#      define L_SIZE(ptab)             SIZE(ptab(1)%pt4d,4)
23#   endif
24#else
25!                          !==  IN: ptab is an array  ==!
26#   define ARRAY_TYPE(i,j,k,l,f)    REAL(wp)         , INTENT(inout) ::   ARRAY_IN(i,j,k,l,f)
27#   define NAT_IN(k)                cd_nat
28#   define SGN_IN(k)                psgn
29#   define F_SIZE(ptab)             1
30#   define LBC_ARG
31#   if defined DIM_2d
32#      define ARRAY_IN(i,j,k,l,f)   ptab(i,j)
33#      define K_SIZE(ptab)          1
34#      define L_SIZE(ptab)          1
35#   endif
36#   if defined DIM_3d
37#      define ARRAY_IN(i,j,k,l,f)   ptab(i,j,k)
38#      define K_SIZE(ptab)          SIZE(ptab,3)
39#      define L_SIZE(ptab)          1
40#   endif
41#   if defined DIM_4d
42#      define ARRAY_IN(i,j,k,l,f)   ptab(i,j,k,l)
43#      define K_SIZE(ptab)          SIZE(ptab,3)
44#      define L_SIZE(ptab)          SIZE(ptab,4)
45#   endif
46#endif
47
48   SUBROUTINE ROUTINE_NFD( ptab, cd_nat, psgn, kfld )
49      !!----------------------------------------------------------------------
50      ARRAY_TYPE(:,:,:,:,:)   ! array or pointer of arrays on which the boundary condition is applied
51      CHARACTER(len=1) , INTENT(in   ) ::   NAT_IN(:)   ! nature of array grid-points
52      REAL(wp)         , INTENT(in   ) ::   SGN_IN(:)   ! sign used across the north fold boundary
53      INTEGER, OPTIONAL, INTENT(in   ) ::   kfld        ! number of pt3d arrays
54      !
55      INTEGER  ::   ji,  jj,  jk,  jl, jh, jf, jr   ! dummy loop indices
56      INTEGER  ::   ipi, ipj, ipk, ipl, ipf         ! dimension of the input array
57      INTEGER  ::   imigr, iihom, ijhom             ! local integers
58      INTEGER  ::   ierr, ibuffsize, ilci, ildi, ilei, iilb
59      INTEGER  ::   ij, iproc
60      INTEGER, DIMENSION (jpmaxngh)       ::   ml_req_nf   ! for mpi_isend when avoiding mpi_allgather
61      INTEGER                             ::   ml_err      ! for mpi_isend when avoiding mpi_allgather
62      INTEGER, DIMENSION(MPI_STATUS_SIZE) ::   ml_stat     ! for mpi_isend when avoiding mpi_allgather
63      !                                                    ! Workspace for message transfers avoiding mpi_allgather
64      INTEGER                             ::   ipf_j       ! sum of lines for all multi fields
65      INTEGER                             ::   js          ! counter
66      INTEGER, DIMENSION(:,:),          ALLOCATABLE ::   jj_s  ! position of sent lines
67      INTEGER, DIMENSION(:),            ALLOCATABLE ::   ipj_s ! number of sent lines
68      REAL(wp), DIMENSION(:,:,:)      , ALLOCATABLE ::   ztabl
69      REAL(wp), DIMENSION(:,:,:,:,:)  , ALLOCATABLE ::   ztab, ztabr
70      REAL(wp), DIMENSION(:,:,:,:,:)  , ALLOCATABLE ::   znorthloc, zfoldwk     
71      REAL(wp), DIMENSION(:,:,:,:,:,:), ALLOCATABLE ::   znorthgloio
72      !!----------------------------------------------------------------------
73      !
74      ipk = K_SIZE(ptab)   ! 3rd dimension
75      ipl = L_SIZE(ptab)   ! 4th    -
76      ipf = F_SIZE(ptab)   ! 5th    -      use in "multi" case (array of pointers)
77      !
78      IF( l_north_nogather ) THEN      !==  no allgather exchanges  ==!
79
80         ALLOCATE(ipj_s(ipf))
81
82         ipj      = 2            ! Max 2nd dimension of message transfers (last two j-line only)
83         ipj_s(:) = 1            ! Real 2nd dimension of message transfers (depending on perf requirement)
84                                 ! by default, only one line is exchanged
85
86         ALLOCATE( jj_s(ipf,2) )
87
88         ! re-define number of exchanged lines :
89         !  must be two during the first two time steps
90         !  to correct possible incoherent values on North fold lines from restart
91
92         !!!!!!!!!           temporary switch off this optimisation ==> force TRUE           !!!!!!!!
93         !!!!!!!!!  needed to get the same results without agrif and with agrif and no zoom  !!!!!!!!
94         !!!!!!!!!                    I don't know why we must do that...                    !!!!!!!!
95         l_full_nf_update = .TRUE.
96
97         ! Two lines update (slower but necessary to avoid different values ion identical grid points
98         IF ( l_full_nf_update .OR.                          &    ! if coupling fields
99              ( ncom_stp == nit000 .AND. .NOT. ln_rstart ) ) &    ! at first time step, if not restart
100            ipj_s(:) = 2
101
102         ! Index of modifying lines in input
103         DO jf = 1, ipf                      ! Loop over the number of arrays to be processed
104            !
105            SELECT CASE ( npolj )
106            !
107            CASE ( 3, 4 )                       ! *  North fold  T-point pivot
108               !
109               SELECT CASE ( NAT_IN(jf) )
110               !
111               CASE ( 'T' , 'W' ,'U' )                            ! T-, U-, W-point
112                  jj_s(jf,1) = nlcj - 2 ;  jj_s(jf,2) = nlcj - 1
113               CASE ( 'V' , 'F' )                                 ! V-, F-point
114                  jj_s(jf,1) = nlcj - 3 ;  jj_s(jf,2) = nlcj - 2
115               END SELECT
116            !
117            CASE ( 5, 6 )                        ! *  North fold  F-point pivot
118               SELECT CASE ( NAT_IN(jf) )
119               !
120               CASE ( 'T' , 'W' ,'U' )                            ! T-, U-, W-point
121                  jj_s(jf,1) = nlcj - 1     
122                  ipj_s(jf) = 1                  ! need only one line anyway
123               CASE ( 'V' , 'F' )                                 ! V-, F-point
124                  jj_s(jf,1) = nlcj - 2 ;  jj_s(jf,2) = nlcj - 1
125               END SELECT
126            !
127            END SELECT
128            !
129         ENDDO
130         !
131         ipf_j = sum (ipj_s(:))      ! Total number of lines to be exchanged
132         !
133         ALLOCATE( znorthloc(jpimax,ipf_j,ipk,ipl,1) )
134         !
135         js = 0
136         DO jf = 1, ipf                      ! Loop over the number of arrays to be processed
137            DO jj = 1, ipj_s(jf)
138               js = js + 1
139               DO jl = 1, ipl
140                  DO jk = 1, ipk
141                     znorthloc(1:jpi,js,jk,jl,1) = ARRAY_IN(1:jpi,jj_s(jf,jj),jk,jl,jf)
142                  END DO
143               END DO
144            END DO
145         END DO
146         !
147         ibuffsize = jpimax * ipf_j * ipk * ipl
148         !
149         ALLOCATE( zfoldwk(jpimax,ipf_j,ipk,ipl,1) )
150         ALLOCATE( ztabr(jpimax*jpmaxngh,ipj,ipk,ipl,ipf) ) 
151         ! when some processors of the north fold are suppressed,
152         ! values of ztab* arrays corresponding to these suppressed domain won't be defined
153         ! and we need a default definition to 0.
154         ! a better test should be: a testing if "suppressed land-processors" belongs to the north-pole folding
155         IF ( jpni*jpnj /= jpnij ) ztabr(:,:,:,:,:) = 0._wp
156         !
157         ! start waiting time measurement
158         IF( ln_timing ) CALL tic_tac(.TRUE.)
159         !
160         DO jr = 1, nsndto
161            IF( nfipproc(isendto(jr),jpnj) /= narea-1 .AND. nfipproc(isendto(jr),jpnj) /= -1 ) THEN
162               CALL mppsend( 5, znorthloc, ibuffsize, nfipproc(isendto(jr),jpnj), ml_req_nf(jr) )
163            ENDIF
164         END DO
165         !
166         DO jr = 1,nsndto
167            iproc = nfipproc(isendto(jr),jpnj)
168            IF(iproc /= -1) THEN
169               iilb = nimppt(iproc+1)
170               ilci = nlcit (iproc+1)
171               ildi = nldit (iproc+1)
172               ilei = nleit (iproc+1)
173               IF( iilb            ==      1 )   ildi = 1      ! e-w boundary already done -> force to take 1st column
174               IF( iilb + ilci - 1 == jpiglo )   ilei = ilci   ! e-w boundary already done -> force to take last column
175               iilb = nfiimpp(isendto(jr),jpnj) - nfiimpp(isendto(1),jpnj)
176            ENDIF
177            IF( iproc /= narea-1 .AND. iproc /= -1 ) THEN
178               CALL mpprecv(5, zfoldwk, ibuffsize, iproc)
179               js = 0
180               DO jf = 1, ipf ; DO jj = 1, ipj_s(jf)
181                  js = js + 1
182                  DO jl = 1, ipl
183                     DO jk = 1, ipk
184                        DO ji = ildi, ilei
185                           ztabr(iilb+ji,jj,jk,jl,jf) = zfoldwk(ji,js,jk,jl,1)
186                        END DO
187                     END DO
188                  END DO
189               END DO; END DO
190            ELSE IF( iproc == narea-1 ) THEN
191               DO jf = 1, ipf ; DO jj = 1, ipj_s(jf)
192                  DO jl = 1, ipl
193                     DO jk = 1, ipk
194                        DO ji = ildi, ilei
195                           ztabr(iilb+ji,jj,jk,jl,jf) = ARRAY_IN(ji,jj_s(jf,jj),jk,jl,jf)
196                        END DO
197                     END DO
198                  END DO
199               END DO; END DO
200            ENDIF
201         END DO
202         DO jr = 1,nsndto
203            IF( nfipproc(isendto(jr),jpnj) /= narea-1 .AND. nfipproc(isendto(jr),jpnj) /= -1 ) THEN
204               CALL mpi_wait( ml_req_nf(jr), ml_stat, ml_err )
205            ENDIF
206         END DO
207         !
208         IF( ln_timing ) CALL tic_tac(.FALSE.)
209         !
210         ! North fold boundary condition
211         !
212         DO jf = 1, ipf
213            CALL lbc_nfd_nogather( ARRAY_IN(:,:,:,:,jf), ztabr(:,1:ipj_s(jf),:,:,jf), cd_nat LBC_ARG, psgn LBC_ARG )
214         END DO
215         !
216         DEALLOCATE( zfoldwk, ztabr, jj_s, ipj_s )
217         !
218      ELSE                             !==  allgather exchanges  ==!
219         !
220         ipj   = 4            ! 2nd dimension of message transfers (last j-lines)
221         !
222         ALLOCATE( znorthloc(jpimax,ipj,ipk,ipl,ipf) )
223         !
224         DO jf = 1, ipf                ! put in znorthloc the last ipj j-lines of ptab
225            DO jl = 1, ipl
226               DO jk = 1, ipk
227                  DO jj = nlcj - ipj +1, nlcj
228                     ij = jj - nlcj + ipj
229                     znorthloc(1:jpi,ij,jk,jl,jf) = ARRAY_IN(1:jpi,jj,jk,jl,jf)
230                  END DO
231               END DO
232            END DO
233         END DO
234         !
235         ibuffsize = jpimax * ipj * ipk * ipl * ipf
236         !
237         ALLOCATE( ztab       (jpiglo,ipj,ipk,ipl,ipf     ) )
238         ALLOCATE( znorthgloio(jpimax,ipj,ipk,ipl,ipf,jpni) )
239         !
240         ! when some processors of the north fold are suppressed,
241         ! values of ztab* arrays corresponding to these suppressed domain won't be defined
242         ! and we need a default definition to 0.
243         ! a better test should be: a testing if "suppressed land-processors" belongs to the north-pole folding
244         IF ( jpni*jpnj /= jpnij ) ztab(:,:,:,:,:) = 0._wp
245         !
246         ! start waiting time measurement
247         IF( ln_timing ) CALL tic_tac(.TRUE.)
248         CALL MPI_ALLGATHER( znorthloc  , ibuffsize, MPI_DOUBLE_PRECISION,                &
249            &                znorthgloio, ibuffsize, MPI_DOUBLE_PRECISION, ncomm_north, ierr )
250         !
251         ! stop waiting time measurement
252         IF( ln_timing ) CALL tic_tac(.FALSE.)
253         !
254         DO jr = 1, ndim_rank_north         ! recover the global north array
255            iproc = nrank_north(jr) + 1
256            iilb  = nimppt(iproc)
257            ilci  = nlcit (iproc)
258            ildi  = nldit (iproc)
259            ilei  = nleit (iproc)
260            IF( iilb            ==      1 )   ildi = 1      ! e-w boundary already done -> force to take 1st column
261            IF( iilb + ilci - 1 == jpiglo )   ilei = ilci   ! e-w boundary already done -> force to take last column
262            DO jf = 1, ipf
263               DO jl = 1, ipl
264                  DO jk = 1, ipk
265                     DO jj = 1, ipj
266                        DO ji = ildi, ilei
267                           ztab(ji+iilb-1,jj,jk,jl,jf) = znorthgloio(ji,jj,jk,jl,jf,jr)
268                        END DO
269                     END DO
270                  END DO
271               END DO
272            END DO
273         END DO
274         DO jf = 1, ipf
275            CALL lbc_nfd( ztab(:,:,:,:,jf), cd_nat LBC_ARG, psgn LBC_ARG )   ! North fold boundary condition
276         END DO
277         !
278         DO jf = 1, ipf
279            DO jl = 1, ipl
280               DO jk = 1, ipk
281                  DO jj = nlcj-ipj+1, nlcj             ! Scatter back to ARRAY_IN
282                     ij = jj - nlcj + ipj
283                     DO ji= 1, nlci
284                        ARRAY_IN(ji,jj,jk,jl,jf) = ztab(ji+nimpp-1,ij,jk,jl,jf)
285                     END DO
286                  END DO
287               END DO
288            END DO
289         END DO
290         !
291      !
292         DEALLOCATE( ztab )
293         DEALLOCATE( znorthgloio )
294      ENDIF
295      !
296      DEALLOCATE( znorthloc )
297      !
298   END SUBROUTINE ROUTINE_NFD
299
300#undef ARRAY_TYPE
301#undef NAT_IN
302#undef SGN_IN
303#undef ARRAY_IN
304#undef K_SIZE
305#undef L_SIZE
306#undef F_SIZE
307#undef LBC_ARG
Note: See TracBrowser for help on using the repository browser.