New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

restart.F90 in NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/IOM – NEMO

Context Navigation

source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OCE/IOM/restart.F90 @ 11949

Last change on this file since 11949 was 11949, checked in by acc, 4 years ago
Merge in changes from 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. This just creates a fresh copy of this branch to use as the merge base. See ticket #2341
Property svn:keywords set to `Id`
File size: 16.3 KB

Rev	Line
[3]	1	MODULE restart
	2	!!======================================================================
	3	!! * MODULE restart *
	4	!! Ocean restart : write the ocean restart file
[508]	5	!!======================================================================
[2528]	6	!! History : OPA ! 1999-11 (M. Imbard) Original code
	7	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form
	8	!! 2.0 ! 2006-07 (S. Masson) use IOM for restart
	9	!! 3.3 ! 2010-04 (M. Leclair, G. Madec) modified LF-RA
	10	!! - - ! 2010-10 (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
[5836]	11	!! 3.7 ! 2014-01 (G. Madec) suppression of curl and hdiv from the restart
	12	!! - ! 2014-12 (G. Madec) remove KPP scheme
[508]	13	!!----------------------------------------------------------------------
[3]	14
	15	!!----------------------------------------------------------------------
[508]	16	!! rst_opn : open the ocean restart file
	17	!! rst_write : write the ocean restart file
	18	!! rst_read : read the ocean restart file
[3]	19	!!----------------------------------------------------------------------
[2528]	20	USE oce ! ocean dynamics and tracers
[3]	21	USE dom_oce ! ocean space and time domain
[9654]	22	USE sbc_ice ! only lk_si3
[3]	23	USE phycst ! physical constants
[5836]	24	USE eosbn2 ! equation of state (eos bn2 routine)
	25	USE trdmxl_oce ! ocean active mixed layer tracers trends variables
	26	!
[508]	27	USE in_out_manager ! I/O manager
	28	USE iom ! I/O module
[11949]	29	USE diu_bulk
[10425]	30	USE lib_mpp ! distribued memory computing library
[9367]	31
[3]	32	IMPLICIT NONE
	33	PRIVATE
	34
[4292]	35	PUBLIC rst_opn ! routine called by step module
	36	PUBLIC rst_write ! routine called by step module
	37	PUBLIC rst_read ! routine called by istate module
	38	PUBLIC rst_read_open ! routine called in rst_read and (possibly) in dom_vvl_init
[3]	39
[508]	40	!! * Substitutions
	41	# include "vectopt_loop_substitute.h90"
[3]	42	!!----------------------------------------------------------------------
[9598]	43	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
[888]	44	!! $Id$
[10068]	45	!! Software governed by the CeCILL license (see ./LICENSE)
[359]	46	!!----------------------------------------------------------------------
[3]	47	CONTAINS
	48
[508]	49	SUBROUTINE rst_opn( kt )
	50	!!---------------------------------------------------------------------
	51	!! * ROUTINE rst_opn *
	52	!!
	53	!! ** Purpose : + initialization (should be read in the namelist) of nitrst
	54	!! + open the restart when we are one time step before nitrst
	55	!! - restart header is defined when kt = nitrst-1
	56	!! - restart data are written when kt = nitrst
	57	!! + define lrst_oce to .TRUE. when we need to define or write the restart
	58	!!----------------------------------------------------------------------
	59	INTEGER, INTENT(in) :: kt ! ocean time-step
	60	!!
	61	CHARACTER(LEN=20) :: clkt ! ocean time-step deine as a character
[5341]	62	CHARACTER(LEN=50) :: clname ! ocean output restart file name
	63	CHARACTER(lc) :: clpath ! full path to ocean output restart file
[9367]	64	CHARACTER(LEN=52) :: clpname ! ocean output restart file name including prefix for AGRIF
[9535]	65	CHARACTER(LEN=256) :: clinfo ! info character
[508]	66	!!----------------------------------------------------------------------
	67	!
[783]	68	IF( kt == nit000 ) THEN ! default definitions
	69	lrst_oce = .FALSE.
[5341]	70	IF( ln_rst_list ) THEN
	71	nrst_lst = 1
[11536]	72	nitrst = nn_stocklist( nrst_lst )
[5341]	73	ELSE
	74	nitrst = nitend
	75	ENDIF
[508]	76	ENDIF
[11536]	77
	78	IF( .NOT. ln_rst_list .AND. nn_stock == -1 ) RETURN ! we will never do any restart
[5341]	79
	80	! frequency-based restart dumping (nn_stock)
[11536]	81	IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nn_stock ) == 0 ) THEN
[783]	82	! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
[11536]	83	nitrst = kt + nn_stock - 1 ! define the next value of nitrst for restart writing
[783]	84	IF( nitrst > nitend ) nitrst = nitend ! make sure we write a restart at the end of the run
	85	ENDIF
	86	! to get better performances with NetCDF format:
	87	! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
	88	! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
