New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icesbc.F90 in NEMO/branches/2019/dev_r11265_ASINTER-01_Guillaume_ABL1D/src/ICE – NEMO

source: NEMO/branches/2019/dev_r11265_ASINTER-01_Guillaume_ABL1D/src/ICE/icesbc.F90 @ 11305

Last change on this file since 11305 was 11304, checked in by smasson, 5 years ago

dev_r11265_ABL : si3 compatibility, see #2131
  • Property svn:keywords set to Id
File size: 17.5 KB
Line 
1MODULE icesbc
2   !!======================================================================
3   !!                       ***  MODULE  icesbc  ***
4   !! Sea-Ice :   air-ice sbc fields
5   !!=====================================================================
6   !! History :  4.0  !  2017-08  (C. Rousset)       Original code
7   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3' :                                     SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE ice            ! sea-ice: variables
16   USE sbc_oce        ! Surface boundary condition: ocean fields
17   USE sbc_ice        ! Surface boundary condition: ice   fields
18   USE usrdef_sbc     ! Surface boundary condition: user defined
19   USE sbcblk         ! Surface boundary condition: bulk
20   USE sbccpl         ! Surface boundary condition: coupled interface
21   USE icealb         ! sea-ice: albedo
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O manager library
25   USE lib_mpp        ! MPP library
26   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
27   USE lbclnk         ! lateral boundary conditions (or mpp links)
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC ice_sbc_tau   ! called by icestp.F90
34   PUBLIC ice_sbc_flx   ! called by icestp.F90
35   PUBLIC ice_sbc_init  ! called by icestp.F90
36
37   !! * Substitutions
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE ice_sbc_tau( kt, ksbc, utau_ice, vtau_ice )
47      !!-------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_sbc_tau  ***
49      !!
50      !! ** Purpose : provide surface boundary condition for sea ice (momentum)
51      !!
52      !! ** Action  : It provides the following fields:
53      !!              utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
54      !!-------------------------------------------------------------------
55      INTEGER                     , INTENT(in   ) ::   kt                   ! ocean time step
56      INTEGER                     , INTENT(in   ) ::   ksbc                 ! type of sbc flux
57      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   utau_ice, vtau_ice   ! air-ice stress   [N/m2]
58      !!
59      INTEGER  ::   ji, jj                 ! dummy loop index
60      REAL(wp), DIMENSION(jpi,jpj) ::   zutau_ice, zvtau_ice 
61      !!-------------------------------------------------------------------
62      !
63      IF( ln_timing )   CALL timing_start('ice_sbc')
64      !
65      IF( kt == nit000 .AND. lwp ) THEN
66         WRITE(numout,*)
67         WRITE(numout,*)'ice_sbc_tau: Surface boundary condition for sea ice (momentum)'
68         WRITE(numout,*)'~~~~~~~~~~~~~~~'
69      ENDIF
70      !
71      SELECT CASE( ksbc )
72         CASE( jp_usr     )   ;    CALL usrdef_sbc_ice_tau( kt )                 ! user defined formulation
73         CASE( jp_blk     )   ;    CALL blk_ice_1( sf(jp_wndi)%fnow(:,:,1), sf(jp_wndj)%fnow(:,:,1),   &
74            &                                      sf(jp_tair)%fnow(:,:,1), sf(jp_humi)%fnow(:,:,1), sf(jp_slp)%fnow(:,:,1),   &
75            &                                      u_ice, v_ice,   &    ! inputs
76            &                                      putaui = utau_ice, pvtaui = vtau_ice )    ! outputs                              ! Bulk         formulation
77         CASE( jp_purecpl )   ;    CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled      formulation
78      END SELECT
79      !
80      IF( ln_mixcpl) THEN                                                        ! Case of a mixed Bulk/Coupled formulation
81                                   CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
82         DO jj = 2, jpjm1
83            DO ji = 2, jpim1
84               utau_ice(ji,jj) = utau_ice(ji,jj) * xcplmask(ji,jj,0) + zutau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
85               vtau_ice(ji,jj) = vtau_ice(ji,jj) * xcplmask(ji,jj,0) + zvtau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) )
86            END DO
87         END DO
88         CALL lbc_lnk_multi( 'icesbc', utau_ice, 'U', -1., vtau_ice, 'V', -1. )
89      ENDIF
90      !
91      IF( ln_timing )   CALL timing_stop('ice_sbc')
92      !
93   END SUBROUTINE ice_sbc_tau
94
95   
96   SUBROUTINE ice_sbc_flx( kt, ksbc )
97      !!-------------------------------------------------------------------
98      !!                  ***  ROUTINE ice_sbc_flx  ***
99      !!
100      !! ** Purpose : provide surface boundary condition for sea ice (flux)
101      !!
102      !! ** Action  : It provides the following fields used in sea ice model:
103      !!                emp_oce , emp_ice                        = E-P over ocean and sea ice                    [Kg/m2/s]
104      !!                sprecip                                  = solid precipitation                           [Kg/m2/s]
105      !!                evap_ice                                 = sublimation                                   [Kg/m2/s]
106      !!                qsr_tot , qns_tot                        = solar & non solar heat flux (total)           [W/m2]
107      !!                qsr_ice , qns_ice                        = solar & non solar heat flux over ice          [W/m2]
108      !!                dqns_ice                                 = non solar  heat sensistivity                  [W/m2]
109      !!                qemp_oce, qemp_ice, qprec_ice, qevap_ice = sensible heat (associated with evap & precip) [W/m2]
110      !!            + some fields that are not used outside this module:
111      !!                qla_ice                                  = latent heat flux over ice                     [W/m2]
112      !!                dqla_ice                                 = latent heat sensistivity                      [W/m2]
113      !!                tprecip                                  = total  precipitation                          [Kg/m2/s]
114      !!                alb_ice                                  = albedo above sea ice
115      !!-------------------------------------------------------------------
116      INTEGER, INTENT(in) ::   kt     ! ocean time step
117      INTEGER, INTENT(in) ::   ksbc   ! flux formulation (user defined, bulk or Pure Coupled)
118      !
119      INTEGER  ::   ji, jj, jl                                ! dummy loop index
120      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
121      REAL(wp), DIMENSION(jpi,jpj)     ::   zalb              ! 2D workspace
122      !!--------------------------------------------------------------------
123      !
124      IF( ln_timing )   CALL timing_start('ice_sbc_flx')
125
126      IF( kt == nit000 .AND. lwp ) THEN
127         WRITE(numout,*)
128         WRITE(numout,*)'ice_sbc_flx: Surface boundary condition for sea ice (flux)'
129         WRITE(numout,*)'~~~~~~~~~~~~~~~'
130      ENDIF
131
132      ! --- cloud-sky and overcast-sky ice albedos --- !
133      CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_frac, h_ip, zalb_cs, zalb_os )
134
135      ! albedo depends on cloud fraction because of non-linear spectral effects
136!!gm cldf_ice is a real, DOCTOR naming rule: start with cd means CHARACTER passed in argument !
137      alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
138      !
139      !
140      SELECT CASE( ksbc )   !== fluxes over sea ice ==!
141      !
142      CASE( jp_usr )              !--- user defined formulation
143                                  CALL usrdef_sbc_ice_flx( kt, h_s, h_i )
144      CASE( jp_blk )              !--- bulk formulation
145                                  CALL blk_ice_2    ( t_su, h_s, h_i, alb_ice, sf(jp_tair)%fnow(:,:,1), sf(jp_humi)%fnow(:,:,1),    &
146            &                                           sf(jp_slp)%fnow(:,:,1), sf(jp_qlw)%fnow(:,:,1), sf(jp_prec)%fnow(:,:,1), sf(jp_snow)%fnow(:,:,1) )    !
147         IF( ln_mixcpl        )   CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
148         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
149         !                        !    compute conduction flux and surface temperature (as in Jules surface module)
150         IF( ln_cndflx .AND. .NOT.ln_cndemulate ) &
151            &                     CALL blk_ice_qcn    ( ln_virtual_itd, t_su, t_bo, h_s, h_i )
152      CASE ( jp_purecpl )         !--- coupled formulation
153                                  CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i )
154         IF( nn_flxdist /= -1 )   CALL ice_flx_dist   ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist )
155      END SELECT
156
157      !--- output ice albedo and surface albedo ---!
158      IF( iom_use('icealb') ) THEN
159         WHERE( at_i_b <= epsi06 )   ;   zalb(:,:) = rn_alb_oce
160         ELSEWHERE                   ;   zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b
161         END WHERE
162         CALL iom_put( "icealb" , zalb(:,:) )
163      ENDIF
164      IF( iom_use('albedo') ) THEN
165         zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b )
166         CALL iom_put( "albedo" , zalb(:,:) )
167      ENDIF
168      !
169      IF( ln_timing )   CALL timing_stop('ice_sbc_flx')
170      !
171   END SUBROUTINE ice_sbc_flx
172
173
174   SUBROUTINE ice_flx_dist( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_flxdist )
175      !!-------------------------------------------------------------------
176      !!                  ***  ROUTINE ice_flx_dist  ***
177      !!
178      !! ** Purpose :   update the ice surface boundary condition by averaging
179      !!              and/or redistributing fluxes on ice categories
180      !!
181      !! ** Method  :   average then redistribute
182      !!
183      !! ** Action  :   depends on k_flxdist
184      !!                = -1  Do nothing (needs N(cat) fluxes)
185      !!                =  0  Average N(cat) fluxes then apply the average over the N(cat) ice
186      !!                =  1  Average N(cat) fluxes then redistribute over the N(cat) ice
187      !!                                                 using T-ice and albedo sensitivity
188      !!                =  2  Redistribute a single flux over categories
189      !!-------------------------------------------------------------------
190      INTEGER                   , INTENT(in   ) ::   k_flxdist  ! redistributor
191      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
192      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
193      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
194      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
195      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
196      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
197      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
198      !
199      INTEGER  ::   jl      ! dummy loop index
200      !
201      REAL(wp), DIMENSION(jpi,jpj) ::   z1_at_i   ! inverse of concentration
202      !
203      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qsr_m   ! Mean solar heat flux over all categories
204      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_qns_m   ! Mean non solar heat flux over all categories
205      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_evap_m  ! Mean sublimation over all categories
206      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_dqn_m   ! Mean d(qns)/dT over all categories
207      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   z_devap_m ! Mean d(evap)/dT over all categories
208      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zalb_m    ! Mean albedo over all categories
209      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztem_m    ! Mean temperature over all categories
210      !!----------------------------------------------------------------------
211      !
212      WHERE ( at_i (:,:) > 0._wp )   ; z1_at_i(:,:) = 1._wp / at_i (:,:)
213      ELSEWHERE                      ; z1_at_i(:,:) = 0._wp
214      END WHERE
215     
216      SELECT CASE( k_flxdist )       !==  averaged on all ice categories  ==!
217      !
218      CASE( 0 , 1 )
219         !
220         ALLOCATE( z_qns_m(jpi,jpj), z_qsr_m(jpi,jpj), z_dqn_m(jpi,jpj), z_evap_m(jpi,jpj), z_devap_m(jpi,jpj) ) 
221         !
222         z_qns_m  (:,:) = SUM( a_i(:,:,:) * pqns_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
223         z_qsr_m  (:,:) = SUM( a_i(:,:,:) * pqsr_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
224         z_dqn_m  (:,:) = SUM( a_i(:,:,:) * pdqn_ice  (:,:,:) , dim=3 ) * z1_at_i(:,:)
225         z_evap_m (:,:) = SUM( a_i(:,:,:) * pevap_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
226         z_devap_m(:,:) = SUM( a_i(:,:,:) * pdevap_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
227         DO jl = 1, jpl
228            pqns_ice  (:,:,jl) = z_qns_m (:,:)
229            pqsr_ice  (:,:,jl) = z_qsr_m (:,:)
230            pdqn_ice  (:,:,jl) = z_dqn_m  (:,:)
231            pevap_ice (:,:,jl) = z_evap_m(:,:)
232            pdevap_ice(:,:,jl) = z_devap_m(:,:)
233         END DO
234         !
235         DEALLOCATE( z_qns_m, z_qsr_m, z_dqn_m, z_evap_m, z_devap_m ) 
236         !
237      END SELECT
238      !
239      SELECT CASE( k_flxdist )       !==  redistribution on all ice categories  ==!
240      !
241      CASE( 1 , 2 )
242         !
243         ALLOCATE( zalb_m(jpi,jpj), ztem_m(jpi,jpj) ) 
244         !
245         zalb_m(:,:) = SUM( a_i(:,:,:) * palb_ice(:,:,:) , dim=3 ) * z1_at_i(:,:)
246         ztem_m(:,:) = SUM( a_i(:,:,:) * ptn_ice (:,:,:) , dim=3 ) * z1_at_i(:,:)
247         DO jl = 1, jpl
248            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
249            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
250            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
251         END DO
252         !
253         DEALLOCATE( zalb_m, ztem_m ) 
254         !
255      END SELECT
256      !
257   END SUBROUTINE ice_flx_dist
258
259
260   SUBROUTINE ice_sbc_init
261      !!-------------------------------------------------------------------
262      !!                  ***  ROUTINE ice_sbc_init  ***
263      !!
264      !! ** Purpose :   Physical constants and parameters linked to the ice dynamics
265      !!     
266      !! ** Method  :   Read the namsbc namelist and check the ice-dynamic
267      !!              parameter values called at the first timestep (nit000)
268      !!
269      !! ** input   :   Namelist namsbc
270      !!-------------------------------------------------------------------
271      INTEGER ::   ios, ioptio   ! Local integer
272      !!
273      NAMELIST/namsbc/ rn_cio, rn_blow_s, nn_flxdist, ln_cndflx, ln_cndemulate
274      !!-------------------------------------------------------------------
275      !
276      REWIND( numnam_ice_ref )         ! Namelist namsbc in reference namelist : Ice dynamics
277      READ  ( numnam_ice_ref, namsbc, IOSTAT = ios, ERR = 901)
278901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
279      REWIND( numnam_ice_cfg )         ! Namelist namsbc in configuration namelist : Ice dynamics
280      READ  ( numnam_ice_cfg, namsbc, IOSTAT = ios, ERR = 902 )
281902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
282      IF(lwm) WRITE( numoni, namsbc )
283      !
284      IF(lwp) THEN                     ! control print
285         WRITE(numout,*)
286         WRITE(numout,*) 'ice_sbc_init: ice parameters for ice dynamics '
287         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
288         WRITE(numout,*) '   Namelist namsbc:'
289         WRITE(numout,*) '      drag coefficient for oceanic stress              rn_cio        = ', rn_cio
290         WRITE(numout,*) '      coefficient for ice-lead partition of snowfall   rn_blow_s     = ', rn_blow_s
291         WRITE(numout,*) '      Multicategory heat flux formulation              nn_flxdist    = ', nn_flxdist
292         WRITE(numout,*) '      Use conduction flux as surface condition         ln_cndflx     = ', ln_cndflx
293         WRITE(numout,*) '         emulate conduction flux                       ln_cndemulate = ', ln_cndemulate
294      ENDIF
295      !
296      IF(lwp) WRITE(numout,*)
297      SELECT CASE( nn_flxdist )         ! SI3 Multi-category heat flux formulation
298      CASE( -1  )
299         IF(lwp) WRITE(numout,*) '   SI3: use per-category fluxes (nn_flxdist = -1) '
300      CASE(  0  )
301         IF(lwp) WRITE(numout,*) '   SI3: use average per-category fluxes (nn_flxdist = 0) '
302      CASE(  1  )
303         IF(lwp) WRITE(numout,*) '   SI3: use average then redistribute per-category fluxes (nn_flxdist = 1) '
304         IF( ln_cpl )         CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in coupled mode must be /=1' )
305      CASE(  2  )
306         IF(lwp) WRITE(numout,*) '   SI3: Redistribute a single flux over categories (nn_flxdist = 2) '
307         IF( .NOT. ln_cpl )   CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in forced mode must be /=2' )
308      CASE DEFAULT
309         CALL ctl_stop( 'ice_thd_init: SI3 option, nn_flxdist, should be between -1 and 2' )
310      END SELECT
311      !
312   END SUBROUTINE ice_sbc_init
313
314#else
315   !!----------------------------------------------------------------------
316   !!   Default option :         Empty module         NO SI3 sea-ice model
317   !!----------------------------------------------------------------------
318#endif
319
320   !!======================================================================
321END MODULE icesbc
Note: See TracBrowser for help on using the repository browser.