New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in NEMO/branches/2019/dev_r11514_HPC-02_single-core-extrahalo/src/OCE/TRA – NEMO

source: NEMO/branches/2019/dev_r11514_HPC-02_single-core-extrahalo/src/OCE/TRA/traadv_mus.F90 @ 12325

Last change on this file since 12325 was 12325, checked in by francesca, 4 years ago

replace halo-copy routines - ticket #2009
  • Property svn:keywords set to Id
File size: 17.3 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26
27   !
28   USE iom            ! XIOS library
29   USE in_out_manager ! I/O manager
30   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
31   USE halo_mng
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
37   
38   REAL(wp), POINTER, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
39   !                                                           !  and in closed seas (orca 2 and 1 configurations)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
41   
42   LOGICAL  ::   l_trd   ! flag to compute trends
43   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
44   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
45   
46   INTEGER :: jphls = 2
47
48   !! * Substitutions
49#  include "vectopt_loop_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
52   !! $Id$
53   !! Software governed by the CeCILL license (see ./LICENSE)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
58      &                                              ptb, pta, kjpt, ld_msc_ups )
59      !!----------------------------------------------------------------------
60      !!                    ***  ROUTINE tra_adv_mus  ***
61      !!
62      !! ** Purpose :   Compute the now trend due to total advection of tracers
63      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
64      !!              Conservation Laws) and add it to the general tracer trend.
65      !!
66      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
67      !!              ld_msc_ups=T :
68      !!
69      !! ** Action : - update pta  with the now advective tracer trends
70      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
71      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
72      !!
73      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
74      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
75      !!----------------------------------------------------------------------
76      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
77      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
78      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
79      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
80      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
81      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
82      REAL(wp), POINTER, DIMENSION(:,:,:)  , INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
83      REAL(wp), POINTER, DIMENSION(:,:,:,:), INTENT(inout) ::   pta             ! tracer trend
84      REAL(wp), POINTER, DIMENSION(:,:,:,:), INTENT(in   ) ::   ptb             ! before tracer trend
85      !
86      INTEGER  ::   ji, jj, jk, jn, ierr   ! dummy loop indices
87      REAL(wp) ::   zu, z0u, zzwx, zw , zalpha   ! local scalars
88      REAL(wp) ::   zv, z0v, zzwy, z0w           !   -      -
89      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwx, zslpx   ! 3D workspace
90      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwy, zslpy   ! -      -
91      !!----------------------------------------------------------------------
92      !
93      CALL halo_mng_set(jphls)
94     
95      ALLOCATE(zwx(jplbi:jpi,jplbj:jpj,jpk))
96      ALLOCATE(zwy(jplbi:jpi,jplbj:jpj,jpk))
97      ALLOCATE(zslpx(jplbi:jpi,jplbj:jpj,jpk))
98      ALLOCATE(zslpy(jplbi:jpi,jplbj:jpj,jpk))
99     
100      CALL halo_mng_resize(r1_e1e2t,'T', 1._wp)
101      CALL halo_mng_resize(r1_e1e2u,'U', -1._wp)
102      CALL halo_mng_resize(r1_e1e2v,'V', -1._wp)
103      CALL halo_mng_resize(tmask,'T', 1._wp)
104      CALL halo_mng_resize(ptb, 'T', 1._wp, kjpt=kjpt )
105      CALL halo_mng_resize(pta, 'T', 1._wp, kjpt=kjpt)
106      CALL halo_mng_resize(wmask, 'W', 1._wp)
107      CALL halo_mng_resize(umask, 'U', 1._wp)
108      CALL halo_mng_resize(vmask, 'V', 1._wp)
109      CALL halo_mng_resize(e3t_n,'T', 1._wp, fillval=1._wp)
110      CALL halo_mng_resize(e3u_n, 'U', -1._wp, fillval=1._wp)
111      CALL halo_mng_resize(e3v_n, 'V', -1._wp, fillval=1._wp)
112      CALL halo_mng_resize(e3w_n, 'W', 1._wp, fillval=1._wp)
113      CALL halo_mng_resize(pun, 'U', -1._wp)
114      CALL halo_mng_resize(pvn, 'V', -1._wp)
115      CALL halo_mng_resize(pwn, 'W', 1._wp)
116     
117      IF( ln_isfcav ) CALL halo_mng_resize(mikt, 'T', 1._wp)
118      IF( ld_msc_ups) CALL halo_mng_resize(rnfmsk, 'T', 1._wp)
119      IF( ld_msc_ups) CALL halo_mng_resize(upsmsk, 'T', 1._wp)
120
121      IF( kt == kit000 )  THEN
122         IF(lwp) WRITE(numout,*)
123         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
124         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
125         IF(lwp) WRITE(numout,*) '~~~~~~~'
126         IF(lwp) WRITE(numout,*)
127         !
128         ! Upstream / MUSCL scheme indicator
129         !
130         ALLOCATE( xind(jplbi:jpi,jplbj:jpj,jpk), STAT=ierr )
131         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
132         !
133         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
134            ALLOCATE( upsmsk(jplbi:jpi,jplbj:jpj), STAT=ierr )
135            upsmsk(:,:) = 0._wp                             ! not upstream by default
136            !
137            DO jk = 1, jpkm1
138               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
139                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
140                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
141            END DO
142         ENDIF 
143         !
144      ENDIF 
145      !     
146      l_trd = .FALSE.
147      l_hst = .FALSE.
148      l_ptr = .FALSE.
149      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
150      IF(   cdtype == 'TRA' .AND. ln_diaptr )                                               l_ptr = .TRUE. 
151      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
152         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
153      !
154      DO jn = 1, kjpt            !==  loop over the tracers  ==!
155         !
156         !                          !* Horizontal advective fluxes
157         !
158         !                                !-- first guess of the slopes
159         zwx(:,:,jpk) = 0._wp                   ! bottom values
160         zwy(:,:,jpk) = 0._wp 
161         DO jk = 1, jpkm1                       ! interior values
162            DO jj = jplbj, jpj-1     
163               DO ji = jplbi, jpi-1   ! vector opt.
164                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
165                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
166               END DO
167           END DO
168         END DO
169         ! lateral boundary conditions   (changed sign)
170         !CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1. , zwy, 'V', -1. )
171         !                                !-- Slopes of tracer
172         zslpx(:,:,jpk) = 0._wp                 ! bottom values
173         zslpy(:,:,jpk) = 0._wp
174         DO jk = 1, jpkm1                       ! interior values
175            DO jj = jplbj+1, jpj
176               DO ji = jplbi+1, jpi   ! vector opt.
177                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
178                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
179                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
180                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
181               END DO
182            END DO
183         END DO
184         !
185         DO jk = 1, jpkm1                 !-- Slopes limitation
186            DO jj = jplbj+1, jpj
187               DO ji = jplbi+1, jpi   ! vector opt.
188                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
189                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
190                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
191                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
192                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
193                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
194               END DO
195           END DO
196         END DO
197         !
198         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
199            DO jj = jplbj+1, jpj-1
200               DO ji = jplbi+1, jpi-1   ! vector opt.
201                  ! MUSCL fluxes
202                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
203                  zalpha = 0.5 - z0u
204                  zu  = z0u - 0.5 * pun(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
205                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
206                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
207                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
208                  !
209                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
210                  zalpha = 0.5 - z0v
211                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
212                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
213                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
214                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
215               END DO
216            END DO
217         END DO
218         !CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1. , zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
219         !
220         DO jk = 1, jpkm1                 !-- Tracer advective trend
221            DO jj = jplbj+1, jpj-1     
222               DO ji = jplbi+1, jpi-1   ! vector opt.
223                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
224                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
225                  &                                   * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
226               END DO
227           END DO
228         END DO       
229         !                                ! trend diagnostics
230         IF( l_trd )  THEN
231            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
232            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
233         END IF
234         !                                 ! "Poleward" heat and salt transports
235         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
236         !                                 !  heat transport
237         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
238         !
239         !                          !* Vertical advective fluxes
240         !
241         !                                !-- first guess of the slopes
242         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
243         zwx(:,:,jpk) = 0._wp
244         DO jk = 2, jpkm1                       ! interior values
245            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
246         END DO
247         !                                !-- Slopes of tracer
248         zslpx(:,:,1) = 0._wp                   ! surface values
249         DO jk = 2, jpkm1                       ! interior value
250            DO jj = jplbj, jpj
251               DO ji = jplbi, jpi
252                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
253                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
254               END DO
255            END DO
256         END DO
257         DO jk = 2, jpkm1                 !-- Slopes limitation
258            DO jj = jplbj, jpj                      ! interior values
259               DO ji = jplbi, jpi
260                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
261                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
262                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
263               END DO
264            END DO
265         END DO
266         DO jk = 1, jpk-2                 !-- vertical advective flux
267            DO jj = jplbj+1, jpj-1     
268               DO ji = jplbi+1, jpi-1   ! vector opt.
269                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
270                  zalpha = 0.5 + z0w
271                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
272                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
273                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
274                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
275               END DO
276            END DO
277         END DO
278         IF( ln_linssh ) THEN                   ! top values, linear free surface only
279            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
280            DO jj = jplbj, jpj     
281               DO ji = jplbi, jpi
282                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
283                  END DO
284               END DO   
285            ELSE                                      ! no cavities: only at the ocean surface
286               zwx(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
287            ENDIF
288         ENDIF
289         !
290         DO jk = 1, jpkm1                 !-- vertical advective trend
291            DO jj = jplbj+1, jpj-1     
292               DO ji = jplbi+1, jpi-1   ! vector opt.
293                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
294               END DO
295            END DO
296         END DO
297         !                                ! send trends for diagnostic
298         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
299         !
300      END DO                     ! end of tracer loop
301      !
302      CALL halo_mng_set(1)
303     
304      CALL halo_mng_resize(r1_e1e2t,'T', 1._wp)
305      CALL halo_mng_resize(r1_e1e2u,'U', 1._wp)
306      CALL halo_mng_resize(r1_e1e2v,'V', 1._wp)
307      CALL halo_mng_resize(ptb, 'T', 1._wp, kjpt=kjpt)
308      CALL halo_mng_resize(pta, 'T', 1._wp, kjpt=kjpt)
309      CALL halo_mng_resize(tmask,'T', 1._wp)
310      CALL halo_mng_resize(wmask, 'W', 1._wp)
311      CALL halo_mng_resize(umask, 'U', 1._wp)
312      CALL halo_mng_resize(vmask, 'V', 1._wp)
313      CALL halo_mng_resize(e3t_n,'T', 1._wp, fillval=1._wp)
314      CALL halo_mng_resize(e3u_n, 'U', 1._wp, fillval=1._wp)
315      CALL halo_mng_resize(e3v_n, 'V', 1._wp, fillval=1._wp)
316      CALL halo_mng_resize(e3w_n, 'W', 1._wp, fillval=1._wp)
317      CALL halo_mng_resize(pun, 'U', 1._wp)
318      CALL halo_mng_resize(pvn, 'V', 1._wp)
319      CALL halo_mng_resize(pwn, 'W', 1._wp)
320      IF( ln_isfcav ) CALL halo_mng_resize(mikt, 'T', 1._wp)
321      IF( ld_msc_ups) CALL halo_mng_resize(rnfmsk, 'T', 1._wp)
322      IF( ld_msc_ups) CALL halo_mng_resize(upsmsk, 'T', 1._wp)
323     
324      DEALLOCATE(zwx,zwy)
325      DEALLOCATE(zslpx,zslpy)
326     
327    END SUBROUTINE tra_adv_mus
328
329   !!======================================================================
330END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.