| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !! 3.6 ! 2014-11 (P. Mathiot, C. Harris) add ice shelves melting |
|---|
| 16 | !! 4.0 ! 2016-06 (L. Brodeau) new general bulk formulation |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! sbc_init : read namsbc namelist |
|---|
| 21 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 22 | !! sbc_final : Finalize CICE ice model (if used) |
|---|
| 23 | !!---------------------------------------------------------------------- |
|---|
| 24 | USE oce ! ocean dynamics and tracers |
|---|
| 25 | USE dom_oce ! ocean space and time domain |
|---|
| 26 | USE closea ! closed seas |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 29 | USE trc_oce ! shared ocean-passive tracers variables |
|---|
| 30 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 31 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 32 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 33 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 34 | USE sbcblk ! surface boundary condition: bulk formulation |
|---|
| 35 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 36 | #if defined key_si3 |
|---|
| 37 | USE icestp ! surface boundary condition: SI3 sea-ice model |
|---|
| 38 | #endif |
|---|
| 39 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 40 | USE sbccpl ! surface boundary condition: coupled formulation |
|---|
| 41 | USE cpl_oasis3 ! OASIS routines for coupling |
|---|
| 42 | USE sbcclo ! surface boundary condition: closed sea correction |
|---|
| 43 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 44 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 45 | USE sbcapr ! surface boundary condition: atmo pressure |
|---|
| 46 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 47 | USE icbstp ! Icebergs |
|---|
| 48 | USE icb_oce , ONLY : ln_passive_mode ! iceberg interaction mode |
|---|
| 49 | USE traqsr ! active tracers: light penetration |
|---|
| 50 | USE sbcwave ! Wave module |
|---|
| 51 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 52 | USE usrdef_sbc ! user defined: surface boundary condition |
|---|
| 53 | USE closea ! closed sea |
|---|
| 54 | ! |
|---|
| 55 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 56 | USE iom ! IOM library |
|---|
| 57 | USE in_out_manager ! I/O manager |
|---|
| 58 | USE lib_mpp ! MPP library |
|---|
| 59 | USE timing ! Timing |
|---|
| 60 | USE wet_dry |
|---|
| 61 | USE diu_bulk, ONLY: ln_diurnal_only ! diurnal SST diagnostic |
|---|
| 62 | |
|---|
| 63 | IMPLICIT NONE |
|---|
| 64 | PRIVATE |
|---|
| 65 | |
|---|
| 66 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 67 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 68 | |
|---|
| 69 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 70 | |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 73 | !! $Id$ |
|---|
| 74 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | CONTAINS |
|---|
| 77 | |
|---|
| 78 | SUBROUTINE sbc_init( Kbb, Kmm, Kaa ) |
|---|
| 79 | !!--------------------------------------------------------------------- |
|---|
| 80 | !! *** ROUTINE sbc_init *** |
|---|
| 81 | !! |
|---|
| 82 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 83 | !! |
|---|
| 84 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 85 | !! Call init routines for all other SBC modules that have one |
|---|
| 86 | !! |
|---|
| 87 | !! ** Action : - read namsbc parameters |
|---|
| 88 | !! - nsbc: type of sbc |
|---|
| 89 | !!---------------------------------------------------------------------- |
|---|
| 90 | INTEGER, INTENT(in) :: Kbb, Kmm, Kaa ! ocean time level indices |
|---|
| 91 | INTEGER :: ios, icpt ! local integer |
|---|
| 92 | LOGICAL :: ll_purecpl, ll_opa, ll_not_nemo ! local logical |
|---|
| 93 | !! |
|---|
| 94 | NAMELIST/namsbc/ nn_fsbc , & |
|---|
| 95 | & ln_usr , ln_flx , ln_blk , & |
|---|
| 96 | & ln_cpl , ln_mixcpl , nn_components, & |
|---|
| 97 | & nn_ice , ln_ice_embd, & |
|---|
| 98 | & ln_traqsr, ln_dm2dc , & |
|---|
| 99 | & ln_rnf , nn_fwb , ln_ssr , ln_apr_dyn, & |
|---|
| 100 | & ln_wave , ln_cdgw , ln_sdw , ln_tauwoc , ln_stcor, & |
|---|
| 101 | & ln_tauw , nn_lsm , nn_sdrift |
|---|
| 102 | !!---------------------------------------------------------------------- |
|---|
| 103 | ! |
|---|
| 104 | IF(lwp) THEN |
|---|
| 105 | WRITE(numout,*) |
|---|
| 106 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 107 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 108 | ENDIF |
|---|
| 109 | ! |
|---|
| 110 | ! !** read Surface Module namelist |
|---|
| 111 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 112 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist' ) |
|---|
| 113 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 114 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist' ) |
|---|
| 115 | IF(lwm) WRITE( numond, namsbc ) |
|---|
| 116 | ! |
|---|
| 117 | #if defined key_mpp_mpi |
|---|
| 118 | ncom_fsbc = nn_fsbc ! make nn_fsbc available for lib_mpp |
|---|
| 119 | #endif |
|---|
| 120 | ! !* overwrite namelist parameter using CPP key information |
|---|
| 121 | #if defined key_agrif |
|---|
| 122 | IF( Agrif_Root() ) THEN ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid) |
|---|
| 123 | IF( lk_si3 ) nn_ice = 2 |
|---|
| 124 | IF( lk_cice ) nn_ice = 3 |
|---|
| 125 | ENDIF |
|---|
| 126 | #else |
|---|
| 127 | IF( lk_si3 ) nn_ice = 2 |
|---|
| 128 | IF( lk_cice ) nn_ice = 3 |
|---|
| 129 | #endif |
|---|
| 130 | ! |
|---|
| 131 | IF(lwp) THEN !* Control print |
|---|
| 132 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 133 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 134 | WRITE(numout,*) ' Type of air-sea fluxes : ' |
|---|
| 135 | WRITE(numout,*) ' user defined formulation ln_usr = ', ln_usr |
|---|
| 136 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 137 | WRITE(numout,*) ' bulk formulation ln_blk = ', ln_blk |
|---|
| 138 | WRITE(numout,*) ' Type of coupling (Ocean/Ice/Atmosphere) : ' |
|---|
| 139 | WRITE(numout,*) ' ocean-atmosphere coupled formulation ln_cpl = ', ln_cpl |
|---|
| 140 | WRITE(numout,*) ' mixed forced-coupled formulation ln_mixcpl = ', ln_mixcpl |
|---|
| 141 | !!gm lk_oasis is controlled by key_oasis3 ===>>> It shoud be removed from the namelist |
|---|
| 142 | WRITE(numout,*) ' OASIS coupling (with atm or sas) lk_oasis = ', lk_oasis |
|---|
| 143 | WRITE(numout,*) ' components of your executable nn_components = ', nn_components |
|---|
| 144 | WRITE(numout,*) ' Sea-ice : ' |
|---|
| 145 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 146 | WRITE(numout,*) ' ice embedded into ocean ln_ice_embd = ', ln_ice_embd |
|---|
| 147 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 148 | WRITE(numout,*) ' Light penetration in temperature Eq. ln_traqsr = ', ln_traqsr |
|---|
| 149 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 150 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 151 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 152 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 153 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 154 | WRITE(numout,*) ' nb of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 155 | WRITE(numout,*) ' surface wave ln_wave = ', ln_wave |
|---|
| 156 | WRITE(numout,*) ' Stokes drift corr. to vert. velocity ln_sdw = ', ln_sdw |
|---|
| 157 | WRITE(numout,*) ' vertical parametrization nn_sdrift = ', nn_sdrift |
|---|
| 158 | WRITE(numout,*) ' wave modified ocean stress ln_tauwoc = ', ln_tauwoc |
|---|
| 159 | WRITE(numout,*) ' wave modified ocean stress component ln_tauw = ', ln_tauw |
|---|
| 160 | WRITE(numout,*) ' Stokes coriolis term ln_stcor = ', ln_stcor |
|---|
| 161 | WRITE(numout,*) ' neutral drag coefficient (CORE,NCAR) ln_cdgw = ', ln_cdgw |
|---|
| 162 | ENDIF |
|---|
| 163 | ! |
|---|
| 164 | IF( .NOT.ln_wave ) THEN |
|---|
| 165 | ln_sdw = .false. ; ln_cdgw = .false. ; ln_tauwoc = .false. ; ln_tauw = .false. ; ln_stcor = .false. |
|---|
| 166 | ENDIF |
|---|
| 167 | IF( ln_sdw ) THEN |
|---|
| 168 | IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) & |
|---|
| 169 | CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' ) |
|---|
| 170 | ENDIF |
|---|
| 171 | ll_st_bv2014 = ( nn_sdrift==jp_breivik_2014 ) |
|---|
| 172 | ll_st_li2017 = ( nn_sdrift==jp_li_2017 ) |
|---|
| 173 | ll_st_bv_li = ( ll_st_bv2014 .OR. ll_st_li2017 ) |
|---|
| 174 | ll_st_peakfr = ( nn_sdrift==jp_peakfr ) |
|---|
| 175 | IF( ln_tauwoc .AND. ln_tauw ) & |
|---|
| 176 | CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', & |
|---|
| 177 | '(ln_tauwoc=.true. and ln_tauw=.true.)' ) |
|---|
| 178 | IF( ln_tauwoc ) & |
|---|
| 179 | CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' ) |
|---|
| 180 | IF( ln_tauw ) & |
|---|
| 181 | CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', & |
|---|
| 182 | 'This will override any other specification of the ocean stress' ) |
|---|
| 183 | ! |
|---|
| 184 | IF( .NOT.ln_usr ) THEN ! the model calendar needs some specificities (except in user defined case) |
|---|
| 185 | IF( MOD( rday , rdt ) /= 0. ) CALL ctl_stop( 'the time step must devide the number of second of in a day' ) |
|---|
| 186 | IF( MOD( rday , 2. ) /= 0. ) CALL ctl_stop( 'the number of second of in a day must be an even number' ) |
|---|
| 187 | IF( MOD( rdt , 2. ) /= 0. ) CALL ctl_stop( 'the time step (in second) must be an even number' ) |
|---|
| 188 | ENDIF |
|---|
| 189 | ! !** check option consistency |
|---|
| 190 | ! |
|---|
| 191 | IF(lwp) WRITE(numout,*) !* Single / Multi - executable (NEMO / OPA+SAS) |
|---|
| 192 | SELECT CASE( nn_components ) |
|---|
| 193 | CASE( jp_iam_nemo ) |
|---|
| 194 | IF(lwp) WRITE(numout,*) ' ==>>> NEMO configured as a single executable (i.e. including both OPA and Surface module)' |
|---|
| 195 | CASE( jp_iam_opa ) |
|---|
| 196 | IF(lwp) WRITE(numout,*) ' ==>>> Multi executable configuration. Here, OPA component' |
|---|
| 197 | IF( .NOT.lk_oasis ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 198 | IF( ln_cpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' ) |
|---|
| 199 | IF( ln_mixcpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 200 | CASE( jp_iam_sas ) |
|---|
| 201 | IF(lwp) WRITE(numout,*) ' ==>>> Multi executable configuration. Here, SAS component' |
|---|
| 202 | IF( .NOT.lk_oasis ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 203 | IF( ln_mixcpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 204 | CASE DEFAULT |
|---|
| 205 | CALL ctl_stop( 'sbc_init : unsupported value for nn_components' ) |
|---|
| 206 | END SELECT |
|---|
| 207 | ! !* coupled options |
|---|
| 208 | IF( ln_cpl ) THEN |
|---|
| 209 | IF( .NOT. lk_oasis ) CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)', & |
|---|
| 210 | & ' required to defined key_oasis3' ) |
|---|
| 211 | ENDIF |
|---|
| 212 | IF( ln_mixcpl ) THEN |
|---|
| 213 | IF( .NOT. lk_oasis ) CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ', & |
|---|
| 214 | & ' required to defined key_oasis3' ) |
|---|
| 215 | IF( .NOT.ln_cpl ) CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' ) |
|---|
| 216 | IF( nn_components /= jp_iam_nemo ) & |
|---|
| 217 | & CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ', & |
|---|
| 218 | & ' not yet working with sas-opa coupling via oasis' ) |
|---|
| 219 | ENDIF |
|---|
| 220 | ! !* sea-ice |
|---|
| 221 | SELECT CASE( nn_ice ) |
|---|
| 222 | CASE( 0 ) !- no ice in the domain |
|---|
| 223 | CASE( 1 ) !- Ice-cover climatology ("Ice-if" model) |
|---|
| 224 | CASE( 2 ) !- SI3 ice model |
|---|
| 225 | CASE( 3 ) !- CICE ice model |
|---|
| 226 | IF( .NOT.( ln_blk .OR. ln_cpl ) ) CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' ) |
|---|
| 227 | IF( lk_agrif ) CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 228 | CASE DEFAULT !- not supported |
|---|
| 229 | END SELECT |
|---|
| 230 | IF( ln_diurnal .AND. .NOT. ln_blk ) CALL ctl_stop( "sbc_init: diurnal flux processing only implemented for bulk forcing" ) |
|---|
| 231 | ! |
|---|
| 232 | ! !** allocate and set required variables |
|---|
| 233 | ! |
|---|
| 234 | ! !* allocate sbc arrays |
|---|
| 235 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 236 | #if ! defined key_si3 && ! defined key_cice |
|---|
| 237 | IF( sbc_ice_alloc() /= 0 ) CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' ) |
|---|
| 238 | #endif |
|---|
| 239 | ! |
|---|
| 240 | IF( nn_ice == 0 ) THEN !* No sea-ice in the domain : ice fraction is always zero |
|---|
| 241 | IF( nn_components /= jp_iam_opa ) fr_i(:,:) = 0._wp ! except for OPA in SAS-OPA coupled case |
|---|
| 242 | ENDIF |
|---|
| 243 | ! |
|---|
| 244 | sfx (:,:) = 0._wp !* salt flux due to freezing/melting |
|---|
| 245 | fmmflx(:,:) = 0._wp !* freezing minus melting flux |
|---|
| 246 | |
|---|
| 247 | taum(:,:) = 0._wp !* wind stress module (needed in GLS in case of reduced restart) |
|---|
| 248 | |
|---|
| 249 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 250 | IF( ln_dm2dc ) THEN !* daily mean to diurnal cycle |
|---|
| 251 | nday_qsr = -1 ! allow initialization at the 1st call |
|---|
| 252 | IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa ) & |
|---|
| 253 | & CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' ) |
|---|
| 254 | ENDIF |
|---|
| 255 | ! !* Choice of the Surface Boudary Condition |
|---|
| 256 | ! (set nsbc) |
|---|
| 257 | ! |
|---|
| 258 | ll_purecpl = ln_cpl .AND. .NOT.ln_mixcpl |
|---|
| 259 | ll_opa = nn_components == jp_iam_opa |
|---|
| 260 | ll_not_nemo = nn_components /= jp_iam_nemo |
|---|
| 261 | icpt = 0 |
|---|
| 262 | ! |
|---|
| 263 | IF( ln_usr ) THEN ; nsbc = jp_usr ; icpt = icpt + 1 ; ENDIF ! user defined formulation |
|---|
| 264 | IF( ln_flx ) THEN ; nsbc = jp_flx ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 265 | IF( ln_blk ) THEN ; nsbc = jp_blk ; icpt = icpt + 1 ; ENDIF ! bulk formulation |
|---|
| 266 | IF( ll_purecpl ) THEN ; nsbc = jp_purecpl ; icpt = icpt + 1 ; ENDIF ! Pure Coupled formulation |
|---|
| 267 | IF( ll_opa ) THEN ; nsbc = jp_none ; icpt = icpt + 1 ; ENDIF ! opa coupling via SAS module |
|---|
| 268 | ! |
|---|
| 269 | IF( icpt /= 1 ) CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' ) |
|---|
| 270 | ! |
|---|
| 271 | IF(lwp) THEN !- print the choice of surface flux formulation |
|---|
| 272 | WRITE(numout,*) |
|---|
| 273 | SELECT CASE( nsbc ) |
|---|
| 274 | CASE( jp_usr ) ; WRITE(numout,*) ' ==>>> user defined forcing formulation' |
|---|
| 275 | CASE( jp_flx ) ; WRITE(numout,*) ' ==>>> flux formulation' |
|---|
| 276 | CASE( jp_blk ) ; WRITE(numout,*) ' ==>>> bulk formulation' |
|---|
| 277 | CASE( jp_purecpl ) ; WRITE(numout,*) ' ==>>> pure coupled formulation' |
|---|
| 278 | !!gm abusive use of jp_none ?? ===>>> need to be check and changed by adding a jp_sas parameter |
|---|
| 279 | CASE( jp_none ) ; WRITE(numout,*) ' ==>>> OPA coupled to SAS via oasis' |
|---|
| 280 | IF( ln_mixcpl ) WRITE(numout,*) ' + forced-coupled mixed formulation' |
|---|
| 281 | END SELECT |
|---|
| 282 | IF( ll_not_nemo ) WRITE(numout,*) ' + OASIS coupled SAS' |
|---|
| 283 | ENDIF |
|---|
| 284 | ! |
|---|
| 285 | ! !* OASIS initialization |
|---|
| 286 | ! |
|---|
| 287 | IF( lk_oasis ) CALL sbc_cpl_init( nn_ice ) ! Must be done before: (1) first time step |
|---|
| 288 | ! ! (2) the use of nn_fsbc |
|---|
| 289 | ! nn_fsbc initialization if OPA-SAS coupling via OASIS |
|---|
| 290 | ! SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly |
|---|
| 291 | IF( nn_components /= jp_iam_nemo ) THEN |
|---|
| 292 | IF( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt) |
|---|
| 293 | IF( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt) |
|---|
| 294 | ! |
|---|
| 295 | IF(lwp)THEN |
|---|
| 296 | WRITE(numout,*) |
|---|
| 297 | WRITE(numout,*)" OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc |
|---|
| 298 | WRITE(numout,*) |
|---|
| 299 | ENDIF |
|---|
| 300 | ENDIF |
|---|
| 301 | ! |
|---|
| 302 | ! !* check consistency between model timeline and nn_fsbc |
|---|
| 303 | IF( ln_rst_list .OR. nn_stock /= -1 ) THEN ! we will do restart files |
|---|
| 304 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 ) THEN |
|---|
| 305 | WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 306 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 307 | ENDIF |
|---|
| 308 | IF( .NOT. ln_rst_list .AND. MOD( nn_stock, nn_fsbc) /= 0 ) THEN ! we don't use nn_stock if ln_rst_list |
|---|
| 309 | WRITE(ctmp1,*) 'sbc_init : nn_stock (', nn_stock, ') is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 310 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 311 | ENDIF |
|---|
| 312 | ENDIF |
|---|
| 313 | ! |
|---|
| 314 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 315 | & CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 316 | ! |
|---|
| 317 | IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8 ) & |
|---|
| 318 | & CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 319 | ! |
|---|
| 320 | |
|---|
| 321 | ! !** associated modules : initialization |
|---|
| 322 | ! |
|---|
| 323 | CALL sbc_ssm_init ( Kbb, Kmm ) ! Sea-surface mean fields initialization |
|---|
| 324 | ! |
|---|
| 325 | IF( l_sbc_clo ) CALL sbc_clo_init ! closed sea surface initialisation |
|---|
| 326 | ! |
|---|
| 327 | IF( ln_blk ) CALL sbc_blk_init ! bulk formulae initialization |
|---|
| 328 | |
|---|
| 329 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialization |
|---|
| 330 | ! |
|---|
| 331 | ! |
|---|
| 332 | CALL sbc_rnf_init( Kmm ) ! Runof initialization |
|---|
| 333 | ! |
|---|
| 334 | IF( ln_apr_dyn ) CALL sbc_apr_init ! Atmo Pressure Forcing initialization |
|---|
| 335 | ! |
|---|
| 336 | #if defined key_si3 |
|---|
| 337 | IF( lk_agrif .AND. nn_ice == 0 ) THEN ! allocate ice arrays in case agrif + ice-model + no-ice in child grid |
|---|
| 338 | IF( sbc_ice_alloc() /= 0 ) CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' ) |
|---|
| 339 | ELSEIF( nn_ice == 2 ) THEN |
|---|
| 340 | CALL ice_init( Kbb, Kmm, Kaa ) ! ICE initialization |
|---|
| 341 | ENDIF |
|---|
| 342 | #endif |
|---|
| 343 | IF( nn_ice == 3 ) CALL cice_sbc_init( nsbc, Kbb, Kmm ) ! CICE initialization |
|---|
| 344 | ! |
|---|
| 345 | IF( ln_wave ) CALL sbc_wave_init ! surface wave initialisation |
|---|
| 346 | ! |
|---|
| 347 | IF( lwxios ) THEN |
|---|
| 348 | CALL iom_set_rstw_var_active('utau_b') |
|---|
| 349 | CALL iom_set_rstw_var_active('vtau_b') |
|---|
| 350 | CALL iom_set_rstw_var_active('qns_b') |
|---|
| 351 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 352 | ! CALL iom_set_rstw_var_active('qsr_b') |
|---|
| 353 | CALL iom_set_rstw_var_active('emp_b') |
|---|
| 354 | CALL iom_set_rstw_var_active('sfx_b') |
|---|
| 355 | ENDIF |
|---|
| 356 | |
|---|
| 357 | END SUBROUTINE sbc_init |
|---|
| 358 | |
|---|
| 359 | |
|---|
| 360 | SUBROUTINE sbc( kt, Kbb, Kmm ) |
|---|
| 361 | !!--------------------------------------------------------------------- |
|---|
| 362 | !! *** ROUTINE sbc *** |
|---|
| 363 | !! |
|---|
| 364 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 365 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 366 | !! |
|---|
| 367 | !! ** Method : blah blah to be written ????????? |
|---|
| 368 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 369 | !! |
|---|
| 370 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 371 | !! time step, i.e. |
|---|
| 372 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 373 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 374 | !! - updte the ice fraction : fr_i |
|---|
| 375 | !!---------------------------------------------------------------------- |
|---|
| 376 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 377 | INTEGER, INTENT(in) :: Kbb, Kmm ! ocean time level indices |
|---|
| 378 | ! |
|---|
| 379 | LOGICAL :: ll_sas, ll_opa ! local logical |
|---|
| 380 | ! |
|---|
| 381 | REAL(wp) :: zthscl ! wd tanh scale |
|---|
| 382 | REAL(wp), DIMENSION(jpi,jpj) :: zwdht, zwght ! wd dep over wd limit, wgt |
|---|
| 383 | |
|---|
| 384 | !!--------------------------------------------------------------------- |
|---|
| 385 | ! |
|---|
| 386 | IF( ln_timing ) CALL timing_start('sbc') |
|---|
| 387 | ! |
|---|
| 388 | ! ! ---------------------------------------- ! |
|---|
| 389 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 390 | ! ! ---------------------------------------- ! |
|---|
| 391 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 392 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 393 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 394 | emp_b (:,:) = emp (:,:) |
|---|
| 395 | sfx_b (:,:) = sfx (:,:) |
|---|
| 396 | IF ( ln_rnf ) THEN |
|---|
| 397 | rnf_b (:,: ) = rnf (:,: ) |
|---|
| 398 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) |
|---|
| 399 | ENDIF |
|---|
| 400 | ! |
|---|
| 401 | ENDIF |
|---|
| 402 | ! ! ---------------------------------------- ! |
|---|
| 403 | ! ! forcing field computation ! |
|---|
| 404 | ! ! ---------------------------------------- ! |
|---|
| 405 | ! |
|---|
| 406 | ll_sas = nn_components == jp_iam_sas ! component flags |
|---|
| 407 | ll_opa = nn_components == jp_iam_opa |
|---|
| 408 | ! |
|---|
| 409 | IF( .NOT.ll_sas ) CALL sbc_ssm ( kt, Kbb, Kmm ) ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 410 | IF( ln_wave ) CALL sbc_wave( kt, Kmm ) ! surface waves |
|---|
| 411 | |
|---|
| 412 | ! |
|---|
| 413 | ! !== sbc formulation ==! |
|---|
| 414 | ! |
|---|
| 415 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 416 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 417 | CASE( jp_usr ) ; CALL usrdef_sbc_oce( kt, Kbb ) ! user defined formulation |
|---|
| 418 | CASE( jp_flx ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 419 | CASE( jp_blk ) |
|---|
| 420 | IF( ll_sas ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice, Kbb, Kmm ) ! OPA-SAS coupling: SAS receiving fields from OPA |
|---|
| 421 | CALL sbc_blk ( kt ) ! bulk formulation for the ocean |
|---|
| 422 | ! |
|---|
| 423 | CASE( jp_purecpl ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice, Kbb, Kmm ) ! pure coupled formulation |
|---|
| 424 | CASE( jp_none ) |
|---|
| 425 | IF( ll_opa ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice, Kbb, Kmm ) ! OPA-SAS coupling: OPA receiving fields from SAS |
|---|
| 426 | END SELECT |
|---|
| 427 | ! |
|---|
| 428 | IF( ln_mixcpl ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice, Kbb, Kmm ) ! forced-coupled mixed formulation after forcing |
|---|
| 429 | ! |
|---|
| 430 | IF ( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( ) ! Wind stress provided by waves |
|---|
| 431 | ! |
|---|
| 432 | ! !== Misc. Options ==! |
|---|
| 433 | ! |
|---|
| 434 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 435 | CASE( 1 ) ; CALL sbc_ice_if ( kt, Kbb, Kmm ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 436 | #if defined key_si3 |
|---|
| 437 | CASE( 2 ) ; CALL ice_stp ( kt, Kbb, Kmm, nsbc ) ! SI3 ice model |
|---|
| 438 | #endif |
|---|
| 439 | CASE( 3 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 440 | END SELECT |
|---|
| 441 | |
|---|
| 442 | IF( ln_icebergs ) THEN |
|---|
| 443 | CALL icb_stp( kt ) ! compute icebergs |
|---|
| 444 | ! icebergs may advect into haloes during the icb step and alter emp. |
|---|
| 445 | ! A lbc_lnk is necessary here to ensure restartability (#2113) |
|---|
| 446 | IF( .NOT. ln_passive_mode ) CALL lbc_lnk( 'sbcmod', emp, 'T', 1. ) ! ensure restartability with icebergs |
|---|
| 447 | ENDIF |
|---|
| 448 | |
|---|
| 449 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 450 | |
|---|
| 451 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 452 | |
|---|
| 453 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc, Kmm ) ! control the freshwater budget |
|---|
| 454 | |
|---|
| 455 | ! Special treatment of freshwater fluxes over closed seas in the model domain |
|---|
| 456 | ! Should not be run if ln_diurnal_only |
|---|
| 457 | IF( l_sbc_clo ) CALL sbc_clo( kt ) |
|---|
| 458 | |
|---|
| 459 | !!$!RBbug do not understand why see ticket 667 |
|---|
| 460 | !!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why. |
|---|
| 461 | !!$ CALL lbc_lnk( 'sbcmod', emp, 'T', 1. ) |
|---|
| 462 | IF ( ll_wd ) THEN ! If near WAD point limit the flux for now |
|---|
| 463 | zthscl = atanh(rn_wd_sbcfra) ! taper frac default is .999 |
|---|
| 464 | zwdht(:,:) = ssh(:,:,Kmm) + ht_0(:,:) - rn_wdmin1 ! do this calc of water |
|---|
| 465 | ! depth above wd limit once |
|---|
| 466 | WHERE( zwdht(:,:) <= 0.0 ) |
|---|
| 467 | taum(:,:) = 0.0 |
|---|
| 468 | utau(:,:) = 0.0 |
|---|
| 469 | vtau(:,:) = 0.0 |
|---|
| 470 | qns (:,:) = 0.0 |
|---|
| 471 | qsr (:,:) = 0.0 |
|---|
| 472 | emp (:,:) = min(emp(:,:),0.0) !can allow puddles to grow but not shrink |
|---|
| 473 | sfx (:,:) = 0.0 |
|---|
| 474 | END WHERE |
|---|
| 475 | zwght(:,:) = tanh(zthscl*zwdht(:,:)) |
|---|
| 476 | WHERE( zwdht(:,:) > 0.0 .and. zwdht(:,:) < rn_wd_sbcdep ) ! 5 m hard limit here is arbitrary |
|---|
| 477 | qsr (:,:) = qsr(:,:) * zwght(:,:) |
|---|
| 478 | qns (:,:) = qns(:,:) * zwght(:,:) |
|---|
| 479 | taum (:,:) = taum(:,:) * zwght(:,:) |
|---|
| 480 | utau (:,:) = utau(:,:) * zwght(:,:) |
|---|
| 481 | vtau (:,:) = vtau(:,:) * zwght(:,:) |
|---|
| 482 | sfx (:,:) = sfx(:,:) * zwght(:,:) |
|---|
| 483 | emp (:,:) = emp(:,:) * zwght(:,:) |
|---|
| 484 | END WHERE |
|---|
| 485 | ENDIF |
|---|
| 486 | ! |
|---|
| 487 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 488 | ! ! ---------------------------------------- ! |
|---|
| 489 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 490 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 491 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 492 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, ldxios = lrxios ) ! before i-stress (U-point) |
|---|
| 493 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, ldxios = lrxios ) ! before j-stress (V-point) |
|---|
| 494 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b, ldxios = lrxios ) ! before non solar heat flux (T-point) |
|---|
| 495 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 496 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, ldxios = lrxios ) ! before solar heat flux (T-point) |
|---|
| 497 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, ldxios = lrxios ) ! before freshwater flux (T-point) |
|---|
| 498 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 499 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 500 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, ldxios = lrxios ) ! before salt flux (T-point) |
|---|
| 501 | ELSE |
|---|
| 502 | sfx_b (:,:) = sfx(:,:) |
|---|
| 503 | ENDIF |
|---|
| 504 | ELSE !* no restart: set from nit000 values |
|---|
| 505 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 506 | utau_b(:,:) = utau(:,:) |
|---|
| 507 | vtau_b(:,:) = vtau(:,:) |
|---|
| 508 | qns_b (:,:) = qns (:,:) |
|---|
| 509 | emp_b (:,:) = emp (:,:) |
|---|
| 510 | sfx_b (:,:) = sfx (:,:) |
|---|
| 511 | ENDIF |
|---|
| 512 | ENDIF |
|---|
| 513 | ! ! ---------------------------------------- ! |
|---|
| 514 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 515 | ! ! ---------------------------------------- ! |
|---|
| 516 | IF(lwp) WRITE(numout,*) |
|---|
| 517 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 518 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 519 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 520 | IF( lwxios ) CALL iom_swap( cwxios_context ) |
|---|
| 521 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios ) |
|---|
| 522 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios ) |
|---|
| 523 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns, ldxios = lwxios ) |
|---|
| 524 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 525 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 526 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp, ldxios = lwxios ) |
|---|
| 527 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx, ldxios = lwxios ) |
|---|
| 528 | IF( lwxios ) CALL iom_swap( cxios_context ) |
|---|
| 529 | ENDIF |
|---|
| 530 | ! ! ---------------------------------------- ! |
|---|
| 531 | ! ! Outputs and control print ! |
|---|
| 532 | ! ! ---------------------------------------- ! |
|---|
| 533 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 534 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 535 | CALL iom_put( "empbmr" , emp_b - rnf ) ! before upward water flux ( needed to recalculate the time evolution of ssh in offline ) |
|---|
| 536 | CALL iom_put( "saltflx", sfx ) ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case) |
|---|
| 537 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 538 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 539 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 540 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 541 | IF( nn_ice > 0 .OR. ll_opa ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 542 | CALL iom_put( "taum" , taum ) ! wind stress module |
|---|
| 543 | CALL iom_put( "wspd" , wndm ) ! wind speed module over free ocean or leads in presence of sea-ice |
|---|
| 544 | ENDIF |
|---|
| 545 | ! |
|---|
| 546 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at each time step in sea-ice) |
|---|
| 547 | CALL iom_put( "vtau", vtau ) ! j-wind stress |
|---|
| 548 | ! |
|---|
| 549 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 550 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask ) |
|---|
| 551 | CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask ) |
|---|
| 552 | CALL prt_ctl(tab2d_1=(sfx-rnf) , clinfo1=' sfx-rnf - : ', mask1=tmask ) |
|---|
| 553 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask ) |
|---|
| 554 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask ) |
|---|
| 555 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, kdim=jpk ) |
|---|
| 556 | CALL prt_ctl(tab3d_1=ts(:,:,:,jp_tem,Kmm), clinfo1=' sst - : ', mask1=tmask, kdim=1 ) |
|---|
| 557 | CALL prt_ctl(tab3d_1=ts(:,:,:,jp_sal,Kmm), clinfo1=' sss - : ', mask1=tmask, kdim=1 ) |
|---|
| 558 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 559 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask ) |
|---|
| 560 | ENDIF |
|---|
| 561 | |
|---|
| 562 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 563 | ! |
|---|
| 564 | IF( ln_timing ) CALL timing_stop('sbc') |
|---|
| 565 | ! |
|---|
| 566 | END SUBROUTINE sbc |
|---|
| 567 | |
|---|
| 568 | |
|---|
| 569 | SUBROUTINE sbc_final |
|---|
| 570 | !!--------------------------------------------------------------------- |
|---|
| 571 | !! *** ROUTINE sbc_final *** |
|---|
| 572 | !! |
|---|
| 573 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 574 | !!--------------------------------------------------------------------- |
|---|
| 575 | ! |
|---|
| 576 | IF( nn_ice == 3 ) CALL cice_sbc_final |
|---|
| 577 | ! |
|---|
| 578 | END SUBROUTINE sbc_final |
|---|
| 579 | |
|---|
| 580 | !!====================================================================== |
|---|
| 581 | END MODULE sbcmod |
|---|
