New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diahsb.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/DIA – NEMO

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/DIA/diahsb.F90 @ 12150

Last change on this file since 12150 was 12150, checked in by davestorkey, 4 years ago

2019/dev_r11943_MERGE_2019: Merge in UKMO_MERGE_2019.
  • Property svn:keywords set to Id
File size: 22.8 KB
Line 
1MODULE diahsb
2   !!======================================================================
3   !!                       ***  MODULE  diahsb  ***
4   !! Ocean diagnostics: Heat, salt and volume budgets
5   !!======================================================================
6   !! History :  3.3  ! 2010-09  (M. Leclair)  Original code
7   !!                 ! 2012-10  (C. Rousset)  add iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dia_hsb       : Diagnose the conservation of ocean heat and salt contents, and volume
12   !!   dia_hsb_rst   : Read or write DIA file in restart file
13   !!   dia_hsb_init  : Initialization of the conservation diagnostic
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE phycst         ! physical constants
18   USE sbc_oce        ! surface thermohaline fluxes
19   USE isf_oce        ! ice shelf fluxes
20   USE sbcrnf         ! river runoff
21   USE domvvl         ! vertical scale factors
22   USE traqsr         ! penetrative solar radiation
23   USE trabbc         ! bottom boundary condition
24   USE trabbc         ! bottom boundary condition
25   USE restart        ! ocean restart
26   USE bdy_oce , ONLY : ln_bdy
27   !
28   USE iom            ! I/O manager
29   USE in_out_manager ! I/O manager
30   USE lib_fortran    ! glob_sum
31   USE lib_mpp        ! distributed memory computing library
32   USE timing         ! preformance summary
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   dia_hsb        ! routine called by step.F90
38   PUBLIC   dia_hsb_init   ! routine called by nemogcm.F90
39
40   LOGICAL, PUBLIC ::   ln_diahsb   !: check the heat and salt budgets
41
42   REAL(wp) ::   surf_tot              ! ocean surface
43   REAL(wp) ::   frc_t, frc_s, frc_v   ! global forcing trends
44   REAL(wp) ::   frc_wn_t, frc_wn_s    ! global forcing trends
45   !
46   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   surf 
47   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   surf_ini      , ssh_ini          !
48   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   ssh_hc_loc_ini, ssh_sc_loc_ini   !
49   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   hc_loc_ini, sc_loc_ini, e3t_ini  !
50   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   tmask_ini
51
52   !! * Substitutions
53#  include "vectopt_loop_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
56   !! $Id$
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE dia_hsb( kt, Kbb, Kmm )
62      !!---------------------------------------------------------------------------
63      !!                  ***  ROUTINE dia_hsb  ***
64      !!     
65      !! ** Purpose: Compute the ocean global heat content, salt content and volume conservation
66      !!
67      !! ** Method : - Compute the deviation of heat content, salt content and volume
68      !!             at the current time step from their values at nit000
69      !!             - Compute the contribution of forcing and remove it from these deviations
70      !!
71      !!---------------------------------------------------------------------------
72      INTEGER, INTENT(in) ::   kt         ! ocean time-step index
73      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
74      !
75      INTEGER    ::   ji, jj, jk                  ! dummy loop indice
76      REAL(wp)   ::   zdiff_hc    , zdiff_sc      ! heat and salt content variations
77      REAL(wp)   ::   zdiff_hc1   , zdiff_sc1     !  -         -     -        -
78      REAL(wp)   ::   zdiff_v1    , zdiff_v2      ! volume variation
79      REAL(wp)   ::   zerr_hc1    , zerr_sc1      ! heat and salt content misfit
80      REAL(wp)   ::   zvol_tot                    ! volume
81      REAL(wp)   ::   z_frc_trd_t , z_frc_trd_s   !    -     -
82      REAL(wp)   ::   z_frc_trd_v                 !    -     -
83      REAL(wp)   ::   z_wn_trd_t , z_wn_trd_s     !    -     -
84      REAL(wp)   ::   z_ssh_hc , z_ssh_sc         !    -     -
85      REAL(wp), DIMENSION(jpi,jpj)       ::   z2d0, z2d1   ! 2D workspace
86      REAL(wp), DIMENSION(jpi,jpj,jpkm1) ::   zwrk         ! 3D workspace
87      !!---------------------------------------------------------------------------
88      IF( ln_timing )   CALL timing_start('dia_hsb')     
89      !
90      ts(:,:,:,1,Kmm) = ts(:,:,:,1,Kmm) * tmask(:,:,:) ; ts(:,:,:,1,Kbb) = ts(:,:,:,1,Kbb) * tmask(:,:,:) ;
91      ts(:,:,:,2,Kmm) = ts(:,:,:,2,Kmm) * tmask(:,:,:) ; ts(:,:,:,2,Kbb) = ts(:,:,:,2,Kbb) * tmask(:,:,:) ;
92      ! ------------------------- !
93      ! 1 - Trends due to forcing !
94      ! ------------------------- !
95      z_frc_trd_v = r1_rau0 * glob_sum( 'diahsb', - ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) ) * surf(:,:) )   ! volume fluxes
96      z_frc_trd_t =           glob_sum( 'diahsb', sbc_tsc(:,:,jp_tem) * surf(:,:) )                       ! heat fluxes
97      z_frc_trd_s =           glob_sum( 'diahsb', sbc_tsc(:,:,jp_sal) * surf(:,:) )                       ! salt fluxes
98      !                    !  Add runoff    heat & salt input
99      IF( ln_rnf    )   z_frc_trd_t = z_frc_trd_t + glob_sum( 'diahsb', rnf_tsc(:,:,jp_tem) * surf(:,:) )
100      IF( ln_rnf_sal)   z_frc_trd_s = z_frc_trd_s + glob_sum( 'diahsb', rnf_tsc(:,:,jp_sal) * surf(:,:) )
101      !                    ! Add ice shelf heat & salt input
102      IF( ln_isf    )   z_frc_trd_t = z_frc_trd_t &
103         &                          + glob_sum( 'diahsb', ( risf_cav_tsc(:,:,jp_tem) + risf_par_tsc(:,:,jp_tem) ) * surf(:,:) )
104      !                    ! Add penetrative solar radiation
105      IF( ln_traqsr )   z_frc_trd_t = z_frc_trd_t + r1_rau0_rcp * glob_sum( 'diahsb', qsr     (:,:) * surf(:,:) )
106      !                    ! Add geothermal heat flux
107      IF( ln_trabbc )   z_frc_trd_t = z_frc_trd_t +               glob_sum( 'diahsb', qgh_trd0(:,:) * surf(:,:) )
108      !
109      IF( ln_linssh ) THEN
110         IF( ln_isfcav ) THEN
111            DO ji=1,jpi
112               DO jj=1,jpj
113                  z2d0(ji,jj) = surf(ji,jj) * ww(ji,jj,mikt(ji,jj)) * ts(ji,jj,mikt(ji,jj),jp_tem,Kbb)
114                  z2d1(ji,jj) = surf(ji,jj) * ww(ji,jj,mikt(ji,jj)) * ts(ji,jj,mikt(ji,jj),jp_sal,Kbb)
115               END DO
116            END DO
117         ELSE
118            z2d0(:,:) = surf(:,:) * ww(:,:,1) * ts(:,:,1,jp_tem,Kbb)
119            z2d1(:,:) = surf(:,:) * ww(:,:,1) * ts(:,:,1,jp_sal,Kbb)
120         END IF
121         z_wn_trd_t = - glob_sum( 'diahsb', z2d0 ) 
122         z_wn_trd_s = - glob_sum( 'diahsb', z2d1 )
123      ENDIF
124
125      frc_v = frc_v + z_frc_trd_v * rdt
126      frc_t = frc_t + z_frc_trd_t * rdt
127      frc_s = frc_s + z_frc_trd_s * rdt
128      !                                          ! Advection flux through fixed surface (z=0)
129      IF( ln_linssh ) THEN
130         frc_wn_t = frc_wn_t + z_wn_trd_t * rdt
131         frc_wn_s = frc_wn_s + z_wn_trd_s * rdt
132      ENDIF
133
134      ! ------------------------ !
135      ! 2 -  Content variations  !
136      ! ------------------------ !
137      ! glob_sum_full is needed because you keep the full interior domain to compute the sum (iscpl)
138
139      !                    ! volume variation (calculated with ssh)
140      zdiff_v1 = glob_sum_full( 'diahsb', surf(:,:)*ssh(:,:,Kmm) - surf_ini(:,:)*ssh_ini(:,:) )
141
142      !                    ! heat & salt content variation (associated with ssh)
143      IF( ln_linssh ) THEN       ! linear free surface case
144         IF( ln_isfcav ) THEN          ! ISF case
145            DO ji = 1, jpi
146               DO jj = 1, jpj
147                  z2d0(ji,jj) = surf(ji,jj) * ( ts(ji,jj,mikt(ji,jj),jp_tem,Kmm) * ssh(ji,jj,Kmm) - ssh_hc_loc_ini(ji,jj) ) 
148                  z2d1(ji,jj) = surf(ji,jj) * ( ts(ji,jj,mikt(ji,jj),jp_sal,Kmm) * ssh(ji,jj,Kmm) - ssh_sc_loc_ini(ji,jj) ) 
149               END DO
150            END DO
151         ELSE                          ! no under ice-shelf seas
152            z2d0(:,:) = surf(:,:) * ( ts(:,:,1,jp_tem,Kmm) * ssh(:,:,Kmm) - ssh_hc_loc_ini(:,:) ) 
153            z2d1(:,:) = surf(:,:) * ( ts(:,:,1,jp_sal,Kmm) * ssh(:,:,Kmm) - ssh_sc_loc_ini(:,:) ) 
154         END IF
155         z_ssh_hc = glob_sum_full( 'diahsb', z2d0 ) 
156         z_ssh_sc = glob_sum_full( 'diahsb', z2d1 ) 
157      ENDIF
158      !
159      DO jk = 1, jpkm1           ! volume variation (calculated with scale factors)
160         zwrk(:,:,jk) = surf(:,:)*e3t(:,:,jk,Kmm)*tmask(:,:,jk) - surf_ini(:,:)*e3t_ini(:,:,jk)*tmask_ini(:,:,jk)
161      END DO
162      zdiff_v2 = glob_sum_full( 'diahsb', zwrk(:,:,:) )     ! glob_sum_full needed as tmask and tmask_ini could be different
163      DO jk = 1, jpkm1           ! heat content variation
164         zwrk(:,:,jk) = ( surf(:,:)*e3t(:,:,jk,Kmm)*ts(:,:,jk,jp_tem,Kmm) - surf_ini(:,:)*hc_loc_ini(:,:,jk) )
165      END DO
166      zdiff_hc = glob_sum_full( 'diahsb', zwrk(:,:,:) )
167      DO jk = 1, jpkm1           ! salt content variation
168         zwrk(:,:,jk) = ( surf(:,:)*e3t(:,:,jk,Kmm)*ts(:,:,jk,jp_sal,Kmm) - surf_ini(:,:)*sc_loc_ini(:,:,jk) )
169      END DO
170      zdiff_sc = glob_sum_full( 'diahsb', zwrk(:,:,:) )
171
172      ! ------------------------ !
173      ! 3 -  Drifts              !
174      ! ------------------------ !
175      zdiff_v1 = zdiff_v1 - frc_v
176      IF( .NOT.ln_linssh )   zdiff_v2 = zdiff_v2 - frc_v
177      zdiff_hc = zdiff_hc - frc_t
178      zdiff_sc = zdiff_sc - frc_s
179      IF( ln_linssh ) THEN
180         zdiff_hc1 = zdiff_hc + z_ssh_hc 
181         zdiff_sc1 = zdiff_sc + z_ssh_sc
182         zerr_hc1  = z_ssh_hc - frc_wn_t
183         zerr_sc1  = z_ssh_sc - frc_wn_s
184      ENDIF
185
186      ! ----------------------- !
187      ! 4 - Diagnostics writing !
188      ! ----------------------- !
189      DO jk = 1, jpkm1           ! total ocean volume (calculated with scale factors)
190         zwrk(:,:,jk) = surf(:,:) * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
191      END DO
192      zvol_tot = glob_sum( 'diahsb', zwrk(:,:,:) )
193
194!!gm to be added ?
195!      IF( ln_linssh ) THEN            ! fixed volume, add the ssh contribution
196!        zvol_tot = zvol_tot + glob_sum( 'diahsb', surf(:,:) * ssh(:,:,Kmm) )
197!      ENDIF
198!!gm end
199
200      CALL iom_put(   'bgfrcvol' , frc_v    * 1.e-9    )              ! vol - surface forcing (km3)
201      CALL iom_put(   'bgfrctem' , frc_t    * rau0 * rcp * 1.e-20 )   ! hc  - surface forcing (1.e20 J)
202      CALL iom_put(   'bgfrchfx' , frc_t    * rau0 * rcp /  &         ! hc  - surface forcing (W/m2)
203         &                       ( surf_tot * kt * rdt )        )
204      CALL iom_put(   'bgfrcsal' , frc_s    * 1.e-9    )              ! sc  - surface forcing (psu*km3)
205
206      IF( .NOT. ln_linssh ) THEN
207         CALL iom_put( 'bgtemper' , zdiff_hc / zvol_tot )              ! Temperature drift     (C)
208         CALL iom_put( 'bgsaline' , zdiff_sc / zvol_tot )              ! Salinity    drift     (PSU)
209         CALL iom_put( 'bgheatco' , zdiff_hc * 1.e-20 * rau0 * rcp )   ! Heat content drift    (1.e20 J)
210         CALL iom_put( 'bgheatfx' , zdiff_hc * rau0 * rcp /  &         ! Heat flux drift       (W/m2)
211            &                       ( surf_tot * kt * rdt )        )
212         CALL iom_put( 'bgsaltco' , zdiff_sc * 1.e-9    )              ! Salt content drift    (psu*km3)
213         CALL iom_put( 'bgvolssh' , zdiff_v1 * 1.e-9    )              ! volume ssh drift      (km3) 
214         CALL iom_put( 'bgvole3t' , zdiff_v2 * 1.e-9    )              ! volume e3t drift      (km3) 
215         !
216         IF( kt == nitend .AND. lwp ) THEN
217            WRITE(numout,*)
218            WRITE(numout,*) 'dia_hsb : last time step hsb diagnostics: at it= ', kt,' date= ', ndastp
219            WRITE(numout,*) '~~~~~~~'
220            WRITE(numout,*) '   Temperature drift = ', zdiff_hc / zvol_tot, ' C'
221            WRITE(numout,*) '   Salinity    drift = ', zdiff_sc / zvol_tot, ' PSU'
222            WRITE(numout,*) '   volume ssh  drift = ', zdiff_v1 * 1.e-9   , ' km^3'
223            WRITE(numout,*) '   volume e3t  drift = ', zdiff_v2 * 1.e-9   , ' km^3'
224         ENDIF
225         !
226      ELSE
227         CALL iom_put( 'bgtemper' , zdiff_hc1 / zvol_tot)              ! Heat content drift    (C)
228         CALL iom_put( 'bgsaline' , zdiff_sc1 / zvol_tot)              ! Salt content drift    (PSU)
229         CALL iom_put( 'bgheatco' , zdiff_hc1 * 1.e-20 * rau0 * rcp )  ! Heat content drift    (1.e20 J)
230         CALL iom_put( 'bgheatfx' , zdiff_hc1 * rau0 * rcp /  &        ! Heat flux drift       (W/m2)
231            &                       ( surf_tot * kt * rdt )         )
232         CALL iom_put( 'bgsaltco' , zdiff_sc1 * 1.e-9    )             ! Salt content drift    (psu*km3)
233         CALL iom_put( 'bgvolssh' , zdiff_v1 * 1.e-9    )              ! volume ssh drift      (km3) 
234         CALL iom_put( 'bgmistem' , zerr_hc1 / zvol_tot )              ! hc  - error due to free surface (C)
235         CALL iom_put( 'bgmissal' , zerr_sc1 / zvol_tot )              ! sc  - error due to free surface (psu)
236      ENDIF
237      !
238      IF( lrst_oce )   CALL dia_hsb_rst( kt, Kmm, 'WRITE' )
239      !
240      IF( ln_timing )   CALL timing_stop('dia_hsb')
241      !
242   END SUBROUTINE dia_hsb
243
244
245   SUBROUTINE dia_hsb_rst( kt, Kmm, cdrw )
246      !!---------------------------------------------------------------------
247      !!                   ***  ROUTINE dia_hsb_rst  ***
248      !!                     
249      !! ** Purpose :   Read or write DIA file in restart file
250      !!
251      !! ** Method  :   use of IOM library
252      !!----------------------------------------------------------------------
253      INTEGER         , INTENT(in) ::   kt     ! ocean time-step
254      INTEGER         , INTENT(in) ::   Kmm    ! ocean time level index
255      CHARACTER(len=*), INTENT(in) ::   cdrw   ! "READ"/"WRITE" flag
256      !
257      INTEGER ::   ji, jj, jk   ! dummy loop indices
258      !!----------------------------------------------------------------------
259      !
260      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
261         IF( ln_rstart ) THEN                   !* Read the restart file
262            !
263            IF(lwp) WRITE(numout,*)
264            IF(lwp) WRITE(numout,*) '   dia_hsb_rst : read hsb restart at it= ', kt,' date= ', ndastp
265            IF(lwp) WRITE(numout,*)
266            CALL iom_get( numror, 'frc_v', frc_v, ldxios = lrxios )
267            CALL iom_get( numror, 'frc_t', frc_t, ldxios = lrxios )
268            CALL iom_get( numror, 'frc_s', frc_s, ldxios = lrxios )
269            IF( ln_linssh ) THEN
270               CALL iom_get( numror, 'frc_wn_t', frc_wn_t, ldxios = lrxios )
271               CALL iom_get( numror, 'frc_wn_s', frc_wn_s, ldxios = lrxios )
272            ENDIF
273            CALL iom_get( numror, jpdom_autoglo, 'surf_ini'  , surf_ini  , ldxios = lrxios ) ! ice sheet coupling
274            CALL iom_get( numror, jpdom_autoglo, 'ssh_ini'   , ssh_ini   , ldxios = lrxios )
275            CALL iom_get( numror, jpdom_autoglo, 'e3t_ini'   , e3t_ini   , ldxios = lrxios )
276            CALL iom_get( numror, jpdom_autoglo, 'tmask_ini' , tmask_ini , ldxios = lrxios )
277            CALL iom_get( numror, jpdom_autoglo, 'hc_loc_ini', hc_loc_ini, ldxios = lrxios )
278            CALL iom_get( numror, jpdom_autoglo, 'sc_loc_ini', sc_loc_ini, ldxios = lrxios )
279            IF( ln_linssh ) THEN
280               CALL iom_get( numror, jpdom_autoglo, 'ssh_hc_loc_ini', ssh_hc_loc_ini, ldxios = lrxios )
281               CALL iom_get( numror, jpdom_autoglo, 'ssh_sc_loc_ini', ssh_sc_loc_ini, ldxios = lrxios )
282            ENDIF
283         ELSE
284            IF(lwp) WRITE(numout,*)
285            IF(lwp) WRITE(numout,*) '   dia_hsb_rst : initialise hsb at initial state '
286            IF(lwp) WRITE(numout,*)
287            surf_ini(:,:) = e1e2t(:,:) * tmask_i(:,:)         ! initial ocean surface
288            ssh_ini(:,:) = ssh(:,:,Kmm)                          ! initial ssh
289            DO jk = 1, jpk
290              ! if ice sheet/oceqn coupling, need to mask ini variables here (mask could change at the next NEMO instance).
291               e3t_ini   (:,:,jk) = e3t(:,:,jk,Kmm)                      * tmask(:,:,jk)  ! initial vertical scale factors
292               tmask_ini (:,:,jk) = tmask(:,:,jk)                                       ! initial mask
293               hc_loc_ini(:,:,jk) = ts(:,:,jk,jp_tem,Kmm) * e3t(:,:,jk,Kmm) * tmask(:,:,jk)  ! initial heat content
294               sc_loc_ini(:,:,jk) = ts(:,:,jk,jp_sal,Kmm) * e3t(:,:,jk,Kmm) * tmask(:,:,jk)  ! initial salt content
295            END DO
296            frc_v = 0._wp                                           ! volume       trend due to forcing
297            frc_t = 0._wp                                           ! heat content   -    -   -    -   
298            frc_s = 0._wp                                           ! salt content   -    -   -    -       
299            IF( ln_linssh ) THEN
300               IF( ln_isfcav ) THEN
301                  DO ji = 1, jpi
302                     DO jj = 1, jpj
303                        ssh_hc_loc_ini(ji,jj) = ts(ji,jj,mikt(ji,jj),jp_tem,Kmm) * ssh(ji,jj,Kmm)   ! initial heat content in ssh
304                        ssh_sc_loc_ini(ji,jj) = ts(ji,jj,mikt(ji,jj),jp_sal,Kmm) * ssh(ji,jj,Kmm)   ! initial salt content in ssh
305                     END DO
306                   END DO
307                ELSE
308                  ssh_hc_loc_ini(:,:) = ts(:,:,1,jp_tem,Kmm) * ssh(:,:,Kmm)   ! initial heat content in ssh
309                  ssh_sc_loc_ini(:,:) = ts(:,:,1,jp_sal,Kmm) * ssh(:,:,Kmm)   ! initial salt content in ssh
310               END IF
311               frc_wn_t = 0._wp                                       ! initial heat content misfit due to free surface
312               frc_wn_s = 0._wp                                       ! initial salt content misfit due to free surface
313            ENDIF
314         ENDIF
315         !
316      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
317         !                                   ! -------------------
318         IF(lwp) WRITE(numout,*)
319         IF(lwp) WRITE(numout,*) '   dia_hsb_rst : write restart at it= ', kt,' date= ', ndastp
320         IF(lwp) WRITE(numout,*)
321         !
322         IF( lwxios ) CALL iom_swap(      cwxios_context          )
323         CALL iom_rstput( kt, nitrst, numrow, 'frc_v', frc_v, ldxios = lwxios )
324         CALL iom_rstput( kt, nitrst, numrow, 'frc_t', frc_t, ldxios = lwxios )
325         CALL iom_rstput( kt, nitrst, numrow, 'frc_s', frc_s, ldxios = lwxios )
326         IF( ln_linssh ) THEN
327            CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_t', frc_wn_t, ldxios = lwxios )
328            CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_s', frc_wn_s, ldxios = lwxios )
329         ENDIF
330         CALL iom_rstput( kt, nitrst, numrow, 'surf_ini'  , surf_ini  , ldxios = lwxios )      ! ice sheet coupling
331         CALL iom_rstput( kt, nitrst, numrow, 'ssh_ini'   , ssh_ini   , ldxios = lwxios )
332         CALL iom_rstput( kt, nitrst, numrow, 'e3t_ini'   , e3t_ini   , ldxios = lwxios )
333         CALL iom_rstput( kt, nitrst, numrow, 'tmask_ini' , tmask_ini , ldxios = lwxios )
334         CALL iom_rstput( kt, nitrst, numrow, 'hc_loc_ini', hc_loc_ini, ldxios = lwxios )
335         CALL iom_rstput( kt, nitrst, numrow, 'sc_loc_ini', sc_loc_ini, ldxios = lwxios )
336         IF( ln_linssh ) THEN
337            CALL iom_rstput( kt, nitrst, numrow, 'ssh_hc_loc_ini', ssh_hc_loc_ini, ldxios = lwxios )
338            CALL iom_rstput( kt, nitrst, numrow, 'ssh_sc_loc_ini', ssh_sc_loc_ini, ldxios = lwxios )
339         ENDIF
340         IF( lwxios ) CALL iom_swap(      cxios_context          )
341         !
342      ENDIF
343      !
344   END SUBROUTINE dia_hsb_rst
345
346
347   SUBROUTINE dia_hsb_init( Kmm )
348      !!---------------------------------------------------------------------------
349      !!                  ***  ROUTINE dia_hsb  ***
350      !!     
351      !! ** Purpose: Initialization for the heat salt volume budgets
352      !!
353      !! ** Method : Compute initial heat content, salt content and volume
354      !!
355      !! ** Action : - Compute initial heat content, salt content and volume
356      !!             - Initialize forcing trends
357      !!             - Compute coefficients for conversion
358      !!---------------------------------------------------------------------------
359      INTEGER, INTENT(in) :: Kmm ! time level index
360      !
361      INTEGER ::   ierror, ios   ! local integer
362      !!
363      NAMELIST/namhsb/ ln_diahsb
364      !!----------------------------------------------------------------------
365      !
366      IF(lwp) THEN
367         WRITE(numout,*)
368         WRITE(numout,*) 'dia_hsb_init : heat and salt budgets diagnostics'
369         WRITE(numout,*) '~~~~~~~~~~~~ '
370      ENDIF
371      READ  ( numnam_ref, namhsb, IOSTAT = ios, ERR = 901)
372901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namhsb in reference namelist' )
373      READ  ( numnam_cfg, namhsb, IOSTAT = ios, ERR = 902 )
374902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namhsb in configuration namelist' )
375      IF(lwm) WRITE( numond, namhsb )
376
377      IF(lwp) THEN
378         WRITE(numout,*) '   Namelist  namhsb :'
379         WRITE(numout,*) '      check the heat and salt budgets (T) or not (F)       ln_diahsb = ', ln_diahsb
380      ENDIF
381      !
382      IF( .NOT. ln_diahsb )   RETURN
383
384      IF(lwxios) THEN
385! define variables in restart file when writing with XIOS
386        CALL iom_set_rstw_var_active('frc_v')
387        CALL iom_set_rstw_var_active('frc_t')
388        CALL iom_set_rstw_var_active('frc_s')
389        CALL iom_set_rstw_var_active('surf_ini')
390        CALL iom_set_rstw_var_active('ssh_ini')
391        CALL iom_set_rstw_var_active('e3t_ini')
392        CALL iom_set_rstw_var_active('hc_loc_ini')
393        CALL iom_set_rstw_var_active('sc_loc_ini')
394        IF( ln_linssh ) THEN
395           CALL iom_set_rstw_var_active('ssh_hc_loc_ini')
396           CALL iom_set_rstw_var_active('ssh_sc_loc_ini')
397           CALL iom_set_rstw_var_active('frc_wn_t')
398           CALL iom_set_rstw_var_active('frc_wn_s')
399        ENDIF
400      ENDIF
401      ! ------------------- !
402      ! 1 - Allocate memory !
403      ! ------------------- !
404      ALLOCATE( hc_loc_ini(jpi,jpj,jpk), sc_loc_ini(jpi,jpj,jpk), surf_ini(jpi,jpj), &
405         &      e3t_ini(jpi,jpj,jpk), surf(jpi,jpj),  ssh_ini(jpi,jpj), tmask_ini(jpi,jpj,jpk),STAT=ierror  )
406      IF( ierror > 0 ) THEN
407         CALL ctl_stop( 'dia_hsb_init: unable to allocate hc_loc_ini' )   ;   RETURN
408      ENDIF
409
410      IF( ln_linssh )   ALLOCATE( ssh_hc_loc_ini(jpi,jpj), ssh_sc_loc_ini(jpi,jpj),STAT=ierror )
411      IF( ierror > 0 ) THEN
412         CALL ctl_stop( 'dia_hsb: unable to allocate ssh_hc_loc_ini' )   ;   RETURN
413      ENDIF
414
415      ! ----------------------------------------------- !
416      ! 2 - Time independant variables and file opening !
417      ! ----------------------------------------------- !
418      surf(:,:) = e1e2t(:,:) * tmask_i(:,:)               ! masked surface grid cell area
419      surf_tot  = glob_sum( 'diahsb', surf(:,:) )         ! total ocean surface area
420
421      IF( ln_bdy ) CALL ctl_warn( 'dia_hsb_init: heat/salt budget does not consider open boundary fluxes' )         
422      !
423      ! ---------------------------------- !
424      ! 4 - initial conservation variables !
425      ! ---------------------------------- !
426      CALL dia_hsb_rst( nit000, Kmm, 'READ' )  !* read or initialize all required files
427      !
428   END SUBROUTINE dia_hsb_init
429
430   !!======================================================================
431END MODULE diahsb
Note: See TracBrowser for help on using the repository browser.