source: NEMO/branches/2019/dev_r11514_HPC-02_single-core-extrahalo/src/OCE/nemogcm.F90 @ 11719

Last change on this file since 11719 was 11719, checked in by francesca, 13 months ago

add extra halo support- ticket #2009

  • Property svn:keywords set to Id
File size: 35.3 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE diaharm        ! tidal harmonics diagnostics  (dia_harm_init routine)
62   USE step           ! NEMO time-stepping                 (stp     routine)
63   USE icbini         ! handle bergs, initialisation
64   USE icbstp         ! handle bergs, calving, themodynamics and transport
65   USE cpl_oasis3     ! OASIS3 coupling
66   USE c1d            ! 1D configuration
67   USE step_c1d       ! Time stepping loop for the 1D configuration
68   USE dyndmp         ! Momentum damping
69   USE stopar         ! Stochastic param.: ???
70   USE stopts         ! Stochastic param.: ???
71   USE diurnal_bulk   ! diurnal bulk SST
72   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
73   USE crsini         ! initialise grid coarsening utility
74   USE diatmb         ! Top,middle,bottom output
75   USE dia25h         ! 25h mean output
76   USE sbc_oce , ONLY : lk_oasis
77   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
78#if defined key_top
79   USE trcini         ! passive tracer initialisation
80#endif
81#if defined key_nemocice_decomp
82   USE ice_domain_size, only: nx_global, ny_global
83#endif
84   !
85   USE lib_mpp        ! distributed memory computing
86   USE mppini         ! shared/distributed memory setting (mpp_init routine)
87   USE lbcnfd  , ONLY : isendto, nsndto   ! Setup of north fold exchanges
88   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
89#if defined key_iomput
90   USE xios           ! xIOserver
91#endif
92#if defined key_agrif
93   USE agrif_all_update   ! Master Agrif update
94#endif
95   USE halo_mng
96
97   IMPLICIT NONE
98   PRIVATE
99
100   PUBLIC   nemo_gcm    ! called by model.F90
101   PUBLIC   nemo_init   ! needed by AGRIF
102   PUBLIC   nemo_alloc  ! needed by TAM
103
104   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
105
106#if defined key_mpp_mpi
107   ! need MPI_Wtime
108   INCLUDE 'mpif.h'
109#endif
110
111   !!----------------------------------------------------------------------
112   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
113   !! $Id$
114   !! Software governed by the CeCILL license (see ./LICENSE)
115   !!----------------------------------------------------------------------
116CONTAINS
117
118   SUBROUTINE nemo_gcm
119      !!----------------------------------------------------------------------
120      !!                     ***  ROUTINE nemo_gcm  ***
121      !!
122      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
123      !!              curvilinear mesh on the sphere.
124      !!
125      !! ** Method  : - model general initialization
126      !!              - launch the time-stepping (stp routine)
127      !!              - finalize the run by closing files and communications
128      !!
129      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
130      !!              Madec, 2008, internal report, IPSL.
131      !!----------------------------------------------------------------------
132      INTEGER ::   istp   ! time step index
133      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
134      !!----------------------------------------------------------------------
135      !
136#if defined key_agrif
137      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
138#endif
139      !                            !-----------------------!
140      CALL nemo_init               !==  Initialisations  ==!
141      !                            !-----------------------!
142#if defined key_agrif
143      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
144      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
145# if defined key_top
146      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
147# endif
148# if defined key_si3
149      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
150# endif
151#endif
152      ! check that all process are still there... If some process have an error,
153      ! they will never enter in step and other processes will wait until the end of the cpu time!
154      CALL mpp_max( 'nemogcm', nstop )
155
156      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
157
158      !                            !-----------------------!
159      !                            !==   time stepping   ==!
160      !                            !-----------------------!
161      istp = nit000
162      !
163#if defined key_c1d
164      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
165         CALL stp_c1d( istp )
166         istp = istp + 1
167      END DO
168#else
169      !
170# if defined key_agrif
171      !                                               !==  AGRIF time-stepping  ==!
172      CALL Agrif_Regrid()
173      !
174      ! Recursive update from highest nested level to lowest:
175      CALL Agrif_step_child_adj(Agrif_Update_All)
176      !
177      DO WHILE( istp <= nitend .AND. nstop == 0 )
178         CALL stp
179         istp = istp + 1
180      END DO
181      !
182      IF( .NOT. Agrif_Root() ) THEN
183         CALL Agrif_ParentGrid_To_ChildGrid()
184         IF( ln_diaobs )   CALL dia_obs_wri
185         IF( ln_timing )   CALL timing_finalize
186         CALL Agrif_ChildGrid_To_ParentGrid()
187      ENDIF
188      !
189# else
190      !
191      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
192         !
193         DO WHILE( istp <= nitend .AND. nstop == 0 )
194
195            ncom_stp = istp
196            IF( ln_timing ) THEN
197               zstptiming = MPI_Wtime()
198               IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
199               IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
200            ENDIF
201           
202            CALL stp        ( istp ) 
203            istp = istp + 1
204
205            IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
206
207         END DO
208         !
209      ELSE                                            !==  diurnal SST time-steeping only  ==!
210         !
211         DO WHILE( istp <= nitend .AND. nstop == 0 )
212            CALL stp_diurnal( istp )   ! time step only the diurnal SST
213            istp = istp + 1
214         END DO
215         !
216      ENDIF
217      !
218# endif
219      !
220#endif
221      !
222      IF( ln_diaobs   )   CALL dia_obs_wri
223      !
224      IF( ln_icebergs )   CALL icb_end( nitend )
225
226      !                            !------------------------!
227      !                            !==  finalize the run  ==!
228      !                            !------------------------!
229      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
230      !
231      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
232         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
233         CALL ctl_stop( ctmp1 )
234      ENDIF
235      !
236      IF( ln_timing )   CALL timing_finalize
237      !
238      CALL nemo_closefile
239      !
240#if defined key_iomput
241                                    CALL xios_finalize  ! end mpp communications with xios
242      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
243#else
244      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
245      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop      ! end mpp communications
246      ENDIF
247#endif
248      !
249      IF(lwm) THEN
250         IF( nstop == 0 ) THEN   ;   STOP 0
251         ELSE                    ;   STOP 123
252         ENDIF
253      ENDIF
254      !
255   END SUBROUTINE nemo_gcm
256
257
258   SUBROUTINE nemo_init
259      !!----------------------------------------------------------------------
260      !!                     ***  ROUTINE nemo_init  ***
261      !!
262      !! ** Purpose :   initialization of the NEMO GCM
263      !!----------------------------------------------------------------------
264      INTEGER ::   ios, ilocal_comm   ! local integers
265      !!
266      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
267         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
268         &             ln_timing, ln_diacfl
269      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
270      !!----------------------------------------------------------------------
271      !
272      cxios_context = 'nemo'
273      nn_hls = 1
274      !
275      !                             !-------------------------------------------------!
276      !                             !     set communicator & select the local rank    !
277      !                             !  must be done as soon as possible to get narea  !
278      !                             !-------------------------------------------------!
279      !
280#if defined key_iomput
281      IF( Agrif_Root() ) THEN
282         IF( lk_oasis ) THEN
283            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
284            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
285         ELSE
286            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
287         ENDIF
288      ENDIF
289      CALL mpp_start( ilocal_comm )
290#else
291      IF( lk_oasis ) THEN
292         IF( Agrif_Root() ) THEN
293            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
294         ENDIF
295         CALL mpp_start( ilocal_comm )
296      ELSE
297         CALL mpp_start( )
298      ENDIF
299#endif
300      !
301      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
302      lwm = (narea == 1)                ! control of output namelists
303      !
304      !                             !---------------------------------------------------------------!
305      !                             ! Open output files, reference and configuration namelist files !
306      !                             !---------------------------------------------------------------!
307      !
308      ! open ocean.output as soon as possible to get all output prints (including errors messages)
309      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
310      ! open reference and configuration namelist files
311                  CALL ctl_opn( numnam_ref,        'namelist_ref',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
312                  CALL ctl_opn( numnam_cfg,        'namelist_cfg',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
313      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
314      ! open /dev/null file to be able to supress output write easily
315                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
316      !
317      !                             !--------------------!
318      !                             ! Open listing units !  -> need ln_ctl from namctl to define lwp
319      !                             !--------------------!
320      !
321      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
322      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
323901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
324      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
325      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
326902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
327      !
328      lwp = (narea == 1) .OR. ln_ctl    ! control of all listing output print
329      !
330      IF(lwp) THEN                      ! open listing units
331         !
332         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
333            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
334         !
335         WRITE(numout,*)
336         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
337         WRITE(numout,*) '                       NEMO team'
338         WRITE(numout,*) '            Ocean General Circulation Model'
339         WRITE(numout,*) '                NEMO version 4.0  (2019) '
340         WRITE(numout,*)
341         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
342         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
343         WRITE(numout,*)
344         WRITE(numout,*) "           o         _,           _,             "
345         WRITE(numout,*) "            o      .' (        .-' /             "
346         WRITE(numout,*) "           o     _/..._'.    .'   /              "
347         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
348         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
349         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
350         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
351         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
352         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
353         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
354         WRITE(numout,*)
355         !
356         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
357         !
358      ENDIF
359      !
360      ! finalize the definition of namctl variables
361      IF( sn_cfctl%l_config ) THEN
362         ! Activate finer control of report outputs
363         ! optionally switch off output from selected areas (note this only
364         ! applies to output which does not involve global communications)
365         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
366           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
367           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
368      ELSE
369         ! Use ln_ctl to turn on or off all options.
370         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
371      ENDIF
372      !
373      IF(lwm) WRITE( numond, namctl )
374      !
375      !                             !------------------------------------!
376      !                             !  Set global domain size parameters !
377      !                             !------------------------------------!
378      !
379      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
380      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
381903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
382      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
383      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
384904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
385      !
386      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
387         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
388      ELSE                              ! user-defined namelist
389         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
390      ENDIF
391      !
392      IF(lwm)   WRITE( numond, namcfg )
393      !
394      !                             !-----------------------------------------!
395      !                             ! mpp parameters and domain decomposition !
396      !                             !-----------------------------------------!
397      CALL mpp_init
398
399      CALL halo_mng_init()
400      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
401      CALL nemo_alloc()
402
403      !                             !-------------------------------!
404      !                             !  NEMO general initialization  !
405      !                             !-------------------------------!
406
407      CALL nemo_ctl                          ! Control prints
408      !
409      !                                      ! General initialization
410      IF( ln_timing    )   CALL timing_init     ! timing
411      IF( ln_timing    )   CALL timing_start( 'nemo_init')
412      !
413                           CALL     phy_cst         ! Physical constants
414                           CALL     eos_init        ! Equation of state
415      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
416                           CALL     wad_init        ! Wetting and drying options
417                           CALL     dom_init("OPA") ! Domain
418      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
419      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
420     
421      CALL diurnal_sst_bulk_init                ! diurnal sst
422      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
423      !                           
424      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
425         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
426         CALL     sbc_init                            ! Forcings : surface module
427         CALL tra_qsr_init                            ! penetrative solar radiation qsr
428         IF( ln_diaobs ) THEN                         ! Observation & model comparison
429            CALL dia_obs_init                            ! Initialize observational data
430            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
431         ENDIF     
432         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
433         !
434         RETURN                                       ! end of initialization
435      ENDIF
436     
437                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
438
439      !                                      ! external forcing
440                           CALL    tide_init    ! tidal harmonics
441                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
442                           CALL     bdy_init    ! Open boundaries initialisation
443
444      !                                      ! Ocean physics
445                           CALL zdf_phy_init    ! Vertical physics
446                                     
447      !                                         ! Lateral physics
448                           CALL ldf_tra_init      ! Lateral ocean tracer physics
449                           CALL ldf_eiv_init      ! eddy induced velocity param.
450                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
451
452      !                                      ! Active tracers
453      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
454                           CALL tra_bbc_init      ! bottom heat flux
455                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
456                           CALL tra_dmp_init      ! internal tracer damping
457                           CALL tra_adv_init      ! horizontal & vertical advection
458                           CALL tra_ldf_init      ! lateral mixing
459
460      !                                      ! Dynamics
461      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
462                           CALL dyn_adv_init      ! advection (vector or flux form)
463                           CALL dyn_vor_init      ! vorticity term including Coriolis
464                           CALL dyn_ldf_init      ! lateral mixing
465                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
466                           CALL dyn_spg_init      ! surface pressure gradient
467
468#if defined key_top
469      !                                      ! Passive tracers
470                           CALL     trc_init
471#endif
472      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
473
474      !                                      ! Icebergs
475                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
476
477      !                                      ! Misc. options
478                           CALL sto_par_init    ! Stochastic parametrization
479      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
480     
481      !                                      ! Diagnostics
482                           CALL     flo_init    ! drifting Floats
483      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
484                           CALL dia_ptr_init    ! Poleward TRansports initialization
485                           CALL dia_dct_init    ! Sections tranports
486                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
487                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
488                           CALL dia_obs_init    ! Initialize observational data
489                           CALL dia_tmb_init    ! TMB outputs
490                           CALL dia_25h_init    ! 25h mean  outputs
491                           CALL dia_harm_init   ! tidal harmonics outputs
492     IF( ln_diaobs    )    CALL dia_obs( nit000-1 )   ! Observation operator for restart
493
494      !                                      ! Assimilation increments
495      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
496      !
497      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
498      !
499      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
500      !
501   END SUBROUTINE nemo_init
502
503
504   SUBROUTINE nemo_ctl
505      !!----------------------------------------------------------------------
506      !!                     ***  ROUTINE nemo_ctl  ***
507      !!
508      !! ** Purpose :   control print setting
509      !!
510      !! ** Method  : - print namctl and namcfg information and check some consistencies
511      !!----------------------------------------------------------------------
512      !
513      IF(lwp) THEN                  ! control print
514         WRITE(numout,*)
515         WRITE(numout,*) 'nemo_ctl: Control prints'
516         WRITE(numout,*) '~~~~~~~~'
517         WRITE(numout,*) '   Namelist namctl'
518         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
519         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
520         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
521         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
522         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
523         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
524         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
525         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
526         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
527         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
528         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
529         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
530         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
531         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
532         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
533         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
534         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
535         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
536         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
537         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
538         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
539      ENDIF
540      !
541      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
542      nictls    = nn_ictls
543      nictle    = nn_ictle
544      njctls    = nn_jctls
545      njctle    = nn_jctle
546      isplt     = nn_isplt
547      jsplt     = nn_jsplt
548
549      IF(lwp) THEN                  ! control print
550         WRITE(numout,*)
551         WRITE(numout,*) '   Namelist namcfg'
552         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
553         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
554         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
555         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
556         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
557         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
558      ENDIF
559      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
560      !
561      !                             ! Parameter control
562      !
563      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
564         IF( lk_mpp .AND. jpnij > 1 ) THEN
565            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
566         ELSE
567            IF( isplt == 1 .AND. jsplt == 1  ) THEN
568               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
569                  &           ' - the print control will be done over the whole domain' )
570            ENDIF
571            ijsplt = isplt * jsplt            ! total number of processors ijsplt
572         ENDIF
573         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
574         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
575         !
576         !                              ! indices used for the SUM control
577         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
578            lsp_area = .FALSE.
579         ELSE                                             ! print control done over a specific  area
580            lsp_area = .TRUE.
581            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
582               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
583               nictls = 1
584            ENDIF
585            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
586               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
587               nictle = jpiglo
588            ENDIF
589            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
590               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
591               njctls = 1
592            ENDIF
593            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
594               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
595               njctle = jpjglo
596            ENDIF
597         ENDIF
598      ENDIF
599      !
600      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
601         &                                                'Compile with key_nosignedzero enabled:',   &
602         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
603      !
604#if defined key_agrif
605      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
606#endif
607      !
608   END SUBROUTINE nemo_ctl
609
610
611   SUBROUTINE nemo_closefile
612      !!----------------------------------------------------------------------
613      !!                     ***  ROUTINE nemo_closefile  ***
614      !!
615      !! ** Purpose :   Close the files
616      !!----------------------------------------------------------------------
617      !
618      IF( lk_mpp )   CALL mppsync
619      !
620      CALL iom_close                                 ! close all input/output files managed by iom_*
621      !
622      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
623      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
624      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
625      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
626      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
627      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
628      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
629      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
630      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
631      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
632      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
633      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
634      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
635      !
636      numout = 6                                     ! redefine numout in case it is used after this point...
637      !
638   END SUBROUTINE nemo_closefile
639
640
641   SUBROUTINE nemo_alloc
642      !!----------------------------------------------------------------------
643      !!                     ***  ROUTINE nemo_alloc  ***
644      !!
645      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
646      !!
647      !! ** Method  :
648      !!----------------------------------------------------------------------
649      USE diawri    , ONLY : dia_wri_alloc
650      USE dom_oce   , ONLY : dom_oce_alloc
651      USE trc_oce   , ONLY : trc_oce_alloc
652      USE bdy_oce   , ONLY : bdy_oce_alloc
653      !
654      INTEGER :: ierr
655      !!----------------------------------------------------------------------
656      !
657      ierr =        oce_alloc    ()    ! ocean
658      ierr = ierr + dia_wri_alloc()
659      ierr = ierr + dom_oce_alloc()    ! ocean domain
660      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
661      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
662      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
663      !
664      CALL mpp_sum( 'nemogcm', ierr )
665      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
666      !
667   END SUBROUTINE nemo_alloc
668
669   
670   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
671      !!----------------------------------------------------------------------
672      !!                     ***  ROUTINE nemo_set_cfctl  ***
673      !!
674      !! ** Purpose :   Set elements of the output control structure to setto.
675      !!                for_all should be .false. unless all areas are to be
676      !!                treated identically.
677      !!
678      !! ** Method  :   Note this routine can be used to switch on/off some
679      !!                types of output for selected areas but any output types
680      !!                that involve global communications (e.g. mpp_max, glob_sum)
681      !!                should be protected from selective switching by the
682      !!                for_all argument
683      !!----------------------------------------------------------------------
684      LOGICAL :: setto, for_all
685      TYPE(sn_ctl) :: sn_cfctl
686      !!----------------------------------------------------------------------
687      IF( for_all ) THEN
688         sn_cfctl%l_runstat = setto
689         sn_cfctl%l_trcstat = setto
690      ENDIF
691      sn_cfctl%l_oceout  = setto
692      sn_cfctl%l_layout  = setto
693      sn_cfctl%l_mppout  = setto
694      sn_cfctl%l_mpptop  = setto
695   END SUBROUTINE nemo_set_cfctl
696
697   !!======================================================================
698END MODULE nemogcm
699
Note: See TracBrowser for help on using the repository browser.