[11536]	89	IF( kt == nitrst - 1 .OR. nn_stock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
[5341]	90	IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
	91	! beware of the format used to write kt (default is i8.8, that should be large enough...)
	92	IF( nitrst > 999999999 ) THEN ; WRITE(clkt, * ) nitrst
	93	ELSE ; WRITE(clkt, '(i8.8)') nitrst
[611]	94	ENDIF
[5341]	95	! create the file
	96	clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
	97	clpath = TRIM(cn_ocerst_outdir)
	98	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
	99	IF(lwp) THEN
	100	WRITE(numout,*)
[9367]	101	IF(.NOT.lwxios) THEN
[10425]	102	WRITE(numout,*) ' open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
[9367]	103	IF ( snc4set%luse ) WRITE(numout,*) ' opened for NetCDF4 chunking and compression'
	104	IF( kt == nitrst - 1 ) THEN ; WRITE(numout,*) ' kt = nitrst - 1 = ', kt
	105	ELSE ; WRITE(numout,*) ' kt = ' , kt
	106	ENDIF
[5341]	107	ENDIF
	108	ENDIF
	109	!
[9367]	110	IF(.NOT.lwxios) THEN
[10425]	111	CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
[9367]	112	ELSE
[9535]	113	#if defined key_iomput
[9367]	114	cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
	115	IF( TRIM(Agrif_CFixed()) == '0' ) THEN
	116	clpname = clname
	117	ELSE
	118	clpname = TRIM(Agrif_CFixed())//"_"//clname
	119	ENDIF
[9903]	120	CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname), .false. )
[9367]	121	CALL xios_update_calendar(nitrst)
	122	CALL iom_swap( cxios_context )
[9535]	123	#else
	124	clinfo = 'Can not use XIOS in rst_opn'
	125	CALL ctl_stop(TRIM(clinfo))
	126	#endif
[9367]	127	ENDIF
[5341]	128	lrst_oce = .TRUE.
[611]	129	ENDIF
[508]	130	ENDIF
	131	!
	132	END SUBROUTINE rst_opn
	133
	134
[11949]	135	SUBROUTINE rst_write( kt, Kbb, Kmm )
[3]	136	!!---------------------------------------------------------------------
	137	!! * ROUTINE rstwrite *
	138	!!
[10425]	139	!! ** Purpose : Write restart fields in NetCDF format
[3]	140	!!
[508]	141	!! ** Method : Write in numrow when kt == nitrst in NetCDF
[2528]	142	!! file, save fields which are necessary for restart
[3]	143	!!----------------------------------------------------------------------
[11949]	144	INTEGER, INTENT(in) :: kt ! ocean time-step
	145	INTEGER, INTENT(in) :: Kbb, Kmm ! ocean time level indices
[3]	146	!!----------------------------------------------------------------------
[9367]	147	IF(lwxios) CALL iom_swap( cwxios_context )
	148	CALL iom_rstput( kt, nitrst, numrow, 'rdt' , rdt , ldxios = lwxios) ! dynamics time step
[10425]	149	CALL iom_delay_rst( 'WRITE', 'OCE', numrow ) ! save only ocean delayed global communication variables
[1239]	150
[6140]	151	IF ( .NOT. ln_diurnal_only ) THEN
[11949]	152	CALL iom_rstput( kt, nitrst, numrow, 'ub' , uu(:,:,: ,Kbb), ldxios = lwxios ) ! before fields
	153	CALL iom_rstput( kt, nitrst, numrow, 'vb' , vv(:,:,: ,Kbb), ldxios = lwxios )
	154	CALL iom_rstput( kt, nitrst, numrow, 'tb' , ts(:,:,:,jp_tem,Kbb), ldxios = lwxios )
	155	CALL iom_rstput( kt, nitrst, numrow, 'sb' , ts(:,:,:,jp_sal,Kbb), ldxios = lwxios )
	156	CALL iom_rstput( kt, nitrst, numrow, 'sshb' ,ssh(:,: ,Kbb), ldxios = lwxios )
[4990]	157	!
[11949]	158	CALL iom_rstput( kt, nitrst, numrow, 'un' , uu(:,:,: ,Kmm), ldxios = lwxios ) ! now fields
	159	CALL iom_rstput( kt, nitrst, numrow, 'vn' , vv(:,:,: ,Kmm), ldxios = lwxios )
	160	CALL iom_rstput( kt, nitrst, numrow, 'tn' , ts(:,:,:,jp_tem,Kmm), ldxios = lwxios )
	161	CALL iom_rstput( kt, nitrst, numrow, 'sn' , ts(:,:,:,jp_sal,Kmm), ldxios = lwxios )
	162	CALL iom_rstput( kt, nitrst, numrow, 'sshn' ,ssh(:,: ,Kmm), ldxios = lwxios )
[9367]	163	CALL iom_rstput( kt, nitrst, numrow, 'rhop' , rhop, ldxios = lwxios )
[6140]	164	! extra variable needed for the ice sheet coupling
	165	IF ( ln_iscpl ) THEN
[9367]	166	CALL iom_rstput( kt, nitrst, numrow, 'tmask' , tmask, ldxios = lwxios ) ! need to extrapolate T/S
	167	CALL iom_rstput( kt, nitrst, numrow, 'umask' , umask, ldxios = lwxios ) ! need to correct barotropic velocity
	168	CALL iom_rstput( kt, nitrst, numrow, 'vmask' , vmask, ldxios = lwxios ) ! need to correct barotropic velocity
	169	CALL iom_rstput( kt, nitrst, numrow, 'smask' , ssmask, ldxios = lwxios) ! need to correct barotropic velocity
[11949]	170	CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t(:,:,:,Kmm), ldxios = lwxios ) ! need to compute temperature correction
	171	CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u(:,:,:,Kmm), ldxios = lwxios ) ! need to compute bt conservation
	172	CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v(:,:,:,Kmm), ldxios = lwxios ) ! need to compute bt conservation
	173	CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw(:,:,:,Kmm), ldxios = lwxios ) ! need to compute extrapolation if vvl
[6140]	174	END IF
	175	ENDIF
	176
[9367]	177	IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios )
	178	IF(lwxios) CALL iom_swap( cxios_context )
[508]	179	IF( kt == nitrst ) THEN
[9367]	180	IF(.NOT.lwxios) THEN
	181	CALL iom_close( numrow ) ! close the restart file (only at last time step)
	182	ELSE
	183	CALL iom_context_finalize( cwxios_context )
	184	ENDIF
[4990]	185	!!gm IF( .NOT. lk_trdmld ) lrst_oce = .FALSE.
	186	!!gm not sure what to do here ===>>> ask to Sebastian
	187	lrst_oce = .FALSE.
[5341]	188	IF( ln_rst_list ) THEN
[11536]	189	nrst_lst = MIN(nrst_lst + 1, SIZE(nn_stocklist,1))
	190	nitrst = nn_stocklist( nrst_lst )
[5341]	191	ENDIF
[3]	192	ENDIF
[508]	193	!
[3]	194	END SUBROUTINE rst_write
	195
[4990]	196
[4292]	197	SUBROUTINE rst_read_open
	198	!!----------------------------------------------------------------------
	199	!! * ROUTINE rst_read_open *
	200	!!
[10425]	201	!! ** Purpose : Open read files for NetCDF restart
[4292]	202	!!
	203	!! ** Method : Use a non-zero, positive value of numror to assess whether or not
	204	!! the file has already been opened
	205	!!----------------------------------------------------------------------
[5341]	206	LOGICAL :: llok
	207	CHARACTER(lc) :: clpath ! full path to ocean output restart file
[4292]	208	!!----------------------------------------------------------------------
[4990]	209	!
	210	IF( numror <= 0 ) THEN
[4292]	211	IF(lwp) THEN ! Contol prints
	212	WRITE(numout,*)
[10425]	213	WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
[4292]	214	IF ( snc4set%luse ) WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
	215	WRITE(numout,*) '~~~~~~~~'
	216	ENDIF
[9367]	217	lxios_sini = .FALSE.
[5341]	218	clpath = TRIM(cn_ocerst_indir)
	219	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
[10425]	220	CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
[9367]	221	! are we using XIOS to read the data? Part above will have to modified once XIOS
	222	! can handle checking if variable is in the restart file (there will be no need to open
	223	! restart)
	224	IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
	225	IF( lrxios) THEN
	226	crxios_context = 'nemo_rst'
	227	IF( .NOT.lxios_set ) THEN
	228	IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
[9903]	229	CALL iom_init( crxios_context, ld_tmppatch = .false. )
[9367]	230	lxios_set = .TRUE.
	231	ENDIF
	232	ENDIF
	233	IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
[9903]	234	CALL iom_init( crxios_context, ld_tmppatch = .false. )
[9367]	235	IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
	236	lxios_set = .TRUE.
	237	ENDIF
[4292]	238	ENDIF
[9367]	239
[4292]	240	END SUBROUTINE rst_read_open
	241
[5836]	242
[11949]	243	SUBROUTINE rst_read( Kbb, Kmm )
[3]	244	!!----------------------------------------------------------------------
	245	!! * ROUTINE rst_read *
	246	!!
