source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p4zmicro.F90 @ 12759

Last change on this file since 12759 was 12759, checked in by aumont, 9 months ago

make parameterizations in PISCES-operationnal more similar to thos of PISCES-QUOTA (prey switching, optimal allocation, size, …)

  • Property svn:keywords set to Id
File size: 18.3 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_micro      : Compute the sources/sinks for microzooplankton
11   !!   p4z_micro_init : Initialize and read the appropriate namelist
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zlim          ! Co-limitations
17   USE p4zprod         ! production
18   USE iom             ! I/O manager
19   USE prtctl_trc      ! print control for debugging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   !! * Shared module variables
25   PUBLIC   p4z_micro         ! called in p4zbio.F90
26   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
27
28   REAL(wp), PUBLIC ::   part        !: part of calcite not dissolved in microzoo guts
29   REAL(wp), PUBLIC ::   xprefc      !: microzoo preference for POC
30   REAL(wp), PUBLIC ::   xprefn      !: microzoo preference for nanophyto
31   REAL(wp), PUBLIC ::   xprefd      !: microzoo preference for diatoms
32   REAL(wp), PUBLIC ::   xthreshdia  !: diatoms feeding threshold for microzooplankton
33   REAL(wp), PUBLIC ::   xthreshphy  !: nanophyto threshold for microzooplankton
34   REAL(wp), PUBLIC ::   xthreshpoc  !: poc threshold for microzooplankton
35   REAL(wp), PUBLIC ::   xthresh     !: feeding threshold for microzooplankton
36   REAL(wp), PUBLIC ::   resrat      !: exsudation rate of microzooplankton
37   REAL(wp), PUBLIC ::   mzrat       !: microzooplankton mortality rate
38   REAL(wp), PUBLIC ::   grazrat     !: maximal microzoo grazing rate
39   REAL(wp), PUBLIC ::   xkgraz      !: Half-saturation constant of assimilation
40   REAL(wp), PUBLIC ::   unass       !: Non-assimilated part of food
41   REAL(wp), PUBLIC ::   sigma1      !: Fraction of microzoo excretion as DOM
42   REAL(wp), PUBLIC ::   epsher      !: growth efficiency for grazing 1
43   REAL(wp), PUBLIC ::   epshermin   !: minimum growth efficiency for grazing 1
44
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
47   !! $Id$
48   !! Software governed by the CeCILL license (see ./LICENSE)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p4z_micro( kt, knt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_micro  ***
55      !!
56      !! ** Purpose :   Compute the sources/sinks for microzooplankton
57      !!                This includes ingestion and assimilation, flux feeding
58      !!                and mortality. We use a passive prey switching 
59      !!                parameterization.
60      !!                All living compartments smaller than microzooplankton
61      !!                are potential preys of mesozooplankton
62      !!
63      !! ** Method  : - ???
64      !!---------------------------------------------------------------------
65      INTEGER, INTENT(in) ::   kt    ! ocean time step
66      INTEGER, INTENT(in) ::   knt   ! ???
67      !
68      INTEGER  :: ji, jj, jk
69      REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
70      REAL(wp) :: zgraze  , zdenom, zdenom2, zfact, zfood, zfoodlim, zbeta
71      REAL(wp) :: zepsherf, zepshert, zepsherq, zepsherv, zgrarsig, zgraztotc, zgraztotn, zgraztotf
72      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
73      REAL(wp) :: zrespz, ztortz, zgrasratf, zgrasratn
74      REAL(wp) :: zgraznc, zgrazpoc, zgrazdc, zgrazpof, zgrazdf, zgraznf
75      REAL(wp) :: zsigma, zdiffdn, ztmp1, ztmp2, ztmp3, ztmptot, zproport
76      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo
77      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zw3d, zzligprod
78      CHARACTER (len=25) :: charout
79      !!---------------------------------------------------------------------
80      !
81      IF( ln_timing )   CALL timing_start('p4z_micro')
82      !
83      IF (ln_ligand) THEN
84         ALLOCATE( zzligprod(jpi,jpj,jpk) )
85         zzligprod(:,:,:) = 0._wp
86      ENDIF
87      !
88      DO jk = 1, jpkm1
89         DO jj = 1, jpj
90            DO ji = 1, jpi
91               zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
92               zfact   = xstep * tgfunc2(ji,jj,jk) * zcompaz
93
94               ! Proportion of nano and diatoms that are within the size range
95               ! accessible to microzooplankton.
96               zproport  = min(1.0, exp(-1.1 * MAX(0., ( sized(ji,jj,jk) - 1.8 ))**0.8 ))
97
98               !  linear mortality of mesozooplankton
99               !  A michaelis menten modulation term is used to avoid extinction of
100               !  microzooplankton at very low food concentrations. Mortality is
101               !  enhanced in low O2 waters
102               !  -----------------------------------------------------------------
103               zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) )  &
104                  &   + resrat * zfact * 3. * nitrfac(ji,jj,jk)
105
106               !  Zooplankton quadratic mortality. A square function has been selected with
107               !  to mimic predation and disease (density dependent mortality). It also tends
108               !  to stabilise the model
109               !  -------------------------------------------------------------------------
110               ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
111
112               !   Computation of the abundance of the preys
113               !   A threshold can be specified in the namelist
114               !   Diatoms have a specific treatment. WHen concentrations
115               !   exceed a certain value, diatoms are suppposed to be too
116               !   big for microzooplankton.
117               !   --------------------------------------------------------
118               zcompadi  = zproport * MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 )
119               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 )
120               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 )
121               
122               ! Microzooplankton grazing
123               ! The total amount of food is the sum of all preys accessible to mesozooplankton
124               ! multiplied by their food preference
125               ! A threshold can be specified in the namelist (xthresh). However, when food
126               ! concentration is close to this threshold, it is decreased to avoid the
127               ! accumulation of food in the mesozoopelagic domain
128               ! -------------------------------------------------------------------------------
129               zfood     = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi
130               zfoodlim  = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
131               zdenom    = zfoodlim / ( xkgraz + zfoodlim )
132               zdenom2   = zdenom / ( zfood + rtrn )
133               zgraze    = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk))
134
135               ! An active switching parameterization is used here.
136               ! We don't use the KTW parameterization proposed by
137               ! Vallina et al. because it tends to produce too steady biomass
138               ! composition and the variance of Chl is too low as it grazes
139               ! too strongly on winning organisms. We use a generalized
140               ! switching parameterization proposed by Morozov and
141               ! Petrovskii (2013)
142               ! ------------------------------------------------------------ 
143               ! The width of the selection window is increased when preys
144               ! have low abundance, .i.e. zooplankton become less specific
145               ! to avoid starvation.
146               ! ----------------------------------------------------------
147               zsigma = 1.0 - zdenom**2/(0.05**2+zdenom**2)
148               zsigma = 0.5 + 1.0*zsigma
149               zdiffdn = exp( -ABS(log(1.67 * sizen(ji,jj,jk) / (5.0 * sized(ji,jj,jk) + rtrn )) )**2 / zsigma**2)
150               ztmp1 = xprefn * zcompaph * ( zcompaph + zdiffdn * zcompadi ) / ( 1.0 + zdiffdn )
151               ztmp2 = xprefd * zcompadi * ( zdiffdn * zcompaph + zcompadi ) / ( 1.0 + zdiffdn )
152               ztmp3 = xprefc * zcompapoc**2
153               ztmptot = ztmp1 + ztmp2 + ztmp3 + rtrn
154               ztmp1 = ztmp1 / ztmptot
155               ztmp2 = ztmp2 / ztmptot
156               ztmp3 = ztmp3 / ztmptot
157
158               zgraznc   = zgraze   * ztmp1 * zdenom
159               zgrazdc   = zgraze   * ztmp2 * zdenom
160               zgrazpoc  = zgraze   * ztmp3 * zdenom
161
162               zgraznf   = zgraznc  * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn)
163               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
164               zgrazdf   = zgrazdc  * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn)
165               !
166               zgraztotc = zgraznc + zgrazpoc + zgrazdc
167               zgraztotf = zgraznf + zgrazdf  + zgrazpof 
168               zgraztotn = zgraznc * quotan(ji,jj,jk) + zgrazpoc + zgrazdc * quotad(ji,jj,jk)
169
170               ! Grazing by microzooplankton
171               zgrazing(ji,jj,jk) = zgraztotc
172
173               ! Microzooplankton efficiency.
174               ! We adopt a formulation proposed by Mitra et al. (2007)
175               ! The gross growth efficiency is controled by the most limiting nutrient.
176               ! Growth is also further decreased when the food quality is poor. This is currently
177               ! hard coded : it can be decreased by up to 50% (zepsherq)
178               ! GGE can also be decreased when food quantity is high, zepsherf (Montagnes and
179               ! Fulton, 2012)
180               ! -----------------------------------------------------------------------------
181               zgrasratf = ( zgraztotf + rtrn ) / ( zgraztotc + rtrn )
182               zgrasratn = ( zgraztotn + rtrn ) / ( zgraztotc + rtrn )
183               zepshert  =  MIN( 1., zgrasratn, zgrasratf / ferat3)
184               zbeta     = MAX(0., (epsher - epshermin) )
185               zepsherf  = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
186               zepsherq  = 0.5 + (1.0 - 0.5) * zepshert * ( 1.0 + 1.0 ) / ( zepshert + 1.0 )
187               zepsherv  = zepsherf * zepshert * zepsherq
188               zgrafer   = zgraztotc * MAX( 0. , ( 1. - unass ) * zgrasratf - ferat3 * zepsherv ) 
189               zgrarem   = zgraztotc * ( 1. - zepsherv - unass )
190               zgrapoc   = zgraztotc * unass
191
192               !  Update of the TRA arrays
193               !  ------------------------
194               zgrarsig  = zgrarem * sigma1
195               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
196               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
197               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig
198               !
199               IF( ln_ligand ) THEN
200                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem - zgrarsig) * ldocz
201                  zzligprod(ji,jj,jk) = (zgrarem - zgrarsig) * ldocz
202               ENDIF
203               !
204               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
205               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
206               zfezoo(ji,jj,jk)    = zgrafer
207               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
208               prodpoc(ji,jj,jk)   = prodpoc(ji,jj,jk) + zgrapoc
209               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass
210               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
211               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig
212               zmortz = ztortz + zrespz
213               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztotc 
214               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgraznc
215               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazdc
216               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgraznc * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
217               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazdc * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn)
218               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
219               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazdc * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn)
220               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
221               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazdf
222               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazpoc
223               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
224               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc
225               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazpof
226               !
227               ! Calcite remineralization due to zooplankton activity
228               ! part of the ingested calcite is dissolving in the acidic gut
229               zprcaca = xfracal(ji,jj,jk) * zgraznc
230               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
231               !
232               zprcaca = part * zprcaca
233               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
234               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
235               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
236            END DO
237         END DO
238      END DO
239      !
240      IF( lk_iomput ) THEN
241         IF( knt == nrdttrc ) THEN
242           ALLOCATE( zw3d(jpi,jpj,jpk) )
243           IF( iom_use( "GRAZ1" ) ) THEN
244              zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !  Total grazing of phyto by zooplankton
245              CALL iom_put( "GRAZ1", zw3d )
246           ENDIF
247           IF( iom_use( "FEZOO" ) ) THEN
248              zw3d(:,:,:) = zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
249              CALL iom_put( "FEZOO", zw3d )
250           ENDIF
251           IF( iom_use( "LPRODZ" ) .AND. ln_ligand )  THEN
252              zw3d(:,:,:) = zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
253              CALL iom_put( "LPRODZ"  , zw3d )
254           ENDIF
255           DEALLOCATE( zw3d )
256         ENDIF
257      ENDIF
258      !
259      IF (ln_ligand)  DEALLOCATE( zzligprod )
260      !
261      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
262         WRITE(charout, FMT="('micro')")
263         CALL prt_ctl_trc_info(charout)
264         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
265      ENDIF
266      !
267      IF( ln_timing )   CALL timing_stop('p4z_micro')
268      !
269   END SUBROUTINE p4z_micro
270
271
272   SUBROUTINE p4z_micro_init
273      !!----------------------------------------------------------------------
274      !!                  ***  ROUTINE p4z_micro_init  ***
275      !!
276      !! ** Purpose :   Initialization of microzooplankton parameters
277      !!
278      !! ** Method  :   Read the namp4zzoo namelist and check the parameters
279      !!                called at the first timestep (nittrc000)
280      !!
281      !! ** input   :   Namelist namp4zzoo
282      !!
283      !!----------------------------------------------------------------------
284      INTEGER ::   ios   ! Local integer
285      !
286      NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xprefn, xprefc, &
287         &                xprefd,  xthreshdia,  xthreshphy,  xthreshpoc, &
288         &                xthresh, xkgraz, epsher, epshermin, sigma1, unass
289      !!----------------------------------------------------------------------
290      !
291      IF(lwp) THEN
292         WRITE(numout,*) 
293         WRITE(numout,*) 'p4z_micro_init : Initialization of microzooplankton parameters'
294         WRITE(numout,*) '~~~~~~~~~~~~~~'
295      ENDIF
296      !
297      REWIND( numnatp_ref )              ! Namelist namp4zzoo in reference namelist : Pisces microzooplankton
298      READ  ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901)
299901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zzoo in reference namelist' )
300      REWIND( numnatp_cfg )              ! Namelist namp4zzoo in configuration namelist : Pisces microzooplankton
301      READ  ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 )
302902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist' )
303      IF(lwm) WRITE( numonp, namp4zzoo )
304      !
305      IF(lwp) THEN                         ! control print
306         WRITE(numout,*) '   Namelist : namp4zzoo'
307         WRITE(numout,*) '      part of calcite not dissolved in microzoo guts  part        =', part
308         WRITE(numout,*) '      microzoo preference for POC                     xprefc      =', xprefc
309         WRITE(numout,*) '      microzoo preference for nano                    xprefn      =', xprefn
310         WRITE(numout,*) '      microzoo preference for diatoms                 xprefd      =', xprefd
311         WRITE(numout,*) '      diatoms feeding threshold  for microzoo         xthreshdia  =', xthreshdia
312         WRITE(numout,*) '      nanophyto feeding threshold for microzoo        xthreshphy  =', xthreshphy
313         WRITE(numout,*) '      poc feeding threshold for microzoo              xthreshpoc  =', xthreshpoc
314         WRITE(numout,*) '      feeding threshold for microzooplankton          xthresh     =', xthresh
315         WRITE(numout,*) '      exsudation rate of microzooplankton             resrat      =', resrat
316         WRITE(numout,*) '      microzooplankton mortality rate                 mzrat       =', mzrat
317         WRITE(numout,*) '      maximal microzoo grazing rate                   grazrat     =', grazrat
318         WRITE(numout,*) '      non assimilated fraction of P by microzoo       unass       =', unass
319         WRITE(numout,*) '      Efficicency of microzoo growth                  epsher      =', epsher
320         WRITE(numout,*) '      Minimum efficicency of microzoo growth          epshermin   =', epshermin
321         WRITE(numout,*) '      Fraction of microzoo excretion as DOM           sigma1      =', sigma1
322         WRITE(numout,*) '      half sturation constant for grazing 1           xkgraz      =', xkgraz
323      ENDIF
324      !
325   END SUBROUTINE p4z_micro_init
326
327   !!======================================================================
328END MODULE p4zmicro
Note: See TracBrowser for help on using the repository browser.