New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in NEMO/branches/2019/dev_r11514_HPC-02_single-core-extrahalo/src/OFF – NEMO

Context Navigation

source: NEMO/branches/2019/dev_r11514_HPC-02_single-core-extrahalo/src/OFF/nemogcm.F90 @ 13658

Last change on this file since 13658 was 11719, checked in by francesca, 5 years ago
add extra halo support- ticket #2009
Property svn:keywords set to `Id`
File size: 28.4 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Off-line Ocean : passive tracer evolution, dynamics read in files
5	!!======================================================================
6	!! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line
7	!! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8	!! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface
9	!!----------------------------------------------------------------------
10
11	!!----------------------------------------------------------------------
12	!! nemo_gcm : off-line: solve ocean tracer only
13	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14	!! nemo_init : initialization of the NEMO system
15	!! nemo_ctl : initialisation of the contol print
16	!! nemo_closefile: close remaining open files
17	!! nemo_alloc : dynamical allocation
18	!! istate_init : simple initialization to zero of ocean fields
19	!! stp_ctl : reduced step control (no dynamics in off-line)
20	!!----------------------------------------------------------------------
21	USE dom_oce ! ocean space domain variables
22	USE oce ! dynamics and tracers variables
23	USE trc_oce ! Shared ocean/passive tracers variables
24	USE c1d ! 1D configuration
25	USE domain ! domain initialization from coordinate & bathymetry (dom_init routine)
26	USE closea ! treatment of closed seas (for ln_closea)
27	USE usrdef_nam ! user defined configuration
28	USE eosbn2 ! equation of state (eos bn2 routine)
29	! ! ocean physics
30	USE ldftra ! lateral diffusivity setting (ldf_tra_init routine)
31	USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine)
32	USE traqsr ! solar radiation penetration (tra_qsr_init routine)
33	USE trabbl ! bottom boundary layer (tra_bbl_init routine)
34	USE traldf ! lateral physics (tra_ldf_init routine)
35	USE sbcmod ! surface boundary condition (sbc_init routine)
36	USE phycst ! physical constant (par_cst routine)
37	USE dtadyn ! Lecture and Interpolation of the dynamical fields
38	USE trcini ! Initilization of the passive tracers
39	USE daymod ! calendar (day routine)
40	USE trcstp ! passive tracer time-stepping (trc_stp routine)
41	USE dtadyn ! Lecture and interpolation of the dynamical fields
42	! ! Passive tracers needs
43	USE trc ! passive tracer : variables
44	USE trcnam ! passive tracer : namelist
45	USE trcrst ! passive tracer restart
46	USE diaptr ! Need to initialise this as some variables are used in if statements later
47	USE sbc_oce , ONLY : ln_rnf
48	USE sbcrnf ! surface boundary condition : runoffs
49	! ! I/O & MPP
50	USE iom ! I/O library
51	USE in_out_manager ! I/O manager
52	USE mppini ! shared/distributed memory setting (mpp_init routine)
53	USE lib_mpp ! distributed memory computing
54	#if defined key_iomput
55	USE xios ! xIOserver
56	#endif
57	USE prtctl ! Print control (prt_ctl_init routine)
58	USE timing ! Timing
59	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
60	USE lbcnfd , ONLY : isendto, nsndto ! Setup of north fold exchanges
61	USE halo_mng
62
63	IMPLICIT NONE
64	PRIVATE
65
66	PUBLIC nemo_gcm ! called by nemo.F90
67
68	CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
69
70	!!----------------------------------------------------------------------
71	!! NEMO/OFF 4.0 , NEMO Consortium (2018)
72	!! $Id$
73	!! Software governed by the CeCILL license (see ./LICENSE)
74	!!----------------------------------------------------------------------
75	CONTAINS
76
77	SUBROUTINE nemo_gcm
78	!!----------------------------------------------------------------------
79	!! * ROUTINE nemo_gcm *
80	!!
81	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
82	!! curvilinear mesh on the sphere.
83	!!
84	!! ** Method : - model general initialization
85	!! - launch the time-stepping (dta_dyn and trc_stp)
86	!! - finalize the run by closing files and communications
87	!!
88	!! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL.
89	!! Madec, 2008, internal report, IPSL.
90	!!----------------------------------------------------------------------
91	INTEGER :: istp, indic ! time step index
92	!!----------------------------------------------------------------------
93
94	CALL nemo_init ! Initializations
95
96	! check that all process are still there... If some process have an error,
97	! they will never enter in step and other processes will wait until the end of the cpu time!
98	CALL mpp_max( 'nemogcm', nstop )
99
100	! !-----------------------!
101	! !== time stepping ==!
102	! !-----------------------!
103	istp = nit000
104	!
105	IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization
106	!
107	CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
108	!
109	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==!
110	!
111	IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init)
112	CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp
113	#if defined key_sed_off
114	CALL dta_dyn_sed( istp ) ! Interpolation of the dynamical fields
115	#else
116	CALL dta_dyn ( istp ) ! Interpolation of the dynamical fields
117	IF( .NOT.ln_linssh ) CALL dta_dyn_swp( istp ) ! swap of sea surface height and vertical scale factors
118	#endif
119	CALL trc_stp ( istp ) ! time-stepping
120	CALL stp_ctl ( istp, indic ) ! Time loop: control and print
121	istp = istp + 1
122	END DO
123	!
124	#if defined key_iomput
125	CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
126	#endif
127
128	! !------------------------!
129	! !== finalize the run ==!
130	! !------------------------!
131	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
132
133	IF( nstop /= 0 .AND. lwp ) THEN ! error print
134	WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
135	CALL ctl_stop( ctmp1 )
136	ENDIF
137	!
138	IF( ln_timing ) CALL timing_finalize
139	!
140	CALL nemo_closefile
141	!
142	#if defined key_iomput
143	CALL xios_finalize ! end mpp communications with xios
144	#else
145	IF( lk_mpp ) CALL mppstop ! end mpp communications
146	#endif
147	!
148	IF(lwm) THEN
149	IF( nstop == 0 ) THEN ; STOP 0
150	ELSE ; STOP 123
151	ENDIF
152	ENDIF
153	!
154	END SUBROUTINE nemo_gcm
155
156
157	SUBROUTINE nemo_init
158	!!----------------------------------------------------------------------
159	!! * ROUTINE nemo_init *
160	!!
161	!! ** Purpose : initialization of the nemo model in off-line mode
162	!!----------------------------------------------------------------------
163	INTEGER :: ios, ilocal_comm ! local integers
164	!!
165	NAMELIST/namctl/ ln_ctl , sn_cfctl, nn_print, nn_ictls, nn_ictle, &
166	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
167	& ln_timing, ln_diacfl
168	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
169	!!----------------------------------------------------------------------
170	!
171	cxios_context = 'nemo'
172	nn_hls = 1
173	!
174	! !-------------------------------------------------!
175	! ! set communicator & select the local rank !
176	! ! must be done as soon as possible to get narea !
177	! !-------------------------------------------------!
178	!
179	#if defined key_iomput
180	CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios
181	CALL mpp_start( ilocal_comm )
182	#else
183	CALL mpp_start( )
184	#endif
185	!
186	narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 )
187	lwm = (narea == 1) ! control of output namelists
188	!
189	! !---------------------------------------------------------------!
190	! ! Open output files, reference and configuration namelist files !
191	! !---------------------------------------------------------------!
192	!
193	! open ocean.output as soon as possible to get all output prints (including errors messages)
194	IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
195	! open reference and configuration namelist files
196	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
197	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
198	IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
199	! open /dev/null file to be able to supress output write easily
200	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
201	!
202	! !--------------------!
203	! ! Open listing units ! -> need ln_ctl from namctl to define lwp
204	! !--------------------!
205	!
206	REWIND( numnam_ref ) ! Namelist namctl in reference namelist
207	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
208	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' )
209	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
210	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
211	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' )
212	!
213	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
214	!
215	IF(lwp) THEN ! open listing units
216	!
217	IF( .NOT. lwm ) & ! alreay opened for narea == 1
218	& CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
219	!
220	WRITE(numout,*)
221	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
222	WRITE(numout,*) ' NEMO team'
223	WRITE(numout,*) ' Off-line TOP Model'
224	WRITE(numout,*) ' NEMO version 4.0 (2019) '
225	WRITE(numout,*)
226	WRITE(numout,*) " ._ ._ ._ ._ ._ "
227	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
228	WRITE(numout,*)
229	WRITE(numout,*) " o _, _, "
230	WRITE(numout,*) " o .' ( .-' / "
231	WRITE(numout,*) " o _/..._'. .' / "
232	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
233	WRITE(numout,*) " ) ( o) ;= <_ ( "
234	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
235	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
236	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
237	WRITE(numout,*) " ) ) ` ( ( "
238	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
239	WRITE(numout,*)
240	!
241	WRITE(numout,cform_aaa) ! Flag AAAAAAA
242	!
243	ENDIF
244	!
245	! finalize the definition of namctl variables
246	IF( sn_cfctl%l_config ) THEN
247	! Activate finer control of report outputs
248	! optionally switch off output from selected areas (note this only
249	! applies to output which does not involve global communications)
250	IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax ) .OR. &
251	& ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) ) &
252	& CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
253	ELSE
254	! Use ln_ctl to turn on or off all options.
255	CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
256	ENDIF
257	!
258	IF(lwm) WRITE( numond, namctl )
259	!
260	! !------------------------------------!
261	! ! Set global domain size parameters !
262	! !------------------------------------!
263	!
264	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist
265	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
266	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' )
267	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist
268	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
269	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' )
270	!
271	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
272	CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
273	ELSE ! user-defined namelist
274	CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
275	ENDIF
276	!
277	IF(lwm) WRITE( numond, namcfg )
278	l_offline = .true. ! passive tracers are run offline
279	!
280	! !-----------------------------------------!
281	! ! mpp parameters and domain decomposition !
282	! !-----------------------------------------!
283	!
284	CALL mpp_init
285
286	CALL halo_mng_init()
287	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
288	CALL nemo_alloc()
289
290	! !-------------------------------!
291	! ! NEMO general initialization !
292	! !-------------------------------!
293
294	CALL nemo_ctl ! Control prints
295	!
296	! ! General initialization
297	IF( ln_timing ) CALL timing_init
298	IF( ln_timing ) CALL timing_start( 'nemo_init')
299	!
300	CALL phy_cst ! Physical constants
301	CALL eos_init ! Equation of state
302	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
303	CALL dom_init("OPA") ! Domain
304	IF( ln_ctl ) CALL prt_ctl_init ! Print control
305
306	CALL istate_init ! ocean initial state (Dynamics and tracers)
307
308	CALL sbc_init ! Forcings : surface module
309
310	! ! Tracer physics
311	CALL ldf_tra_init ! Lateral ocean tracer physics
312	CALL ldf_eiv_init ! Eddy induced velocity param
313	CALL tra_ldf_init ! lateral mixing
314	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
315	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation
316	IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
317
318	! ! Passive tracers
319	CALL trc_nam_run ! Needed to get restart parameters for passive tracers
320	CALL trc_rst_cal( nit000, 'READ' ) ! calendar
321	#if defined key_sed_off
322	CALL dta_dyn_sed_init ! Initialization for the dynamics
323	#else
324	CALL dta_dyn_init ! Initialization for the dynamics
325	#endif
326
327	CALL trc_init ! Passive tracers initialization
328	CALL dia_ptr_init ! Poleward TRansports initialization
329
330	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
331	!
332	IF( ln_timing ) CALL timing_stop( 'nemo_init')
333	!
334	END SUBROUTINE nemo_init
335
336
337	SUBROUTINE nemo_ctl
338	!!----------------------------------------------------------------------
339	!! * ROUTINE nemo_ctl *
340	!!
341	!! ** Purpose : control print setting
342	!!
343	!! ** Method : - print namctl information and check some consistencies
344	!!----------------------------------------------------------------------
345	!
346	IF(lwp) THEN ! control print
347	WRITE(numout,*)
348	WRITE(numout,*) 'nemo_ctl: Control prints'
349	WRITE(numout,*) '~~~~~~~~'
350	WRITE(numout,*) ' Namelist namctl'
351	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
352	WRITE(numout,*) ' finer control over o/p sn_cfctl%l_config = ', sn_cfctl%l_config
353	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
354	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
355	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
356	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
357	WRITE(numout,*) ' sn_cfctl%l_mppout = ', sn_cfctl%l_mppout
358	WRITE(numout,*) ' sn_cfctl%l_mpptop = ', sn_cfctl%l_mpptop
359	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
360	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
361	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
362	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
363	WRITE(numout,*) ' level of print nn_print = ', nn_print
364	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
365	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
366	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
367	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
368	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
369	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
370	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
371	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
372	ENDIF
373	!
374	nprint = nn_print ! convert DOCTOR namelist names into OLD names
375	nictls = nn_ictls
376	nictle = nn_ictle
377	njctls = nn_jctls
378	njctle = nn_jctle
379	isplt = nn_isplt
380	jsplt = nn_jsplt
381
382	IF(lwp) THEN ! control print
383	WRITE(numout,*)
384	WRITE(numout,*) ' Namelist namcfg'
385	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
386	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
387	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
388	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
389	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
390	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
391	ENDIF
392	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
393	!
394	! ! Parameter control
395	!
396	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
397	IF( lk_mpp .AND. jpnij > 1 ) THEN
398	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
399	ELSE
400	IF( isplt == 1 .AND. jsplt == 1 ) THEN
401	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
402	& ' - the print control will be done over the whole domain' )
403	ENDIF
404	ijsplt = isplt * jsplt ! total number of processors ijsplt
405	ENDIF
406	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
407	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
408	!
409	! ! indices used for the SUM control
410	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
411	lsp_area = .FALSE.
412	ELSE ! print control done over a specific area
413	lsp_area = .TRUE.
414	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
415	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
416	nictls = 1
417	ENDIF
418	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
419	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
420	nictle = jpiglo
421	ENDIF
422	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
423	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
424	njctls = 1
425	ENDIF
426	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
427	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
428	njctle = jpjglo
429	ENDIF
430	ENDIF
431	ENDIF
432	!
433	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
434	& 'Compile with key_nosignedzero enabled' )
435	!
436	END SUBROUTINE nemo_ctl
437
438
439	SUBROUTINE nemo_closefile
440	!!----------------------------------------------------------------------
441	!! * ROUTINE nemo_closefile *
442	!!
443	!! ** Purpose : Close the files
444	!!----------------------------------------------------------------------
445	!
446	IF( lk_mpp ) CALL mppsync
447	!
448	CALL iom_close ! close all input/output files managed by iom_*
449	!
450	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
451	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
452	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
453	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
454	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
455	!
456	numout = 6 ! redefine numout in case it is used after this point...
457	!
458	END SUBROUTINE nemo_closefile
459
460
461	SUBROUTINE nemo_alloc
462	!!----------------------------------------------------------------------
463	!! * ROUTINE nemo_alloc *
464	!!
465	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
466	!!
467	!! ** Method :
468	!!----------------------------------------------------------------------
469	USE diawri , ONLY : dia_wri_alloc
470	USE dom_oce, ONLY : dom_oce_alloc
471	USE zdf_oce, ONLY : zdf_oce_alloc
472	USE trc_oce, ONLY : trc_oce_alloc
473	!
474	INTEGER :: ierr
475	!!----------------------------------------------------------------------
476	!
477	ierr = oce_alloc () ! ocean
478	ierr = ierr + dia_wri_alloc()
479	ierr = ierr + dom_oce_alloc() ! ocean domain
480	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
481	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
482	!
483	CALL mpp_sum( 'nemogcm', ierr )
484	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
485	!
486	END SUBROUTINE nemo_alloc
487
488	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
489	!!----------------------------------------------------------------------
490	!! * ROUTINE nemo_set_cfctl *
491	!!
492	!! ** Purpose : Set elements of the output control structure to setto.
493	!! for_all should be .false. unless all areas are to be
494	!! treated identically.
495	!!
496	!! ** Method : Note this routine can be used to switch on/off some
497	!! types of output for selected areas but any output types
498	!! that involve global communications (e.g. mpp_max, glob_sum)
499	!! should be protected from selective switching by the
500	!! for_all argument
501	!!----------------------------------------------------------------------
502	LOGICAL :: setto, for_all
503	TYPE(sn_ctl) :: sn_cfctl
504	!!----------------------------------------------------------------------
505	IF( for_all ) THEN
506	sn_cfctl%l_runstat = setto
507	sn_cfctl%l_trcstat = setto
508	ENDIF
509	sn_cfctl%l_oceout = setto
510	sn_cfctl%l_layout = setto
511	sn_cfctl%l_mppout = setto
512	sn_cfctl%l_mpptop = setto
513	END SUBROUTINE nemo_set_cfctl
514
515	SUBROUTINE istate_init
516	!!----------------------------------------------------------------------
517	!! * ROUTINE istate_init *
518	!!
519	!! ** Purpose : Initialization to zero of the dynamics and tracers.
520	!!----------------------------------------------------------------------
521	!
522	! now fields ! after fields !
523	un (:,:,:) = 0._wp ; ua(:,:,:) = 0._wp !
524	vn (:,:,:) = 0._wp ; va(:,:,:) = 0._wp !
525	wn (:,:,:) = 0._wp ! !
526	hdivn(:,:,:) = 0._wp ! !
527	tsn (:,:,:,:) = 0._wp ! !
528	!
529	rhd (:,:,:) = 0.e0
530	rhop (:,:,:) = 0.e0
531	rn2 (:,:,:) = 0.e0
532	!
533	END SUBROUTINE istate_init
534
535
536	SUBROUTINE stp_ctl( kt, kindic )
537	!!----------------------------------------------------------------------
538	!! * ROUTINE stp_ctl *
539	!!
540	!! ** Purpose : Control the run
541	!!
542	!! ** Method : - Save the time step in numstp
543	!!
544	!! ** Actions : 'time.step' file containing the last ocean time-step
545	!!----------------------------------------------------------------------
546	INTEGER, INTENT(in ) :: kt ! ocean time-step index
547	INTEGER, INTENT(inout) :: kindic ! indicator of solver convergence
548	!!----------------------------------------------------------------------
549	!
550	IF( kt == nit000 .AND. lwm ) THEN
551	WRITE(numout,*)
552	WRITE(numout,*) 'stp_ctl : time-stepping control'
553	WRITE(numout,*) '~~~~~~~'
554	! open time.step file
555	CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
556	ENDIF
557	!
558	IF(lwm) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp
559	IF(lwm) REWIND( numstp ) ! --------------------------
560	!
561	END SUBROUTINE stp_ctl
562	!!======================================================================
563	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: