| 1 | MODULE sbcblk |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcblk *** |
|---|
| 4 | !! Ocean forcing: momentum, heat and freshwater flux formulation |
|---|
| 5 | !! Aerodynamic Bulk Formulas |
|---|
| 6 | !! SUCCESSOR OF "sbcblk_core" |
|---|
| 7 | !!===================================================================== |
|---|
| 8 | !! History : 1.0 ! 2004-08 (U. Schweckendiek) Original CORE code |
|---|
| 9 | !! 2.0 ! 2005-04 (L. Brodeau, A.M. Treguier) improved CORE bulk and its user interface |
|---|
| 10 | !! 3.0 ! 2006-06 (G. Madec) sbc rewritting |
|---|
| 11 | !! - ! 2006-12 (L. Brodeau) Original code for turb_core |
|---|
| 12 | !! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put |
|---|
| 13 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 14 | !! 3.4 ! 2011-11 (C. Harris) Fill arrays required by CICE |
|---|
| 15 | !! 3.7 ! 2014-06 (L. Brodeau) simplification and optimization of CORE bulk |
|---|
| 16 | !! 4.0 ! 2016-06 (L. Brodeau) sbcblk_core becomes sbcblk and is not restricted to the CORE algorithm anymore |
|---|
| 17 | !! ! ==> based on AeroBulk (https://github.com/brodeau/aerobulk/) |
|---|
| 18 | !! 4.0 ! 2016-10 (G. Madec) introduce a sbc_blk_init routine |
|---|
| 19 | !! 4.0 ! 2016-10 (M. Vancoppenolle) Introduce conduction flux emulator (M. Vancoppenolle) |
|---|
| 20 | !! 4.0 ! 2019-03 (F. Lemarié & G. Samson) add ABL compatibility (ln_abl=TRUE) |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | |
|---|
| 23 | !!---------------------------------------------------------------------- |
|---|
| 24 | !! sbc_blk_init : initialisation of the chosen bulk formulation as ocean surface boundary condition |
|---|
| 25 | !! sbc_blk : bulk formulation as ocean surface boundary condition |
|---|
| 26 | !! blk_oce_1 : computes pieces of momentum, heat and freshwater fluxes over ocean for ABL model (ln_abl=TRUE) |
|---|
| 27 | !! blk_oce_2 : finalizes momentum, heat and freshwater fluxes computation over ocean after the ABL step (ln_abl=TRUE) |
|---|
| 28 | !! sea-ice case only : |
|---|
| 29 | !! blk_ice_1 : provide the air-ice stress |
|---|
| 30 | !! blk_ice_2 : provide the heat and mass fluxes at air-ice interface |
|---|
| 31 | !! blk_ice_qcn : provide ice surface temperature and snow/ice conduction flux (emulating conduction flux) |
|---|
| 32 | !! Cdn10_Lupkes2012 : Lupkes et al. (2012) air-ice drag |
|---|
| 33 | !! Cdn10_Lupkes2015 : Lupkes et al. (2015) air-ice drag |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | USE oce ! ocean dynamics and tracers |
|---|
| 36 | USE dom_oce ! ocean space and time domain |
|---|
| 37 | USE phycst ! physical constants |
|---|
| 38 | USE fldread ! read input fields |
|---|
| 39 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 40 | USE cyclone ! Cyclone 10m wind form trac of cyclone centres |
|---|
| 41 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 42 | USE sbcwave , ONLY : cdn_wave ! wave module |
|---|
| 43 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 44 | USE lib_fortran ! to use key_nosignedzero |
|---|
| 45 | #if defined key_si3 |
|---|
| 46 | USE ice , ONLY : jpl, a_i_b, at_i_b, rn_cnd_s, hfx_err_dif |
|---|
| 47 | USE icethd_dh ! for CALL ice_thd_snwblow |
|---|
| 48 | #endif |
|---|
| 49 | USE sbcblk_algo_ncar ! => turb_ncar : NCAR - CORE (Large & Yeager, 2009) |
|---|
| 50 | USE sbcblk_algo_coare3p0 ! => turb_coare3p0 : COAREv3.0 (Fairall et al. 2003) |
|---|
| 51 | USE sbcblk_algo_coare3p6 ! => turb_coare3p6 : COAREv3.6 (Fairall et al. 2018 + Edson et al. 2013) |
|---|
| 52 | USE sbcblk_algo_ecmwf ! => turb_ecmwf : ECMWF (IFS cycle 45r1) |
|---|
| 53 | ! |
|---|
| 54 | USE iom ! I/O manager library |
|---|
| 55 | USE in_out_manager ! I/O manager |
|---|
| 56 | USE lib_mpp ! distribued memory computing library |
|---|
| 57 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 58 | USE prtctl ! Print control |
|---|
| 59 | |
|---|
| 60 | USE sbcblk_phy ! a catalog of functions for physical/meteorological parameters in the marine boundary layer, rho_air, q_sat, etc... |
|---|
| 61 | |
|---|
| 62 | |
|---|
| 63 | IMPLICIT NONE |
|---|
| 64 | PRIVATE |
|---|
| 65 | |
|---|
| 66 | PUBLIC sbc_blk_init ! called in sbcmod |
|---|
| 67 | PUBLIC sbc_blk ! called in sbcmod |
|---|
| 68 | PUBLIC blk_oce_1 ! called in sbcabl |
|---|
| 69 | PUBLIC blk_oce_2 ! called in sbcabl |
|---|
| 70 | #if defined key_si3 |
|---|
| 71 | PUBLIC blk_ice_1 ! routine called in icesbc |
|---|
| 72 | PUBLIC blk_ice_2 ! routine called in icesbc |
|---|
| 73 | PUBLIC blk_ice_qcn ! routine called in icesbc |
|---|
| 74 | #endif |
|---|
| 75 | |
|---|
| 76 | INTEGER , PUBLIC :: jpfld ! maximum number of files to read |
|---|
| 77 | INTEGER , PUBLIC, PARAMETER :: jp_wndi = 1 ! index of 10m wind velocity (i-component) (m/s) at T-point |
|---|
| 78 | INTEGER , PUBLIC, PARAMETER :: jp_wndj = 2 ! index of 10m wind velocity (j-component) (m/s) at T-point |
|---|
| 79 | INTEGER , PUBLIC, PARAMETER :: jp_tair = 3 ! index of 10m air temperature (Kelvin) |
|---|
| 80 | INTEGER , PUBLIC, PARAMETER :: jp_humi = 4 ! index of specific humidity ( % ) |
|---|
| 81 | INTEGER , PUBLIC, PARAMETER :: jp_qsr = 5 ! index of solar heat (W/m2) |
|---|
| 82 | INTEGER , PUBLIC, PARAMETER :: jp_qlw = 6 ! index of Long wave (W/m2) |
|---|
| 83 | INTEGER , PUBLIC, PARAMETER :: jp_prec = 7 ! index of total precipitation (rain+snow) (Kg/m2/s) |
|---|
| 84 | INTEGER , PUBLIC, PARAMETER :: jp_snow = 8 ! index of snow (solid prcipitation) (kg/m2/s) |
|---|
| 85 | INTEGER , PUBLIC, PARAMETER :: jp_slp = 9 ! index of sea level pressure (Pa) |
|---|
| 86 | INTEGER , PUBLIC, PARAMETER :: jp_hpgi =10 ! index of ABL geostrophic wind or hpg (i-component) (m/s) at T-point |
|---|
| 87 | INTEGER , PUBLIC, PARAMETER :: jp_hpgj =11 ! index of ABL geostrophic wind or hpg (j-component) (m/s) at T-point |
|---|
| 88 | |
|---|
| 89 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf ! structure of input atmospheric fields (file informations, fields read) |
|---|
| 90 | |
|---|
| 91 | ! !!* Namelist namsbc_blk : bulk parameters |
|---|
| 92 | LOGICAL :: ln_NCAR ! "NCAR" algorithm (Large and Yeager 2008) |
|---|
| 93 | LOGICAL :: ln_COARE_3p0 ! "COARE 3.0" algorithm (Fairall et al. 2003) |
|---|
| 94 | LOGICAL :: ln_COARE_3p6 ! "COARE 3.6" algorithm (Edson et al. 2013) |
|---|
| 95 | LOGICAL :: ln_ECMWF ! "ECMWF" algorithm (IFS cycle 45r1) |
|---|
| 96 | ! |
|---|
| 97 | LOGICAL :: ln_Cd_L12 ! ice-atm drag = F( ice concentration ) (Lupkes et al. JGR2012) |
|---|
| 98 | LOGICAL :: ln_Cd_L15 ! ice-atm drag = F( ice concentration, atmospheric stability ) (Lupkes et al. JGR2015) |
|---|
| 99 | ! |
|---|
| 100 | REAL(wp) :: rn_pfac ! multiplication factor for precipitation |
|---|
| 101 | REAL(wp), PUBLIC :: rn_efac ! multiplication factor for evaporation |
|---|
| 102 | REAL(wp), PUBLIC :: rn_vfac ! multiplication factor for ice/ocean velocity in the calculation of wind stress |
|---|
| 103 | REAL(wp) :: rn_zqt ! z(q,t) : height of humidity and temperature measurements |
|---|
| 104 | REAL(wp) :: rn_zu ! z(u) : height of wind measurements |
|---|
| 105 | ! |
|---|
| 106 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: Cd_ice , Ch_ice , Ce_ice ! transfert coefficients over ice |
|---|
| 107 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: Cdn_oce, Chn_oce, Cen_oce ! neutral coeffs over ocean (L15 bulk scheme) |
|---|
| 108 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: t_zu, q_zu ! air temp. and spec. hum. at wind speed height (L15 bulk scheme) |
|---|
| 109 | |
|---|
| 110 | LOGICAL :: ln_skin_cs ! use the cool-skin (only available in ECMWF and COARE algorithms) !LB |
|---|
| 111 | LOGICAL :: ln_skin_wl ! use the warm-layer parameterization (only available in ECMWF and COARE algorithms) !LB |
|---|
| 112 | LOGICAL :: ln_humi_sph ! humidity read in files ("sn_humi") is specific humidity [kg/kg] if .true. !LB |
|---|
| 113 | LOGICAL :: ln_humi_dpt ! humidity read in files ("sn_humi") is dew-point temperature [K] if .true. !LB |
|---|
| 114 | LOGICAL :: ln_humi_rlh ! humidity read in files ("sn_humi") is relative humidity [%] if .true. !LB |
|---|
| 115 | ! |
|---|
| 116 | INTEGER :: nhumi ! choice of the bulk algorithm |
|---|
| 117 | ! ! associated indices: |
|---|
| 118 | INTEGER, PARAMETER :: np_humi_sph = 1 |
|---|
| 119 | INTEGER, PARAMETER :: np_humi_dpt = 2 |
|---|
| 120 | INTEGER, PARAMETER :: np_humi_rlh = 3 |
|---|
| 121 | |
|---|
| 122 | INTEGER :: nblk ! choice of the bulk algorithm |
|---|
| 123 | ! ! associated indices: |
|---|
| 124 | INTEGER, PARAMETER :: np_NCAR = 1 ! "NCAR" algorithm (Large and Yeager 2008) |
|---|
| 125 | INTEGER, PARAMETER :: np_COARE_3p0 = 2 ! "COARE 3.0" algorithm (Fairall et al. 2003) |
|---|
| 126 | INTEGER, PARAMETER :: np_COARE_3p6 = 3 ! "COARE 3.6" algorithm (Edson et al. 2013) |
|---|
| 127 | INTEGER, PARAMETER :: np_ECMWF = 4 ! "ECMWF" algorithm (IFS cycle 45r1) |
|---|
| 128 | |
|---|
| 129 | !! * Substitutions |
|---|
| 130 | # include "vectopt_loop_substitute.h90" |
|---|
| 131 | !!---------------------------------------------------------------------- |
|---|
| 132 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 133 | !! $Id$ |
|---|
| 134 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 135 | !!---------------------------------------------------------------------- |
|---|
| 136 | CONTAINS |
|---|
| 137 | |
|---|
| 138 | INTEGER FUNCTION sbc_blk_alloc() |
|---|
| 139 | !!------------------------------------------------------------------- |
|---|
| 140 | !! *** ROUTINE sbc_blk_alloc *** |
|---|
| 141 | !!------------------------------------------------------------------- |
|---|
| 142 | ALLOCATE( t_zu(jpi,jpj) , q_zu(jpi,jpj) , & |
|---|
| 143 | & Cdn_oce(jpi,jpj), Chn_oce(jpi,jpj), Cen_oce(jpi,jpj), & |
|---|
| 144 | & Cd_ice (jpi,jpj), Ch_ice (jpi,jpj), Ce_ice (jpi,jpj), STAT=sbc_blk_alloc ) |
|---|
| 145 | ! |
|---|
| 146 | CALL mpp_sum ( 'sbcblk', sbc_blk_alloc ) |
|---|
| 147 | IF( sbc_blk_alloc /= 0 ) CALL ctl_stop( 'STOP', 'sbc_blk_alloc: failed to allocate arrays' ) |
|---|
| 148 | END FUNCTION sbc_blk_alloc |
|---|
| 149 | |
|---|
| 150 | |
|---|
| 151 | SUBROUTINE sbc_blk_init |
|---|
| 152 | !!--------------------------------------------------------------------- |
|---|
| 153 | !! *** ROUTINE sbc_blk_init *** |
|---|
| 154 | !! |
|---|
| 155 | !! ** Purpose : choose and initialize a bulk formulae formulation |
|---|
| 156 | !! |
|---|
| 157 | !! ** Method : |
|---|
| 158 | !! |
|---|
| 159 | !!---------------------------------------------------------------------- |
|---|
| 160 | INTEGER :: jfpr ! dummy loop indice and argument |
|---|
| 161 | INTEGER :: ios, ierror, ioptio ! Local integer |
|---|
| 162 | !! |
|---|
| 163 | CHARACTER(len=100) :: cn_dir ! Root directory for location of atmospheric forcing files |
|---|
| 164 | TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: slf_i ! array of namelist informations on the fields to read |
|---|
| 165 | TYPE(FLD_N) :: sn_wndi, sn_wndj, sn_humi, sn_qsr ! informations about the fields to be read |
|---|
| 166 | TYPE(FLD_N) :: sn_qlw , sn_tair, sn_prec, sn_snow ! " " |
|---|
| 167 | TYPE(FLD_N) :: sn_slp , sn_hpgi, sn_hpgj ! " " |
|---|
| 168 | NAMELIST/namsbc_blk/ sn_wndi, sn_wndj, sn_humi, sn_qsr, sn_qlw , & ! input fields |
|---|
| 169 | & sn_tair, sn_prec, sn_snow, sn_slp, sn_hpgi, sn_hpgj, & |
|---|
| 170 | & ln_NCAR, ln_COARE_3p0, ln_COARE_3p6, ln_ECMWF, & ! bulk algorithm |
|---|
| 171 | & cn_dir , rn_zqt, rn_zu, & |
|---|
| 172 | & rn_pfac, rn_efac, rn_vfac, ln_Cd_L12, ln_Cd_L15, & |
|---|
| 173 | & ln_skin_cs, ln_skin_wl, ln_humi_sph, ln_humi_dpt, ln_humi_rlh ! cool-skin / warm-layer !LB |
|---|
| 174 | !!--------------------------------------------------------------------- |
|---|
| 175 | ! |
|---|
| 176 | ! ! allocate sbc_blk_core array |
|---|
| 177 | IF( sbc_blk_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_blk : unable to allocate standard arrays' ) |
|---|
| 178 | ! |
|---|
| 179 | ! !** read bulk namelist |
|---|
| 180 | READ ( numnam_ref, namsbc_blk, IOSTAT = ios, ERR = 901) |
|---|
| 181 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_blk in reference namelist' ) |
|---|
| 182 | ! |
|---|
| 183 | READ ( numnam_cfg, namsbc_blk, IOSTAT = ios, ERR = 902 ) |
|---|
| 184 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namsbc_blk in configuration namelist' ) |
|---|
| 185 | ! |
|---|
| 186 | IF(lwm) WRITE( numond, namsbc_blk ) |
|---|
| 187 | ! |
|---|
| 188 | ! !** initialization of the chosen bulk formulae (+ check) |
|---|
| 189 | ! !* select the bulk chosen in the namelist and check the choice |
|---|
| 190 | ioptio = 0 |
|---|
| 191 | IF( ln_NCAR ) THEN |
|---|
| 192 | nblk = np_NCAR ; ioptio = ioptio + 1 |
|---|
| 193 | ENDIF |
|---|
| 194 | IF( ln_COARE_3p0 ) THEN |
|---|
| 195 | nblk = np_COARE_3p0 ; ioptio = ioptio + 1 |
|---|
| 196 | ENDIF |
|---|
| 197 | IF( ln_COARE_3p6 ) THEN |
|---|
| 198 | nblk = np_COARE_3p6 ; ioptio = ioptio + 1 |
|---|
| 199 | ENDIF |
|---|
| 200 | IF( ln_ECMWF ) THEN |
|---|
| 201 | nblk = np_ECMWF ; ioptio = ioptio + 1 |
|---|
| 202 | ENDIF |
|---|
| 203 | IF( ioptio /= 1 ) CALL ctl_stop( 'sbc_blk_init: Choose one and only one bulk algorithm' ) |
|---|
| 204 | |
|---|
| 205 | ! !** initialization of the cool-skin / warm-layer parametrization |
|---|
| 206 | IF( ln_skin_cs .OR. ln_skin_wl ) THEN |
|---|
| 207 | !! Some namelist sanity tests: |
|---|
| 208 | IF( ln_NCAR ) & |
|---|
| 209 | & CALL ctl_stop( 'sbc_blk_init: Cool-skin/warm-layer param. not compatible with NCAR algorithm' ) |
|---|
| 210 | IF( nn_fsbc /= 1 ) & |
|---|
| 211 | & CALL ctl_stop( 'sbc_blk_init: Please set "nn_fsbc" to 1 when using cool-skin/warm-layer param.') |
|---|
| 212 | END IF |
|---|
| 213 | |
|---|
| 214 | IF( ln_skin_wl ) THEN |
|---|
| 215 | !! Check if the frequency of downwelling solar flux input makes sense and if ln_dm2dc=T if it is daily! |
|---|
| 216 | IF( (sn_qsr%freqh < 0.).OR.(sn_qsr%freqh > 24.) ) & |
|---|
| 217 | & CALL ctl_stop( 'sbc_blk_init: Warm-layer param. (ln_skin_wl) not compatible with freq. of solar flux > daily' ) |
|---|
| 218 | IF( (sn_qsr%freqh == 24.).AND.(.NOT. ln_dm2dc) ) & |
|---|
| 219 | & CALL ctl_stop( 'sbc_blk_init: Please set ln_dm2dc=T for warm-layer param. (ln_skin_wl) to work properly' ) |
|---|
| 220 | END IF |
|---|
| 221 | |
|---|
| 222 | ioptio = 0 |
|---|
| 223 | IF( ln_humi_sph ) THEN |
|---|
| 224 | nhumi = np_humi_sph ; ioptio = ioptio + 1 |
|---|
| 225 | ENDIF |
|---|
| 226 | IF( ln_humi_dpt ) THEN |
|---|
| 227 | nhumi = np_humi_dpt ; ioptio = ioptio + 1 |
|---|
| 228 | ENDIF |
|---|
| 229 | IF( ln_humi_rlh ) THEN |
|---|
| 230 | nhumi = np_humi_rlh ; ioptio = ioptio + 1 |
|---|
| 231 | ENDIF |
|---|
| 232 | IF( ioptio /= 1 ) CALL ctl_stop( 'sbc_blk_init: Choose one and only one type of air humidity' ) |
|---|
| 233 | ! |
|---|
| 234 | IF( ln_dm2dc ) THEN !* check: diurnal cycle on Qsr |
|---|
| 235 | IF( sn_qsr%freqh /= 24. ) CALL ctl_stop( 'sbc_blk_init: ln_dm2dc=T only with daily short-wave input' ) |
|---|
| 236 | IF( sn_qsr%ln_tint ) THEN |
|---|
| 237 | CALL ctl_warn( 'sbc_blk_init: ln_dm2dc=T daily qsr time interpolation done by sbcdcy module', & |
|---|
| 238 | & ' ==> We force time interpolation = .false. for qsr' ) |
|---|
| 239 | sn_qsr%ln_tint = .false. |
|---|
| 240 | ENDIF |
|---|
| 241 | ENDIF |
|---|
| 242 | ! !* set the bulk structure |
|---|
| 243 | ! !- store namelist information in an array |
|---|
| 244 | IF( ln_blk ) jpfld = 9 |
|---|
| 245 | IF( ln_abl ) jpfld = 11 |
|---|
| 246 | ALLOCATE( slf_i(jpfld) ) |
|---|
| 247 | ! |
|---|
| 248 | slf_i(jp_wndi) = sn_wndi ; slf_i(jp_wndj) = sn_wndj |
|---|
| 249 | slf_i(jp_qsr ) = sn_qsr ; slf_i(jp_qlw ) = sn_qlw |
|---|
| 250 | slf_i(jp_tair) = sn_tair ; slf_i(jp_humi) = sn_humi |
|---|
| 251 | slf_i(jp_prec) = sn_prec ; slf_i(jp_snow) = sn_snow |
|---|
| 252 | slf_i(jp_slp ) = sn_slp |
|---|
| 253 | IF( ln_abl ) THEN |
|---|
| 254 | slf_i(jp_hpgi) = sn_hpgi ; slf_i(jp_hpgj) = sn_hpgj |
|---|
| 255 | END IF |
|---|
| 256 | ! |
|---|
| 257 | ! !- allocate the bulk structure |
|---|
| 258 | ALLOCATE( sf(jpfld), STAT=ierror ) |
|---|
| 259 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_blk_init: unable to allocate sf structure' ) |
|---|
| 260 | ! |
|---|
| 261 | DO jfpr= 1, jpfld |
|---|
| 262 | ! |
|---|
| 263 | IF( TRIM(sf(jfpr)%clrootname) == 'NOT USED' ) THEN !-- not used field --! (only now allocated and set to zero) |
|---|
| 264 | ALLOCATE( sf(jfpr)%fnow(jpi,jpj,1) ) |
|---|
| 265 | sf(jfpr)%fnow(:,:,1) = 0._wp |
|---|
| 266 | ELSE !-- used field --! |
|---|
| 267 | IF( ln_abl .AND. & |
|---|
| 268 | & ( jfpr == jp_wndi .OR. jfpr == jp_wndj .OR. jfpr == jp_humi .OR. & |
|---|
| 269 | & jfpr == jp_hpgi .OR. jfpr == jp_hpgj .OR. jfpr == jp_tair ) ) THEN ! ABL: some fields are 3D input |
|---|
| 270 | ALLOCATE( sf(jfpr)%fnow(jpi,jpj,jpka) ) |
|---|
| 271 | IF( slf_i(jfpr)%ln_tint ) ALLOCATE( sf(jfpr)%fdta(jpi,jpj,jpka,2) ) |
|---|
| 272 | ELSE ! others or Bulk fields are 2D fiels |
|---|
| 273 | ALLOCATE( sf(jfpr)%fnow(jpi,jpj,1) ) |
|---|
| 274 | IF( slf_i(jfpr)%ln_tint ) ALLOCATE( sf(jfpr)%fdta(jpi,jpj,1,2) ) |
|---|
| 275 | ENDIF |
|---|
| 276 | ! |
|---|
| 277 | IF( slf_i(jfpr)%freqh > 0. .AND. MOD( NINT(3600. * slf_i(jfpr)%freqh), nn_fsbc * NINT(rdt) ) /= 0 ) & |
|---|
| 278 | & CALL ctl_warn( 'sbc_blk_init: sbcmod timestep rdt*nn_fsbc is NOT a submultiple of atmospheric forcing frequency.', & |
|---|
| 279 | & ' This is not ideal. You should consider changing either rdt or nn_fsbc value...' ) |
|---|
| 280 | ENDIF |
|---|
| 281 | END DO |
|---|
| 282 | ! !- fill the bulk structure with namelist informations |
|---|
| 283 | CALL fld_fill( sf, slf_i, cn_dir, 'sbc_blk_init', 'surface boundary condition -- bulk formulae', 'namsbc_blk' ) |
|---|
| 284 | ! |
|---|
| 285 | IF( ln_wave ) THEN |
|---|
| 286 | !Activated wave module but neither drag nor stokes drift activated |
|---|
| 287 | IF( .NOT.(ln_cdgw .OR. ln_sdw .OR. ln_tauwoc .OR. ln_stcor ) ) THEN |
|---|
| 288 | CALL ctl_stop( 'STOP', 'Ask for wave coupling but ln_cdgw=F, ln_sdw=F, ln_tauwoc=F, ln_stcor=F' ) |
|---|
| 289 | !drag coefficient read from wave model definable only with mfs bulk formulae and core |
|---|
| 290 | ELSEIF(ln_cdgw .AND. .NOT. ln_NCAR ) THEN |
|---|
| 291 | CALL ctl_stop( 'drag coefficient read from wave model definable only with NCAR and CORE bulk formulae') |
|---|
| 292 | ELSEIF(ln_stcor .AND. .NOT. ln_sdw) THEN |
|---|
| 293 | CALL ctl_stop( 'Stokes-Coriolis term calculated only if activated Stokes Drift ln_sdw=T') |
|---|
| 294 | ENDIF |
|---|
| 295 | ELSE |
|---|
| 296 | IF( ln_cdgw .OR. ln_sdw .OR. ln_tauwoc .OR. ln_stcor ) & |
|---|
| 297 | & CALL ctl_stop( 'Not Activated Wave Module (ln_wave=F) but asked coupling ', & |
|---|
| 298 | & 'with drag coefficient (ln_cdgw =T) ' , & |
|---|
| 299 | & 'or Stokes Drift (ln_sdw=T) ' , & |
|---|
| 300 | & 'or ocean stress modification due to waves (ln_tauwoc=T) ', & |
|---|
| 301 | & 'or Stokes-Coriolis term (ln_stcori=T)' ) |
|---|
| 302 | ENDIF |
|---|
| 303 | ! |
|---|
| 304 | IF( ln_abl ) THEN ! ABL: read 3D fields for wind, temperature, humidity and pressure gradient |
|---|
| 305 | rn_zqt = ght_abl(2) ! set the bulk altitude to ABL first level |
|---|
| 306 | rn_zu = ght_abl(2) |
|---|
| 307 | IF(lwp) WRITE(numout,*) |
|---|
| 308 | IF(lwp) WRITE(numout,*) ' ABL formulation: overwrite rn_zqt & rn_zu with ABL first level altitude' |
|---|
| 309 | ENDIF |
|---|
| 310 | ! |
|---|
| 311 | ! set transfer coefficients to default sea-ice values |
|---|
| 312 | Cd_ice(:,:) = rCd_ice |
|---|
| 313 | Ch_ice(:,:) = rCd_ice |
|---|
| 314 | Ce_ice(:,:) = rCd_ice |
|---|
| 315 | ! |
|---|
| 316 | IF(lwp) THEN !** Control print |
|---|
| 317 | ! |
|---|
| 318 | WRITE(numout,*) !* namelist |
|---|
| 319 | WRITE(numout,*) ' Namelist namsbc_blk (other than data information):' |
|---|
| 320 | WRITE(numout,*) ' "NCAR" algorithm (Large and Yeager 2008) ln_NCAR = ', ln_NCAR |
|---|
| 321 | WRITE(numout,*) ' "COARE 3.0" algorithm (Fairall et al. 2003) ln_COARE_3p0 = ', ln_COARE_3p0 |
|---|
| 322 | WRITE(numout,*) ' "COARE 3.6" algorithm (Fairall 2018 + Edson al 2013)ln_COARE_3p6 = ', ln_COARE_3p6 |
|---|
| 323 | WRITE(numout,*) ' "ECMWF" algorithm (IFS cycle 45r1) ln_ECMWF = ', ln_ECMWF |
|---|
| 324 | WRITE(numout,*) ' Air temperature and humidity reference height (m) rn_zqt = ', rn_zqt |
|---|
| 325 | WRITE(numout,*) ' Wind vector reference height (m) rn_zu = ', rn_zu |
|---|
| 326 | WRITE(numout,*) ' factor applied on precipitation (total & snow) rn_pfac = ', rn_pfac |
|---|
| 327 | WRITE(numout,*) ' factor applied on evaporation rn_efac = ', rn_efac |
|---|
| 328 | WRITE(numout,*) ' factor applied on ocean/ice velocity rn_vfac = ', rn_vfac |
|---|
| 329 | WRITE(numout,*) ' (form absolute (=0) to relative winds(=1))' |
|---|
| 330 | WRITE(numout,*) ' use ice-atm drag from Lupkes2012 ln_Cd_L12 = ', ln_Cd_L12 |
|---|
| 331 | WRITE(numout,*) ' use ice-atm drag from Lupkes2015 ln_Cd_L15 = ', ln_Cd_L15 |
|---|
| 332 | ! |
|---|
| 333 | WRITE(numout,*) |
|---|
| 334 | SELECT CASE( nblk ) !* Print the choice of bulk algorithm |
|---|
| 335 | CASE( np_NCAR ) ; WRITE(numout,*) ' ==>>> "NCAR" algorithm (Large and Yeager 2008)' |
|---|
| 336 | CASE( np_COARE_3p0 ) ; WRITE(numout,*) ' ==>>> "COARE 3.0" algorithm (Fairall et al. 2003)' |
|---|
| 337 | CASE( np_COARE_3p6 ) ; WRITE(numout,*) ' ==>>> "COARE 3.6" algorithm (Fairall 2018+Edson et al. 2013)' |
|---|
| 338 | CASE( np_ECMWF ) ; WRITE(numout,*) ' ==>>> "ECMWF" algorithm (IFS cycle 45r1)' |
|---|
| 339 | END SELECT |
|---|
| 340 | ! |
|---|
| 341 | WRITE(numout,*) |
|---|
| 342 | WRITE(numout,*) ' use cool-skin parameterization (SSST) ln_skin_cs = ', ln_skin_cs |
|---|
| 343 | WRITE(numout,*) ' use warm-layer parameterization (SSST) ln_skin_wl = ', ln_skin_wl |
|---|
| 344 | ! |
|---|
| 345 | WRITE(numout,*) |
|---|
| 346 | SELECT CASE( nhumi ) !* Print the choice of air humidity |
|---|
| 347 | CASE( np_humi_sph ) ; WRITE(numout,*) ' ==>>> air humidity is SPECIFIC HUMIDITY [kg/kg]' |
|---|
| 348 | CASE( np_humi_dpt ) ; WRITE(numout,*) ' ==>>> air humidity is DEW-POINT TEMPERATURE [K]' |
|---|
| 349 | CASE( np_humi_rlh ) ; WRITE(numout,*) ' ==>>> air humidity is RELATIVE HUMIDITY [%]' |
|---|
| 350 | END SELECT |
|---|
| 351 | ! |
|---|
| 352 | ENDIF |
|---|
| 353 | ! |
|---|
| 354 | END SUBROUTINE sbc_blk_init |
|---|
| 355 | |
|---|
| 356 | |
|---|
| 357 | SUBROUTINE sbc_blk( kt ) |
|---|
| 358 | !!--------------------------------------------------------------------- |
|---|
| 359 | !! *** ROUTINE sbc_blk *** |
|---|
| 360 | !! |
|---|
| 361 | !! ** Purpose : provide at each time step the surface ocean fluxes |
|---|
| 362 | !! (momentum, heat, freshwater and runoff) |
|---|
| 363 | !! |
|---|
| 364 | !! ** Method : |
|---|
| 365 | !! (1) READ each fluxes in NetCDF files: |
|---|
| 366 | !! the wind velocity (i-component) at z=rn_zu (m/s) at T-point |
|---|
| 367 | !! the wind velocity (j-component) at z=rn_zu (m/s) at T-point |
|---|
| 368 | !! the specific humidity at z=rn_zqt (kg/kg) |
|---|
| 369 | !! the air temperature at z=rn_zqt (Kelvin) |
|---|
| 370 | !! the solar heat (W/m2) |
|---|
| 371 | !! the Long wave (W/m2) |
|---|
| 372 | !! the total precipitation (rain+snow) (Kg/m2/s) |
|---|
| 373 | !! the snow (solid precipitation) (kg/m2/s) |
|---|
| 374 | !! ABL dynamical forcing (i/j-components of either hpg or geostrophic winds) |
|---|
| 375 | !! (2) CALL blk_oce_1 and blk_oce_2 |
|---|
| 376 | !! |
|---|
| 377 | !! C A U T I O N : never mask the surface stress fields |
|---|
| 378 | !! the stress is assumed to be in the (i,j) mesh referential |
|---|
| 379 | !! |
|---|
| 380 | !! ** Action : defined at each time-step at the air-sea interface |
|---|
| 381 | !! - utau, vtau i- and j-component of the wind stress |
|---|
| 382 | !! - taum wind stress module at T-point |
|---|
| 383 | !! - wndm wind speed module at T-point over free ocean or leads in presence of sea-ice |
|---|
| 384 | !! - qns, qsr non-solar and solar heat fluxes |
|---|
| 385 | !! - emp upward mass flux (evapo. - precip.) |
|---|
| 386 | !! - sfx salt flux due to freezing/melting (non-zero only if ice is present) |
|---|
| 387 | !! |
|---|
| 388 | !! ** References : Large & Yeager, 2004 / Large & Yeager, 2008 |
|---|
| 389 | !! Brodeau et al. Ocean Modelling 2010 |
|---|
| 390 | !!---------------------------------------------------------------------- |
|---|
| 391 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 392 | !!---------------------------------------------------------------------- |
|---|
| 393 | REAL(wp), DIMENSION(jpi,jpj) :: zssq, zcd_du, zsen, zevp |
|---|
| 394 | REAL(wp) :: ztmp |
|---|
| 395 | !!---------------------------------------------------------------------- |
|---|
| 396 | ! |
|---|
| 397 | CALL fld_read( kt, nn_fsbc, sf ) ! input fields provided at the current time-step |
|---|
| 398 | |
|---|
| 399 | ! Sanity/consistence test on humidity at first time step to detect potential screw-up: |
|---|
| 400 | IF( kt == nit000 ) THEN |
|---|
| 401 | WRITE(numout,*) '' |
|---|
| 402 | #if defined key_agrif |
|---|
| 403 | WRITE(numout,*) ' === AGRIF => Sanity/consistence test on air humidity SKIPPED! :( ===' |
|---|
| 404 | #else |
|---|
| 405 | ztmp = SUM(tmask(:,:,1)) ! number of ocean points on local proc domain |
|---|
| 406 | IF( ztmp > 8._wp ) THEN ! test only on proc domains with at least 8 ocean points! |
|---|
| 407 | ztmp = SUM(sf(jp_humi)%fnow(:,:,1)*tmask(:,:,1))/ztmp ! mean humidity over ocean on proc |
|---|
| 408 | SELECT CASE( nhumi ) |
|---|
| 409 | CASE( np_humi_sph ) ! specific humidity => expect: 0. <= something < 0.065 [kg/kg] (0.061 is saturation at 45degC !!!) |
|---|
| 410 | IF( (ztmp < 0._wp) .OR. (ztmp > 0.065) ) ztmp = -1._wp |
|---|
| 411 | CASE( np_humi_dpt ) ! dew-point temperature => expect: 110. <= something < 320. [K] |
|---|
| 412 | IF( (ztmp < 110._wp).OR.(ztmp > 320._wp) ) ztmp = -1._wp |
|---|
| 413 | CASE( np_humi_rlh ) ! relative humidity => expect: 0. <= something < 100. [%] |
|---|
| 414 | IF( (ztmp < 0._wp) .OR.(ztmp > 100._wp) ) ztmp = -1._wp |
|---|
| 415 | END SELECT |
|---|
| 416 | IF(ztmp < 0._wp) THEN |
|---|
| 417 | WRITE(numout,'(" Mean humidity value found on proc #",i5.5," is: ",f)') narea, ztmp |
|---|
| 418 | CALL ctl_stop( 'STOP', 'Something is wrong with air humidity!!!', & |
|---|
| 419 | & ' ==> check the unit in your input files' , & |
|---|
| 420 | & ' ==> check consistence of namelist choice: specific? relative? dew-point?', & |
|---|
| 421 | & ' ==> ln_humi_sph -> [kg/kg] | ln_humi_rlh -> [%] | ln_humi_dpt -> [K] !!!' ) |
|---|
| 422 | END IF |
|---|
| 423 | END IF |
|---|
| 424 | WRITE(numout,*) ' === Sanity/consistence test on air humidity sucessfuly passed! ===' |
|---|
| 425 | #endif |
|---|
| 426 | WRITE(numout,*) '' |
|---|
| 427 | END IF !IF( kt == nit000 ) |
|---|
| 428 | ! ! compute the surface ocean fluxes using bulk formulea |
|---|
| 429 | IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN |
|---|
| 430 | CALL blk_oce_1( kt, sf(jp_wndi)%fnow(:,:,1), sf(jp_wndj)%fnow(:,:,1), & ! <<= in |
|---|
| 431 | & sf(jp_tair)%fnow(:,:,1), sf(jp_humi)%fnow(:,:,1), & ! <<= in |
|---|
| 432 | & sf(jp_slp )%fnow(:,:,1), sst_m, ssu_m, ssv_m, & ! <<= in |
|---|
| 433 | & sf(jp_qsr )%fnow(:,:,1), sf(jp_qlw )%fnow(:,:,1), & ! <<= in (wl/cs) |
|---|
| 434 | & zssq, zcd_du, zsen, zevp ) ! =>> out |
|---|
| 435 | |
|---|
| 436 | CALL blk_oce_2( sf(jp_tair)%fnow(:,:,1), sf(jp_qsr )%fnow(:,:,1), & ! <<= in |
|---|
| 437 | & sf(jp_qlw )%fnow(:,:,1), sf(jp_prec)%fnow(:,:,1), & ! <<= in |
|---|
| 438 | & sf(jp_snow)%fnow(:,:,1), sst_m, & ! <<= in |
|---|
| 439 | & zsen, zevp ) ! <=> in out |
|---|
| 440 | ENDIF |
|---|
| 441 | ! |
|---|
| 442 | #if defined key_cice |
|---|
| 443 | IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN |
|---|
| 444 | qlw_ice(:,:,1) = sf(jp_qlw )%fnow(:,:,1) |
|---|
| 445 | IF( ln_dm2dc ) THEN |
|---|
| 446 | qsr_ice(:,:,1) = sbc_dcy( sf(jp_qsr)%fnow(:,:,1) ) |
|---|
| 447 | ELSE |
|---|
| 448 | qsr_ice(:,:,1) = sf(jp_qsr)%fnow(:,:,1) |
|---|
| 449 | ENDIF |
|---|
| 450 | tatm_ice(:,:) = sf(jp_tair)%fnow(:,:,1) |
|---|
| 451 | |
|---|
| 452 | SELECT CASE( nhumi ) |
|---|
| 453 | CASE( np_humi_sph ) |
|---|
| 454 | qatm_ice(:,:) = sf(jp_humi)%fnow(:,:,1) |
|---|
| 455 | CASE( np_humi_dpt ) |
|---|
| 456 | qatm_ice(:,:) = q_sat( sf(jp_humi)%fnow(:,:,1), sf(jp_slp)%fnow(:,:,1) ) |
|---|
| 457 | CASE( np_humi_rlh ) |
|---|
| 458 | qatm_ice(:,:) = q_air_rh( 0.01_wp*sf(jp_humi)%fnow(:,:,1), sf(jp_tair)%fnow(:,:,1), sf(jp_slp)%fnow(:,:,1)) !LB: 0.01 => RH is % percent in file |
|---|
| 459 | END SELECT |
|---|
| 460 | |
|---|
| 461 | tprecip(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac |
|---|
| 462 | sprecip(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac |
|---|
| 463 | wndi_ice(:,:) = sf(jp_wndi)%fnow(:,:,1) |
|---|
| 464 | wndj_ice(:,:) = sf(jp_wndj)%fnow(:,:,1) |
|---|
| 465 | ENDIF |
|---|
| 466 | #endif |
|---|
| 467 | ! |
|---|
| 468 | END SUBROUTINE sbc_blk |
|---|
| 469 | |
|---|
| 470 | |
|---|
| 471 | SUBROUTINE blk_oce_1( kt, pwndi, pwndj , ptair, phumi, & ! inp |
|---|
| 472 | & pslp , pst , pu , pv, & ! inp |
|---|
| 473 | & pqsr , pqlw , & ! inp |
|---|
| 474 | & pssq , pcd_du, psen , pevp ) ! out |
|---|
| 475 | !!--------------------------------------------------------------------- |
|---|
| 476 | !! *** ROUTINE blk_oce_1 *** |
|---|
| 477 | !! |
|---|
| 478 | !! ** Purpose : if ln_blk=T, computes surface momentum, heat and freshwater fluxes |
|---|
| 479 | !! if ln_abl=T, computes Cd x |U|, Ch x |U|, Ce x |U| for ABL integration |
|---|
| 480 | !! |
|---|
| 481 | !! ** Method : bulk formulae using atmospheric fields from : |
|---|
| 482 | !! if ln_blk=T, atmospheric fields read in sbc_read |
|---|
| 483 | !! if ln_abl=T, the ABL model at previous time-step |
|---|
| 484 | !! |
|---|
| 485 | !! ** Outputs : - pssq : surface humidity used to compute latent heat flux (kg/kg) |
|---|
| 486 | !! - pcd_du : Cd x |dU| at T-points (m/s) |
|---|
| 487 | !! - psen : Ch x |dU| at T-points (m/s) |
|---|
| 488 | !! - pevp : Ce x |dU| at T-points (m/s) |
|---|
| 489 | !!--------------------------------------------------------------------- |
|---|
| 490 | INTEGER , INTENT(in ) :: kt ! time step index |
|---|
| 491 | REAL(wp), INTENT(in ), DIMENSION(:,:) :: pwndi ! atmospheric wind at U-point [m/s] |
|---|
| 492 | REAL(wp), INTENT(in ), DIMENSION(:,:) :: pwndj ! atmospheric wind at V-point [m/s] |
|---|
| 493 | REAL(wp), INTENT(in ), DIMENSION(:,:) :: phumi ! specific humidity at T-points [kg/kg] |
|---|
| 494 | REAL(wp), INTENT(in ), DIMENSION(:,:) :: ptair ! potential temperature at T-points [Kelvin] |
|---|
| 495 | REAL(wp), INTENT(in ), DIMENSION(:,:) :: pslp ! sea-level pressure [Pa] |
|---|
| 496 | REAL(wp), INTENT(in ), DIMENSION(:,:) :: pst ! surface temperature [Celcius] |
|---|
| 497 | REAL(wp), INTENT(in ), DIMENSION(:,:) :: pu ! surface current at U-point (i-component) [m/s] |
|---|
| 498 | REAL(wp), INTENT(in ), DIMENSION(:,:) :: pv ! surface current at V-point (j-component) [m/s] |
|---|
| 499 | REAL(wp), INTENT(in ), DIMENSION(:,:) :: pqsr ! |
|---|
| 500 | REAL(wp), INTENT(in ), DIMENSION(:,:) :: pqlw ! |
|---|
| 501 | REAL(wp), INTENT( out), DIMENSION(:,:) :: pssq ! specific humidity at pst [kg/kg] |
|---|
| 502 | REAL(wp), INTENT( out), DIMENSION(:,:) :: pcd_du ! Cd x |dU| at T-points [m/s] |
|---|
| 503 | REAL(wp), INTENT( out), DIMENSION(:,:) :: psen ! Ch x |dU| at T-points [m/s] |
|---|
| 504 | REAL(wp), INTENT( out), DIMENSION(:,:) :: pevp ! Ce x |dU| at T-points [m/s] |
|---|
| 505 | ! |
|---|
| 506 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 507 | REAL(wp) :: zztmp ! local variable |
|---|
| 508 | REAL(wp), DIMENSION(jpi,jpj) :: zwnd_i, zwnd_j ! wind speed components at T-point |
|---|
| 509 | REAL(wp), DIMENSION(jpi,jpj) :: zst ! surface temperature in Kelvin |
|---|
| 510 | REAL(wp), DIMENSION(jpi,jpj) :: zU_zu ! bulk wind speed at height zu [m/s] |
|---|
| 511 | REAL(wp), DIMENSION(jpi,jpj) :: ztpot ! potential temperature of air at z=rn_zqt [K] |
|---|
| 512 | REAL(wp), DIMENSION(jpi,jpj) :: zqair ! specific humidity of air at z=rn_zqt [kg/kg] |
|---|
| 513 | REAL(wp), DIMENSION(jpi,jpj) :: zcd_oce ! momentum transfert coefficient over ocean |
|---|
| 514 | REAL(wp), DIMENSION(jpi,jpj) :: zch_oce ! sensible heat transfert coefficient over ocean |
|---|
| 515 | REAL(wp), DIMENSION(jpi,jpj) :: zce_oce ! latent heat transfert coefficient over ocean |
|---|
| 516 | REAL(wp), DIMENSION(jpi,jpj) :: zqla ! latent heat flux |
|---|
| 517 | REAL(wp), DIMENSION(jpi,jpj) :: zztmp1, zztmp2 |
|---|
| 518 | !!--------------------------------------------------------------------- |
|---|
| 519 | ! |
|---|
| 520 | ! local scalars ( place there for vector optimisation purposes) |
|---|
| 521 | zst(:,:) = pst(:,:) + rt0 ! convert SST from Celcius to Kelvin (and set minimum value far above 0 K) |
|---|
| 522 | |
|---|
| 523 | ! ----------------------------------------------------------------------------- ! |
|---|
| 524 | ! 0 Wind components and module at T-point relative to the moving ocean ! |
|---|
| 525 | ! ----------------------------------------------------------------------------- ! |
|---|
| 526 | |
|---|
| 527 | ! ... components ( U10m - U_oce ) at T-point (unmasked) |
|---|
| 528 | #if defined key_cyclone |
|---|
| 529 | zwnd_i(:,:) = 0._wp |
|---|
| 530 | zwnd_j(:,:) = 0._wp |
|---|
| 531 | CALL wnd_cyc( kt, zwnd_i, zwnd_j ) ! add analytical tropical cyclone (Vincent et al. JGR 2012) |
|---|
| 532 | DO jj = 2, jpjm1 |
|---|
| 533 | DO ji = fs_2, fs_jpim1 ! vect. opt. |
|---|
| 534 | pwndi(ji,jj) = pwndi(ji,jj) + zwnd_i(ji,jj) |
|---|
| 535 | pwndj(ji,jj) = pwndj(ji,jj) + zwnd_j(ji,jj) |
|---|
| 536 | END DO |
|---|
| 537 | END DO |
|---|
| 538 | #endif |
|---|
| 539 | DO jj = 2, jpjm1 |
|---|
| 540 | DO ji = fs_2, fs_jpim1 ! vect. opt. |
|---|
| 541 | zwnd_i(ji,jj) = ( pwndi(ji,jj) - rn_vfac * 0.5 * ( pu(ji-1,jj ) + pu(ji,jj) ) ) |
|---|
| 542 | zwnd_j(ji,jj) = ( pwndj(ji,jj) - rn_vfac * 0.5 * ( pv(ji ,jj-1) + pv(ji,jj) ) ) |
|---|
| 543 | END DO |
|---|
| 544 | END DO |
|---|
| 545 | CALL lbc_lnk_multi( 'sbcblk', zwnd_i, 'T', -1., zwnd_j, 'T', -1. ) |
|---|
| 546 | ! ... scalar wind ( = | U10m - U_oce | ) at T-point (masked) |
|---|
| 547 | wndm(:,:) = SQRT( zwnd_i(:,:) * zwnd_i(:,:) & |
|---|
| 548 | & + zwnd_j(:,:) * zwnd_j(:,:) ) * tmask(:,:,1) |
|---|
| 549 | |
|---|
| 550 | ! ----------------------------------------------------------------------------- ! |
|---|
| 551 | ! I Solar FLUX ! |
|---|
| 552 | ! ----------------------------------------------------------------------------- ! |
|---|
| 553 | |
|---|
| 554 | ! ocean albedo assumed to be constant + modify now Qsr to include the diurnal cycle ! Short Wave |
|---|
| 555 | zztmp = 1. - albo |
|---|
| 556 | IF( ln_dm2dc ) THEN |
|---|
| 557 | qsr(:,:) = zztmp * sbc_dcy( sf(jp_qsr)%fnow(:,:,1) ) * tmask(:,:,1) |
|---|
| 558 | ELSE |
|---|
| 559 | qsr(:,:) = zztmp * sf(jp_qsr)%fnow(:,:,1) * tmask(:,:,1) |
|---|
| 560 | ENDIF |
|---|
| 561 | |
|---|
| 562 | |
|---|
| 563 | ! ----------------------------------------------------------------------------- ! |
|---|
| 564 | ! II Turbulent FLUXES ! |
|---|
| 565 | ! ----------------------------------------------------------------------------- ! |
|---|
| 566 | |
|---|
| 567 | ! specific humidity at SST |
|---|
| 568 | pssq(:,:) = rdct_qsat_salt * q_sat( zst(:,:), pslp(:,:) ) |
|---|
| 569 | |
|---|
| 570 | IF( ln_skin_cs .OR. ln_skin_wl ) THEN |
|---|
| 571 | zztmp1(:,:) = zst(:,:) |
|---|
| 572 | zztmp2(:,:) = pssq(:,:) |
|---|
| 573 | ENDIF |
|---|
| 574 | |
|---|
| 575 | ! specific humidity of air at "rn_zqt" m above the sea |
|---|
| 576 | SELECT CASE( nhumi ) |
|---|
| 577 | CASE( np_humi_sph ) |
|---|
| 578 | zqair(:,:) = phumi(:,:) ! what we read in file is already a spec. humidity! |
|---|
| 579 | CASE( np_humi_dpt ) |
|---|
| 580 | !IF(lwp) WRITE(numout,*) ' *** blk_oce => computing q_air out of d_air and slp !' !LBrm |
|---|
| 581 | zqair(:,:) = q_sat( phumi(:,:), pslp(:,:) ) |
|---|
| 582 | CASE( np_humi_rlh ) |
|---|
| 583 | !IF(lwp) WRITE(numout,*) ' *** blk_oce => computing q_air out of RH, t_air and slp !' !LBrm |
|---|
| 584 | zqair(:,:) = q_air_rh( 0.01_wp*phumi(:,:), ptair(:,:), pslp(:,:) ) !LB: 0.01 => RH is % percent in file |
|---|
| 585 | END SELECT |
|---|
| 586 | ! |
|---|
| 587 | ! potential temperature of air at "rn_zqt" m above the sea |
|---|
| 588 | IF( ln_abl ) THEN |
|---|
| 589 | ztpot = ptair(:,:) |
|---|
| 590 | ELSE |
|---|
| 591 | ! Estimate of potential temperature at z=rn_zqt, based on adiabatic lapse-rate |
|---|
| 592 | ! (see Josey, Gulev & Yu, 2013) / doi=10.1016/B978-0-12-391851-2.00005-2 |
|---|
| 593 | ! (since reanalysis products provide T at z, not theta !) |
|---|
| 594 | !#LB: because AGRIF hates functions that return something else than a scalar, need to |
|---|
| 595 | ! use scalar version of gamma_moist() ... |
|---|
| 596 | DO jj = 1, jpj |
|---|
| 597 | DO ji = 1, jpi |
|---|
| 598 | ztpot(ji,jj) = ptair(ji,jj) + gamma_moist( ptair(ji,jj), zqair(ji,jj) ) * rn_zqt |
|---|
| 599 | END DO |
|---|
| 600 | END DO |
|---|
| 601 | ENDIF |
|---|
| 602 | |
|---|
| 603 | |
|---|
| 604 | |
|---|
| 605 | !! Time to call the user-selected bulk parameterization for |
|---|
| 606 | !! == transfer coefficients ==! Cd, Ch, Ce at T-point, and more... |
|---|
| 607 | SELECT CASE( nblk ) |
|---|
| 608 | |
|---|
| 609 | CASE( np_NCAR ) |
|---|
| 610 | CALL turb_ncar ( rn_zqt, rn_zu, zst, ztpot, pssq, zqair, wndm, & |
|---|
| 611 | & zcd_oce, zch_oce, zce_oce, t_zu, q_zu, zU_zu, cdn_oce, chn_oce, cen_oce ) |
|---|
| 612 | |
|---|
| 613 | CASE( np_COARE_3p0 ) |
|---|
| 614 | CALL turb_coare3p0 ( kt, rn_zqt, rn_zu, zst, ztpot, pssq, zqair, wndm, ln_skin_cs, ln_skin_wl, & |
|---|
| 615 | & zcd_oce, zch_oce, zce_oce, t_zu, q_zu, zU_zu, cdn_oce, chn_oce, cen_oce, & |
|---|
| 616 | & Qsw=qsr(:,:), rad_lw=pqlw(:,:), slp=pslp(:,:) ) |
|---|
| 617 | |
|---|
| 618 | CASE( np_COARE_3p6 ) |
|---|
| 619 | CALL turb_coare3p6 ( kt, rn_zqt, rn_zu, zst, ztpot, pssq, zqair, wndm, ln_skin_cs, ln_skin_wl, & |
|---|
| 620 | & zcd_oce, zch_oce, zce_oce, t_zu, q_zu, zU_zu, cdn_oce, chn_oce, cen_oce, & |
|---|
| 621 | & Qsw=qsr(:,:), rad_lw=pqlw(:,:), slp=pslp(:,:) ) |
|---|
| 622 | |
|---|
| 623 | CASE( np_ECMWF ) |
|---|
| 624 | CALL turb_ecmwf ( kt, rn_zqt, rn_zu, zst, ztpot, pssq, zqair, wndm, ln_skin_cs, ln_skin_wl, & |
|---|
| 625 | & zcd_oce, zch_oce, zce_oce, t_zu, q_zu, zU_zu, cdn_oce, chn_oce, cen_oce, & |
|---|
| 626 | & Qsw=qsr(:,:), rad_lw=pqlw(:,:), slp=pslp(:,:) ) |
|---|
| 627 | |
|---|
| 628 | CASE DEFAULT |
|---|
| 629 | CALL ctl_stop( 'STOP', 'sbc_oce: non-existing bulk formula selected' ) |
|---|
| 630 | |
|---|
| 631 | END SELECT |
|---|
| 632 | |
|---|
| 633 | IF( ln_skin_cs .OR. ln_skin_wl ) THEN |
|---|
| 634 | !! In the presence of sea-ice we forget about the cool-skin/warm-layer update of zst and pssq: |
|---|
| 635 | WHERE ( fr_i < 0.001_wp ) |
|---|
| 636 | ! zst and pssq have been updated by cool-skin/warm-layer scheme and we keep it!!! |
|---|
| 637 | zst(:,:) = zst(:,:)*tmask(:,:,1) |
|---|
| 638 | pssq(:,:) = pssq(:,:)*tmask(:,:,1) |
|---|
| 639 | ELSEWHERE |
|---|
| 640 | ! we forget about the update... |
|---|
| 641 | zst(:,:) = zztmp1(:,:) !#LB: using what we backed up before skin-algo |
|---|
| 642 | pssq(:,:) = zztmp2(:,:) !#LB: " " " |
|---|
| 643 | END WHERE |
|---|
| 644 | END IF |
|---|
| 645 | |
|---|
| 646 | !! CALL iom_put( "Cd_oce", zcd_oce) ! output value of pure ocean-atm. transfer coef. |
|---|
| 647 | !! CALL iom_put( "Ch_oce", zch_oce) ! output value of pure ocean-atm. transfer coef. |
|---|
| 648 | |
|---|
| 649 | IF( ABS(rn_zu - rn_zqt) < 0.1_wp ) THEN |
|---|
| 650 | !! If zu == zt, then ensuring once for all that: |
|---|
| 651 | t_zu(:,:) = ztpot(:,:) |
|---|
| 652 | q_zu(:,:) = zqair(:,:) |
|---|
| 653 | ENDIF |
|---|
| 654 | |
|---|
| 655 | |
|---|
| 656 | ! Turbulent fluxes over ocean => BULK_FORMULA @ sbcblk_phy.F90 |
|---|
| 657 | ! ------------------------------------------------------------- |
|---|
| 658 | |
|---|
| 659 | IF( ln_abl ) THEN !== ABL formulation ==! multiplication by rho_air and turbulent fluxes computation done in ablstp |
|---|
| 660 | !! FL do we need this multiplication by tmask ... ??? |
|---|
| 661 | DO jj = 1, jpj |
|---|
| 662 | DO ji = 1, jpi |
|---|
| 663 | zztmp = zU_zu(ji,jj) !* tmask(ji,jj,1) |
|---|
| 664 | wndm(ji,jj) = zztmp ! Store zU_zu in wndm to compute ustar2 in ablmod |
|---|
| 665 | pcd_du(ji,jj) = zztmp * zcd_oce(ji,jj) |
|---|
| 666 | psen(ji,jj) = zztmp * zch_oce(ji,jj) |
|---|
| 667 | pevp(ji,jj) = zztmp * zce_oce(ji,jj) |
|---|
| 668 | END DO |
|---|
| 669 | END DO |
|---|
| 670 | ELSE !== BLK formulation ==! turbulent fluxes computation |
|---|
| 671 | CALL BULK_FORMULA( rn_zu, zst(:,:), pssq(:,:), t_zu(:,:), q_zu(:,:), & |
|---|
| 672 | & zcd_oce(:,:), zch_oce(:,:), zce_oce(:,:), & |
|---|
| 673 | & wndm(:,:), zU_zu(:,:), pslp(:,:), & |
|---|
| 674 | & taum(:,:), psen(:,:), zqla(:,:), & |
|---|
| 675 | & pEvap=pevp(:,:), prhoa=rhoa(:,:) ) |
|---|
| 676 | |
|---|
| 677 | zqla(:,:) = zqla(:,:) * tmask(:,:,1) |
|---|
| 678 | psen(:,:) = psen(:,:) * tmask(:,:,1) |
|---|
| 679 | taum(:,:) = taum(:,:) * tmask(:,:,1) |
|---|
| 680 | pevp(:,:) = pevp(:,:) * tmask(:,:,1) |
|---|
| 681 | |
|---|
| 682 | ! Tau i and j component on T-grid points, using array "zcd_oce" as a temporary array... |
|---|
| 683 | zcd_oce = 0._wp |
|---|
| 684 | WHERE ( wndm > 0._wp ) zcd_oce = taum / wndm |
|---|
| 685 | zwnd_i = zcd_oce * zwnd_i |
|---|
| 686 | zwnd_j = zcd_oce * zwnd_j |
|---|
| 687 | |
|---|
| 688 | CALL iom_put( "taum_oce", taum ) ! output wind stress module |
|---|
| 689 | |
|---|
| 690 | ! ... utau, vtau at U- and V_points, resp. |
|---|
| 691 | ! Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines |
|---|
| 692 | ! Note the use of MAX(tmask(i,j),tmask(i+1,j) is to mask tau over ice shelves |
|---|
| 693 | DO jj = 1, jpjm1 |
|---|
| 694 | DO ji = 1, fs_jpim1 |
|---|
| 695 | utau(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zwnd_i(ji,jj) + zwnd_i(ji+1,jj ) ) & |
|---|
| 696 | & * MAX(tmask(ji,jj,1),tmask(ji+1,jj,1)) |
|---|
| 697 | vtau(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zwnd_j(ji,jj) + zwnd_j(ji ,jj+1) ) & |
|---|
| 698 | & * MAX(tmask(ji,jj,1),tmask(ji,jj+1,1)) |
|---|
| 699 | END DO |
|---|
| 700 | END DO |
|---|
| 701 | CALL lbc_lnk_multi( 'sbcblk', utau, 'U', -1., vtau, 'V', -1. ) |
|---|
| 702 | |
|---|
| 703 | IF(ln_ctl) THEN |
|---|
| 704 | CALL prt_ctl( tab2d_1=wndm , clinfo1=' blk_oce_1: wndm : ') |
|---|
| 705 | CALL prt_ctl( tab2d_1=utau , clinfo1=' blk_oce_1: utau : ', mask1=umask, & |
|---|
| 706 | & tab2d_2=vtau , clinfo2=' vtau : ', mask2=vmask ) |
|---|
| 707 | ENDIF |
|---|
| 708 | ! |
|---|
| 709 | ENDIF |
|---|
| 710 | ! |
|---|
| 711 | IF(ln_ctl) THEN |
|---|
| 712 | CALL prt_ctl( tab2d_1=pevp , clinfo1=' blk_oce_1: pevp : ' ) |
|---|
| 713 | CALL prt_ctl( tab2d_1=psen , clinfo1=' blk_oce_1: psen : ' ) |
|---|
| 714 | CALL prt_ctl( tab2d_1=pssq , clinfo1=' blk_oce_1: pssq : ' ) |
|---|
| 715 | ENDIF |
|---|
| 716 | ! |
|---|
| 717 | END SUBROUTINE blk_oce_1 |
|---|
| 718 | |
|---|
| 719 | |
|---|
| 720 | SUBROUTINE blk_oce_2( ptair, pqsr, pqlw, pprec, & ! <<= in |
|---|
| 721 | & psnow, pst , psen, pevp ) ! <<= in |
|---|
| 722 | !!--------------------------------------------------------------------- |
|---|
| 723 | !! *** ROUTINE blk_oce_2 *** |
|---|
| 724 | !! |
|---|
| 725 | !! ** Purpose : finalize the momentum, heat and freshwater fluxes computation |
|---|
| 726 | !! at the ocean surface at each time step knowing Cd, Ch, Ce and |
|---|
| 727 | !! atmospheric variables (from ABL or external data) |
|---|
| 728 | !! |
|---|
| 729 | !! ** Outputs : - utau : i-component of the stress at U-point (N/m2) |
|---|
| 730 | !! - vtau : j-component of the stress at V-point (N/m2) |
|---|
| 731 | !! - taum : Wind stress module at T-point (N/m2) |
|---|
| 732 | !! - wndm : Wind speed module at T-point (m/s) |
|---|
| 733 | !! - qsr : Solar heat flux over the ocean (W/m2) |
|---|
| 734 | !! - qns : Non Solar heat flux over the ocean (W/m2) |
|---|
| 735 | !! - emp : evaporation minus precipitation (kg/m2/s) |
|---|
| 736 | !!--------------------------------------------------------------------- |
|---|
| 737 | REAL(wp), INTENT(in), DIMENSION(:,:) :: ptair |
|---|
| 738 | REAL(wp), INTENT(in), DIMENSION(:,:) :: pqsr |
|---|
| 739 | REAL(wp), INTENT(in), DIMENSION(:,:) :: pqlw |
|---|
| 740 | REAL(wp), INTENT(in), DIMENSION(:,:) :: pprec |
|---|
| 741 | REAL(wp), INTENT(in), DIMENSION(:,:) :: psnow |
|---|
| 742 | REAL(wp), INTENT(in), DIMENSION(:,:) :: pst ! surface temperature [Celcius] |
|---|
| 743 | REAL(wp), INTENT(in), DIMENSION(:,:) :: psen |
|---|
| 744 | REAL(wp), INTENT(in), DIMENSION(:,:) :: pevp |
|---|
| 745 | ! |
|---|
| 746 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 747 | REAL(wp) :: zztmp,zz1,zz2,zz3 ! local variable |
|---|
| 748 | REAL(wp), DIMENSION(jpi,jpj) :: zqlw ! long wave and sensible heat fluxes |
|---|
| 749 | REAL(wp), DIMENSION(jpi,jpj) :: zqla ! latent heat fluxes and evaporation |
|---|
| 750 | REAL(wp), DIMENSION(jpi,jpj) :: zst ! surface temperature in Kelvin |
|---|
| 751 | !!--------------------------------------------------------------------- |
|---|
| 752 | ! |
|---|
| 753 | ! local scalars ( place there for vector optimisation purposes) |
|---|
| 754 | zst(:,:) = pst(:,:) + rt0 ! convert SST from Celcius to Kelvin (and set minimum value far above 0 K) |
|---|
| 755 | |
|---|
| 756 | |
|---|
| 757 | ! ----------------------------------------------------------------------------- ! |
|---|
| 758 | ! III Net longwave radiative FLUX ! |
|---|
| 759 | ! ----------------------------------------------------------------------------- ! |
|---|
| 760 | |
|---|
| 761 | !! LB: now moved after Turbulent fluxes because must use the skin temperature rather that the SST |
|---|
| 762 | !! (zst is skin temperature if ln_skin_cs==.TRUE. .OR. ln_skin_wl==.TRUE.) |
|---|
| 763 | zqlw(:,:) = emiss_w * ( pqlw(:,:) - stefan*zst(:,:)*zst(:,:)*zst(:,:)*zst(:,:) ) * tmask(:,:,1) ! Net radiative longwave flux |
|---|
| 764 | |
|---|
| 765 | ! Turbulent fluxes over ocean |
|---|
| 766 | ! ----------------------------- |
|---|
| 767 | |
|---|
| 768 | ! use scalar version of L_vap() for AGRIF compatibility |
|---|
| 769 | DO jj = 1, jpj |
|---|
| 770 | DO ji = 1, jpi |
|---|
| 771 | zqla(ji,jj) = -1._wp * L_vap( zst(ji,jj) ) * pevp(ji,jj) ! Latent Heat flux !!GS: possibility to add a global qla to avoid recomputation after abl update |
|---|
| 772 | ENDDO |
|---|
| 773 | ENDDO |
|---|
| 774 | |
|---|
| 775 | IF(ln_ctl) THEN |
|---|
| 776 | CALL prt_ctl( tab2d_1=zqla , clinfo1=' blk_oce_2: zqla : ' ) |
|---|
| 777 | CALL prt_ctl( tab2d_1=zqlw , clinfo1=' blk_oce_2: zqlw : ', tab2d_2=qsr, clinfo2=' qsr : ' ) |
|---|
| 778 | |
|---|
| 779 | ENDIF |
|---|
| 780 | |
|---|
| 781 | ! ----------------------------------------------------------------------------- ! |
|---|
| 782 | ! IV Total FLUXES ! |
|---|
| 783 | ! ----------------------------------------------------------------------------- ! |
|---|
| 784 | ! |
|---|
| 785 | emp (:,:) = ( pevp(:,:) & ! mass flux (evap. - precip.) |
|---|
| 786 | & - pprec(:,:) * rn_pfac ) * tmask(:,:,1) |
|---|
| 787 | ! |
|---|
| 788 | qns(:,:) = zqlw(:,:) + psen(:,:) + zqla(:,:) & ! Downward Non Solar |
|---|
| 789 | & - psnow(:,:) * rn_pfac * rLfus & ! remove latent melting heat for solid precip |
|---|
| 790 | & - pevp(:,:) * pst(:,:) * rcp & ! remove evap heat content at SST !LB??? pst is Celsius !? |
|---|
| 791 | & + ( pprec(:,:) - psnow(:,:) ) * rn_pfac & ! add liquid precip heat content at Tair |
|---|
| 792 | & * ( ptair(:,:) - rt0 ) * rcp & |
|---|
| 793 | & + psnow(:,:) * rn_pfac & ! add solid precip heat content at min(Tair,Tsnow) |
|---|
| 794 | & * ( MIN( ptair(:,:), rt0 ) - rt0 ) * rcpi |
|---|
| 795 | qns(:,:) = qns(:,:) * tmask(:,:,1) |
|---|
| 796 | ! |
|---|
| 797 | #if defined key_si3 |
|---|
| 798 | qns_oce(:,:) = zqlw(:,:) + psen(:,:) + zqla(:,:) ! non solar without emp (only needed by SI3) |
|---|
| 799 | qsr_oce(:,:) = qsr(:,:) |
|---|
| 800 | #endif |
|---|
| 801 | ! |
|---|
| 802 | CALL iom_put( "rho_air" , rhoa*tmask(:,:,1) ) ! output air density [kg/m^3] |
|---|
| 803 | CALL iom_put( "evap_oce" , pevp ) ! evaporation |
|---|
| 804 | CALL iom_put( "qlw_oce" , zqlw ) ! output downward longwave heat over the ocean |
|---|
| 805 | CALL iom_put( "qsb_oce" , psen ) ! output downward sensible heat over the ocean |
|---|
| 806 | CALL iom_put( "qla_oce" , zqla ) ! output downward latent heat over the ocean |
|---|
| 807 | tprecip(:,:) = pprec(:,:) * rn_pfac * tmask(:,:,1) ! output total precipitation [kg/m2/s] |
|---|
| 808 | sprecip(:,:) = psnow(:,:) * rn_pfac * tmask(:,:,1) ! output solid precipitation [kg/m2/s] |
|---|
| 809 | CALL iom_put( 'snowpre', sprecip ) ! Snow |
|---|
| 810 | CALL iom_put( 'precip' , tprecip ) ! Total precipitation |
|---|
| 811 | ! |
|---|
| 812 | IF ( nn_ice == 0 ) THEN |
|---|
| 813 | CALL iom_put( "qemp_oce" , qns-zqlw-psen-zqla ) ! output downward heat content of E-P over the ocean |
|---|
| 814 | CALL iom_put( "qns_oce" , qns ) ! output downward non solar heat over the ocean |
|---|
| 815 | CALL iom_put( "qsr_oce" , qsr ) ! output downward solar heat over the ocean |
|---|
| 816 | CALL iom_put( "qt_oce" , qns+qsr ) ! output total downward heat over the ocean |
|---|
| 817 | ENDIF |
|---|
| 818 | ! |
|---|
| 819 | IF( ln_skin_cs .OR. ln_skin_wl ) THEN |
|---|
| 820 | CALL iom_put( "t_skin" , (zst - rt0) * tmask(:,:,1) ) ! T_skin in Celsius |
|---|
| 821 | CALL iom_put( "dt_skin" , (zst - pst - rt0) * tmask(:,:,1) ) ! T_skin - SST temperature difference... |
|---|
| 822 | ENDIF |
|---|
| 823 | ! |
|---|
| 824 | IF(ln_ctl) THEN |
|---|
| 825 | CALL prt_ctl(tab2d_1=zqlw , clinfo1=' blk_oce_2: zqlw : ') |
|---|
| 826 | CALL prt_ctl(tab2d_1=zqla , clinfo1=' blk_oce_2: zqla : ', tab2d_2=qsr , clinfo2=' qsr : ') |
|---|
| 827 | CALL prt_ctl(tab2d_1=emp , clinfo1=' blk_oce_2: emp : ') |
|---|
| 828 | ENDIF |
|---|
| 829 | ! |
|---|
| 830 | END SUBROUTINE blk_oce_2 |
|---|
| 831 | |
|---|
| 832 | |
|---|
| 833 | #if defined key_si3 |
|---|
| 834 | !!---------------------------------------------------------------------- |
|---|
| 835 | !! 'key_si3' SI3 sea-ice model |
|---|
| 836 | !!---------------------------------------------------------------------- |
|---|
| 837 | !! blk_ice_1 : provide the air-ice stress |
|---|
| 838 | !! blk_ice_2 : provide the heat and mass fluxes at air-ice interface |
|---|
| 839 | !! blk_ice_qcn : provide ice surface temperature and snow/ice conduction flux (emulating conduction flux) |
|---|
| 840 | !! Cdn10_Lupkes2012 : Lupkes et al. (2012) air-ice drag |
|---|
| 841 | !! Cdn10_Lupkes2015 : Lupkes et al. (2015) air-ice drag |
|---|
| 842 | !!---------------------------------------------------------------------- |
|---|
| 843 | |
|---|
| 844 | SUBROUTINE blk_ice_1( pwndi, pwndj, ptair, phumi, pslp , puice, pvice, ptsui, & ! inputs |
|---|
| 845 | & putaui, pvtaui, pseni, pevpi, pssqi, pcd_dui ) ! optional outputs |
|---|
| 846 | !!--------------------------------------------------------------------- |
|---|
| 847 | !! *** ROUTINE blk_ice_1 *** |
|---|
| 848 | !! |
|---|
| 849 | !! ** Purpose : provide the surface boundary condition over sea-ice |
|---|
| 850 | !! |
|---|
| 851 | !! ** Method : compute momentum using bulk formulation |
|---|
| 852 | !! formulea, ice variables and read atmospheric fields. |
|---|
| 853 | !! NB: ice drag coefficient is assumed to be a constant |
|---|
| 854 | !!--------------------------------------------------------------------- |
|---|
| 855 | REAL(wp) , INTENT(in ), DIMENSION(:,: ) :: pslp ! sea-level pressure [Pa] |
|---|
| 856 | REAL(wp) , INTENT(in ), DIMENSION(:,: ) :: pwndi ! atmospheric wind at T-point [m/s] |
|---|
| 857 | REAL(wp) , INTENT(in ), DIMENSION(:,: ) :: pwndj ! atmospheric wind at T-point [m/s] |
|---|
| 858 | REAL(wp) , INTENT(in ), DIMENSION(:,: ) :: ptair ! atmospheric wind at T-point [m/s] |
|---|
| 859 | REAL(wp) , INTENT(in ), DIMENSION(:,: ) :: phumi ! atmospheric wind at T-point [m/s] |
|---|
| 860 | REAL(wp) , INTENT(in ), DIMENSION(:,: ) :: puice ! sea-ice velocity on I or C grid [m/s] |
|---|
| 861 | REAL(wp) , INTENT(in ), DIMENSION(:,: ) :: pvice ! " |
|---|
| 862 | REAL(wp) , INTENT(in ), DIMENSION(:,: ) :: ptsui ! sea-ice surface temperature [K] |
|---|
| 863 | REAL(wp) , INTENT( out), DIMENSION(:,: ), OPTIONAL :: putaui ! if ln_blk |
|---|
| 864 | REAL(wp) , INTENT( out), DIMENSION(:,: ), OPTIONAL :: pvtaui ! if ln_blk |
|---|
| 865 | REAL(wp) , INTENT( out), DIMENSION(:,: ), OPTIONAL :: pseni ! if ln_abl |
|---|
| 866 | REAL(wp) , INTENT( out), DIMENSION(:,: ), OPTIONAL :: pevpi ! if ln_abl |
|---|
| 867 | REAL(wp) , INTENT( out), DIMENSION(:,: ), OPTIONAL :: pssqi ! if ln_abl |
|---|
| 868 | REAL(wp) , INTENT( out), DIMENSION(:,: ), OPTIONAL :: pcd_dui ! if ln_abl |
|---|
| 869 | ! |
|---|
| 870 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 871 | REAL(wp) :: zwndi_t , zwndj_t ! relative wind components at T-point |
|---|
| 872 | REAL(wp) :: zootm_su ! sea-ice surface mean temperature |
|---|
| 873 | REAL(wp) :: zztmp1, zztmp2 ! temporary arrays |
|---|
| 874 | REAL(wp), DIMENSION(jpi,jpj) :: zcd_dui ! transfer coefficient for momentum (tau) |
|---|
| 875 | !!--------------------------------------------------------------------- |
|---|
| 876 | ! |
|---|
| 877 | |
|---|
| 878 | ! ------------------------------------------------------------ ! |
|---|
| 879 | ! Wind module relative to the moving ice ( U10m - U_ice ) ! |
|---|
| 880 | ! ------------------------------------------------------------ ! |
|---|
| 881 | ! C-grid ice dynamics : U & V-points (same as ocean) |
|---|
| 882 | DO jj = 2, jpjm1 |
|---|
| 883 | DO ji = fs_2, fs_jpim1 ! vect. opt. |
|---|
| 884 | zwndi_t = ( pwndi(ji,jj) - rn_vfac * 0.5_wp * ( puice(ji-1,jj ) + puice(ji,jj) ) ) |
|---|
| 885 | zwndj_t = ( pwndj(ji,jj) - rn_vfac * 0.5_wp * ( pvice(ji ,jj-1) + pvice(ji,jj) ) ) |
|---|
| 886 | wndm_ice(ji,jj) = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1) |
|---|
| 887 | END DO |
|---|
| 888 | END DO |
|---|
| 889 | CALL lbc_lnk( 'sbcblk', wndm_ice, 'T', 1. ) |
|---|
| 890 | ! |
|---|
| 891 | ! Make ice-atm. drag dependent on ice concentration |
|---|
| 892 | IF ( ln_Cd_L12 ) THEN ! calculate new drag from Lupkes(2012) equations |
|---|
| 893 | CALL Cdn10_Lupkes2012( Cd_ice ) |
|---|
| 894 | Ch_ice(:,:) = Cd_ice(:,:) ! momentum and heat transfer coef. are considered identical |
|---|
| 895 | Ce_ice(:,:) = Cd_ice(:,:) |
|---|
| 896 | ELSEIF( ln_Cd_L15 ) THEN ! calculate new drag from Lupkes(2015) equations |
|---|
| 897 | CALL Cdn10_Lupkes2015( ptsui, pslp, Cd_ice, Ch_ice ) |
|---|
| 898 | Ce_ice(:,:) = Ch_ice(:,:) ! sensible and latent heat transfer coef. are considered identical |
|---|
| 899 | ENDIF |
|---|
| 900 | |
|---|
| 901 | !! IF ( iom_use("Cd_ice") ) CALL iom_put("Cd_ice", Cd_ice) ! output value of pure ice-atm. transfer coef. |
|---|
| 902 | !! IF ( iom_use("Ch_ice") ) CALL iom_put("Ch_ice", Ch_ice) ! output value of pure ice-atm. transfer coef. |
|---|
| 903 | |
|---|
| 904 | ! local scalars ( place there for vector optimisation purposes) |
|---|
| 905 | !IF (ln_abl) rhoa (:,:) = rho_air( ptair(:,:), phumi(:,:), pslp(:,:) ) !!GS: rhoa must be (re)computed here with ABL to avoid division by zero after (TBI) |
|---|
| 906 | zcd_dui(:,:) = wndm_ice(:,:) * Cd_ice(:,:) |
|---|
| 907 | |
|---|
| 908 | IF( ln_blk ) THEN |
|---|
| 909 | ! ------------------------------------------------------------ ! |
|---|
| 910 | ! Wind stress relative to the moving ice ( U10m - U_ice ) ! |
|---|
| 911 | ! ------------------------------------------------------------ ! |
|---|
| 912 | ! C-grid ice dynamics : U & V-points (same as ocean) |
|---|
| 913 | DO jj = 2, jpjm1 |
|---|
| 914 | DO ji = fs_2, fs_jpim1 ! vect. opt. |
|---|
| 915 | putaui(ji,jj) = 0.5_wp * ( rhoa(ji+1,jj) * zcd_dui(ji+1,jj) & |
|---|
| 916 | & + rhoa(ji ,jj) * zcd_dui(ji ,jj) ) & |
|---|
| 917 | & * ( 0.5_wp * ( pwndi(ji+1,jj) + pwndi(ji,jj) ) - rn_vfac * puice(ji,jj) ) |
|---|
| 918 | pvtaui(ji,jj) = 0.5_wp * ( rhoa(ji,jj+1) * zcd_dui(ji,jj+1) & |
|---|
| 919 | & + rhoa(ji,jj ) * zcd_dui(ji,jj ) ) & |
|---|
| 920 | & * ( 0.5_wp * ( pwndj(ji,jj+1) + pwndj(ji,jj) ) - rn_vfac * pvice(ji,jj) ) |
|---|
| 921 | END DO |
|---|
| 922 | END DO |
|---|
| 923 | CALL lbc_lnk_multi( 'sbcblk', putaui, 'U', -1., pvtaui, 'V', -1. ) |
|---|
| 924 | ! |
|---|
| 925 | IF(ln_ctl) CALL prt_ctl( tab2d_1=putaui , clinfo1=' blk_ice: putaui : ' & |
|---|
| 926 | & , tab2d_2=pvtaui , clinfo2=' pvtaui : ' ) |
|---|
| 927 | ELSE |
|---|
| 928 | zztmp1 = 11637800.0_wp |
|---|
| 929 | zztmp2 = -5897.8_wp |
|---|
| 930 | DO jj = 1, jpj |
|---|
| 931 | DO ji = 1, jpi |
|---|
| 932 | pcd_dui(ji,jj) = zcd_dui (ji,jj) |
|---|
| 933 | pseni (ji,jj) = wndm_ice(ji,jj) * Ch_ice(ji,jj) |
|---|
| 934 | pevpi (ji,jj) = wndm_ice(ji,jj) * Ce_ice(ji,jj) |
|---|
| 935 | zootm_su = zztmp2 / ptsui(ji,jj) ! ptsui is in K (it can't be zero ??) |
|---|
| 936 | pssqi (ji,jj) = zztmp1 * EXP( zootm_su ) / rhoa(ji,jj) |
|---|
| 937 | END DO |
|---|
| 938 | END DO |
|---|
| 939 | ENDIF |
|---|
| 940 | ! |
|---|
| 941 | IF(ln_ctl) CALL prt_ctl(tab2d_1=wndm_ice , clinfo1=' blk_ice: wndm_ice : ') |
|---|
| 942 | ! |
|---|
| 943 | END SUBROUTINE blk_ice_1 |
|---|
| 944 | |
|---|
| 945 | |
|---|
| 946 | SUBROUTINE blk_ice_2( ptsu, phs, phi, palb, ptair, phumi, pslp, pqlw, pprec, psnow ) |
|---|
| 947 | !!--------------------------------------------------------------------- |
|---|
| 948 | !! *** ROUTINE blk_ice_2 *** |
|---|
| 949 | !! |
|---|
| 950 | !! ** Purpose : provide the heat and mass fluxes at air-ice interface |
|---|
| 951 | !! |
|---|
| 952 | !! ** Method : compute heat and freshwater exchanged |
|---|
| 953 | !! between atmosphere and sea-ice using bulk formulation |
|---|
| 954 | !! formulea, ice variables and read atmmospheric fields. |
|---|
| 955 | !! |
|---|
| 956 | !! caution : the net upward water flux has with mm/day unit |
|---|
| 957 | !!--------------------------------------------------------------------- |
|---|
| 958 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: ptsu ! sea ice surface temperature [K] |
|---|
| 959 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: phs ! snow thickness |
|---|
| 960 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: phi ! ice thickness |
|---|
| 961 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: palb ! ice albedo (all skies) |
|---|
| 962 | REAL(wp), DIMENSION(:,: ), INTENT(in) :: ptair |
|---|
| 963 | REAL(wp), DIMENSION(:,: ), INTENT(in) :: phumi |
|---|
| 964 | REAL(wp), DIMENSION(:,: ), INTENT(in) :: pslp |
|---|
| 965 | REAL(wp), DIMENSION(:,: ), INTENT(in) :: pqlw |
|---|
| 966 | REAL(wp), DIMENSION(:,: ), INTENT(in) :: pprec |
|---|
| 967 | REAL(wp), DIMENSION(:,: ), INTENT(in) :: psnow |
|---|
| 968 | !! |
|---|
| 969 | INTEGER :: ji, jj, jl ! dummy loop indices |
|---|
| 970 | REAL(wp) :: zst3 ! local variable |
|---|
| 971 | REAL(wp) :: zcoef_dqlw, zcoef_dqla ! - - |
|---|
| 972 | REAL(wp) :: zztmp, zztmp2, z1_rLsub ! - - |
|---|
| 973 | REAL(wp) :: zfr1, zfr2 ! local variables |
|---|
| 974 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: z1_st ! inverse of surface temperature |
|---|
| 975 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: z_qlw ! long wave heat flux over ice |
|---|
| 976 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: z_qsb ! sensible heat flux over ice |
|---|
| 977 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: z_dqlw ! long wave heat sensitivity over ice |
|---|
| 978 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: z_dqsb ! sensible heat sensitivity over ice |
|---|
| 979 | REAL(wp), DIMENSION(jpi,jpj) :: zevap, zsnw ! evaporation and snw distribution after wind blowing (SI3) |
|---|
| 980 | REAL(wp), DIMENSION(jpi,jpj) :: zqair ! specific humidity of air at z=rn_zqt [kg/kg] !LB |
|---|
| 981 | REAL(wp), DIMENSION(jpi,jpj) :: ztmp, ztmp2 |
|---|
| 982 | !!--------------------------------------------------------------------- |
|---|
| 983 | ! |
|---|
| 984 | zcoef_dqlw = 4._wp * 0.95_wp * stefan ! local scalars |
|---|
| 985 | zcoef_dqla = -rLsub * 11637800._wp * (-5897.8_wp) !LB: BAD! |
|---|
| 986 | ! |
|---|
| 987 | SELECT CASE( nhumi ) |
|---|
| 988 | CASE( np_humi_sph ) |
|---|
| 989 | zqair(:,:) = phumi(:,:) ! what we read in file is already a spec. humidity! |
|---|
| 990 | CASE( np_humi_dpt ) |
|---|
| 991 | zqair(:,:) = q_sat( phumi(:,:), pslp ) |
|---|
| 992 | CASE( np_humi_rlh ) |
|---|
| 993 | zqair(:,:) = q_air_rh( 0.01_wp*phumi(:,:), ptair(:,:), pslp(:,:) ) !LB: 0.01 => RH is % percent in file |
|---|
| 994 | END SELECT |
|---|
| 995 | ! |
|---|
| 996 | zztmp = 1. / ( 1. - albo ) |
|---|
| 997 | WHERE( ptsu(:,:,:) /= 0._wp ) |
|---|
| 998 | z1_st(:,:,:) = 1._wp / ptsu(:,:,:) |
|---|
| 999 | ELSEWHERE |
|---|
| 1000 | z1_st(:,:,:) = 0._wp |
|---|
| 1001 | END WHERE |
|---|
| 1002 | ! ! ========================== ! |
|---|
| 1003 | DO jl = 1, jpl ! Loop over ice categories ! |
|---|
| 1004 | ! ! ========================== ! |
|---|
| 1005 | DO jj = 1 , jpj |
|---|
| 1006 | DO ji = 1, jpi |
|---|
| 1007 | ! ----------------------------! |
|---|
| 1008 | ! I Radiative FLUXES ! |
|---|
| 1009 | ! ----------------------------! |
|---|
| 1010 | zst3 = ptsu(ji,jj,jl) * ptsu(ji,jj,jl) * ptsu(ji,jj,jl) |
|---|
| 1011 | ! Short Wave (sw) |
|---|
| 1012 | qsr_ice(ji,jj,jl) = zztmp * ( 1. - palb(ji,jj,jl) ) * qsr(ji,jj) |
|---|
| 1013 | ! Long Wave (lw) |
|---|
| 1014 | z_qlw(ji,jj,jl) = 0.95 * ( pqlw(ji,jj) - stefan * ptsu(ji,jj,jl) * zst3 ) * tmask(ji,jj,1) |
|---|
| 1015 | ! lw sensitivity |
|---|
| 1016 | z_dqlw(ji,jj,jl) = zcoef_dqlw * zst3 |
|---|
| 1017 | |
|---|
| 1018 | ! ----------------------------! |
|---|
| 1019 | ! II Turbulent FLUXES ! |
|---|
| 1020 | ! ----------------------------! |
|---|
| 1021 | |
|---|
| 1022 | ! ... turbulent heat fluxes with Ch_ice recalculated in blk_ice_1 |
|---|
| 1023 | ! Sensible Heat |
|---|
| 1024 | z_qsb(ji,jj,jl) = rhoa(ji,jj) * rCp_air * Ch_ice(ji,jj) * wndm_ice(ji,jj) * (ptsu(ji,jj,jl) - ptair(ji,jj)) |
|---|
| 1025 | ! Latent Heat |
|---|
| 1026 | zztmp2 = EXP( -5897.8 * z1_st(ji,jj,jl) ) |
|---|
| 1027 | qla_ice(ji,jj,jl) = rn_efac * MAX( 0.e0, rhoa(ji,jj) * rLsub * Ce_ice(ji,jj) * wndm_ice(ji,jj) * & |
|---|
| 1028 | & ( 11637800. * zztmp2 / rhoa(ji,jj) - zqair(ji,jj) ) ) |
|---|
| 1029 | ! Latent heat sensitivity for ice (Dqla/Dt) |
|---|
| 1030 | IF( qla_ice(ji,jj,jl) > 0._wp ) THEN |
|---|
| 1031 | dqla_ice(ji,jj,jl) = rn_efac * zcoef_dqla * Ce_ice(ji,jj) * wndm_ice(ji,jj) * & |
|---|
| 1032 | & z1_st(ji,jj,jl) * z1_st(ji,jj,jl) * zztmp2 |
|---|
| 1033 | ELSE |
|---|
| 1034 | dqla_ice(ji,jj,jl) = 0._wp |
|---|
| 1035 | ENDIF |
|---|
| 1036 | |
|---|
| 1037 | ! Sensible heat sensitivity (Dqsb_ice/Dtn_ice) |
|---|
| 1038 | z_dqsb(ji,jj,jl) = rhoa(ji,jj) * rCp_air * Ch_ice(ji,jj) * wndm_ice(ji,jj) |
|---|
| 1039 | |
|---|
| 1040 | ! ----------------------------! |
|---|
| 1041 | ! III Total FLUXES ! |
|---|
| 1042 | ! ----------------------------! |
|---|
| 1043 | ! Downward Non Solar flux |
|---|
| 1044 | qns_ice (ji,jj,jl) = z_qlw (ji,jj,jl) - z_qsb (ji,jj,jl) - qla_ice (ji,jj,jl) |
|---|
| 1045 | ! Total non solar heat flux sensitivity for ice |
|---|
| 1046 | dqns_ice(ji,jj,jl) = - ( z_dqlw(ji,jj,jl) + z_dqsb(ji,jj,jl) + dqla_ice(ji,jj,jl) ) |
|---|
| 1047 | END DO |
|---|
| 1048 | ! |
|---|
| 1049 | END DO |
|---|
| 1050 | ! |
|---|
| 1051 | END DO |
|---|
| 1052 | ! |
|---|
| 1053 | tprecip(:,:) = pprec(:,:) * rn_pfac * tmask(:,:,1) ! total precipitation [kg/m2/s] |
|---|
| 1054 | sprecip(:,:) = psnow(:,:) * rn_pfac * tmask(:,:,1) ! solid precipitation [kg/m2/s] |
|---|
| 1055 | CALL iom_put( 'snowpre', sprecip ) ! Snow precipitation |
|---|
| 1056 | CALL iom_put( 'precip' , tprecip ) ! Total precipitation |
|---|
| 1057 | |
|---|
| 1058 | ! --- evaporation --- ! |
|---|
| 1059 | z1_rLsub = 1._wp / rLsub |
|---|
| 1060 | evap_ice (:,:,:) = rn_efac * qla_ice (:,:,:) * z1_rLsub ! sublimation |
|---|
| 1061 | devap_ice(:,:,:) = rn_efac * dqla_ice(:,:,:) * z1_rLsub ! d(sublimation)/dT |
|---|
| 1062 | zevap (:,:) = rn_efac * ( emp(:,:) + tprecip(:,:) ) ! evaporation over ocean |
|---|
| 1063 | |
|---|
| 1064 | ! --- evaporation minus precipitation --- ! |
|---|
| 1065 | zsnw(:,:) = 0._wp |
|---|
| 1066 | CALL ice_thd_snwblow( (1.-at_i_b(:,:)), zsnw ) ! snow distribution over ice after wind blowing |
|---|
| 1067 | emp_oce(:,:) = ( 1._wp - at_i_b(:,:) ) * zevap(:,:) - ( tprecip(:,:) - sprecip(:,:) ) - sprecip(:,:) * (1._wp - zsnw ) |
|---|
| 1068 | emp_ice(:,:) = SUM( a_i_b(:,:,:) * evap_ice(:,:,:), dim=3 ) - sprecip(:,:) * zsnw |
|---|
| 1069 | emp_tot(:,:) = emp_oce(:,:) + emp_ice(:,:) |
|---|
| 1070 | |
|---|
| 1071 | ! --- heat flux associated with emp --- ! |
|---|
| 1072 | qemp_oce(:,:) = - ( 1._wp - at_i_b(:,:) ) * zevap(:,:) * sst_m(:,:) * rcp & ! evap at sst |
|---|
| 1073 | & + ( tprecip(:,:) - sprecip(:,:) ) * ( ptair(:,:) - rt0 ) * rcp & ! liquid precip at Tair |
|---|
| 1074 | & + sprecip(:,:) * ( 1._wp - zsnw ) * & ! solid precip at min(Tair,Tsnow) |
|---|
| 1075 | & ( ( MIN( ptair(:,:), rt0 ) - rt0 ) * rcpi * tmask(:,:,1) - rLfus ) |
|---|
| 1076 | qemp_ice(:,:) = sprecip(:,:) * zsnw * & ! solid precip (only) |
|---|
| 1077 | & ( ( MIN( ptair(:,:), rt0 ) - rt0 ) * rcpi * tmask(:,:,1) - rLfus ) |
|---|
| 1078 | |
|---|
| 1079 | ! --- total solar and non solar fluxes --- ! |
|---|
| 1080 | qns_tot(:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + SUM( a_i_b(:,:,:) * qns_ice(:,:,:), dim=3 ) & |
|---|
| 1081 | & + qemp_ice(:,:) + qemp_oce(:,:) |
|---|
| 1082 | qsr_tot(:,:) = ( 1._wp - at_i_b(:,:) ) * qsr_oce(:,:) + SUM( a_i_b(:,:,:) * qsr_ice(:,:,:), dim=3 ) |
|---|
| 1083 | |
|---|
| 1084 | ! --- heat content of precip over ice in J/m3 (to be used in 1D-thermo) --- ! |
|---|
| 1085 | qprec_ice(:,:) = rhos * ( ( MIN( ptair(:,:), rt0 ) - rt0 ) * rcpi * tmask(:,:,1) - rLfus ) |
|---|
| 1086 | |
|---|
| 1087 | ! --- heat content of evap over ice in W/m2 (to be used in 1D-thermo) --- |
|---|
| 1088 | DO jl = 1, jpl |
|---|
| 1089 | qevap_ice(:,:,jl) = 0._wp ! should be -evap_ice(:,:,jl)*( ( Tice - rt0 ) * rcpi * tmask(:,:,1) ) |
|---|
| 1090 | ! ! But we do not have Tice => consider it at 0degC => evap=0 |
|---|
| 1091 | END DO |
|---|
| 1092 | |
|---|
| 1093 | ! --- shortwave radiation transmitted below the surface (W/m2, see Grenfell Maykut 77) --- ! |
|---|
| 1094 | zfr1 = ( 0.18 * ( 1.0 - cldf_ice ) + 0.35 * cldf_ice ) ! transmission when hi>10cm |
|---|
| 1095 | zfr2 = ( 0.82 * ( 1.0 - cldf_ice ) + 0.65 * cldf_ice ) ! zfr2 such that zfr1 + zfr2 to equal 1 |
|---|
| 1096 | ! |
|---|
| 1097 | WHERE ( phs(:,:,:) <= 0._wp .AND. phi(:,:,:) < 0.1_wp ) ! linear decrease from hi=0 to 10cm |
|---|
| 1098 | qtr_ice_top(:,:,:) = qsr_ice(:,:,:) * ( zfr1 + zfr2 * ( 1._wp - phi(:,:,:) * 10._wp ) ) |
|---|
| 1099 | ELSEWHERE( phs(:,:,:) <= 0._wp .AND. phi(:,:,:) >= 0.1_wp ) ! constant (zfr1) when hi>10cm |
|---|
| 1100 | qtr_ice_top(:,:,:) = qsr_ice(:,:,:) * zfr1 |
|---|
| 1101 | ELSEWHERE ! zero when hs>0 |
|---|
| 1102 | qtr_ice_top(:,:,:) = 0._wp |
|---|
| 1103 | END WHERE |
|---|
| 1104 | ! |
|---|
| 1105 | |
|---|
| 1106 | IF( iom_use('evap_ao_cea') .OR. iom_use('hflx_evap_cea') ) THEN |
|---|
| 1107 | ztmp(:,:) = zevap(:,:) * ( 1._wp - at_i_b(:,:) ) |
|---|
| 1108 | IF( iom_use('evap_ao_cea' ) ) CALL iom_put( 'evap_ao_cea' , ztmp(:,:) * tmask(:,:,1) ) ! ice-free oce evap (cell average) |
|---|
| 1109 | IF( iom_use('hflx_evap_cea') ) CALL iom_put( 'hflx_evap_cea', ztmp(:,:) * sst_m(:,:) * rcp * tmask(:,:,1) ) ! heat flux from evap (cell average) |
|---|
| 1110 | ENDIF |
|---|
| 1111 | IF( iom_use('hflx_rain_cea') ) THEN |
|---|
| 1112 | ztmp(:,:) = rcp * ( SUM( (ptsu-rt0) * a_i_b, dim=3 ) + sst_m(:,:) * ( 1._wp - at_i_b(:,:) ) ) |
|---|
| 1113 | IF( iom_use('hflx_rain_cea') ) CALL iom_put( 'hflx_rain_cea', ( tprecip(:,:) - sprecip(:,:) ) * ztmp(:,:) ) ! heat flux from rain (cell average) |
|---|
| 1114 | ENDIF |
|---|
| 1115 | IF( iom_use('hflx_snow_cea') .OR. iom_use('hflx_snow_ao_cea') .OR. iom_use('hflx_snow_ai_cea') ) THEN |
|---|
| 1116 | WHERE( SUM( a_i_b, dim=3 ) > 1.e-10 ) ; ztmp(:,:) = rcpi * SUM( (ptsu-rt0) * a_i_b, dim=3 ) / SUM( a_i_b, dim=3 ) |
|---|
| 1117 | ELSEWHERE ; ztmp(:,:) = rcp * sst_m(:,:) |
|---|
| 1118 | ENDWHERE |
|---|
| 1119 | ztmp2(:,:) = sprecip(:,:) * ( ztmp(:,:) - rLfus ) |
|---|
| 1120 | IF( iom_use('hflx_snow_cea') ) CALL iom_put('hflx_snow_cea' , ztmp2(:,:) ) ! heat flux from snow (cell average) |
|---|
| 1121 | IF( iom_use('hflx_snow_ao_cea') ) CALL iom_put('hflx_snow_ao_cea', ztmp2(:,:) * ( 1._wp - zsnw(:,:) ) ) ! heat flux from snow (over ocean) |
|---|
| 1122 | IF( iom_use('hflx_snow_ai_cea') ) CALL iom_put('hflx_snow_ai_cea', ztmp2(:,:) * zsnw(:,:) ) ! heat flux from snow (over ice) |
|---|
| 1123 | ENDIF |
|---|
| 1124 | ! |
|---|
| 1125 | IF(ln_ctl) THEN |
|---|
| 1126 | CALL prt_ctl(tab3d_1=qla_ice , clinfo1=' blk_ice: qla_ice : ', tab3d_2=z_qsb , clinfo2=' z_qsb : ', kdim=jpl) |
|---|
| 1127 | CALL prt_ctl(tab3d_1=z_qlw , clinfo1=' blk_ice: z_qlw : ', tab3d_2=dqla_ice, clinfo2=' dqla_ice : ', kdim=jpl) |
|---|
| 1128 | CALL prt_ctl(tab3d_1=z_dqsb , clinfo1=' blk_ice: z_dqsb : ', tab3d_2=z_dqlw , clinfo2=' z_dqlw : ', kdim=jpl) |
|---|
| 1129 | CALL prt_ctl(tab3d_1=dqns_ice, clinfo1=' blk_ice: dqns_ice : ', tab3d_2=qsr_ice , clinfo2=' qsr_ice : ', kdim=jpl) |
|---|
| 1130 | CALL prt_ctl(tab3d_1=ptsu , clinfo1=' blk_ice: ptsu : ', tab3d_2=qns_ice , clinfo2=' qns_ice : ', kdim=jpl) |
|---|
| 1131 | CALL prt_ctl(tab2d_1=tprecip , clinfo1=' blk_ice: tprecip : ', tab2d_2=sprecip , clinfo2=' sprecip : ') |
|---|
| 1132 | ENDIF |
|---|
| 1133 | ! |
|---|
| 1134 | END SUBROUTINE blk_ice_2 |
|---|
| 1135 | |
|---|
| 1136 | |
|---|
| 1137 | SUBROUTINE blk_ice_qcn( ld_virtual_itd, ptsu, ptb, phs, phi ) |
|---|
| 1138 | !!--------------------------------------------------------------------- |
|---|
| 1139 | !! *** ROUTINE blk_ice_qcn *** |
|---|
| 1140 | !! |
|---|
| 1141 | !! ** Purpose : Compute surface temperature and snow/ice conduction flux |
|---|
| 1142 | !! to force sea ice / snow thermodynamics |
|---|
| 1143 | !! in the case conduction flux is emulated |
|---|
| 1144 | !! |
|---|
| 1145 | !! ** Method : compute surface energy balance assuming neglecting heat storage |
|---|
| 1146 | !! following the 0-layer Semtner (1976) approach |
|---|
| 1147 | !! |
|---|
| 1148 | !! ** Outputs : - ptsu : sea-ice / snow surface temperature (K) |
|---|
| 1149 | !! - qcn_ice : surface inner conduction flux (W/m2) |
|---|
| 1150 | !! |
|---|
| 1151 | !!--------------------------------------------------------------------- |
|---|
| 1152 | LOGICAL , INTENT(in ) :: ld_virtual_itd ! single-category option |
|---|
| 1153 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: ptsu ! sea ice / snow surface temperature |
|---|
| 1154 | REAL(wp), DIMENSION(:,:) , INTENT(in ) :: ptb ! sea ice base temperature |
|---|
| 1155 | REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: phs ! snow thickness |
|---|
| 1156 | REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: phi ! sea ice thickness |
|---|
| 1157 | ! |
|---|
| 1158 | INTEGER , PARAMETER :: nit = 10 ! number of iterations |
|---|
| 1159 | REAL(wp), PARAMETER :: zepsilon = 0.1_wp ! characteristic thickness for enhanced conduction |
|---|
| 1160 | ! |
|---|
| 1161 | INTEGER :: ji, jj, jl ! dummy loop indices |
|---|
| 1162 | INTEGER :: iter ! local integer |
|---|
| 1163 | REAL(wp) :: zfac, zfac2, zfac3 ! local scalars |
|---|
| 1164 | REAL(wp) :: zkeff_h, ztsu, ztsu0 ! |
|---|
| 1165 | REAL(wp) :: zqc, zqnet ! |
|---|
| 1166 | REAL(wp) :: zhe, zqa0 ! |
|---|
| 1167 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zgfac ! enhanced conduction factor |
|---|
| 1168 | !!--------------------------------------------------------------------- |
|---|
| 1169 | |
|---|
| 1170 | ! -------------------------------------! |
|---|
| 1171 | ! I Enhanced conduction factor ! |
|---|
| 1172 | ! -------------------------------------! |
|---|
| 1173 | ! Emulates the enhancement of conduction by unresolved thin ice (ld_virtual_itd = T) |
|---|
| 1174 | ! Fichefet and Morales Maqueda, JGR 1997 |
|---|
| 1175 | ! |
|---|
| 1176 | zgfac(:,:,:) = 1._wp |
|---|
| 1177 | |
|---|
| 1178 | IF( ld_virtual_itd ) THEN |
|---|
| 1179 | ! |
|---|
| 1180 | zfac = 1._wp / ( rn_cnd_s + rcnd_i ) |
|---|
| 1181 | zfac2 = EXP(1._wp) * 0.5_wp * zepsilon |
|---|
| 1182 | zfac3 = 2._wp / zepsilon |
|---|
| 1183 | ! |
|---|
| 1184 | DO jl = 1, jpl |
|---|
| 1185 | DO jj = 1 , jpj |
|---|
| 1186 | DO ji = 1, jpi |
|---|
| 1187 | zhe = ( rn_cnd_s * phi(ji,jj,jl) + rcnd_i * phs(ji,jj,jl) ) * zfac ! Effective thickness |
|---|
| 1188 | IF( zhe >= zfac2 ) zgfac(ji,jj,jl) = MIN( 2._wp, 0.5_wp * ( 1._wp + LOG( zhe * zfac3 ) ) ) ! Enhanced conduction factor |
|---|
| 1189 | END DO |
|---|
| 1190 | END DO |
|---|
| 1191 | END DO |
|---|
| 1192 | ! |
|---|
| 1193 | ENDIF |
|---|
| 1194 | |
|---|
| 1195 | ! -------------------------------------------------------------! |
|---|
| 1196 | ! II Surface temperature and conduction flux ! |
|---|
| 1197 | ! -------------------------------------------------------------! |
|---|
| 1198 | ! |
|---|
| 1199 | zfac = rcnd_i * rn_cnd_s |
|---|
| 1200 | ! |
|---|
| 1201 | DO jl = 1, jpl |
|---|
| 1202 | DO jj = 1 , jpj |
|---|
| 1203 | DO ji = 1, jpi |
|---|
| 1204 | ! |
|---|
| 1205 | zkeff_h = zfac * zgfac(ji,jj,jl) / & ! Effective conductivity of the snow-ice system divided by thickness |
|---|
| 1206 | & ( rcnd_i * phs(ji,jj,jl) + rn_cnd_s * MAX( 0.01, phi(ji,jj,jl) ) ) |
|---|
| 1207 | ztsu = ptsu(ji,jj,jl) ! Store current iteration temperature |
|---|
| 1208 | ztsu0 = ptsu(ji,jj,jl) ! Store initial surface temperature |
|---|
| 1209 | zqa0 = qsr_ice(ji,jj,jl) - qtr_ice_top(ji,jj,jl) + qns_ice(ji,jj,jl) ! Net initial atmospheric heat flux |
|---|
| 1210 | ! |
|---|
| 1211 | DO iter = 1, nit ! --- Iterative loop |
|---|
| 1212 | zqc = zkeff_h * ( ztsu - ptb(ji,jj) ) ! Conduction heat flux through snow-ice system (>0 downwards) |
|---|
| 1213 | zqnet = zqa0 + dqns_ice(ji,jj,jl) * ( ztsu - ptsu(ji,jj,jl) ) - zqc ! Surface energy budget |
|---|
| 1214 | ztsu = ztsu - zqnet / ( dqns_ice(ji,jj,jl) - zkeff_h ) ! Temperature update |
|---|
| 1215 | END DO |
|---|
| 1216 | ! |
|---|
| 1217 | ptsu (ji,jj,jl) = MIN( rt0, ztsu ) |
|---|
| 1218 | qcn_ice(ji,jj,jl) = zkeff_h * ( ptsu(ji,jj,jl) - ptb(ji,jj) ) |
|---|
| 1219 | qns_ice(ji,jj,jl) = qns_ice(ji,jj,jl) + dqns_ice(ji,jj,jl) * ( ptsu(ji,jj,jl) - ztsu0 ) |
|---|
| 1220 | qml_ice(ji,jj,jl) = ( qsr_ice(ji,jj,jl) - qtr_ice_top(ji,jj,jl) + qns_ice(ji,jj,jl) - qcn_ice(ji,jj,jl) ) & |
|---|
| 1221 | & * MAX( 0._wp , SIGN( 1._wp, ptsu(ji,jj,jl) - rt0 ) ) |
|---|
| 1222 | |
|---|
| 1223 | ! --- Diagnose the heat loss due to changing non-solar flux (as in icethd_zdf_bl99) --- ! |
|---|
| 1224 | hfx_err_dif(ji,jj) = hfx_err_dif(ji,jj) - ( dqns_ice(ji,jj,jl) * ( ptsu(ji,jj,jl) - ztsu0 ) ) * a_i_b(ji,jj,jl) |
|---|
| 1225 | |
|---|
| 1226 | END DO |
|---|
| 1227 | END DO |
|---|
| 1228 | ! |
|---|
| 1229 | END DO |
|---|
| 1230 | ! |
|---|
| 1231 | END SUBROUTINE blk_ice_qcn |
|---|
| 1232 | |
|---|
| 1233 | |
|---|
| 1234 | SUBROUTINE Cdn10_Lupkes2012( pcd ) |
|---|
| 1235 | !!---------------------------------------------------------------------- |
|---|
| 1236 | !! *** ROUTINE Cdn10_Lupkes2012 *** |
|---|
| 1237 | !! |
|---|
| 1238 | !! ** Purpose : Recompute the neutral air-ice drag referenced at 10m |
|---|
| 1239 | !! to make it dependent on edges at leads, melt ponds and flows. |
|---|
| 1240 | !! After some approximations, this can be resumed to a dependency |
|---|
| 1241 | !! on ice concentration. |
|---|
| 1242 | !! |
|---|
| 1243 | !! ** Method : The parameterization is taken from Lupkes et al. (2012) eq.(50) |
|---|
| 1244 | !! with the highest level of approximation: level4, eq.(59) |
|---|
| 1245 | !! The generic drag over a cell partly covered by ice can be re-written as follows: |
|---|
| 1246 | !! |
|---|
| 1247 | !! Cd = Cdw * (1-A) + Cdi * A + Ce * (1-A)**(nu+1/(10*beta)) * A**mu |
|---|
| 1248 | !! |
|---|
| 1249 | !! Ce = 2.23e-3 , as suggested by Lupkes (eq. 59) |
|---|
| 1250 | !! nu = mu = beta = 1 , as suggested by Lupkes (eq. 59) |
|---|
| 1251 | !! A is the concentration of ice minus melt ponds (if any) |
|---|
| 1252 | !! |
|---|
| 1253 | !! This new drag has a parabolic shape (as a function of A) starting at |
|---|
| 1254 | !! Cdw(say 1.5e-3) for A=0, reaching 1.97e-3 for A~0.5 |
|---|
| 1255 | !! and going down to Cdi(say 1.4e-3) for A=1 |
|---|
| 1256 | !! |
|---|
| 1257 | !! It is theoretically applicable to all ice conditions (not only MIZ) |
|---|
| 1258 | !! => see Lupkes et al (2013) |
|---|
| 1259 | !! |
|---|
| 1260 | !! ** References : Lupkes et al. JGR 2012 (theory) |
|---|
| 1261 | !! Lupkes et al. GRL 2013 (application to GCM) |
|---|
| 1262 | !! |
|---|
| 1263 | !!---------------------------------------------------------------------- |
|---|
| 1264 | REAL(wp), DIMENSION(:,:), INTENT(inout) :: pcd |
|---|
| 1265 | REAL(wp), PARAMETER :: zCe = 2.23e-03_wp |
|---|
| 1266 | REAL(wp), PARAMETER :: znu = 1._wp |
|---|
| 1267 | REAL(wp), PARAMETER :: zmu = 1._wp |
|---|
| 1268 | REAL(wp), PARAMETER :: zbeta = 1._wp |
|---|
| 1269 | REAL(wp) :: zcoef |
|---|
| 1270 | !!---------------------------------------------------------------------- |
|---|
| 1271 | zcoef = znu + 1._wp / ( 10._wp * zbeta ) |
|---|
| 1272 | |
|---|
| 1273 | ! generic drag over a cell partly covered by ice |
|---|
| 1274 | !!Cd(:,:) = Cd_oce(:,:) * ( 1._wp - at_i_b(:,:) ) + & ! pure ocean drag |
|---|
| 1275 | !! & Cd_ice * at_i_b(:,:) + & ! pure ice drag |
|---|
| 1276 | !! & zCe * ( 1._wp - at_i_b(:,:) )**zcoef * at_i_b(:,:)**zmu ! change due to sea-ice morphology |
|---|
| 1277 | |
|---|
| 1278 | ! ice-atm drag |
|---|
| 1279 | pcd(:,:) = rCd_ice + & ! pure ice drag |
|---|
| 1280 | & zCe * ( 1._wp - at_i_b(:,:) )**zcoef * at_i_b(:,:)**(zmu-1._wp) ! change due to sea-ice morphology |
|---|
| 1281 | |
|---|
| 1282 | END SUBROUTINE Cdn10_Lupkes2012 |
|---|
| 1283 | |
|---|
| 1284 | |
|---|
| 1285 | SUBROUTINE Cdn10_Lupkes2015( ptm_su, pslp, pcd, pch ) |
|---|
| 1286 | !!---------------------------------------------------------------------- |
|---|
| 1287 | !! *** ROUTINE Cdn10_Lupkes2015 *** |
|---|
| 1288 | !! |
|---|
| 1289 | !! ** pUrpose : Alternative turbulent transfert coefficients formulation |
|---|
| 1290 | !! between sea-ice and atmosphere with distinct momentum |
|---|
| 1291 | !! and heat coefficients depending on sea-ice concentration |
|---|
| 1292 | !! and atmospheric stability (no meltponds effect for now). |
|---|
| 1293 | !! |
|---|
| 1294 | !! ** Method : The parameterization is adapted from Lupkes et al. (2015) |
|---|
| 1295 | !! and ECHAM6 atmospheric model. Compared to Lupkes2012 scheme, |
|---|
| 1296 | !! it considers specific skin and form drags (Andreas et al. 2010) |
|---|
| 1297 | !! to compute neutral transfert coefficients for both heat and |
|---|
| 1298 | !! momemtum fluxes. Atmospheric stability effect on transfert |
|---|
| 1299 | !! coefficient is also taken into account following Louis (1979). |
|---|
| 1300 | !! |
|---|
| 1301 | !! ** References : Lupkes et al. JGR 2015 (theory) |
|---|
| 1302 | !! Lupkes et al. ECHAM6 documentation 2015 (implementation) |
|---|
| 1303 | !! |
|---|
| 1304 | !!---------------------------------------------------------------------- |
|---|
| 1305 | ! |
|---|
| 1306 | REAL(wp), DIMENSION(:,:), INTENT(in ) :: ptm_su ! sea-ice surface temperature [K] |
|---|
| 1307 | REAL(wp), DIMENSION(:,:), INTENT(in ) :: pslp ! sea-level pressure [Pa] |
|---|
| 1308 | REAL(wp), DIMENSION(:,:), INTENT(inout) :: pcd ! momentum transfert coefficient |
|---|
| 1309 | REAL(wp), DIMENSION(:,:), INTENT(inout) :: pch ! heat transfert coefficient |
|---|
| 1310 | REAL(wp), DIMENSION(jpi,jpj) :: zst, zqo_sat, zqi_sat |
|---|
| 1311 | ! |
|---|
| 1312 | ! ECHAM6 constants |
|---|
| 1313 | REAL(wp), PARAMETER :: z0_skin_ice = 0.69e-3_wp ! Eq. 43 [m] |
|---|
| 1314 | REAL(wp), PARAMETER :: z0_form_ice = 0.57e-3_wp ! Eq. 42 [m] |
|---|
| 1315 | REAL(wp), PARAMETER :: z0_ice = 1.00e-3_wp ! Eq. 15 [m] |
|---|
| 1316 | REAL(wp), PARAMETER :: zce10 = 2.80e-3_wp ! Eq. 41 |
|---|
| 1317 | REAL(wp), PARAMETER :: zbeta = 1.1_wp ! Eq. 41 |
|---|
| 1318 | REAL(wp), PARAMETER :: zc = 5._wp ! Eq. 13 |
|---|
| 1319 | REAL(wp), PARAMETER :: zc2 = zc * zc |
|---|
| 1320 | REAL(wp), PARAMETER :: zam = 2. * zc ! Eq. 14 |
|---|
| 1321 | REAL(wp), PARAMETER :: zah = 3. * zc ! Eq. 30 |
|---|
| 1322 | REAL(wp), PARAMETER :: z1_alpha = 1._wp / 0.2_wp ! Eq. 51 |
|---|
| 1323 | REAL(wp), PARAMETER :: z1_alphaf = z1_alpha ! Eq. 56 |
|---|
| 1324 | REAL(wp), PARAMETER :: zbetah = 1.e-3_wp ! Eq. 26 |
|---|
| 1325 | REAL(wp), PARAMETER :: zgamma = 1.25_wp ! Eq. 26 |
|---|
| 1326 | REAL(wp), PARAMETER :: z1_gamma = 1._wp / zgamma |
|---|
| 1327 | REAL(wp), PARAMETER :: r1_3 = 1._wp / 3._wp |
|---|
| 1328 | ! |
|---|
| 1329 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 1330 | REAL(wp) :: zthetav_os, zthetav_is, zthetav_zu |
|---|
| 1331 | REAL(wp) :: zrib_o, zrib_i |
|---|
| 1332 | REAL(wp) :: zCdn_skin_ice, zCdn_form_ice, zCdn_ice |
|---|
| 1333 | REAL(wp) :: zChn_skin_ice, zChn_form_ice |
|---|
| 1334 | REAL(wp) :: z0w, z0i, zfmi, zfmw, zfhi, zfhw |
|---|
| 1335 | REAL(wp) :: zCdn_form_tmp |
|---|
| 1336 | !!---------------------------------------------------------------------- |
|---|
| 1337 | |
|---|
| 1338 | ! Momentum Neutral Transfert Coefficients (should be a constant) |
|---|
| 1339 | zCdn_form_tmp = zce10 * ( LOG( 10._wp / z0_form_ice + 1._wp ) / LOG( rn_zu / z0_form_ice + 1._wp ) )**2 ! Eq. 40 |
|---|
| 1340 | zCdn_skin_ice = ( vkarmn / LOG( rn_zu / z0_skin_ice + 1._wp ) )**2 ! Eq. 7 |
|---|
| 1341 | zCdn_ice = zCdn_skin_ice ! Eq. 7 |
|---|
| 1342 | !zCdn_ice = 1.89e-3 ! old ECHAM5 value (cf Eq. 32) |
|---|
| 1343 | |
|---|
| 1344 | ! Heat Neutral Transfert Coefficients |
|---|
| 1345 | zChn_skin_ice = vkarmn**2 / ( LOG( rn_zu / z0_ice + 1._wp ) * LOG( rn_zu * z1_alpha / z0_skin_ice + 1._wp ) ) ! Eq. 50 + Eq. 52 |
|---|
| 1346 | |
|---|
| 1347 | ! Atmospheric and Surface Variables |
|---|
| 1348 | zst(:,:) = sst_m(:,:) + rt0 ! convert SST from Celcius to Kelvin |
|---|
| 1349 | zqo_sat(:,:) = rdct_qsat_salt * q_sat( zst(:,:) , pslp(:,:) ) ! saturation humidity over ocean [kg/kg] |
|---|
| 1350 | zqi_sat(:,:) = q_sat( ptm_su(:,:), pslp(:,:) ) ! saturation humidity over ice [kg/kg] |
|---|
| 1351 | ! |
|---|
| 1352 | DO jj = 2, jpjm1 ! reduced loop is necessary for reproducibility |
|---|
| 1353 | DO ji = fs_2, fs_jpim1 |
|---|
| 1354 | ! Virtual potential temperature [K] |
|---|
| 1355 | zthetav_os = zst(ji,jj) * ( 1._wp + rctv0 * zqo_sat(ji,jj) ) ! over ocean |
|---|
| 1356 | zthetav_is = ptm_su(ji,jj) * ( 1._wp + rctv0 * zqi_sat(ji,jj) ) ! ocean ice |
|---|
| 1357 | zthetav_zu = t_zu (ji,jj) * ( 1._wp + rctv0 * q_zu(ji,jj) ) ! at zu |
|---|
| 1358 | |
|---|
| 1359 | ! Bulk Richardson Number (could use Ri_bulk function from aerobulk instead) |
|---|
| 1360 | zrib_o = grav / zthetav_os * ( zthetav_zu - zthetav_os ) * rn_zu / MAX( 0.5, wndm(ji,jj) )**2 ! over ocean |
|---|
| 1361 | zrib_i = grav / zthetav_is * ( zthetav_zu - zthetav_is ) * rn_zu / MAX( 0.5, wndm_ice(ji,jj) )**2 ! over ice |
|---|
| 1362 | |
|---|
| 1363 | ! Momentum and Heat Neutral Transfert Coefficients |
|---|
| 1364 | zCdn_form_ice = zCdn_form_tmp * at_i_b(ji,jj) * ( 1._wp - at_i_b(ji,jj) )**zbeta ! Eq. 40 |
|---|
| 1365 | zChn_form_ice = zCdn_form_ice / ( 1._wp + ( LOG( z1_alphaf ) / vkarmn ) * SQRT( zCdn_form_ice ) ) ! Eq. 53 |
|---|
| 1366 | |
|---|
| 1367 | ! Momentum and Heat Stability functions (possibility to use psi_m_ecmwf instead ?) |
|---|
| 1368 | z0w = rn_zu * EXP( -1._wp * vkarmn / SQRT( Cdn_oce(ji,jj) ) ) ! over water |
|---|
| 1369 | z0i = z0_skin_ice ! over ice |
|---|
| 1370 | IF( zrib_o <= 0._wp ) THEN |
|---|
| 1371 | zfmw = 1._wp - zam * zrib_o / ( 1._wp + 3._wp * zc2 * Cdn_oce(ji,jj) * SQRT( -zrib_o * ( rn_zu / z0w + 1._wp ) ) ) ! Eq. 10 |
|---|
| 1372 | zfhw = ( 1._wp + ( zbetah * ( zthetav_os - zthetav_zu )**r1_3 / ( Chn_oce(ji,jj) * MAX(0.01, wndm(ji,jj)) ) & ! Eq. 26 |
|---|
| 1373 | & )**zgamma )**z1_gamma |
|---|
| 1374 | ELSE |
|---|
| 1375 | zfmw = 1._wp / ( 1._wp + zam * zrib_o / SQRT( 1._wp + zrib_o ) ) ! Eq. 12 |
|---|
| 1376 | zfhw = 1._wp / ( 1._wp + zah * zrib_o / SQRT( 1._wp + zrib_o ) ) ! Eq. 28 |
|---|
| 1377 | ENDIF |
|---|
| 1378 | |
|---|
| 1379 | IF( zrib_i <= 0._wp ) THEN |
|---|
| 1380 | zfmi = 1._wp - zam * zrib_i / (1._wp + 3._wp * zc2 * zCdn_ice * SQRT( -zrib_i * ( rn_zu / z0i + 1._wp))) ! Eq. 9 |
|---|
| 1381 | zfhi = 1._wp - zah * zrib_i / (1._wp + 3._wp * zc2 * zCdn_ice * SQRT( -zrib_i * ( rn_zu / z0i + 1._wp))) ! Eq. 25 |
|---|
| 1382 | ELSE |
|---|
| 1383 | zfmi = 1._wp / ( 1._wp + zam * zrib_i / SQRT( 1._wp + zrib_i ) ) ! Eq. 11 |
|---|
| 1384 | zfhi = 1._wp / ( 1._wp + zah * zrib_i / SQRT( 1._wp + zrib_i ) ) ! Eq. 27 |
|---|
| 1385 | ENDIF |
|---|
| 1386 | |
|---|
| 1387 | ! Momentum Transfert Coefficients (Eq. 38) |
|---|
| 1388 | pcd(ji,jj) = zCdn_skin_ice * zfmi + & |
|---|
| 1389 | & zCdn_form_ice * ( zfmi * at_i_b(ji,jj) + zfmw * ( 1._wp - at_i_b(ji,jj) ) ) / MAX( 1.e-06, at_i_b(ji,jj) ) |
|---|
| 1390 | |
|---|
| 1391 | ! Heat Transfert Coefficients (Eq. 49) |
|---|
| 1392 | pch(ji,jj) = zChn_skin_ice * zfhi + & |
|---|
| 1393 | & zChn_form_ice * ( zfhi * at_i_b(ji,jj) + zfhw * ( 1._wp - at_i_b(ji,jj) ) ) / MAX( 1.e-06, at_i_b(ji,jj) ) |
|---|
| 1394 | ! |
|---|
| 1395 | END DO |
|---|
| 1396 | END DO |
|---|
| 1397 | CALL lbc_lnk_multi( 'sbcblk', pcd, 'T', 1., pch, 'T', 1. ) |
|---|
| 1398 | ! |
|---|
| 1399 | END SUBROUTINE Cdn10_Lupkes2015 |
|---|
| 1400 | |
|---|
| 1401 | #endif |
|---|
| 1402 | |
|---|
| 1403 | !!====================================================================== |
|---|
| 1404 | END MODULE sbcblk |
|---|
