New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlim.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p4zlim.F90 @ 13233

Last change on this file since 13233 was 13233, checked in by aumont, 4 years ago

update of the PISCES comments
File size: 21.8 KB
Line 
1MODULE p4zlim
2   !!======================================================================
3   !!                         ***  MODULE p4zlim  ***
4   !! TOP :   Computes the nutrient limitation terms of phytoplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-04  (O. Aumont, C. Ethe) Limitation for iron modelled in quota
9   !!----------------------------------------------------------------------
10   !!   p4z_lim        :   Compute the nutrients limitation terms
11   !!   p4z_lim_init   :   Read the namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! Shared ocean-passive tracers variables
14   USE trc             ! Tracers defined
15   USE sms_pisces      ! PISCES variables
16   USE iom             ! I/O manager
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC p4z_lim           ! called in p4zbio.F90
22   PUBLIC p4z_lim_init      ! called in trcsms_pisces.F90
23   PUBLIC p4z_lim_alloc     ! called in trcini_pisces.F90
24
25   !! * Shared module variables
26   REAL(wp), PUBLIC ::  concnno3    !:  NO3, PO4 half saturation   
27   REAL(wp), PUBLIC ::  concdno3    !:  Phosphate half saturation for diatoms 
28   REAL(wp), PUBLIC ::  concnnh4    !:  NH4 half saturation for nanophyto 
29   REAL(wp), PUBLIC ::  concdnh4    !:  NH4 half saturation for diatoms
30   REAL(wp), PUBLIC ::  concnfer    !:  Iron half saturation for nanophyto
31   REAL(wp), PUBLIC ::  concdfer    !:  Iron half saturation for diatoms 
32   REAL(wp), PUBLIC ::  concbno3    !:  NO3 half saturation  for bacteria
33   REAL(wp), PUBLIC ::  concbnh4    !:  NH4 half saturation for bacteria
34   REAL(wp), PUBLIC ::  xsizedia    !:  Minimum size criteria for diatoms
35   REAL(wp), PUBLIC ::  xsizephy    !:  Minimum size criteria for nanophyto
36   REAL(wp), PUBLIC ::  xsizern     !:  Size ratio for nanophytoplankton
37   REAL(wp), PUBLIC ::  xsizerd     !:  Size ratio for diatoms
38   REAL(wp), PUBLIC ::  xksi1       !:  half saturation constant for Si uptake
39   REAL(wp), PUBLIC ::  xksi2       !:  half saturation constant for Si/C
40   REAL(wp), PUBLIC ::  xkdoc       !:  2nd half-sat. of DOC remineralization 
41   REAL(wp), PUBLIC ::  concbfe     !:  Fe half saturation for bacteria
42   REAL(wp), PUBLIC ::  oxymin      !:  half saturation constant for anoxia
43   REAL(wp), PUBLIC ::  qnfelim     !:  optimal Fe quota for nanophyto
44   REAL(wp), PUBLIC ::  qdfelim     !:  optimal Fe quota for diatoms
45   REAL(wp), PUBLIC ::  caco3r      !:  mean rainratio
46
47   !!* Phytoplankton limitation terms
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanono3   !: Nanophyto limitation by NO3
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatno3   !: Diatoms limitation by NO3
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanonh4   !: Nanophyto limitation by NH4
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatnh4   !:  Diatoms limitation by NH4
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanopo4   !: Nanophyto limitation by PO4
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatpo4   !: Diatoms limitation by PO4
54   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimphy    !: Nutrient limitation term of nanophytoplankton
55   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimdia    !: Nutrient limitation term of diatoms
56   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimnfe    !: Nanophyto limitation by Iron
57   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimdfe    !: Diatoms limitation by iron
58   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimsi     !: Diatoms limitation by Si
59   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimbac    !: Bacterial limitation term
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimbacl   !: Bacterial limitation term
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   concdfe    !: Limitation of diatoms uptake of Fe
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   concnfe    !: Limitation of Nano uptake of Fe
63   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanofer   !: Limitation of Fe uptake by nanophyto
64   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatfer   !: Limitation of Fe uptake by diatoms
65
66   ! Coefficient for iron limitation following Flynn and Hipkin (1999)
67   REAL(wp) ::  xcoef1   = 0.0016  / 55.85 
68   REAL(wp) ::  xcoef2   = 1.21E-5 * 14. / 55.85 / 7.625 * 0.5 * 1.5
69   REAL(wp) ::  xcoef3   = 1.15E-4 * 14. / 55.85 / 7.625 * 0.5 
70
71   !!----------------------------------------------------------------------
72   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
73   !! $Id: p4zlim.F90 10069 2018-08-28 14:12:24Z nicolasmartin $
74   !! Software governed by the CeCILL license (see ./LICENSE)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   SUBROUTINE p4z_lim( kt, knt )
79      !!---------------------------------------------------------------------
80      !!                     ***  ROUTINE p4z_lim  ***
81      !!
82      !! ** Purpose :   Compute the co-limitations by the various nutrients
83      !!                for the various phytoplankton species
84      !!
85      !! ** Method  : - Limitation follows the Liebieg law of the minimum
86      !!              - Monod approach for N, P and Si. Quota approach
87      !!                for Iron
88      !!---------------------------------------------------------------------
89      INTEGER, INTENT(in)  :: kt, knt
90      !
91      INTEGER  ::   ji, jj, jk
92      REAL(wp) ::   zlim1, zlim2, zlim3, zlim4, zno3, zferlim, zcoef
93      REAL(wp) ::   z1_trbdia, z1_trbphy, ztem1, ztem2, zetot1, zetot2
94      REAL(wp) ::   zdenom, zratio, zironmin
95      REAL(wp) ::   zconc1d, zconc1dnh4, zconc0n, zconc0nnh4   
96      REAL(wp) ::   fananof, fadiatf, znutlim, zfalim
97      !!---------------------------------------------------------------------
98      !
99      IF( ln_timing )   CALL timing_start('p4z_lim')
100      !
101      sizena(:,:,:) = 0.0  ;  sizeda(:,:,:) = 0.0
102      !
103      DO jk = 1, jpkm1
104         DO jj = 1, jpj
105            DO ji = 1, jpi
106               
107               ! Tuning of the iron concentration to a minimum level that
108               ! is set to the detection limit
109               ! --------------------------------------------------------
110               zno3    = trb(ji,jj,jk,jpno3) / 40.e-6
111               zferlim = MAX( 3e-11 * zno3 * zno3, 5e-12 )
112               zferlim = MIN( zferlim, 7e-11 )
113               trb(ji,jj,jk,jpfer) = MAX( trb(ji,jj,jk,jpfer), zferlim )
114
115               ! Computation of a variable Ks of diatoms taking into account
116               ! that increasing biomass is made of generally bigger cells
117               ! The allometric relationship is classical.
118               !------------------------------------------------------------
119               z1_trbphy   = 1. / ( trb(ji,jj,jk,jpphy) + rtrn )
120               z1_trbdia   = 1. / ( trb(ji,jj,jk,jpdia) + rtrn )
121
122               concnfe(ji,jj,jk) = concnfer * sizen(ji,jj,jk)**0.81
123               zconc0n           = concnno3 * sizen(ji,jj,jk)**0.81
124               zconc0nnh4        = concnnh4 * sizen(ji,jj,jk)**0.81
125
126               concdfe(ji,jj,jk) = concdfer * sized(ji,jj,jk)**0.81 
127               zconc1d           = concdno3 * sized(ji,jj,jk)**0.81 
128               zconc1dnh4        = concdnh4 * sized(ji,jj,jk)**0.81 
129
130               ! Computation of the optimal allocation parameters
131               ! Based on the different papers by Pahlow et al., and
132               ! Smith et al.
133               ! ---------------------------------------------------
134
135               ! Nanophytoplankton
136               znutlim = biron(ji,jj,jk) / concnfe(ji,jj,jk)
137               fananof = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
138
139               ! Diatoms
140               znutlim = biron(ji,jj,jk) / concdfe(ji,jj,jk)
141               fadiatf = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
142
143               ! Michaelis-Menten Limitation term by nutrients of
144               ! heterotrophic bacteria
145               ! -------------------------------------------------
146               zdenom = 1. /  ( concbno3 * concbnh4 + concbnh4 * trb(ji,jj,jk,jpno3) + concbno3 * trb(ji,jj,jk,jpnh4) )
147               xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * concbnh4 * zdenom
148               xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * concbno3 * zdenom
149               !
150               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
151               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concbnh4 )
152               zlim3    = trb(ji,jj,jk,jpfer) / ( concbfe + trb(ji,jj,jk,jpfer) )
153               zlim4    = trb(ji,jj,jk,jpdoc) / ( xkdoc   + trb(ji,jj,jk,jpdoc) )
154               ! Xlimbac is used for DOC solubilization whereas xlimbacl
155               ! is used for all the other bacterial-dependent terms
156               ! -------------------------------------------------------
157               xlimbacl(ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
158               xlimbac (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 ) * zlim4
159
160               ! Michaelis-Menten Limitation term by nutrients: Nanophyto
161               ! Optimal parameterization by Smith and Pahlow series of
162               ! papers is used. Optimal allocation is supposed independant
163               ! for all nutrients.
164               ! --------------------------------------------------------
165
166               ! Limitation of Fe uptake (Quota formalism)
167               zfalim = (1.-fananof) / fananof
168               xnanofer(ji,jj,jk) = (1. - fananof) * biron(ji,jj,jk) / ( biron(ji,jj,jk) + zfalim * concnfe(ji,jj,jk) )
169
170               ! Limitation of nanophytoplankton growth
171               zdenom = 1. /  ( zconc0n * zconc0nnh4 + zconc0nnh4 * trb(ji,jj,jk,jpno3) + zconc0n * trb(ji,jj,jk,jpnh4) )
172               xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc0nnh4 * zdenom
173               xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc0n    * zdenom
174               !
175               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
176               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc0nnh4 )
177               zratio   = trb(ji,jj,jk,jpnfe) * z1_trbphy 
178
179               ! The minimum iron quota depends on the size of PSU, respiration
180               ! and the reduction of nitrate following the parameterization
181               ! proposed by Flynn and Hipkin (1999)
182               zironmin = xcoef1 * trb(ji,jj,jk,jpnch) * z1_trbphy + xcoef2 * zlim1 + xcoef3 * xnanono3(ji,jj,jk)
183               zlim3    = MAX( 0.,( zratio - zironmin ) / qnfelim )
184               xnanopo4(ji,jj,jk) = zlim2
185               xlimnfe (ji,jj,jk) = MIN( 1., zlim3 )
186               xlimphy (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
187               
188               !   Michaelis-Menten Limitation term by nutrients : Diatoms
189               !   -------------------------------------------------------
190               ! Limitation of Fe uptake (Quota formalism)
191               zfalim = (1.-fadiatf) / fadiatf
192               xdiatfer(ji,jj,jk) = (1. - fadiatf) * biron(ji,jj,jk) / ( biron(ji,jj,jk) + zfalim * concdfe(ji,jj,jk) )
193
194               ! Limitation of diatoms growth
195               zdenom   = 1. / ( zconc1d * zconc1dnh4 + zconc1dnh4 * trb(ji,jj,jk,jpno3) + zconc1d * trb(ji,jj,jk,jpnh4) )
196               xdiatno3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc1dnh4 * zdenom
197               xdiatnh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc1d    * zdenom
198               !
199               zlim1    = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk)
200               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc1dnh4  )
201               zlim3    = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi(ji,jj) )
202               zratio   = trb(ji,jj,jk,jpdfe) * z1_trbdia
203
204               ! The minimum iron quota depends on the size of PSU, respiration
205               ! and the reduction of nitrate following the parameterization
206               ! proposed by Flynn and Hipkin (1999)
207               zironmin = xcoef1 * trb(ji,jj,jk,jpdch) * z1_trbdia + xcoef2 * zlim1 + xcoef3 * xdiatno3(ji,jj,jk)
208               zlim4    = MAX( 0., ( zratio - zironmin ) / qdfelim )
209               xdiatpo4(ji,jj,jk) = zlim2
210               xlimdfe (ji,jj,jk) = MIN( 1., zlim4 )
211               xlimdia (ji,jj,jk) = MIN( zlim1, zlim2, zlim3, zlim4 )
212               xlimsi  (ji,jj,jk) = MIN( zlim1, zlim2, zlim4 )
213           END DO
214         END DO
215      END DO
216
217      ! Size estimation of phytoplankton based on total biomass
218      ! Assumes that larger biomass implies addition of larger cells
219      ! ------------------------------------------------------------
220      DO jk = 1, jpkm1
221         DO jj = 1, jpj
222            DO ji = 1, jpi
223               zcoef = trb(ji,jj,jk,jpphy) - MIN(xsizephy, trb(ji,jj,jk,jpphy) )
224               sizena(ji,jj,jk) = 1. + ( xsizern -1.0 ) * zcoef / ( xsizephy + zcoef )
225               zcoef = trb(ji,jj,jk,jpdia) - MIN(xsizedia, trb(ji,jj,jk,jpdia) )
226               sizeda(ji,jj,jk) = 1. + ( xsizerd - 1.0 ) * zcoef / ( xsizedia + zcoef )
227
228            END DO
229         END DO
230      END DO
231
232
233      ! Compute the fraction of nanophytoplankton that is made of calcifiers
234      ! This is a purely adhoc formulation described in Aumont et al. (2015)
235      ! This fraction depends on nutrient limitation, light, temperature
236      ! --------------------------------------------------------------------
237      DO jk = 1, jpkm1
238         DO jj = 1, jpj
239            DO ji = 1, jpi
240               zlim1 =  ( trb(ji,jj,jk,jpno3) * concnnh4 + trb(ji,jj,jk,jpnh4) * concnno3 )    &
241                  &   / ( concnno3 * concnnh4 + concnnh4 * trb(ji,jj,jk,jpno3) + concnno3 * trb(ji,jj,jk,jpnh4) ) 
242               zlim2  = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concnnh4 )
243               zlim3  = trb(ji,jj,jk,jpfer) / ( trb(ji,jj,jk,jpfer) +  5.E-11   )
244               ztem1  = MAX( 0., tsn(ji,jj,jk,jp_tem) )
245               ztem2  = tsn(ji,jj,jk,jp_tem) - 10.
246               zetot1 = MAX( 0., etot_ndcy(ji,jj,jk) - 1.) / ( 4. + etot_ndcy(ji,jj,jk) ) 
247               zetot2 = 30. / ( 30. + etot_ndcy(ji,jj,jk) ) 
248
249               xfracal(ji,jj,jk) = caco3r * MIN( zlim1, zlim2, zlim3 )                  &
250                  &                       * ztem1 / ( 0.1 + ztem1 )                     &
251                  &                       * MAX( 1., trb(ji,jj,jk,jpphy) * 1.e6 / 2. )  &
252                  &                       * zetot1 * zetot2               &
253                  &                       * ( 1. + EXP(-ztem2 * ztem2 / 25. ) )         &
254                  &                       * MIN( 1., 50. / ( hmld(ji,jj) + rtrn ) )
255               xfracal(ji,jj,jk) = MIN( 0.8 , xfracal(ji,jj,jk) )
256               xfracal(ji,jj,jk) = MAX( 0.02, xfracal(ji,jj,jk) )
257            END DO
258         END DO
259      END DO
260      !
261      DO jk = 1, jpkm1
262         DO jj = 1, jpj
263            DO ji = 1, jpi
264               ! denitrification factor computed from O2 levels
265               ! This factor diagnoses below which level of O2 denitrification
266               ! is active
267               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( 6.e-6  - trb(ji,jj,jk,jpoxy) )    &
268                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
269               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
270               !
271               ! redox factor computed from NO3 levels
272               ! This factor diagnoses below which level of NO3 additional redox
273               ! reactions are taking place.
274               nitrfac2(ji,jj,jk) = MAX( 0.e0,       ( 1.E-6 - trb(ji,jj,jk,jpno3) )  &
275                  &                                / ( 1.E-6 + trb(ji,jj,jk,jpno3) ) )
276               nitrfac2(ji,jj,jk) = MIN( 1., nitrfac2(ji,jj,jk) )
277            END DO
278         END DO
279      END DO
280      !
281      IF( lk_iomput .AND. knt == nrdttrc ) THEN        ! save output diagnostics
282        IF( iom_use( "xfracal" ) )   CALL iom_put( "xfracal", xfracal(:,:,:) * tmask(:,:,:) )  ! Faction of nanophytoplankton that is calcifiers
283        IF( iom_use( "LNnut"   ) )   CALL iom_put( "LNnut"  , xlimphy(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
284        IF( iom_use( "LDnut"   ) )   CALL iom_put( "LDnut"  , xlimdia(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
285        IF( iom_use( "LNFe"    ) )   CALL iom_put( "LNFe"   , xlimnfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
286        IF( iom_use( "LDFe"    ) )   CALL iom_put( "LDFe"   , xlimdfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
287        IF( iom_use( "SIZEN"   ) )   CALL iom_put( "SIZEN"  , sizen(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
288        IF( iom_use( "SIZED"   ) )   CALL iom_put( "SIZED"  , sized(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
289      ENDIF
290      !
291      IF( ln_timing )   CALL timing_stop('p4z_lim')
292      !
293   END SUBROUTINE p4z_lim
294
295
296   SUBROUTINE p4z_lim_init
297      !!----------------------------------------------------------------------
298      !!                  ***  ROUTINE p4z_lim_init  ***
299      !!
300      !! ** Purpose :   Initialization of the nutrient limitation parameters
301      !!
302      !! ** Method  :   Read the namp4zlim namelist and check the parameters
303      !!      called at the first timestep (nittrc000)
304      !!
305      !! ** input   :   Namelist namp4zlim
306      !!
307      !!----------------------------------------------------------------------
308      INTEGER ::   ios   ! Local integer
309
310      ! Namelist block
311      NAMELIST/namp4zlim/ concnno3, concdno3, concnnh4, concdnh4, concnfer, concdfer, concbfe,   &
312         &                concbno3, concbnh4, xsizedia, xsizephy, xsizern, xsizerd,          & 
313         &                xksi1, xksi2, xkdoc, qnfelim, qdfelim, caco3r, oxymin
314      !!----------------------------------------------------------------------
315      !
316      IF(lwp) THEN
317         WRITE(numout,*)
318         WRITE(numout,*) 'p4z_lim_init : initialization of nutrient limitations'
319         WRITE(numout,*) '~~~~~~~~~~~~'
320      ENDIF
321      !
322      REWIND( numnatp_ref )              ! Namelist namp4zlim in reference namelist : Pisces nutrient limitation parameters
323      READ  ( numnatp_ref, namp4zlim, IOSTAT = ios, ERR = 901)
324901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zlim in reference namelist' )
325      REWIND( numnatp_cfg )              ! Namelist namp4zlim in configuration namelist : Pisces nutrient limitation parameters
326      READ  ( numnatp_cfg, namp4zlim, IOSTAT = ios, ERR = 902 )
327902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zlim in configuration namelist' )
328      IF(lwm) WRITE( numonp, namp4zlim )
329      !
330      IF(lwp) THEN                         ! control print
331         WRITE(numout,*) '   Namelist : namp4zlim'
332         WRITE(numout,*) '      mean rainratio                           caco3r    = ', caco3r
333         WRITE(numout,*) '      NO3 half saturation of nanophyto         concnno3  = ', concnno3
334         WRITE(numout,*) '      NO3 half saturation of diatoms           concdno3  = ', concdno3
335         WRITE(numout,*) '      NH4 half saturation for phyto            concnnh4  = ', concnnh4
336         WRITE(numout,*) '      NH4 half saturation for diatoms          concdnh4  = ', concdnh4
337         WRITE(numout,*) '      half saturation constant for Si uptake   xksi1     = ', xksi1
338         WRITE(numout,*) '      half saturation constant for Si/C        xksi2     = ', xksi2
339         WRITE(numout,*) '      half-sat. of DOC remineralization        xkdoc     = ', xkdoc
340         WRITE(numout,*) '      Iron half saturation for nanophyto       concnfer  = ', concnfer
341         WRITE(numout,*) '      Iron half saturation for diatoms         concdfer  = ', concdfer
342         WRITE(numout,*) '      size ratio for nanophytoplankton         xsizern   = ', xsizern
343         WRITE(numout,*) '      size ratio for diatoms                   xsizerd   = ', xsizerd
344         WRITE(numout,*) '      NO3 half saturation of bacteria          concbno3  = ', concbno3
345         WRITE(numout,*) '      NH4 half saturation for bacteria         concbnh4  = ', concbnh4
346         WRITE(numout,*) '      Minimum size criteria for diatoms        xsizedia  = ', xsizedia
347         WRITE(numout,*) '      Minimum size criteria for nanophyto      xsizephy  = ', xsizephy
348         WRITE(numout,*) '      Fe half saturation for bacteria          concbfe   = ', concbfe
349         WRITE(numout,*) '      halk saturation constant for anoxia       oxymin   =' , oxymin
350         WRITE(numout,*) '      optimal Fe quota for nano.               qnfelim   = ', qnfelim
351         WRITE(numout,*) '      Optimal Fe quota for diatoms             qdfelim   = ', qdfelim
352      ENDIF
353      !
354      nitrfac (:,:,:) = 0._wp
355      !
356   END SUBROUTINE p4z_lim_init
357
358
359   INTEGER FUNCTION p4z_lim_alloc()
360      !!----------------------------------------------------------------------
361      !!                     ***  ROUTINE p5z_lim_alloc  ***
362      !!
363      !            Allocation of the arrays used in this module
364      !!----------------------------------------------------------------------
365      USE lib_mpp , ONLY: ctl_stop
366      !!----------------------------------------------------------------------
367
368      !*  Biological arrays for phytoplankton growth
369      ALLOCATE( xnanono3(jpi,jpj,jpk), xdiatno3(jpi,jpj,jpk),       &
370         &      xnanonh4(jpi,jpj,jpk), xdiatnh4(jpi,jpj,jpk),       &
371         &      xnanopo4(jpi,jpj,jpk), xdiatpo4(jpi,jpj,jpk),       &
372         &      xnanofer(jpi,jpj,jpk), xdiatfer(jpi,jpj,jpk),       &
373         &      xlimphy (jpi,jpj,jpk), xlimdia (jpi,jpj,jpk),       &
374         &      xlimnfe (jpi,jpj,jpk), xlimdfe (jpi,jpj,jpk),       &
375         &      xlimbac (jpi,jpj,jpk), xlimbacl(jpi,jpj,jpk),       &
376         &      concnfe (jpi,jpj,jpk), concdfe (jpi,jpj,jpk),       &
377         &      xlimsi  (jpi,jpj,jpk), STAT=p4z_lim_alloc )
378      !
379      IF( p4z_lim_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p4z_lim_alloc : failed to allocate arrays.' )
380      !
381   END FUNCTION p4z_lim_alloc
382
383   !!======================================================================
384END MODULE p4zlim
Note: See TracBrowser for help on using the repository browser.