[10425]	247	!! ** Purpose : Read files for NetCDF restart
[3]	248	!!
[1531]	249	!! ** Method : Read in restart.nc file fields which are necessary for restart
[3]	250	!!----------------------------------------------------------------------
[11949]	251	INTEGER, INTENT(in) :: Kbb, Kmm ! ocean time level indices
[6140]	252	REAL(wp) :: zrdt
[4292]	253	INTEGER :: jk
[9367]	254	REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
[3]	255	!!----------------------------------------------------------------------
	256
[4292]	257	CALL rst_read_open ! open restart for reading (if not already opened)
[3]	258
[544]	259	! Check dynamics and tracer time-step consistency and force Euler restart if changed
[746]	260	IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 ) THEN
[9367]	261	CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
[544]	262	IF( zrdt /= rdt ) neuler = 0
	263	ENDIF
[6140]	264
[10425]	265	CALL iom_delay_rst( 'READ', 'OCE', numror ) ! read only ocean delayed global communication variables
	266
[6140]	267	! Diurnal DSST
[9367]	268	IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios )
[6140]	269	IF ( ln_diurnal_only ) THEN
	270	IF(lwp) WRITE( numout, * ) &
	271	& "rst_read:- ln_diurnal_only set, setting rhop=rau0"
	272	rhop = rau0
[9367]	273	CALL iom_get( numror, jpdom_autoglo, 'tn' , w3d, ldxios = lrxios )
[11949]	274	ts(:,:,1,jp_tem,Kmm) = w3d(:,:,1)
[6140]	275	RETURN
	276	ENDIF
	277
[3680]	278	IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
[11949]	279	CALL iom_get( numror, jpdom_autoglo, 'ub' , uu(:,:,: ,Kbb), ldxios = lrxios ) ! before fields
	280	CALL iom_get( numror, jpdom_autoglo, 'vb' , vv(:,:,: ,Kbb), ldxios = lrxios )
	281	CALL iom_get( numror, jpdom_autoglo, 'tb' , ts(:,:,:,jp_tem,Kbb), ldxios = lrxios )
	282	CALL iom_get( numror, jpdom_autoglo, 'sb' , ts(:,:,:,jp_sal,Kbb), ldxios = lrxios )
	283	CALL iom_get( numror, jpdom_autoglo, 'sshb' ,ssh(:,: ,Kbb), ldxios = lrxios )
[3680]	284	ELSE
	285	neuler = 0
	286	ENDIF
	287	!
[11949]	288	CALL iom_get( numror, jpdom_autoglo, 'un' , uu(:,:,: ,Kmm), ldxios = lrxios ) ! now fields
	289	CALL iom_get( numror, jpdom_autoglo, 'vn' , vv(:,:,: ,Kmm), ldxios = lrxios )
	290	CALL iom_get( numror, jpdom_autoglo, 'tn' , ts(:,:,:,jp_tem,Kmm), ldxios = lrxios )
	291	CALL iom_get( numror, jpdom_autoglo, 'sn' , ts(:,:,:,jp_sal,Kmm), ldxios = lrxios )
	292	CALL iom_get( numror, jpdom_autoglo, 'sshn' ,ssh(:,: ,Kmm), ldxios = lrxios )
[3680]	293	IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
[9367]	294	CALL iom_get( numror, jpdom_autoglo, 'rhop' , rhop, ldxios = lrxios ) ! now potential density
[3680]	295	ELSE
[11949]	296	CALL eos( ts(:,:,:,:,Kmm), rhd, rhop, gdept(:,:,:,Kmm) )
[3680]	297	ENDIF
[2528]	298	!
[508]	299	IF( neuler == 0 ) THEN ! Euler restart (neuler=0)
[11949]	300	ts (:,:,:,:,Kbb) = ts (:,:,:,:,Kmm) ! all before fields set to now values
	301	uu (:,:,: ,Kbb) = uu (:,:,: ,Kmm)
	302	vv (:,:,: ,Kbb) = vv (:,:,: ,Kmm)
	303	ssh (:,: ,Kbb) = ssh (:,: ,Kmm)
[5836]	304	!
[6140]	305	IF( .NOT.ln_linssh ) THEN
[4689]	306	DO jk = 1, jpk
[11949]	307	e3t(:,:,jk,Kbb) = e3t(:,:,jk,Kmm)
[4689]	308	END DO
	309	ENDIF
[5836]	310	!
[3]	311	ENDIF
[508]	312	!
	313	END SUBROUTINE rst_read
[473]	314
[3]	315	!!=====================================================================
	316	END MODULE restart

Note: See TracBrowser for help on using the repository browser.

Download in other formats: